libffi/src/sparc/v8.S

   1 /* -----------------------------------------------------------------------
   2    v8.S - Copyright (c) 1996, 1997, 2003, 2004 Red Hat, Inc.
   3
   4    SPARC Foreign Function Interface
   5
   6    Permission is hereby granted, free of charge, to any person obtaining
   7    a copy of this software and associated documentation files (the
   8    ``Software''), to deal in the Software without restriction, including
   9    without limitation the rights to use, copy, modify, merge, publish,
  10    distribute, sublicense, and/or sell copies of the Software, and to
  11    permit persons to whom the Software is furnished to do so, subject to
  12    the following conditions:
  13
  14    The above copyright notice and this permission notice shall be included
  15    in all copies or substantial portions of the Software.
  16
  17    THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, EXPRESS
  18    OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19    MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  20    IN NO EVENT SHALL CYGNUS SOLUTIONS BE LIABLE FOR ANY CLAIM, DAMAGES OR
  21    OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
  22    ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  23    OTHER DEALINGS IN THE SOFTWARE.
  24    ----------------------------------------------------------------------- */
  25
  26 #define LIBFFI_ASM
  27 #include <fficonfig.h>
  28 #include <ffi.h>
  29
  30 #define STACKFRAME 96           /* Minimum stack framesize for SPARC */
  31 #define ARGS (64+4)             /* Offset of register area in frame */
  32
  33 .text
  34         .align 8
  35 .globl ffi_call_v8
  36 .globl _ffi_call_v8
  37
  38 ffi_call_v8:
  39 _ffi_call_v8:
  40 .LLFB1:
  41         save    %sp, -STACKFRAME, %sp
  42 .LLCFI0:
  43
  44         sub     %sp, %i2, %sp   ! alloca() space in stack for frame to set up
  45         add     %sp, STACKFRAME, %l0    ! %l0 has start of
  46                                         ! frame to set up
  47
  48         mov     %l0, %o0        ! call routine to set up frame
  49         call    %i0
  50         mov     %i1, %o1        ! (delay)
  51
  52         ld      [%l0+ARGS], %o0 ! call foreign function
  53         ld      [%l0+ARGS+4], %o1
  54         ld      [%l0+ARGS+8], %o2
  55         ld      [%l0+ARGS+12], %o3
  56         ld      [%l0+ARGS+16], %o4
  57         ld      [%l0+ARGS+20], %o5
  58         call    %i5
  59         mov     %l0, %sp        ! (delay) switch to frame
  60         nop                     ! STRUCT returning functions skip 12 instead of 8 bytes
  61
  62         ! If the return value pointer is NULL, assume no return value.
  63         tst     %i4
  64         bz      done
  65         nop
  66
  67         cmp     %i3, FFI_TYPE_INT
  68         be,a    done
  69         st      %o0, [%i4]      ! (delay)
  70
  71         cmp     %i3, FFI_TYPE_FLOAT
  72         be,a    done
  73         st      %f0, [%i4+0]    ! (delay)
  74
  75         cmp     %i3, FFI_TYPE_SINT64
  76         be      longlong
  77
  78         cmp     %i3, FFI_TYPE_DOUBLE
  79         bne     done
  80         nop
  81         st      %f0, [%i4+0]
  82         st      %f1, [%i4+4]
  83
  84 done:
  85         ret
  86         restore
  87
  88 longlong:
  89         st      %o0, [%i4+0]
  90         st      %o1, [%i4+4]
  91         ret
  92         restore
  93 .LLFE1:
  94
  95 .ffi_call_v8_end:
  96         .size   ffi_call_v8,.ffi_call_v8_end-ffi_call_v8
  97
  98
  99 #undef STACKFRAME
 100 #define STACKFRAME      104     /* 16*4 register window +
 101                                    1*4 struct return +
 102                                    6*4 args backing store +
 103                                    3*4 locals */
 104
 105 /* ffi_closure_v8(...)
 106
 107    Receives the closure argument in %g2.   */
 108
 109         .text
 110         .align 8
 111         .globl ffi_closure_v8
 112
 113 ffi_closure_v8:
 114 #ifdef HAVE_AS_REGISTER_PSEUDO_OP
 115                 .register       %g2, #scratch
 116 #endif
 117 .LLFB2:
 118         save    %sp, -STACKFRAME, %sp
 119 .LLCFI1:
 120
 121         ! Store all of the potential argument registers in va_list format.
 122         st      %i0, [%fp+68+0]
 123         st      %i1, [%fp+68+4]
 124         st      %i2, [%fp+68+8]
 125         st      %i3, [%fp+68+12]
 126         st      %i4, [%fp+68+16]
 127         st      %i5, [%fp+68+20]
 128
 129         ! Call ffi_closure_sparc_inner to do the bulk of the work.
 130         mov     %g2, %o0
 131         add     %fp, -8, %o1
 132         call    ffi_closure_sparc_inner_v8
 133          add    %fp,  64, %o2
 134
 135         ! Load up the return value in the proper type.
 136         ! See ffi_prep_cif_machdep for the list of cases.
 137         cmp     %o0, FFI_TYPE_VOID
 138         be      done1
 139
 140         cmp     %o0, FFI_TYPE_INT
 141         be      integer
 142
 143         cmp     %o0, FFI_TYPE_FLOAT
 144         be,a    done1
 145          ld     [%fp-8], %f0
 146
 147         cmp     %o0, FFI_TYPE_DOUBLE
 148         be,a    done1
 149          ldd    [%fp-8], %f0
 150
 151 #if FFI_TYPE_LONGDOUBLE != FFI_TYPE_DOUBLE
 152         cmp     %o0, FFI_TYPE_LONGDOUBLE
 153         be      done2
 154 #endif
 155
 156         cmp     %o0, FFI_TYPE_STRUCT
 157         be      done2
 158
 159         ! FFI_TYPE_SINT64
 160         ld      [%fp-4], %i1
 161
 162 integer:
 163         ld      [%fp-8], %i0
 164
 165 done1:
 166         jmp     %i7+8
 167          restore
 168 done2:
 169         ! Skip 'unimp'.
 170         jmp     %i7+12
 171          restore
 172 .LLFE2:
 173
 174 .ffi_closure_v8_end:
 175         .size   ffi_closure_v8,.ffi_closure_v8_end-ffi_closure_v8
 176
 177 #ifdef SPARC64
 178 #define WS 8
 179 #define nword   xword
 180 #define uanword uaxword
 181 #else
 182 #define WS 4
 183 #define nword   long
 184 #define uanword uaword
 185 #endif
 186
 187 #ifdef HAVE_RO_EH_FRAME
 188         .section        ".eh_frame",#alloc
 189 #else
 190         .section        ".eh_frame",#alloc,#write
 191 #endif
 192 .LLframe1:
 193         .uaword .LLECIE1-.LLSCIE1       ! Length of Common Information Entry
 194 .LLSCIE1:
 195         .uaword 0x0     ! CIE Identifier Tag
 196         .byte   0x1     ! CIE Version
 197         .ascii "zR\0"   ! CIE Augmentation
 198         .byte   0x1     ! uleb128 0x1; CIE Code Alignment Factor
 199         .byte   0x80-WS ! sleb128 -WS; CIE Data Alignment Factor
 200         .byte   0xf     ! CIE RA Column
 201         .byte   0x1     ! uleb128 0x1; Augmentation size
 202 #ifdef HAVE_AS_SPARC_UA_PCREL
 203         .byte   0x1b    ! FDE Encoding (pcrel sdata4)
 204 #else
 205         .byte   0x50    ! FDE Encoding (aligned absolute)
 206 #endif
 207         .byte   0xc     ! DW_CFA_def_cfa
 208         .byte   0xe     ! uleb128 0xe
 209         .byte   0x0     ! uleb128 0x0
 210         .align  WS
 211 .LLECIE1:
 212 .LLSFDE1:
 213         .uaword .LLEFDE1-.LLASFDE1      ! FDE Length
 214 .LLASFDE1:
 215         .uaword .LLASFDE1-.LLframe1     ! FDE CIE offset
 216 #ifdef HAVE_AS_SPARC_UA_PCREL
 217         .uaword %r_disp32(.LLFB1)
 218         .uaword .LLFE1-.LLFB1   ! FDE address range
 219 #else
 220         .align  WS
 221         .nword  .LLFB1
 222         .uanword .LLFE1-.LLFB1  ! FDE address range
 223 #endif
 224         .byte   0x0     ! uleb128 0x0; Augmentation size
 225         .byte   0x4     ! DW_CFA_advance_loc4
 226         .uaword .LLCFI0-.LLFB1
 227         .byte   0xd     ! DW_CFA_def_cfa_register
 228         .byte   0x1e    ! uleb128 0x1e
 229         .byte   0x2d    ! DW_CFA_GNU_window_save
 230         .byte   0x9     ! DW_CFA_register
 231         .byte   0xf     ! uleb128 0xf
 232         .byte   0x1f    ! uleb128 0x1f
 233         .align  WS
 234 .LLEFDE1:
 235 .LLSFDE2:
 236         .uaword .LLEFDE2-.LLASFDE2      ! FDE Length
 237 .LLASFDE2:
 238         .uaword .LLASFDE2-.LLframe1     ! FDE CIE offset
 239 #ifdef HAVE_AS_SPARC_UA_PCREL
 240         .uaword %r_disp32(.LLFB2)
 241         .uaword .LLFE2-.LLFB2   ! FDE address range
 242 #else
 243         .align  WS
 244         .nword  .LLFB2
 245         .uanword .LLFE2-.LLFB2  ! FDE address range
 246 #endif
 247         .byte   0x0     ! uleb128 0x0; Augmentation size
 248         .byte   0x4     ! DW_CFA_advance_loc4
 249         .uaword .LLCFI1-.LLFB2
 250         .byte   0xd     ! DW_CFA_def_cfa_register
 251         .byte   0x1e    ! uleb128 0x1e
 252         .byte   0x2d    ! DW_CFA_GNU_window_save
 253         .byte   0x9     ! DW_CFA_register
 254         .byte   0xf     ! uleb128 0xf
 255         .byte   0x1f    ! uleb128 0x1f
 256         .align  WS
 257 .LLEFDE2: