?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
2015-09-28 Paul Thomas <pault@gcc.gnu.org>
[official-gcc.git] / gcc / ada / lib-load.adb
blob83d3576eeb6f1e56813491b5f073abc99d1ce6f6
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- L I B . L O A D --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2015, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 with Atree; use Atree;
27 with Debug; use Debug;
28 with Einfo; use Einfo;
29 with Errout; use Errout;
30 with Fname; use Fname;
31 with Fname.UF; use Fname.UF;
32 with Nlists; use Nlists;
33 with Nmake; use Nmake;
34 with Opt; use Opt;
35 with Osint; use Osint;
36 with Osint.C; use Osint.C;
37 with Output; use Output;
38 with Par;
39 with Restrict; use Restrict;
40 with Scn; use Scn;
41 with Sinfo; use Sinfo;
42 with Sinput; use Sinput;
43 with Sinput.L; use Sinput.L;
44 with Stand; use Stand;
45 with Tbuild; use Tbuild;
46 with Uname; use Uname;
47
48 package body Lib.Load is
49
50 -----------------------
51 -- Local Subprograms --
52 -----------------------
53
54 function From_Limited_With_Chain return Boolean;
55 -- Check whether a possible circular dependence includes units that
56 -- have been loaded through limited_with clauses, in which case there
57 -- is no real circularity.
58
59 function Spec_Is_Irrelevant
60 (Spec_Unit : Unit_Number_Type;
61 Body_Unit : Unit_Number_Type) return Boolean;
62 -- The Spec_Unit and Body_Unit parameters are the unit numbers of the
63 -- spec file that corresponds to the main unit which is a body. This
64 -- function determines if the spec file is irrelevant and will be
65 -- overridden by the body as described in RM 10.1.4(4). See description
66 -- in "Special Handling of Subprogram Bodies" for further details.
67
68 procedure Write_Dependency_Chain;
69 -- This procedure is used to generate error message info lines that
70 -- trace the current dependency chain when a load error occurs.
71
72 ------------------------------
73 -- Change_Main_Unit_To_Spec --
74 ------------------------------
75
76 procedure Change_Main_Unit_To_Spec is
77 U : Unit_Record renames Units.Table (Main_Unit);
78 N : File_Name_Type;
79 X : Source_File_Index;
80
81 begin
82 -- Get name of unit body
83
84 Get_Name_String (U.Unit_File_Name);
85
86 -- Note: for the following we should really generalize and consult the
87 -- file name pattern data, but for now we just deal with the common
88 -- naming cases, which is probably good enough in practice ???
89
90 -- Change .adb to .ads
91
92 if Name_Len >= 5
93 and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".adb"
94 then
95 Name_Buffer (Name_Len) := 's';
96
97 -- Change .2.ada to .1.ada (Rational convention)
98
99 elsif Name_Len >= 7
100 and then Name_Buffer (Name_Len - 5 .. Name_Len) = ".2.ada"
101 then
102 Name_Buffer (Name_Len - 4) := '1';
103
104 -- Change .ada to _.ada (DEC convention)
105
106 elsif Name_Len >= 5
107 and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".ada"
108 then
109 Name_Buffer (Name_Len - 3 .. Name_Len + 1) := "_.ada";
110 Name_Len := Name_Len + 1;
111
112 -- No match, don't make the change
113
114 else
115 return;
116 end if;
117
118 -- Try loading the spec
119
120 N := Name_Find;
121 X := Load_Source_File (N);
122
123 -- No change if we did not find the spec
124
125 if X = No_Source_File then
126 return;
127 end if;
128
129 -- Otherwise modify Main_Unit entry to point to spec
130
131 U.Unit_File_Name := N;
132 U.Source_Index := X;
133 end Change_Main_Unit_To_Spec;
134
135 -------------------------------
136 -- Create_Dummy_Package_Unit --
137 -------------------------------
138
139 function Create_Dummy_Package_Unit
140 (With_Node : Node_Id;
141 Spec_Name : Unit_Name_Type) return Unit_Number_Type
142 is
143 Unum : Unit_Number_Type;
144 Cunit_Entity : Entity_Id;
145 Cunit : Node_Id;
146 Du_Name : Node_Or_Entity_Id;
147 End_Lab : Node_Id;
148 Save_CS : constant Boolean := Get_Comes_From_Source_Default;
149
150 begin
151 -- The created dummy package unit does not come from source
152
153 Set_Comes_From_Source_Default (False);
154
155 -- Normal package
156
157 if Nkind (Name (With_Node)) = N_Identifier then
158 Cunit_Entity :=
159 Make_Defining_Identifier (No_Location,
160 Chars => Chars (Name (With_Node)));
161 Du_Name := Cunit_Entity;
162 End_Lab := New_Occurrence_Of (Cunit_Entity, No_Location);
163
164 -- Child package
165
166 else
167 Cunit_Entity :=
168 Make_Defining_Identifier (No_Location,
169 Chars => Chars (Selector_Name (Name (With_Node))));
170 Du_Name :=
171 Make_Defining_Program_Unit_Name (No_Location,
172 Name => Copy_Separate_Tree (Prefix (Name (With_Node))),
173 Defining_Identifier => Cunit_Entity);
174
175 Set_Is_Child_Unit (Cunit_Entity);
176
177 End_Lab :=
178 Make_Designator (No_Location,
179 Name => Copy_Separate_Tree (Prefix (Name (With_Node))),
180 Identifier => New_Occurrence_Of (Cunit_Entity, No_Location));
181 end if;
182
183 Set_Scope (Cunit_Entity, Standard_Standard);
184
185 Cunit :=
186 Make_Compilation_Unit (No_Location,
187 Context_Items => Empty_List,
188 Unit =>
189 Make_Package_Declaration (No_Location,
190 Specification =>
191 Make_Package_Specification (No_Location,
192 Defining_Unit_Name => Du_Name,
193 Visible_Declarations => Empty_List,
194 End_Label => End_Lab)),
195 Aux_Decls_Node =>
196 Make_Compilation_Unit_Aux (No_Location));
197
198 -- Mark the dummy package as analyzed to prevent analysis of this
199 -- (non-existent) unit in -gnatQ mode because at the moment the
200 -- structure and attributes of this dummy package does not allow
201 -- a normal analysis of this unit
202
203 Set_Analyzed (Cunit);
204
205 Units.Increment_Last;
206 Unum := Units.Last;
207
208 Units.Table (Unum) := (
209 Cunit => Cunit,
210 Cunit_Entity => Cunit_Entity,
211 Dependency_Num => 0,
212 Dynamic_Elab => False,
213 Error_Location => Sloc (With_Node),
214 Expected_Unit => Spec_Name,
215 Fatal_Error => Error_Detected,
216 Generate_Code => False,
217 Has_RACW => False,
218 Filler => False,
219 Ident_String => Empty,
220 Loading => False,
221 Main_Priority => Default_Main_Priority,
222 Main_CPU => Default_Main_CPU,
223 Munit_Index => 0,
224 No_Elab_Code_All => False,
225 Serial_Number => 0,
226 Source_Index => No_Source_File,
227 Unit_File_Name => Get_File_Name (Spec_Name, Subunit => False),
228 Unit_Name => Spec_Name,
229 Version => 0,
230 OA_Setting => 'O',
231 SPARK_Mode_Pragma => Empty);
232
233 Set_Comes_From_Source_Default (Save_CS);
234 Set_Error_Posted (Cunit_Entity);
235 Set_Error_Posted (Cunit);
236 return Unum;
237 end Create_Dummy_Package_Unit;
238
239 -----------------------------
240 -- From_Limited_With_Chain --
241 -----------------------------
242
243 function From_Limited_With_Chain return Boolean is
244 Curr_Num : constant Unit_Number_Type :=
245 Load_Stack.Table (Load_Stack.Last).Unit_Number;
246
247 begin
248 -- True if the current load operation is through a limited_with clause
249 -- and we are not within a loop of regular with_clauses.
250
251 for U in reverse Load_Stack.First .. Load_Stack.Last - 1 loop
252 if Load_Stack.Table (U).Unit_Number = Curr_Num then
253 return False;
254
255 elsif Present (Load_Stack.Table (U).With_Node)
256 and then Limited_Present (Load_Stack.Table (U).With_Node)
257 then
258 return True;
259 end if;
260 end loop;
261
262 return False;
263 end From_Limited_With_Chain;
264
265 ----------------
266 -- Initialize --
267 ----------------
268
269 procedure Initialize is
270 begin
271 Units.Init;
272 Load_Stack.Init;
273 end Initialize;
274
275 ------------------------
276 -- Initialize_Version --
277 ------------------------
278
279 procedure Initialize_Version (U : Unit_Number_Type) is
280 begin
281 Units.Table (U).Version := Source_Checksum (Source_Index (U));
282 end Initialize_Version;
283
284 ----------------------
285 -- Load_Main_Source --
286 ----------------------
287
288 procedure Load_Main_Source is
289 Fname : File_Name_Type;
290 Version : Word := 0;
291
292 begin
293 Load_Stack.Increment_Last;
294 Load_Stack.Table (Load_Stack.Last) := (Main_Unit, Empty);
295
296 -- Initialize unit table entry for Main_Unit. Note that we don't know
297 -- the unit name yet, that gets filled in when the parser parses the
298 -- main unit, at which time a check is made that it matches the main
299 -- file name, and then the Unit_Name field is set. The Cunit and
300 -- Cunit_Entity fields also get filled in later by the parser.
301
302 Units.Increment_Last;
303 Fname := Next_Main_Source;
304
305 Units.Table (Main_Unit).Unit_File_Name := Fname;
306
307 if Fname /= No_File then
308 Main_Source_File := Load_Source_File (Fname);
309 Current_Error_Source_File := Main_Source_File;
310
311 if Main_Source_File /= No_Source_File then
312 Version := Source_Checksum (Main_Source_File);
313 end if;
314
315 Units.Table (Main_Unit) := (
316 Cunit => Empty,
317 Cunit_Entity => Empty,
318 Dependency_Num => 0,
319 Dynamic_Elab => False,
320 Error_Location => No_Location,
321 Expected_Unit => No_Unit_Name,
322 Fatal_Error => None,
323 Generate_Code => False,
324 Has_RACW => False,
325 Filler => False,
326 Ident_String => Empty,
327 Loading => True,
328 Main_Priority => Default_Main_Priority,
329 Main_CPU => Default_Main_CPU,
330 Munit_Index => 0,
331 No_Elab_Code_All => False,
332 Serial_Number => 0,
333 Source_Index => Main_Source_File,
334 Unit_File_Name => Fname,
335 Unit_Name => No_Unit_Name,
336 Version => Version,
337 OA_Setting => 'O',
338 SPARK_Mode_Pragma => Empty);
339 end if;
340 end Load_Main_Source;
341
342 ---------------
343 -- Load_Unit --
344 ---------------
345
346 function Load_Unit
347 (Load_Name : Unit_Name_Type;
348 Required : Boolean;
349 Error_Node : Node_Id;
350 Subunit : Boolean;
351 Corr_Body : Unit_Number_Type := No_Unit;
352 Renamings : Boolean := False;
353 With_Node : Node_Id := Empty;
354 PMES : Boolean := False) return Unit_Number_Type
355 is
356 Calling_Unit : Unit_Number_Type;
357 Uname_Actual : Unit_Name_Type;
358 Unum : Unit_Number_Type;
359 Unump : Unit_Number_Type;
360 Fname : File_Name_Type;
361 Src_Ind : Source_File_Index;
362 Save_PMES : constant Boolean := Parsing_Main_Extended_Source;
363
364 Save_Cunit_Restrictions : constant Save_Cunit_Boolean_Restrictions :=
365 Cunit_Boolean_Restrictions_Save;
366 -- Save current restrictions for restore at end
367
368 begin
369 Parsing_Main_Extended_Source := PMES;
370
371 -- Initialize restrictions to config restrictions for unit to load if
372 -- it is part of the main extended source, otherwise reset them.
373
374 -- Note: it's a bit odd but PMES is False for subunits, which is why
375 -- we have the OR here. Should be investigated some time???
376
377 if PMES or Subunit then
378 Restore_Config_Cunit_Boolean_Restrictions;
379 else
380 Reset_Cunit_Boolean_Restrictions;
381 end if;
382
383 -- If renamings are allowed and we have a child unit name, then we
384 -- must first load the parent to deal with finding the real name.
385 -- Retain the with_clause that names the child, so that if it is
386 -- limited, the parent is loaded under the same condition.
387
388 if Renamings and then Is_Child_Name (Load_Name) then
389 Unump :=
390 Load_Unit
391 (Load_Name => Get_Parent_Spec_Name (Load_Name),
392 Required => Required,
393 Subunit => False,
394 Renamings => True,
395 Error_Node => Error_Node,
396 With_Node => With_Node);
397
398 if Unump = No_Unit then
399 Parsing_Main_Extended_Source := Save_PMES;
400 return No_Unit;
401 end if;
402
403 -- If parent is a renaming, then we use the renamed package as
404 -- the actual parent for the subsequent load operation.
405
406 if Nkind (Unit (Cunit (Unump))) = N_Package_Renaming_Declaration then
407 Uname_Actual :=
408 New_Child
409 (Load_Name, Get_Unit_Name (Name (Unit (Cunit (Unump)))));
410
411 -- If the load is for a with_clause, for visibility purposes both
412 -- the renamed entity and renaming one must be available in the
413 -- current unit: the renamed one in order to retrieve the child
414 -- unit, and the original one because it may be used as a prefix
415 -- in the body of the current unit. We add an explicit with_clause
416 -- for the original parent so that the renaming declaration is
417 -- properly loaded and analyzed.
418
419 if Present (With_Node) then
420 Insert_After (With_Node,
421 Make_With_Clause (Sloc (With_Node),
422 Name => Copy_Separate_Tree (Prefix (Name (With_Node)))));
423 end if;
424
425 -- Save the renaming entity, to establish its visibility when
426 -- installing the context. The implicit with is on this entity,
427 -- not on the package it renames. This is somewhat redundant given
428 -- the with_clause just created, but it simplifies subsequent
429 -- expansion of the current with_clause. Optimizable ???
430
431 if Nkind (Error_Node) = N_With_Clause
432 and then Nkind (Name (Error_Node)) = N_Selected_Component
433 then
434 declare
435 Par : Node_Id := Name (Error_Node);
436
437 begin
438 while Nkind (Par) = N_Selected_Component
439 and then Chars (Selector_Name (Par)) /=
440 Chars (Cunit_Entity (Unump))
441 loop
442 Par := Prefix (Par);
443 end loop;
444
445 -- Case of some intermediate parent is a renaming
446
447 if Nkind (Par) = N_Selected_Component then
448 Set_Entity (Selector_Name (Par), Cunit_Entity (Unump));
449
450 -- Case where the ultimate parent is a renaming
451
452 else
453 Set_Entity (Par, Cunit_Entity (Unump));
454 end if;
455 end;
456 end if;
457
458 -- If the parent is not a renaming, then get its name (this may
459 -- be different from the parent spec name obtained above because
460 -- of renamings higher up in the hierarchy).
461
462 else
463 Uname_Actual := New_Child (Load_Name, Unit_Name (Unump));
464 end if;
465
466 -- Here if unit to be loaded is not a child unit
467
468 else
469 Uname_Actual := Load_Name;
470 end if;
471
472 Fname := Get_File_Name (Uname_Actual, Subunit);
473
474 if Debug_Flag_L then
475 Write_Eol;
476 Write_Str ("*** Load request for unit: ");
477 Write_Unit_Name (Load_Name);
478
479 if Required then
480 Write_Str (" (Required = True)");
481 else
482 Write_Str (" (Required = False)");
483 end if;
484
485 Write_Eol;
486
487 if Uname_Actual /= Load_Name then
488 Write_Str ("*** Actual unit loaded: ");
489 Write_Unit_Name (Uname_Actual);
490 end if;
491 end if;
492
493 -- Capture error location if it is for the main unit. The idea is to
494 -- post errors on the main unit location, not the most recent unit.
495 -- Note: Unit_Name (Main_Unit) is not set if we are parsing gnat.adc.
496
497 if Present (Error_Node)
498 and then Unit_Name (Main_Unit) /= No_Unit_Name
499 then
500 -- It seems like In_Extended_Main_Source_Unit (Error_Node) would
501 -- do the trick here, but that's wrong, it is much too early to
502 -- call this routine. We are still in the parser, and the required
503 -- semantic information is not established yet. So we base the
504 -- judgment on unit names.
505
506 Get_External_Unit_Name_String (Unit_Name (Main_Unit));
507
508 declare
509 Main_Unit_Name : constant String := Name_Buffer (1 .. Name_Len);
510
511 begin
512 Get_External_Unit_Name_String
513 (Unit_Name (Get_Source_Unit (Error_Node)));
514
515 -- If the two names are identical, then for sure we are part
516 -- of the extended main unit
517
518 if Main_Unit_Name = Name_Buffer (1 .. Name_Len) then
519 Load_Msg_Sloc := Sloc (Error_Node);
520
521 -- If the load is called from a with_type clause, the error
522 -- node is correct.
523
524 -- Otherwise, check for the subunit case, and if so, consider
525 -- we have a match if one name is a prefix of the other name.
526
527 else
528 if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit
529 or else
530 Nkind (Unit (Cunit (Get_Source_Unit (Error_Node)))) =
531 N_Subunit
532 then
533 Name_Len := Integer'Min (Name_Len, Main_Unit_Name'Length);
534
535 if Name_Buffer (1 .. Name_Len)
536 =
537 Main_Unit_Name (1 .. Name_Len)
538 then
539 Load_Msg_Sloc := Sloc (Error_Node);
540 end if;
541 end if;
542 end if;
543 end;
544 end if;
545
546 -- If we are generating error messages, then capture calling unit
547
548 if Present (Error_Node) then
549 Calling_Unit := Get_Source_Unit (Error_Node);
550 else
551 Calling_Unit := No_Unit;
552 end if;
553
554 -- See if we already have an entry for this unit
555
556 Unum := Main_Unit;
557 while Unum <= Units.Last loop
558 exit when Uname_Actual = Units.Table (Unum).Unit_Name;
559 Unum := Unum + 1;
560 end loop;
561
562 -- Whether or not the entry was found, Unum is now the right value,
563 -- since it is one more than Units.Last (i.e. the index of the new
564 -- entry we will create) in the not found case.
565
566 -- A special check is necessary in the unit not found case. If the unit
567 -- is not found, but the file in which it lives has already been loaded,
568 -- then we have the problem that the file does not contain the unit that
569 -- is needed. We simply treat this as a file not found condition.
570
571 -- We skip this test in multiple unit per file mode since in this
572 -- case we can have multiple units from the same source file.
573
574 if Unum > Units.Last and then Get_Unit_Index (Uname_Actual) = 0 then
575 for J in Units.First .. Units.Last loop
576 if Fname = Units.Table (J).Unit_File_Name then
577 if Debug_Flag_L then
578 Write_Str (" file does not contain unit, Unit_Number = ");
579 Write_Int (Int (Unum));
580 Write_Eol;
581 Write_Eol;
582 end if;
583
584 if Present (Error_Node) then
585 if Is_Predefined_File_Name (Fname) then
586 Error_Msg_Unit_1 := Uname_Actual;
587 Error_Msg
588 ("$$ is not a language defined unit", Load_Msg_Sloc);
589 else
590 Error_Msg_File_1 := Fname;
591 Error_Msg_Unit_1 := Uname_Actual;
592 Error_Msg ("File{ does not contain unit$", Load_Msg_Sloc);
593 end if;
594
595 Write_Dependency_Chain;
596 Unum := No_Unit;
597 goto Done;
598
599 else
600 Unum := No_Unit;
601 goto Done;
602 end if;
603 end if;
604 end loop;
605 end if;
606
607 -- If we are proceeding with load, then make load stack entry,
608 -- and indicate the kind of with_clause responsible for the load.
609
610 Load_Stack.Increment_Last;
611 Load_Stack.Table (Load_Stack.Last) := (Unum, With_Node);
612
613 -- Case of entry already in table
614
615 if Unum <= Units.Last then
616
617 -- Here is where we check for a circular dependency, which is
618 -- an attempt to load a unit which is currently in the process
619 -- of being loaded. We do *not* care about a circular chain that
620 -- leads back to a body, because this kind of circular dependence
621 -- legitimately occurs (e.g. two package bodies that contain
622 -- inlined subprogram referenced by the other).
623
624 -- Ada 2005 (AI-50217): We also ignore limited_with clauses, because
625 -- their purpose is precisely to create legal circular structures.
626
627 if Loading (Unum)
628 and then (Is_Spec_Name (Units.Table (Unum).Unit_Name)
629 or else Acts_As_Spec (Units.Table (Unum).Cunit))
630 and then (Nkind (Error_Node) /= N_With_Clause
631 or else not Limited_Present (Error_Node))
632 and then not From_Limited_With_Chain
633 then
634 if Debug_Flag_L then
635 Write_Str (" circular dependency encountered");
636 Write_Eol;
637 end if;
638
639 if Present (Error_Node) then
640 Error_Msg ("circular unit dependency", Load_Msg_Sloc);
641 Write_Dependency_Chain;
642 else
643 Load_Stack.Decrement_Last;
644 end if;
645
646 Unum := No_Unit;
647 goto Done;
648 end if;
649
650 if Debug_Flag_L then
651 Write_Str (" unit already in file table, Unit_Number = ");
652 Write_Int (Int (Unum));
653 Write_Eol;
654 end if;
655
656 Load_Stack.Decrement_Last;
657 goto Done;
658
659 -- Unit is not already in table, so try to open the file
660
661 else
662 if Debug_Flag_L then
663 Write_Str (" attempt unit load, Unit_Number = ");
664 Write_Int (Int (Unum));
665 Write_Eol;
666 end if;
667
668 Src_Ind := Load_Source_File (Fname);
669
670 -- Make a partial entry in the file table, used even in the file not
671 -- found case to print the dependency chain including the last entry
672
673 Units.Increment_Last;
674 Units.Table (Unum).Unit_Name := Uname_Actual;
675
676 -- File was found
677
678 if Src_Ind /= No_Source_File then
679 Units.Table (Unum) := (
680 Cunit => Empty,
681 Cunit_Entity => Empty,
682 Dependency_Num => 0,
683 Dynamic_Elab => False,
684 Error_Location => Sloc (Error_Node),
685 Expected_Unit => Uname_Actual,
686 Fatal_Error => None,
687 Generate_Code => False,
688 Has_RACW => False,
689 Filler => False,
690 Ident_String => Empty,
691 Loading => True,
692 Main_Priority => Default_Main_Priority,
693 Main_CPU => Default_Main_CPU,
694 Munit_Index => 0,
695 No_Elab_Code_All => False,
696 Serial_Number => 0,
697 Source_Index => Src_Ind,
698 Unit_File_Name => Fname,
699 Unit_Name => Uname_Actual,
700 Version => Source_Checksum (Src_Ind),
701 OA_Setting => 'O',
702 SPARK_Mode_Pragma => Empty);
703
704 -- Parse the new unit
705
706 declare
707 Save_Index : constant Nat := Multiple_Unit_Index;
708 Save_PMES : constant Boolean := Parsing_Main_Extended_Source;
709
710 begin
711 Multiple_Unit_Index := Get_Unit_Index (Uname_Actual);
712 Units.Table (Unum).Munit_Index := Multiple_Unit_Index;
713 Initialize_Scanner (Unum, Source_Index (Unum));
714
715 if Calling_Unit = Main_Unit and then Subunit then
716 Parsing_Main_Extended_Source := True;
717 end if;
718
719 Discard_List (Par (Configuration_Pragmas => False));
720
721 Parsing_Main_Extended_Source := Save_PMES;
722
723 Multiple_Unit_Index := Save_Index;
724 Set_Loading (Unum, False);
725 end;
726
727 -- If spec is irrelevant, then post errors and quit
728
729 if Corr_Body /= No_Unit
730 and then Spec_Is_Irrelevant (Unum, Corr_Body)
731 then
732 Error_Msg_File_1 := Unit_File_Name (Corr_Body);
733 Error_Msg
734 ("cannot compile subprogram in file {!", Load_Msg_Sloc);
735 Error_Msg_File_1 := Unit_File_Name (Unum);
736 Error_Msg
737 ("\incorrect spec in file { must be removed first!",
738 Load_Msg_Sloc);
739 Unum := No_Unit;
740 goto Done;
741 end if;
742
743 -- If loaded unit had an error, then caller inherits setting
744
745 if Present (Error_Node) then
746 case Units.Table (Unum).Fatal_Error is
747
748 -- Nothing to do if with'ed unit had no error
749
750 when None =>
751 null;
752
753 -- If with'ed unit had a detected fatal error, propagate it
754
755 when Error_Detected =>
756 Units.Table (Calling_Unit).Fatal_Error := Error_Detected;
757
758 -- If with'ed unit had an ignored error, then propagate it
759 -- but do not overide an existring setting.
760
761 when Error_Ignored =>
762 if Units.Table (Calling_Unit).Fatal_Error = None then
763 Units.Table (Calling_Unit).Fatal_Error :=
764 Error_Ignored;
765 end if;
766 end case;
767 end if;
768
769 -- Remove load stack entry and return the entry in the file table
770
771 Load_Stack.Decrement_Last;
772
773 -- All done, return unit number
774
775 goto Done;
776
777 -- Case of file not found
778
779 else
780 if Debug_Flag_L then
781 Write_Str (" file was not found, load failed");
782 Write_Eol;
783 end if;
784
785 -- Generate message if unit required
786
787 if Required and then Present (Error_Node) then
788 if Is_Predefined_File_Name (Fname) then
789
790 -- This is a predefined library unit which is not present
791 -- in the run time. If a predefined unit is not available
792 -- it may very likely be the case that there is also pragma
793 -- Restriction forbidding its usage. This is typically the
794 -- case when building a configurable run time, where the
795 -- usage of certain run-time units is restricted by means
796 -- of both the corresponding pragma Restriction (such as
797 -- No_Calendar), and by not including the unit. Hence, we
798 -- check whether this predefined unit is forbidden, so that
799 -- the message about the restriction violation is generated,
800 -- if needed.
801
802 Check_Restricted_Unit (Load_Name, Error_Node);
803
804 Error_Msg_Unit_1 := Uname_Actual;
805 Error_Msg -- CODEFIX
806 ("$$ is not a predefined library unit", Load_Msg_Sloc);
807
808 else
809 Error_Msg_File_1 := Fname;
810 Error_Msg ("file{ not found", Load_Msg_Sloc);
811 end if;
812
813 Write_Dependency_Chain;
814
815 -- Remove unit from stack, to avoid cascaded errors on
816 -- subsequent missing files.
817
818 Load_Stack.Decrement_Last;
819 Units.Decrement_Last;
820
821 -- If unit not required, remove load stack entry and the junk
822 -- file table entry, and return No_Unit to indicate not found,
823
824 else
825 Load_Stack.Decrement_Last;
826 Units.Decrement_Last;
827 end if;
828
829 Unum := No_Unit;
830 goto Done;
831 end if;
832 end if;
833
834 -- Here to exit, with result in Unum
835
836 <<Done>>
837 Parsing_Main_Extended_Source := Save_PMES;
838 Cunit_Boolean_Restrictions_Restore (Save_Cunit_Restrictions);
839 return Unum;
840 end Load_Unit;
841
842 --------------------------
843 -- Make_Child_Decl_Unit --
844 --------------------------
845
846 procedure Make_Child_Decl_Unit (N : Node_Id) is
847 Unit_Decl : constant Node_Id := Library_Unit (N);
848
849 begin
850 Units.Increment_Last;
851 Units.Table (Units.Last) := Units.Table (Get_Cunit_Unit_Number (N));
852 Units.Table (Units.Last).Unit_Name :=
853 Get_Spec_Name (Unit_Name (Get_Cunit_Unit_Number (N)));
854 Units.Table (Units.Last).Cunit := Unit_Decl;
855 Units.Table (Units.Last).Cunit_Entity :=
856 Defining_Identifier
857 (Defining_Unit_Name (Specification (Unit (Unit_Decl))));
858
859 -- The library unit created for of a child subprogram unit plays no
860 -- role in code generation and binding, so label it accordingly.
861
862 Units.Table (Units.Last).Generate_Code := False;
863 Set_Has_No_Elaboration_Code (Unit_Decl);
864 end Make_Child_Decl_Unit;
865
866 ------------------------
867 -- Make_Instance_Unit --
868 ------------------------
869
870 -- If the unit is an instance, it appears as a package declaration, but
871 -- contains both declaration and body of the instance. The body becomes
872 -- the main unit of the compilation, and the declaration is inserted
873 -- at the end of the unit table. The main unit now has the name of a
874 -- body, which is constructed from the name of the original spec,
875 -- and is attached to the compilation node of the original unit. The
876 -- declaration has been attached to a new compilation unit node, and
877 -- code will have to be generated for it.
878
879 procedure Make_Instance_Unit (N : Node_Id; In_Main : Boolean) is
880 Sind : constant Source_File_Index := Source_Index (Main_Unit);
881
882 begin
883 Units.Increment_Last;
884
885 if In_Main then
886 Units.Table (Units.Last) := Units.Table (Main_Unit);
887 Units.Table (Units.Last).Cunit := Library_Unit (N);
888 Units.Table (Units.Last).Generate_Code := True;
889 Units.Table (Main_Unit).Cunit := N;
890 Units.Table (Main_Unit).Unit_Name :=
891 Get_Body_Name
892 (Unit_Name (Get_Cunit_Unit_Number (Library_Unit (N))));
893 Units.Table (Main_Unit).Version := Source_Checksum (Sind);
894
895 else
896 -- Duplicate information from instance unit, for the body. The unit
897 -- node N has been rewritten as a body, but it was placed in the
898 -- units table when first loaded as a declaration.
899
900 Units.Table (Units.Last) := Units.Table (Get_Cunit_Unit_Number (N));
901 Units.Table (Units.Last).Cunit := Library_Unit (N);
902 end if;
903 end Make_Instance_Unit;
904
905 ------------------------
906 -- Spec_Is_Irrelevant --
907 ------------------------
908
909 function Spec_Is_Irrelevant
910 (Spec_Unit : Unit_Number_Type;
911 Body_Unit : Unit_Number_Type) return Boolean
912 is
913 Sunit : constant Node_Id := Cunit (Spec_Unit);
914 Bunit : constant Node_Id := Cunit (Body_Unit);
915
916 begin
917 -- The spec is irrelevant if the body is a subprogram body, and the spec
918 -- is other than a subprogram spec or generic subprogram spec. Note that
919 -- the names must be the same, we don't need to check that, because we
920 -- already know that from the fact that the file names are the same.
921
922 return
923 Nkind (Unit (Bunit)) = N_Subprogram_Body
924 and then Nkind (Unit (Sunit)) /= N_Subprogram_Declaration
925 and then Nkind (Unit (Sunit)) /= N_Generic_Subprogram_Declaration;
926 end Spec_Is_Irrelevant;
927
928 --------------------
929 -- Version_Update --
930 --------------------
931
932 procedure Version_Update (U : Node_Id; From : Node_Id) is
933 Unum : constant Unit_Number_Type := Get_Cunit_Unit_Number (U);
934 Fnum : constant Unit_Number_Type := Get_Cunit_Unit_Number (From);
935 begin
936 if Source_Index (Fnum) /= No_Source_File then
937 Units.Table (Unum).Version :=
938 Units.Table (Unum).Version
939 xor
940 Source_Checksum (Source_Index (Fnum));
941 end if;
942 end Version_Update;
943
944 ----------------------------
945 -- Write_Dependency_Chain --
946 ----------------------------
947
948 procedure Write_Dependency_Chain is
949 begin
950 -- The dependency chain is only written if it is at least two entries
951 -- deep, otherwise it is trivial (the main unit depending on a unit
952 -- that it obviously directly depends on).
953
954 if Load_Stack.Last - 1 > Load_Stack.First then
955 for U in Load_Stack.First .. Load_Stack.Last - 1 loop
956 Error_Msg_Unit_1 :=
957 Unit_Name (Load_Stack.Table (U).Unit_Number);
958 Error_Msg_Unit_2 :=
959 Unit_Name (Load_Stack.Table (U + 1).Unit_Number);
960 Error_Msg ("$ depends on $!", Load_Msg_Sloc);
961 end loop;
962 end if;
963 end Write_Dependency_Chain;
964
965 end Lib.Load;
Mirror of the offical gcc git repository hosted at gcc.gnu.org