gcc/ada/s-tposen.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --               GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --              SYSTEM.TASKING.PROTECTED_OBJECTS.SINGLE_ENTRY               --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1998-2004, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Style_Checks (All_Checks);
  35 --  Turn off subprogram ordering check, since restricted GNARLI
  36 --  subprograms are gathered together at end.
  37
  38 --  This package provides an optimized version of Protected_Objects.Operations
  39 --  and Protected_Objects.Entries making the following assumptions:
  40 --
  41 --  PO have only one entry
  42 --  There is only one caller at a time (No_Entry_Queue)
  43 --  There is no dynamic priority support (No_Dynamic_Priorities)
  44 --  No Abort Statements
  45 --    (No_Abort_Statements, Max_Asynchronous_Select_Nesting => 0)
  46 --  PO are at library level
  47 --  No Requeue
  48 --  None of the tasks will terminate (no need for finalization)
  49 --
  50 --  This interface is intended to be used in the ravenscar and restricted
  51 --  profiles, the compiler is responsible for ensuring that the conditions
  52 --  mentioned above are respected, except for the No_Entry_Queue restriction
  53 --  that is checked dynamically in this package, since the check cannot be
  54 --  performed at compile time, and is relatively cheap (see PO_Do_Or_Queue,
  55 --  Service_Entry).
  56
  57 pragma Polling (Off);
  58 --  Turn off polling, we do not want polling to take place during tasking
  59 --  operations. It can cause  infinite loops and other problems.
  60
  61 pragma Suppress (All_Checks);
  62
  63 with System.Task_Primitives.Operations;
  64 --  used for Self
  65 --           Finalize_Lock
  66 --           Write_Lock
  67 --           Unlock
  68
  69 with Ada.Exceptions;
  70 --  used for Exception_Id
  71 --           Raise_Exception
  72
  73 with System.Parameters;
  74 --  used for Single_Lock
  75
  76 package body System.Tasking.Protected_Objects.Single_Entry is
  77
  78    package STPO renames System.Task_Primitives.Operations;
  79
  80    use Parameters;
  81
  82    -----------------------
  83    -- Local Subprograms --
  84    -----------------------
  85
  86    procedure Send_Program_Error
  87      (Self_Id    : Task_Id;
  88       Entry_Call : Entry_Call_Link);
  89    pragma Inline (Send_Program_Error);
  90    --  Raise Program_Error in the caller of the specified entry call
  91
  92    --------------------------
  93    -- Entry Calls Handling --
  94    --------------------------
  95
  96    procedure Wakeup_Entry_Caller
  97      (Self_ID    : Task_Id;
  98       Entry_Call : Entry_Call_Link;
  99       New_State  : Entry_Call_State);
 100    pragma Inline (Wakeup_Entry_Caller);
 101    --  This is called at the end of service of an entry call,
 102    --  to abort the caller if he is in an abortable part, and
 103    --  to wake up the caller if he is on Entry_Caller_Sleep.
 104    --  Call it holding the lock of Entry_Call.Self.
 105    --
 106    --  Timed_Call or Simple_Call:
 107    --    The caller is waiting on Entry_Caller_Sleep, in
 108    --    Wait_For_Completion, or Wait_For_Completion_With_Timeout.
 109
 110    procedure Wait_For_Completion (Entry_Call : Entry_Call_Link);
 111    pragma Inline (Wait_For_Completion);
 112    --  This procedure suspends the calling task until the specified entry call
 113    --  has either been completed or cancelled. On exit, the call will not be
 114    --  queued. This waits for calls on protected entries.
 115    --  Call this only when holding Self_ID locked.
 116
 117    procedure Wait_For_Completion_With_Timeout
 118      (Entry_Call  : Entry_Call_Link;
 119       Wakeup_Time : Duration;
 120       Mode        : Delay_Modes);
 121    --  Same as Wait_For_Completion but it waits for a timeout with the value
 122    --  specified in Wakeup_Time as well.
 123
 124    procedure Check_Exception
 125      (Self_ID : Task_Id;
 126       Entry_Call : Entry_Call_Link);
 127    pragma Inline (Check_Exception);
 128    --  Raise any pending exception from the Entry_Call.
 129    --  This should be called at the end of every compiler interface procedure
 130    --  that implements an entry call.
 131    --  The caller should not be holding any locks, or there will be deadlock.
 132
 133    procedure PO_Do_Or_Queue
 134      (Self_Id    : Task_Id;
 135       Object     : Protection_Entry_Access;
 136       Entry_Call : Entry_Call_Link);
 137    --  This procedure executes or queues an entry call, depending
 138    --  on the status of the corresponding barrier. It assumes that the
 139    --  specified object is locked.
 140
 141    ---------------------
 142    -- Check_Exception --
 143    ---------------------
 144
 145    procedure Check_Exception
 146      (Self_ID    : Task_Id;
 147       Entry_Call : Entry_Call_Link)
 148    is
 149       pragma Warnings (Off, Self_ID);
 150
 151       procedure Internal_Raise (X : Ada.Exceptions.Exception_Id);
 152       pragma Import (C, Internal_Raise, "__gnat_raise_with_msg");
 153
 154       use type Ada.Exceptions.Exception_Id;
 155
 156       E : constant Ada.Exceptions.Exception_Id :=
 157         Entry_Call.Exception_To_Raise;
 158
 159    begin
 160       if E /= Ada.Exceptions.Null_Id then
 161          Internal_Raise (E);
 162       end if;
 163    end Check_Exception;
 164
 165    ------------------------
 166    -- Send_Program_Error --
 167    ------------------------
 168
 169    procedure Send_Program_Error
 170      (Self_Id    : Task_Id;
 171       Entry_Call : Entry_Call_Link)
 172    is
 173       Caller : constant Task_Id := Entry_Call.Self;
 174    begin
 175       Entry_Call.Exception_To_Raise := Program_Error'Identity;
 176
 177       if Single_Lock then
 178          STPO.Lock_RTS;
 179       end if;
 180
 181       STPO.Write_Lock (Caller);
 182       Wakeup_Entry_Caller (Self_Id, Entry_Call, Done);
 183       STPO.Unlock (Caller);
 184
 185       if Single_Lock then
 186          STPO.Unlock_RTS;
 187       end if;
 188    end Send_Program_Error;
 189
 190    -------------------------
 191    -- Wait_For_Completion --
 192    -------------------------
 193
 194    procedure Wait_For_Completion (Entry_Call : Entry_Call_Link) is
 195       Self_Id : constant Task_Id := Entry_Call.Self;
 196    begin
 197       Self_Id.Common.State := Entry_Caller_Sleep;
 198       STPO.Sleep (Self_Id, Entry_Caller_Sleep);
 199       Self_Id.Common.State := Runnable;
 200    end Wait_For_Completion;
 201
 202    --------------------------------------
 203    -- Wait_For_Completion_With_Timeout --
 204    --------------------------------------
 205
 206    procedure Wait_For_Completion_With_Timeout
 207      (Entry_Call  : Entry_Call_Link;
 208       Wakeup_Time : Duration;
 209       Mode        : Delay_Modes)
 210    is
 211       Self_Id  : constant Task_Id := Entry_Call.Self;
 212       Timedout : Boolean;
 213       Yielded  : Boolean;
 214
 215       use type Ada.Exceptions.Exception_Id;
 216
 217    begin
 218       --  This procedure waits for the entry call to be served, with a timeout.
 219       --  It tries to cancel the call if the timeout expires before the call is
 220       --  served.
 221
 222       --  If we wake up from the timed sleep operation here, it may be for the
 223       --  following possible reasons:
 224
 225       --  1) The entry call is done being served.
 226       --  2) The timeout has expired (Timedout = True)
 227
 228       --  Once the timeout has expired we may need to continue to wait if the
 229       --  call is already being serviced. In that case, we want to go back to
 230       --  sleep, but without any timeout. The variable Timedout is used to
 231       --  control this. If the Timedout flag is set, we do not need to Sleep
 232       --  with a timeout. We just sleep until we get a wakeup for some status
 233       --  change.
 234
 235       pragma Assert (Entry_Call.Mode = Timed_Call);
 236       Self_Id.Common.State := Entry_Caller_Sleep;
 237
 238       STPO.Timed_Sleep
 239         (Self_Id, Wakeup_Time, Mode, Entry_Caller_Sleep, Timedout, Yielded);
 240
 241       if Timedout then
 242          Entry_Call.State := Cancelled;
 243       else
 244          Entry_Call.State := Done;
 245       end if;
 246
 247       Self_Id.Common.State := Runnable;
 248    end Wait_For_Completion_With_Timeout;
 249
 250    -------------------------
 251    -- Wakeup_Entry_Caller --
 252    -------------------------
 253
 254    --  This is called at the end of service of an entry call, to abort the
 255    --  caller if he is in an abortable part, and to wake up the caller if it
 256    --  is on Entry_Caller_Sleep. It assumes that the call is already off-queue.
 257
 258    --  (This enforces the rule that a task must be off-queue if its state is
 259    --  Done or Cancelled.) Call it holding the lock of Entry_Call.Self.
 260
 261    --  Timed_Call or Simple_Call:
 262    --    The caller is waiting on Entry_Caller_Sleep, in
 263    --    Wait_For_Completion, or Wait_For_Completion_With_Timeout.
 264
 265    --  Conditional_Call:
 266    --    The caller might be in Wait_For_Completion,
 267    --    waiting for a rendezvous (possibly requeued without abort)
 268    --    to complete.
 269
 270    procedure Wakeup_Entry_Caller
 271      (Self_ID    : Task_Id;
 272       Entry_Call : Entry_Call_Link;
 273       New_State  : Entry_Call_State)
 274    is
 275       pragma Warnings (Off, Self_ID);
 276
 277       Caller : constant Task_Id := Entry_Call.Self;
 278
 279    begin
 280       pragma Assert (New_State = Done or else New_State = Cancelled);
 281       pragma Assert
 282         (Caller.Common.State /= Terminated and then
 283          Caller.Common.State /= Unactivated);
 284
 285       Entry_Call.State := New_State;
 286       STPO.Wakeup (Caller, Entry_Caller_Sleep);
 287    end Wakeup_Entry_Caller;
 288
 289    -----------------------
 290    -- Restricted GNARLI --
 291    -----------------------
 292
 293    --------------------------------
 294    -- Complete_Single_Entry_Body --
 295    --------------------------------
 296
 297    procedure Complete_Single_Entry_Body (Object : Protection_Entry_Access) is
 298       pragma Warnings (Off, Object);
 299
 300    begin
 301       --  Nothing needs to do (Object.Call_In_Progress.Exception_To_Raise
 302       --  has already been set to Null_Id).
 303
 304       null;
 305    end Complete_Single_Entry_Body;
 306
 307    --------------------------------------------
 308    -- Exceptional_Complete_Single_Entry_Body --
 309    --------------------------------------------
 310
 311    procedure Exceptional_Complete_Single_Entry_Body
 312      (Object : Protection_Entry_Access;
 313       Ex     : Ada.Exceptions.Exception_Id) is
 314    begin
 315       Object.Call_In_Progress.Exception_To_Raise := Ex;
 316    end Exceptional_Complete_Single_Entry_Body;
 317
 318    ---------------------------------
 319    -- Initialize_Protection_Entry --
 320    ---------------------------------
 321
 322    procedure Initialize_Protection_Entry
 323      (Object            : Protection_Entry_Access;
 324       Ceiling_Priority  : Integer;
 325       Compiler_Info     : System.Address;
 326       Entry_Body        : Entry_Body_Access)
 327    is
 328       Init_Priority : Integer := Ceiling_Priority;
 329    begin
 330       if Init_Priority = Unspecified_Priority then
 331          Init_Priority := System.Priority'Last;
 332       end if;
 333
 334       STPO.Initialize_Lock (Init_Priority, Object.L'Access);
 335       Object.Ceiling := System.Any_Priority (Init_Priority);
 336       Object.Compiler_Info := Compiler_Info;
 337       Object.Call_In_Progress := null;
 338       Object.Entry_Body := Entry_Body;
 339       Object.Entry_Queue := null;
 340    end Initialize_Protection_Entry;
 341
 342    ----------------
 343    -- Lock_Entry --
 344    ----------------
 345
 346    --  Compiler interface only.
 347    --  Do not call this procedure from within the run-time system.
 348
 349    procedure Lock_Entry (Object : Protection_Entry_Access) is
 350       Ceiling_Violation : Boolean;
 351
 352    begin
 353       --  If pragma Detect_Blocking is active then the protected object
 354       --  nesting level must be increased.
 355
 356       if Detect_Blocking then
 357          declare
 358             Self_Id : constant Task_Id := STPO.Self;
 359          begin
 360             --  We are entering in a protected action, so that we
 361             --  increase the protected object nesting level.
 362
 363             Self_Id.Common.Protected_Action_Nesting :=
 364               Self_Id.Common.Protected_Action_Nesting + 1;
 365          end;
 366       end if;
 367
 368       STPO.Write_Lock (Object.L'Access, Ceiling_Violation);
 369
 370       if Ceiling_Violation then
 371          raise Program_Error;
 372       end if;
 373    end Lock_Entry;
 374
 375    --------------------------
 376    -- Lock_Read_Only_Entry --
 377    --------------------------
 378
 379    --  Compiler interface only.
 380    --  Do not call this procedure from within the runtime system.
 381
 382    procedure Lock_Read_Only_Entry (Object : Protection_Entry_Access) is
 383       Ceiling_Violation : Boolean;
 384
 385    begin
 386       --  If pragma Detect_Blocking is active then the protected object
 387       --  nesting level must be increased.
 388
 389       if Detect_Blocking then
 390          declare
 391             Self_Id : constant Task_Id := STPO.Self;
 392          begin
 393             --  We are entering in a protected action, so that we
 394             --  increase the protected object nesting level.
 395
 396             Self_Id.Common.Protected_Action_Nesting :=
 397               Self_Id.Common.Protected_Action_Nesting + 1;
 398          end;
 399       end if;
 400
 401       STPO.Read_Lock (Object.L'Access, Ceiling_Violation);
 402
 403       if Ceiling_Violation then
 404          raise Program_Error;
 405       end if;
 406    end Lock_Read_Only_Entry;
 407
 408    --------------------
 409    -- PO_Do_Or_Queue --
 410    --------------------
 411
 412    procedure PO_Do_Or_Queue
 413      (Self_Id    : Task_Id;
 414       Object     : Protection_Entry_Access;
 415       Entry_Call : Entry_Call_Link)
 416    is
 417       Barrier_Value : Boolean;
 418    begin
 419       --  When the Action procedure for an entry body returns, it must be
 420       --  completed (having called [Exceptional_]Complete_Entry_Body).
 421
 422       Barrier_Value := Object.Entry_Body.Barrier (Object.Compiler_Info, 1);
 423
 424       if Barrier_Value then
 425          if Object.Call_In_Progress /= null then
 426             --  This violates the No_Entry_Queue restriction, send
 427             --  Program_Error to the caller.
 428
 429             Send_Program_Error (Self_Id, Entry_Call);
 430             return;
 431          end if;
 432
 433          Object.Call_In_Progress := Entry_Call;
 434          Object.Entry_Body.Action
 435            (Object.Compiler_Info, Entry_Call.Uninterpreted_Data, 1);
 436          Object.Call_In_Progress := null;
 437
 438          if Single_Lock then
 439             STPO.Lock_RTS;
 440          end if;
 441
 442          STPO.Write_Lock (Entry_Call.Self);
 443          Wakeup_Entry_Caller (Self_Id, Entry_Call, Done);
 444          STPO.Unlock (Entry_Call.Self);
 445
 446          if Single_Lock then
 447             STPO.Unlock_RTS;
 448          end if;
 449
 450       elsif Entry_Call.Mode /= Conditional_Call then
 451          Object.Entry_Queue := Entry_Call;
 452       else
 453          --  Conditional_Call
 454
 455          if Single_Lock then
 456             STPO.Lock_RTS;
 457          end if;
 458
 459          STPO.Write_Lock (Entry_Call.Self);
 460          Wakeup_Entry_Caller (Self_Id, Entry_Call, Cancelled);
 461          STPO.Unlock (Entry_Call.Self);
 462
 463          if Single_Lock then
 464             STPO.Unlock_RTS;
 465          end if;
 466       end if;
 467
 468    exception
 469       when others =>
 470          Send_Program_Error
 471            (Self_Id, Entry_Call);
 472    end PO_Do_Or_Queue;
 473
 474    ----------------------------
 475    -- Protected_Single_Count --
 476    ----------------------------
 477
 478    function Protected_Count_Entry (Object : Protection_Entry) return Natural is
 479    begin
 480       if Object.Entry_Queue /= null then
 481          return 1;
 482       else
 483          return 0;
 484       end if;
 485    end Protected_Count_Entry;
 486
 487    ---------------------------------
 488    -- Protected_Single_Entry_Call --
 489    ---------------------------------
 490
 491    procedure Protected_Single_Entry_Call
 492      (Object             : Protection_Entry_Access;
 493       Uninterpreted_Data : System.Address;
 494       Mode               : Call_Modes)
 495    is
 496       Self_Id           : constant Task_Id := STPO.Self;
 497       Entry_Call        : Entry_Call_Record renames Self_Id.Entry_Calls (1);
 498       Ceiling_Violation : Boolean;
 499
 500    begin
 501       --  If pragma Detect_Blocking is active then Program_Error must be
 502       --  raised if this potentially blocking operation is called from a
 503       --  protected action.
 504
 505       if Detect_Blocking
 506         and then Self_Id.Common.Protected_Action_Nesting > 0
 507       then
 508          Ada.Exceptions.Raise_Exception
 509            (Program_Error'Identity, "potentially blocking operation");
 510       end if;
 511
 512       STPO.Write_Lock (Object.L'Access, Ceiling_Violation);
 513
 514       if Ceiling_Violation then
 515          raise Program_Error;
 516       end if;
 517
 518       Entry_Call.Mode := Mode;
 519       Entry_Call.State := Now_Abortable;
 520       Entry_Call.Uninterpreted_Data := Uninterpreted_Data;
 521       Entry_Call.Exception_To_Raise := Ada.Exceptions.Null_Id;
 522
 523       PO_Do_Or_Queue (Self_Id, Object, Entry_Call'Access);
 524       Unlock_Entry (Object);
 525
 526       --  The call is either `Done' or not. It cannot be cancelled since there
 527       --  is no ATC construct.
 528
 529       pragma Assert (Entry_Call.State /= Cancelled);
 530
 531       if Entry_Call.State /= Done then
 532          if Single_Lock then
 533             STPO.Lock_RTS;
 534          end if;
 535
 536          STPO.Write_Lock (Self_Id);
 537          Wait_For_Completion (Entry_Call'Access);
 538          STPO.Unlock (Self_Id);
 539
 540          if Single_Lock then
 541             STPO.Unlock_RTS;
 542          end if;
 543       end if;
 544
 545       Check_Exception (Self_Id, Entry_Call'Access);
 546    end Protected_Single_Entry_Call;
 547
 548    -----------------------------------
 549    -- Protected_Single_Entry_Caller --
 550    -----------------------------------
 551
 552    function Protected_Single_Entry_Caller
 553      (Object : Protection_Entry) return Task_Id is
 554    begin
 555       return Object.Call_In_Progress.Self;
 556    end Protected_Single_Entry_Caller;
 557
 558    -------------------
 559    -- Service_Entry --
 560    -------------------
 561
 562    procedure Service_Entry (Object : Protection_Entry_Access) is
 563       Self_Id    : constant Task_Id := STPO.Self;
 564       Entry_Call : constant Entry_Call_Link := Object.Entry_Queue;
 565       Caller     : Task_Id;
 566
 567    begin
 568       if Entry_Call /= null
 569         and then Object.Entry_Body.Barrier (Object.Compiler_Info, 1)
 570       then
 571          Object.Entry_Queue := null;
 572
 573          if Object.Call_In_Progress /= null then
 574
 575             --  Violation of No_Entry_Queue restriction, raise exception
 576
 577             Send_Program_Error (Self_Id, Entry_Call);
 578             Unlock_Entry (Object);
 579             return;
 580          end if;
 581
 582          Object.Call_In_Progress := Entry_Call;
 583          Object.Entry_Body.Action
 584            (Object.Compiler_Info, Entry_Call.Uninterpreted_Data, 1);
 585          Object.Call_In_Progress := null;
 586          Caller := Entry_Call.Self;
 587          Unlock_Entry (Object);
 588
 589          if Single_Lock then
 590             STPO.Lock_RTS;
 591          end if;
 592
 593          STPO.Write_Lock (Caller);
 594          Wakeup_Entry_Caller (Self_Id, Entry_Call, Done);
 595          STPO.Unlock (Caller);
 596
 597          if Single_Lock then
 598             STPO.Unlock_RTS;
 599          end if;
 600
 601       else
 602          --  Just unlock the entry
 603
 604          Unlock_Entry (Object);
 605       end if;
 606
 607    exception
 608       when others =>
 609          Send_Program_Error (Self_Id, Entry_Call);
 610          Unlock_Entry (Object);
 611    end Service_Entry;
 612
 613    ---------------------------------------
 614    -- Timed_Protected_Single_Entry_Call --
 615    ---------------------------------------
 616
 617    --  Compiler interface only. Do not call from within the RTS.
 618
 619    procedure Timed_Protected_Single_Entry_Call
 620      (Object                : Protection_Entry_Access;
 621       Uninterpreted_Data    : System.Address;
 622       Timeout               : Duration;
 623       Mode                  : Delay_Modes;
 624       Entry_Call_Successful : out Boolean)
 625    is
 626       Self_Id           : constant Task_Id  := STPO.Self;
 627       Entry_Call        : Entry_Call_Record renames Self_Id.Entry_Calls (1);
 628       Ceiling_Violation : Boolean;
 629
 630    begin
 631       --  If pragma Detect_Blocking is active then Program_Error must be
 632       --  raised if this potentially blocking operation is called from a
 633       --  protected action.
 634
 635       if Detect_Blocking
 636         and then Self_Id.Common.Protected_Action_Nesting > 0
 637       then
 638          Ada.Exceptions.Raise_Exception
 639            (Program_Error'Identity, "potentially blocking operation");
 640       end if;
 641
 642       STPO.Write_Lock (Object.L'Access, Ceiling_Violation);
 643
 644       if Ceiling_Violation then
 645          raise Program_Error;
 646       end if;
 647
 648       Entry_Call.Mode := Timed_Call;
 649       Entry_Call.State := Now_Abortable;
 650       Entry_Call.Uninterpreted_Data := Uninterpreted_Data;
 651       Entry_Call.Exception_To_Raise := Ada.Exceptions.Null_Id;
 652
 653       PO_Do_Or_Queue (Self_Id, Object, Entry_Call'Access);
 654       Unlock_Entry (Object);
 655
 656       --  Try to avoid waiting for completed calls.
 657       --  The call is either `Done' or not. It cannot be cancelled since there
 658       --  is no ATC construct and the timed wait has not started yet.
 659
 660       pragma Assert (Entry_Call.State /= Cancelled);
 661
 662       if Entry_Call.State = Done then
 663          Check_Exception (Self_Id, Entry_Call'Access);
 664          Entry_Call_Successful := True;
 665          return;
 666       end if;
 667
 668       if Single_Lock then
 669          STPO.Lock_RTS;
 670       else
 671          STPO.Write_Lock (Self_Id);
 672       end if;
 673
 674       Wait_For_Completion_With_Timeout (Entry_Call'Access, Timeout, Mode);
 675
 676       if Single_Lock then
 677          STPO.Unlock_RTS;
 678       else
 679          STPO.Unlock (Self_Id);
 680       end if;
 681
 682       pragma Assert (Entry_Call.State >= Done);
 683
 684       Check_Exception (Self_Id, Entry_Call'Access);
 685       Entry_Call_Successful := Entry_Call.State = Done;
 686    end Timed_Protected_Single_Entry_Call;
 687
 688    ------------------
 689    -- Unlock_Entry --
 690    ------------------
 691
 692    procedure Unlock_Entry (Object : Protection_Entry_Access) is
 693    begin
 694       --  We are exiting from a protected action, so that we decrease the
 695       --  protected object nesting level (if pragma Detect_Blocking is active).
 696
 697       if Detect_Blocking then
 698          declare
 699             Self_Id : constant Task_Id := Self;
 700
 701          begin
 702             --  Cannot call Unlock_Entry without being within protected action
 703
 704             pragma Assert (Self_Id.Common.Protected_Action_Nesting > 0);
 705
 706             Self_Id.Common.Protected_Action_Nesting :=
 707               Self_Id.Common.Protected_Action_Nesting - 1;
 708          end;
 709       end if;
 710
 711       STPO.Unlock (Object.L'Access);
 712    end Unlock_Entry;
 713
 714 end System.Tasking.Protected_Objects.Single_Entry;