libquadmath/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
   8 #
   9 # You will slowly go insane if you do not grok the following fact:  when
  10 # building this library, the top-level /target/ becomes the library's /host/.
  11 #
  12 # configure then causes --target to default to --host, exactly like any
  13 # other package using autoconf.  Therefore, 'target' and 'host' will
  14 # always be the same.  This makes sense both for native and cross compilers
  15 # just think about it for a little while.  :-)
  16 #
  17 # Also, if this library is being configured as part of a cross compiler, the
  18 # top-level configure script will pass the "real" host as $with_cross_host.
  19 #
  20 # Do not delete or change the following two lines.  For why, see
  21 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  22 AC_CANONICAL_SYSTEM
  23 ACX_NONCANONICAL_TARGET
  24
  25 AM_ENABLE_MULTILIB(, ..)
  26
  27 target_alias=${target_alias-$host_alias}
  28 AC_SUBST(target_alias)
  29
  30 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
  31
  32 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  33 AC_ARG_ENABLE(version-specific-runtime-libs,
  34 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  35  [specify that runtime libraries should be installed in a compiler-specific directory]),
  36 [case "$enableval" in
  37  yes) version_specific_libs=yes ;;
  38  no)  version_specific_libs=no ;;
  39  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  40  esac],
  41 [version_specific_libs=no])
  42 AC_MSG_RESULT($version_specific_libs)
  43
  44 GCC_NO_EXECUTABLES
  45
  46 AC_USE_SYSTEM_EXTENSIONS
  47
  48 # See if makeinfo has been installed and is modern enough
  49 # that we can use it.
  50 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  51                    [GNU texinfo.* \([0-9][0-9.]*\)],
  52                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  53 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  54
  55 ACX_BUGURL([https://gcc.gnu.org/bugs/])
  56
  57 # Configure libtool
  58 AM_PROG_LIBTOOL
  59 ACX_LT_HOST_FLAGS
  60 AC_SUBST(enable_shared)
  61 AC_SUBST(enable_static)
  62 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
  63
  64 AM_MAINTAINER_MODE
  65
  66 AC_LANG_C
  67 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  68 # We must force CC to /not/ be precious variables; otherwise
  69 # the wrong, non-multilib-adjusted value will be used in multilibs.
  70 # As a side effect, we have to subst CFLAGS ourselves.
  71
  72 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  73 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  74 AC_PROG_CC
  75 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  76
  77 AC_SUBST(CFLAGS)
  78
  79 AM_PROG_CC_C_O
  80
  81 if test "x$GCC" != "xyes"; then
  82   AC_MSG_ERROR([libquadmath must be built with GCC])
  83 fi
  84 AC_PROG_CPP
  85
  86 GCC_WITH_TOOLEXECLIBDIR
  87
  88 # Calculate toolexeclibdir
  89 # Also toolexecdir, though it's only used in toolexeclibdir
  90 case ${version_specific_libs} in
  91   yes)
  92     # Need the gcc compiler version to know where to install libraries
  93     # and header files if --enable-version-specific-runtime-libs option
  94     # is selected.
  95     toolexecdir='$(libdir)/gcc/$(target_alias)'
  96     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  97     ;;
  98   no)
  99     if test -n "$with_cross_host" &&
 100        test x"$with_cross_host" != x"no"; then
 101       # Install a library built with a cross compiler in tooldir, not libdir.
 102       toolexecdir='$(exec_prefix)/$(target_alias)'
 103       case ${with_toolexeclibdir} in
 104         no)
 105           toolexeclibdir='$(toolexecdir)/lib'
 106           ;;
 107         *)
 108           toolexeclibdir=${with_toolexeclibdir}
 109           ;;
 110       esac
 111     else
 112       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 113       toolexeclibdir='$(libdir)'
 114     fi
 115     multi_os_directory=`$CC -print-multi-os-directory`
 116     case $multi_os_directory in
 117       .) ;; # Avoid trailing /.
 118       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 119     esac
 120     ;;
 121 esac
 122 AC_SUBST(toolexecdir)
 123 AC_SUBST(toolexeclibdir)
 124
 125 AC_CHECK_HEADERS(fenv.h langinfo.h locale.h wchar.h wctype.h limits.h ctype.h printf.h errno.h)
 126 LIBQUAD_CHECK_MATH_H_SIGNGAM
 127
 128 # If available, sqrtl and cbrtl speed up the calculation -
 129 # but they are not required
 130 if test x$gcc_no_link != xyes; then
 131   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
 132   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
 133   AC_CHECK_LIB([m],[feholdexcept],[AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])])
 134   AC_CHECK_LIB([m],[fesetround],[AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])])
 135   AC_CHECK_LIB([m],[feupdateenv],[AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])])
 136   AC_CHECK_LIB([m],[fesetenv],[AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])])
 137   AC_CHECK_LIB([m],[fetestexcept],[AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])])
 138   AC_CHECK_FUNCS(strtoull)
 139 else
 140   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
 141     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])
 142   fi
 143   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
 144     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])
 145   fi
 146   if test "x$ac_cv_lib_m_feholdexcept" = x""yes; then
 147     AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])
 148   fi
 149   if test "x$ac_cv_lib_m_fesetround" = x""yes; then
 150     AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])
 151   fi
 152   if test "x$ac_cv_lib_m_feupdateenv" = x""yes; then
 153     AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])
 154   fi
 155   if test "x$ac_cv_lib_m_fesetenv" = x""yes; then
 156     AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])
 157   fi
 158   if test "x$ac_cv_lib_m_fetestexcept" = x""yes; then
 159     AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])
 160   fi
 161 fi
 162
 163 # Check for hidden visibility (copied from libssp).
 164 saved_CFLAGS="$CFLAGS"
 165 CFLAGS="$CFLAGS -Werror"
 166 AC_MSG_CHECKING([whether hidden visibility is supported])
 167 AC_TRY_COMPILE([
 168 void __attribute__((visibility ("hidden"))) bar (void) {}],,
 169 [quadmath_hidden=yes],[quadmath_hidden=no])
 170 AC_MSG_RESULT($quadmath_hidden)
 171 if test x$quadmath_hidden = xyes; then
 172   AC_DEFINE([HAVE_HIDDEN_VISIBILITY],[1],[__attribute__((visibility ("hidden"))) supported])
 173 fi
 174 CFLAGS="$saved_CFLAGS"
 175
 176 # Check for symbol versioning (copied from libssp).
 177 AC_MSG_CHECKING([whether symbol versioning is supported])
 178 AC_ARG_ENABLE(symvers,
 179 AS_HELP_STRING([--disable-symvers],
 180   [disable symbol versioning for libquadmath]),
 181 quadmath_use_symver=$enableval,
 182 quadmath_use_symver=yes)
 183 if test "x$quadmath_use_symver" != xno; then
 184   if test x$gcc_no_link = xyes; then
 185     # If we cannot link, we cannot build shared libraries, so do not use
 186     # symbol versioning.
 187     quadmath_use_symver=no
 188   else
 189     save_LDFLAGS="$LDFLAGS"
 190     LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 191     cat > conftest.map <<EOF
 192 FOO_1.0 {
 193   global: *foo*; bar; local: *;
 194 };
 195 EOF
 196     AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
 197     if test x$quadmath_use_symver = xno; then
 198       case "$target_os" in
 199         solaris2*)
 200           LDFLAGS="$save_LDFLAGS"
 201           LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 202           # Sun ld cannot handle wildcards and treats all entries as undefined.
 203           cat > conftest.map <<EOF
 204 FOO_1.0 {
 205   global: foo; local: *;
 206 };
 207 EOF
 208           AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
 209           ;;
 210       esac
 211     fi
 212     LDFLAGS="$save_LDFLAGS"
 213   fi
 214 fi
 215 AC_MSG_RESULT($quadmath_use_symver)
 216 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
 217 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
 218 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
 219
 220 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
 221   [GCC_TRY_COMPILE_OR_LINK([
 222     #if (!defined(_ARCH_PPC)) || defined(__LONG_DOUBLE_IEEE128__)
 223     typedef _Complex float __attribute__((mode(TC))) __complex128;
 224     #else
 225     typedef _Complex float __attribute__((mode(KC))) __complex128;
 226     #endif
 227
 228     __float128 foo (__float128 x)
 229     {
 230
 231      __complex128 z1, z2;
 232
 233      z1 = x;
 234      z2 = x / 7.Q;
 235      z2 /= z1;
 236
 237      return (__float128) z2;
 238     }
 239
 240     __float128 bar (__float128 x)
 241     {
 242       return x * __builtin_huge_valq ();
 243     }
 244   ],[
 245     foo (1.2Q);
 246     bar (1.2Q);
 247   ],[
 248     libquad_cv_have_float128=yes
 249   ],[
 250     libquad_cv_have_float128=no
 251 ])])
 252 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
 253
 254 # Check for printf hook support.
 255 AC_MSG_CHECKING([whether printf hooks are supported])
 256 AC_TRY_COMPILE([
 257 #include <printf.h>
 258 #include <stdarg.h>
 259 #include <stdlib.h>
 260 extern void flt128_va (void *, va_list *);
 261 extern int flt128_ais (const struct printf_info *, size_t, int *, int *);
 262 extern int flt128_printf_fp (FILE *, const struct printf_info *, const void *const *);
 263 ],[
 264 int pa_flt128 = register_printf_type (flt128_va);
 265 int mod_Q = register_printf_modifier (L"Q");
 266 int res = register_printf_specifier ('f', flt128_printf_fp, flt128_ais);
 267 struct printf_info info = { .user = -1 };
 268 ],
 269 [quadmath_printf_hooks=yes],[quadmath_printf_hooks=no])
 270 AC_MSG_RESULT($quadmath_printf_hooks)
 271 if test x$quadmath_printf_hooks = xyes; then
 272   AC_DEFINE([HAVE_PRINTF_HOOKS],[1],[GNU C Library stype printf hooks supported])
 273 fi
 274
 275 # Check for whether locale support for quadmath_snprintf or Q printf hooks
 276 # should be provided.
 277 AC_MSG_CHECKING([whether nl_langinfo should be used])
 278 AC_TRY_COMPILE([#include <langinfo.h>],[
 279 const char *s;
 280 s = nl_langinfo (DECIMAL_POINT);
 281 s = nl_langinfo (MON_DECIMAL_POINT);
 282 s = nl_langinfo (GROUPING);
 283 s = nl_langinfo (MON_GROUPING);
 284 s = nl_langinfo (THOUSANDS_SEP);
 285 s = nl_langinfo (MON_THOUSANDS_SEP);
 286 (void) s;
 287 ],
 288 [quadmath_use_nl_langinfo=yes],[quadmath_use_nl_langinfo=no])
 289 AC_MSG_RESULT($quadmath_use_nl_langinfo)
 290 if test x$quadmath_use_nl_langinfo = xyes; then
 291   AC_DEFINE([USE_NL_LANGINFO],[1],[whether nl_langinfo should be used])
 292 fi
 293
 294 AC_MSG_CHECKING([whether nl_langinfo should be used for wide char locale info])
 295 AC_TRY_COMPILE([#include <langinfo.h>],[
 296 const char *s;
 297 s = nl_langinfo (_NL_NUMERIC_DECIMAL_POINT_WC);
 298 s = nl_langinfo (_NL_MONETARY_DECIMAL_POINT_WC);
 299 s = nl_langinfo (_NL_NUMERIC_THOUSANDS_SEP_WC);
 300 s = nl_langinfo (_NL_MONETARY_THOUSANDS_SEP_WC);
 301 (void) s;
 302 ],
 303 [quadmath_use_nl_langinfo_wc=yes],[quadmath_use_nl_langinfo_wc=no])
 304 AC_MSG_RESULT($quadmath_use_nl_langinfo_wc)
 305 if test x$quadmath_use_nl_langinfo_wc = xyes; then
 306   AC_DEFINE([USE_NL_LANGINFO_WC],[1],[whether nl_langinfo should be used for wide char locale info])
 307 fi
 308
 309 AC_MSG_CHECKING([whether localeconv should be used])
 310 AC_TRY_COMPILE([#include <locale.h>],[
 311 const struct lconv *l = localeconv ();
 312 const char *s;
 313 s = l->decimal_point;
 314 s = l->mon_decimal_point;
 315 s = l->grouping;
 316 s = l->mon_grouping;
 317 s = l->thousands_sep;
 318 s = l->mon_thousands_sep;
 319 (void) s;
 320 ],
 321 [quadmath_use_localeconv=yes],[quadmath_use_localeconv=no])
 322 AC_MSG_RESULT($quadmath_use_localeconv)
 323 if test x$quadmath_use_localeconv = xyes; then
 324   AC_DEFINE([USE_LOCALECONV],[1],[whether localeconv should be used])
 325 fi
 326
 327 # Check for whether i18n number rewriting support for quadmath_snprintf
 328 # or Q printf hooks should be provided.
 329 AC_MSG_CHECKING([whether i18n number rewriting support for quadmath_snprintf should be added])
 330 AC_TRY_COMPILE([#include <langinfo.h>
 331 #include <limits.h>
 332 #include <string.h>
 333 #include <wchar.h>
 334 #include <wctype.h>],[
 335 const char *s;
 336 char decimal[MB_LEN_MAX];
 337 wctrans_t map = wctrans ("to_outpunct");
 338 wint_t wdecimal = towctrans (L'.', map);
 339 mbstate_t state;
 340 memset (&state, '\0', sizeof (state));
 341 wcrtomb (decimal, wdecimal, &state);
 342 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
 343 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
 344 s = nl_langinfo (_NL_CTYPE_MB_CUR_MAX);
 345 (void) s;
 346 ],
 347 [quadmath_use_i18n_number_h=yes],[quadmath_use_i18n_number_h=no])
 348 AC_MSG_RESULT($quadmath_use_i18n_number_h)
 349 if test x$quadmath_use_i18n_number_h = xyes; then
 350   AC_DEFINE([USE_I18N_NUMBER_H],[1],[whether i18n number rewriting can be supported])
 351 fi
 352
 353 # Add CET specific flags if CET is enabled
 354 GCC_CET_FLAGS(CET_FLAGS)
 355 XCFLAGS="$XCFLAGS $CET_FLAGS"
 356
 357 case x$target in
 358   xpowerpc64le*-linux*)
 359     AC_PREPROC_IFELSE(
 360       [AC_LANG_PROGRAM([[#if __SIZEOF_LONG_DOUBLE__ != 16
 361                          #error long double is double
 362                          #endif]],
 363                        [[(void) 0;]])],
 364       [XCFLAGS="$XCFLAGS -mno-gnu-attribute"])
 365     ;;
 366   *)
 367     ;;
 368 esac
 369 AC_SUBST(XCFLAGS)
 370
 371 AC_CACHE_SAVE
 372
 373 if test ${multilib} = yes; then
 374   multilib_arg="--enable-multilib"
 375 else
 376   multilib_arg=
 377 fi
 378
 379
 380 # We would like our source tree to be readonly. However when releases or
 381 # pre-releases are generated, the flex/bison generated files as well as the
 382 # various formats of manuals need to be included along with the rest of the
 383 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 384 # just that.
 385 AC_MSG_CHECKING(generated-files-in-srcdir)
 386 AC_ARG_ENABLE(generated-files-in-srcdir,
 387 AS_HELP_STRING([--enable-generated-files-in-srcdir],
 388  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
 389 [case "$enableval" in
 390  yes) enable_generated_files_in_srcdir=yes ;;
 391  no)  enable_generated_files_in_srcdir=no ;;
 392  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 393  esac],
 394 [enable_generated_files_in_srcdir=no])
 395 AC_MSG_RESULT($enable_generated_files_in_srcdir)
 396 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
 397
 398 # Determine what GCC version number to use in filesystem paths.
 399 GCC_BASE_VER
 400
 401 AC_CONFIG_FILES(Makefile)
 402 AC_OUTPUT