gcc/ada/a-except-2005.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2015, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This version of Ada.Exceptions fully supports Ada 95 and later language
  37 --  versions.  It is used in all situations except for the build of the
  38 --  compiler and other basic tools. For these latter builds, we use an
  39 --  Ada 95-only version.
  40
  41 --  The reason for this splitting off of a separate version is to support
  42 --  older bootstrap compilers that do not support Ada 2005 features, and
  43 --  Ada.Exceptions is part of the compiler sources.
  44
  45 pragma Polling (Off);
  46 --  We must turn polling off for this unit, because otherwise we get
  47 --  elaboration circularities with ourself.
  48
  49 with System;
  50 with System.Parameters;
  51 with System.Standard_Library;
  52 with System.Traceback_Entries;
  53
  54 package Ada.Exceptions is
  55    pragma Preelaborate;
  56    --  In accordance with Ada 2005 AI-362.
  57
  58    type Exception_Id is private;
  59    pragma Preelaborable_Initialization (Exception_Id);
  60
  61    Null_Id : constant Exception_Id;
  62
  63    type Exception_Occurrence is limited private;
  64    pragma Preelaborable_Initialization (Exception_Occurrence);
  65
  66    type Exception_Occurrence_Access is access all Exception_Occurrence;
  67
  68    Null_Occurrence : constant Exception_Occurrence;
  69
  70    function Exception_Name (Id : Exception_Id) return String;
  71
  72    function Exception_Name (X : Exception_Occurrence) return String;
  73
  74    function Wide_Exception_Name
  75      (Id : Exception_Id) return Wide_String;
  76    pragma Ada_05 (Wide_Exception_Name);
  77
  78    function Wide_Exception_Name
  79      (X : Exception_Occurrence) return Wide_String;
  80    pragma Ada_05 (Wide_Exception_Name);
  81
  82    function Wide_Wide_Exception_Name
  83      (Id : Exception_Id) return Wide_Wide_String;
  84    pragma Ada_05 (Wide_Wide_Exception_Name);
  85
  86    function Wide_Wide_Exception_Name
  87      (X : Exception_Occurrence) return Wide_Wide_String;
  88    pragma Ada_05 (Wide_Wide_Exception_Name);
  89
  90    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  91    pragma No_Return (Raise_Exception);
  92    --  Note: In accordance with AI-466, CE is raised if E = Null_Id
  93
  94    function Exception_Message (X : Exception_Occurrence) return String;
  95
  96    procedure Reraise_Occurrence (X : Exception_Occurrence);
  97    --  Note: it would be really nice to give a pragma No_Return for this
  98    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  99    --  if the argument is the null exception occurrence. See also procedure
 100    --  Reraise_Occurrence_Always in the private part of this package.
 101
 102    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
 103
 104    function Exception_Information (X : Exception_Occurrence) return String;
 105    --  The format of the exception information is as follows:
 106    --
 107    --    exception name (as in Exception_Name)
 108    --    message (or a null line if no message)
 109    --    PID=nnnn
 110    --    0xyyyyyyyy 0xyyyyyyyy ...
 111    --
 112    --  The lines are separated by a ASCII.LF character
 113    --
 114    --  The nnnn is the partition Id given as decimal digits
 115    --
 116    --  The 0x... line represents traceback program counter locations,
 117    --  in order with the first one being the exception location.
 118
 119    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 120    --  not the function from Rtsfind, so it is important that the procedure
 121    --  come first, since Rtsfind finds the first matching entity.
 122
 123    procedure Save_Occurrence
 124      (Target : out Exception_Occurrence;
 125       Source : Exception_Occurrence);
 126
 127    function Save_Occurrence
 128      (Source : Exception_Occurrence)
 129       return   Exception_Occurrence_Access;
 130
 131    --  Ada 2005 (AI-438): The language revision introduces the following
 132    --  subprograms and attribute definitions. We do not provide them
 133    --  explicitly. instead, the corresponding stream attributes are made
 134    --  available through a pragma Stream_Convert in the private part.
 135
 136    --  procedure Read_Exception_Occurrence
 137    --    (Stream : not null access Ada.Streams.Root_Stream_Type'Class;
 138    --     Item   : out Exception_Occurrence);
 139
 140    --  procedure Write_Exception_Occurrence
 141    --    (Stream : not null access Ada.Streams.Root_Stream_Type'Class;
 142    --     Item   : Exception_Occurrence);
 143
 144    --  for Exception_Occurrence'Read use Read_Exception_Occurrence;
 145    --  for Exception_Occurrence'Write use Write_Exception_Occurrence;
 146
 147 private
 148    package SSL renames System.Standard_Library;
 149    package SP renames System.Parameters;
 150
 151    subtype EOA is Exception_Occurrence_Access;
 152
 153    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 154
 155    ------------------
 156    -- Exception_Id --
 157    ------------------
 158
 159    subtype Code_Loc is System.Address;
 160    --  Code location used in building exception tables and for call addresses
 161    --  when propagating an exception. Values of this type are created by using
 162    --  Label'Address or extracted from machine states using Get_Code_Loc.
 163
 164    Null_Loc : constant Code_Loc := System.Null_Address;
 165    --  Null code location, used to flag outer level frame
 166
 167    type Exception_Id is new SSL.Exception_Data_Ptr;
 168
 169    function EId_To_String (X : Exception_Id) return String;
 170    function String_To_EId (S : String) return Exception_Id;
 171    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 172    --  Functions for implementing Exception_Id stream attributes
 173
 174    Null_Id : constant Exception_Id := null;
 175
 176    -------------------------
 177    -- Private Subprograms --
 178    -------------------------
 179
 180    function Current_Target_Exception return Exception_Occurrence;
 181    pragma Export
 182      (Ada, Current_Target_Exception,
 183       "__gnat_current_target_exception");
 184    --  This routine should return the current raised exception on targets which
 185    --  have built-in exception handling such as the Java Virtual Machine. For
 186    --  other targets this routine is simply ignored. Currently, only JGNAT
 187    --  uses this. See 4jexcept.ads for details. The pragma Export allows this
 188    --  routine to be accessed elsewhere in the run-time, even though it is in
 189    --  the private part of this package (it is not allowed to be in the visible
 190    --  part, since this is set by the reference manual).
 191
 192    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 193    --  Like Exception_Name, but returns the simple non-qualified name of the
 194    --  exception. This is used to implement the Exception_Name function in
 195    --  Current_Exceptions (the DEC compatible unit). It is called from the
 196    --  compiler generated code (using Rtsfind, which does not respect the
 197    --  private barrier, so we can place this function in the private part
 198    --  where the compiler can find it, but the spec is unchanged.)
 199
 200    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 201    pragma No_Return (Raise_Exception_Always);
 202    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 203    --  This differs from Raise_Exception only in that the caller has determined
 204    --  that for sure the parameter E is not null, and that therefore no check
 205    --  for Null_Id is required. The expander converts Raise_Exception calls to
 206    --  Raise_Exception_Always if it can determine this is the case. The Export
 207    --  allows this routine to be accessed from Pure units.
 208
 209    procedure Raise_From_Signal_Handler
 210      (E : Exception_Id;
 211       M : System.Address);
 212    pragma Export
 213      (Ada, Raise_From_Signal_Handler,
 214            "ada__exceptions__raise_from_signal_handler");
 215    pragma No_Return (Raise_From_Signal_Handler);
 216    --  This routine is used to raise an exception from a signal handler. The
 217    --  signal handler has already stored the machine state (i.e. the state that
 218    --  corresponds to the location at which the signal was raised). E is the
 219    --  Exception_Id specifying what exception is being raised, and M is a
 220    --  pointer to a null-terminated string which is the message to be raised.
 221    --  Note that this routine never returns, so it is permissible to simply
 222    --  jump to this routine, rather than call it. This may be appropriate for
 223    --  systems where the right way to get out of signal handler is to alter the
 224    --  PC value in the machine state or in some other way ask the operating
 225    --  system to return here rather than to the original location.
 226
 227    procedure Raise_From_Controlled_Operation
 228      (X : Ada.Exceptions.Exception_Occurrence);
 229    pragma No_Return (Raise_From_Controlled_Operation);
 230    pragma Export
 231      (Ada, Raise_From_Controlled_Operation,
 232            "__gnat_raise_from_controlled_operation");
 233    --  Raise Program_Error, providing information about X (an exception raised
 234    --  during a controlled operation) in the exception message.
 235
 236    procedure Reraise_Library_Exception_If_Any;
 237    pragma Export
 238      (Ada, Reraise_Library_Exception_If_Any,
 239            "__gnat_reraise_library_exception_if_any");
 240    --  If there was an exception raised during library-level finalization,
 241    --  reraise the exception.
 242
 243    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 244    pragma No_Return (Reraise_Occurrence_Always);
 245    --  This differs from Raise_Occurrence only in that the caller guarantees
 246    --  that for sure the parameter X is not the null occurrence, and that
 247    --  therefore this procedure cannot return. The expander uses this routine
 248    --  in the translation of a raise statement with no parameter (reraise).
 249
 250    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 251    pragma No_Return (Reraise_Occurrence_No_Defer);
 252    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 253    --  before the call and the parameter X is known not to be the null
 254    --  occurrence. This is used in generated code when it is known that abort
 255    --  is already deferred.
 256
 257    function Triggered_By_Abort return Boolean;
 258    --  Determine whether the current exception (if it exists) is an instance of
 259    --  Standard'Abort_Signal.
 260
 261    -----------------------
 262    -- Polling Interface --
 263    -----------------------
 264
 265    --  The GNAT compiler has an option to generate polling calls to the Poll
 266    --  routine in this package. Specifying the -gnatP option for a compilation
 267    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 268    --  entry and on every iteration of a loop, thus avoiding the possibility of
 269    --  a case of unbounded time between calls.
 270
 271    --  This polling interface may be used for instrumentation or debugging
 272    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 273
 274    --  In the GNAT technology itself, this interface is used to implement
 275    --  immediate asynchronous transfer of control and immediate abort on
 276    --  targets which do not provide for one thread interrupting another.
 277
 278    --  Note: this used to be in a separate unit called System.Poll, but that
 279    --  caused horrible circular elaboration problems between System.Poll and
 280    --  Ada.Exceptions.
 281
 282    procedure Poll;
 283    --  Check for asynchronous abort. Note that we do not inline the body.
 284    --  This makes the interface more useful for debugging purposes.
 285
 286    --------------------------
 287    -- Exception_Occurrence --
 288    --------------------------
 289
 290    package TBE renames System.Traceback_Entries;
 291
 292    Max_Tracebacks : constant := 50;
 293    --  Maximum number of trace backs stored in exception occurrence
 294
 295    subtype Tracebacks_Array is TBE.Tracebacks_Array (1 .. Max_Tracebacks);
 296    --  Traceback array stored in exception occurrence
 297
 298    type Exception_Occurrence is record
 299       Id : Exception_Id;
 300       --  Exception_Identity for this exception occurrence
 301
 302       Machine_Occurrence : System.Address;
 303       --  The underlying machine occurrence. For GCC, this corresponds to the
 304       --  _Unwind_Exception structure address.
 305
 306       Msg_Length : Natural := 0;
 307       --  Length of message (zero = no message)
 308
 309       Msg : String (1 .. Exception_Msg_Max_Length);
 310       --  Characters of message
 311
 312       Exception_Raised : Boolean := False;
 313       --  Set to true to indicate that this exception occurrence has actually
 314       --  been raised. When an exception occurrence is first created, this is
 315       --  set to False, then when it is processed by Raise_Current_Exception,
 316       --  it is set to True. If Raise_Current_Exception is used to raise an
 317       --  exception for which this flag is already True, then it knows that
 318       --  it is dealing with the reraise case (which is useful to distinguish
 319       --  for exception tracing purposes).
 320
 321       Pid : Natural := 0;
 322       --  Partition_Id for partition raising exception
 323
 324       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 325       --  Number of traceback entries stored
 326
 327       Tracebacks : Tracebacks_Array;
 328       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 329    end record;
 330
 331    function "=" (Left, Right : Exception_Occurrence) return Boolean
 332      is abstract;
 333    --  Don't allow comparison on exception occurrences, we should not need
 334    --  this, and it would not work right, because of the Msg and Tracebacks
 335    --  fields which have unused entries not copied by Save_Occurrence.
 336
 337    function Get_Exception_Machine_Occurrence
 338      (X : Exception_Occurrence) return System.Address;
 339    pragma Export (Ada, Get_Exception_Machine_Occurrence,
 340                   "__gnat_get_exception_machine_occurrence");
 341    --  Get the machine occurrence corresponding to an exception occurrence.
 342    --  It is Null_Address if there is no machine occurrence (in runtimes that
 343    --  doesn't use GCC mechanism) or if it has been lost (Save_Occurrence
 344    --  doesn't save the machine occurrence).
 345
 346    function EO_To_String (X : Exception_Occurrence) return String;
 347    function String_To_EO (S : String) return Exception_Occurrence;
 348    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 349    --  Functions for implementing Exception_Occurrence stream attributes
 350
 351    Null_Occurrence : constant Exception_Occurrence := (
 352      Id                 => null,
 353      Machine_Occurrence => System.Null_Address,
 354      Msg_Length         => 0,
 355      Msg                => (others => ' '),
 356      Exception_Raised   => False,
 357      Pid                => 0,
 358      Num_Tracebacks     => 0,
 359      Tracebacks         => (others => TBE.Null_TB_Entry));
 360
 361 end Ada.Exceptions;