gcc/ada/s-intman-posix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the POSIX threads version of this package
  35
  36 --  Make a careful study of all signals available under the OS, to see which
  37 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  38 --  the lookout for special signals that may be used by the thread library.
  39
  40 --  Since this is a multi target file, the signal <-> exception mapping
  41 --  is simple minded. If you need a more precise and target specific
  42 --  signal handling, create a new s-intman.adb that will fit your needs.
  43
  44 --  This file assumes that:
  45
  46 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  47 --      SIGPFE  => Constraint_Error
  48 --      SIGILL  => Program_Error
  49 --      SIGSEGV => Storage_Error
  50 --      SIGBUS  => Storage_Error
  51
  52 --    SIGINT exists and will be kept unmasked unless the pragma
  53 --     Unreserve_All_Interrupts is specified anywhere in the application.
  54
  55 --    System.OS_Interface contains the following:
  56 --      SIGADAABORT: the signal that will be used to abort tasks.
  57 --      Unmasked: the OS specific set of signals that should be unmasked in
  58 --                all the threads. SIGADAABORT is unmasked by
  59 --                default
  60 --      Reserved: the OS specific set of signals that are reserved.
  61
  62 package body System.Interrupt_Management is
  63
  64    use Interfaces.C;
  65    use System.OS_Interface;
  66
  67    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  68    Exception_Interrupts : constant Interrupt_List :=
  69      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  70
  71    Unreserve_All_Interrupts : Interfaces.C.int;
  72    pragma Import
  73      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  74
  75    -----------------------
  76    -- Local Subprograms --
  77    -----------------------
  78
  79    function State (Int : Interrupt_ID) return Character;
  80    pragma Import (C, State, "__gnat_get_interrupt_state");
  81    --  Get interrupt state. Defined in init.c
  82    --  The input argument is the interrupt number,
  83    --  and the result is one of the following:
  84
  85    User    : constant Character := 'u';
  86    Runtime : constant Character := 'r';
  87    Default : constant Character := 's';
  88    --    'n'   this interrupt not set by any Interrupt_State pragma
  89    --    'u'   Interrupt_State pragma set state to User
  90    --    'r'   Interrupt_State pragma set state to Runtime
  91    --    's'   Interrupt_State pragma set state to System (use "default"
  92    --           system handler)
  93
  94    procedure Notify_Exception
  95      (signo    : Signal;
  96       siginfo  : System.Address;
  97       ucontext : System.Address);
  98    --  This function identifies the Ada exception to be raised using
  99    --  the information when the system received a synchronous signal.
 100    --  Since this function is machine and OS dependent, different code
 101    --  has to be provided for different target.
 102
 103    ----------------------
 104    -- Notify_Exception --
 105    ----------------------
 106
 107    Signal_Mask : aliased sigset_t;
 108    --  The set of signals handled by Notify_Exception
 109
 110    procedure Notify_Exception
 111      (signo    : Signal;
 112       siginfo  : System.Address;
 113       ucontext : System.Address)
 114    is
 115       pragma Unreferenced (siginfo);
 116
 117       --  The GCC unwinder requires adjustments to the signal's machine
 118       --  context to be able to properly unwind through the signal handler.
 119       --  This is achieved by the target specific subprogram below, provided
 120       --  by init.c to be usable by the non-tasking handler also.
 121
 122       procedure Adjust_Context_For_Raise
 123         (signo    : Signal;
 124          ucontext : System.Address);
 125       pragma Import
 126         (C, Adjust_Context_For_Raise, "__gnat_adjust_context_for_raise");
 127
 128       Result  : Interfaces.C.int;
 129
 130    begin
 131       --  With the __builtin_longjmp, the signal mask is not restored, so we
 132       --  need to restore it explicitely.
 133
 134       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 135       pragma Assert (Result = 0);
 136
 137       --  Perform the necessary context adjustments required by the GCC/ZCX
 138       --  unwinder, harmless in the SJLJ case.
 139
 140       Adjust_Context_For_Raise (signo, ucontext);
 141
 142       --  Check that treatment of exception propagation here
 143       --  is consistent with treatment of the abort signal in
 144       --  System.Task_Primitives.Operations.
 145
 146       case signo is
 147          when SIGFPE =>
 148             raise Constraint_Error;
 149          when SIGILL =>
 150             raise Program_Error;
 151          when SIGSEGV =>
 152             raise Storage_Error;
 153          when SIGBUS =>
 154             raise Storage_Error;
 155          when others =>
 156             null;
 157       end case;
 158    end Notify_Exception;
 159
 160    ----------------
 161    -- Initialize --
 162    ----------------
 163
 164    Initialized : Boolean := False;
 165
 166    procedure Initialize is
 167       act     : aliased struct_sigaction;
 168       old_act : aliased struct_sigaction;
 169       Result  : System.OS_Interface.int;
 170
 171    begin
 172       if Initialized then
 173          return;
 174       end if;
 175
 176       Initialized := True;
 177
 178       --  Need to call pthread_init very early because it is doing signal
 179       --  initializations.
 180
 181       pthread_init;
 182
 183       Abort_Task_Interrupt := SIGADAABORT;
 184
 185       act.sa_handler := Notify_Exception'Address;
 186
 187       act.sa_flags := SA_SIGINFO;
 188
 189       --  Setting SA_SIGINFO asks the kernel to pass more than just the signal
 190       --  number argument to the handler when it is called. The set of extra
 191       --  parameters includes a pointer to the interrupted context, which the
 192       --  ZCX propagation scheme needs.
 193
 194       --  Most man pages for sigaction mention that sa_sigaction should be set
 195       --  instead of sa_handler when SA_SIGINFO is on.  In practice, the two
 196       --  fields are actually union'ed and located at the same offset.
 197
 198       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 199       --  handler execution we do not change the Signal_Mask to be masked for
 200       --  the Signal.
 201
 202       --  This is a temporary fix to the problem that the Signal_Mask is
 203       --  not restored after the exception (longjmp) from the handler.
 204       --  The right fix should be made in sigsetjmp so that we save
 205       --  the Signal_Set and restore it after a longjmp.
 206
 207       --  Since SA_NODEFER is obsolete, instead we reset explicitely
 208       --  the mask in the exception handler.
 209
 210       Result := sigemptyset (Signal_Mask'Access);
 211       pragma Assert (Result = 0);
 212
 213       --  Add signals that map to Ada exceptions to the mask.
 214       for J in Exception_Interrupts'Range loop
 215          if State (Exception_Interrupts (J)) /= Default  then
 216             Result :=
 217             sigaddset (Signal_Mask'Access, Signal (Exception_Interrupts (J)));
 218             pragma Assert (Result = 0);
 219          end if;
 220       end loop;
 221
 222       act.sa_mask := Signal_Mask;
 223
 224       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 225       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 226
 227       --  Process state of exception signals
 228       for J in Exception_Interrupts'Range loop
 229          if State (Exception_Interrupts (J)) /= User then
 230             Keep_Unmasked (Exception_Interrupts (J)) := True;
 231             Reserve (Exception_Interrupts (J)) := True;
 232
 233             if State (Exception_Interrupts (J)) /= Default then
 234                Result :=
 235                  sigaction
 236                  (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 237                   old_act'Unchecked_Access);
 238                pragma Assert (Result = 0);
 239             end if;
 240          end if;
 241       end loop;
 242
 243       if State (Abort_Task_Interrupt) /= User then
 244          Keep_Unmasked (Abort_Task_Interrupt) := True;
 245          Reserve (Abort_Task_Interrupt) := True;
 246       end if;
 247
 248       --  Set SIGINT to unmasked state as long as it is not in "User"
 249       --  state. Check for Unreserve_All_Interrupts last
 250
 251       if State (SIGINT) /= User then
 252          Keep_Unmasked (SIGINT) := True;
 253          Reserve (SIGINT) := True;
 254       end if;
 255
 256       --  Check all signals for state that requires keeping them
 257       --  unmasked and reserved
 258
 259       for J in Interrupt_ID'Range loop
 260          if State (J) = Default or else State (J) = Runtime then
 261             Keep_Unmasked (J) := True;
 262             Reserve (J) := True;
 263          end if;
 264       end loop;
 265
 266       --  Add the set of signals that must always be unmasked for this target
 267
 268       for J in Unmasked'Range loop
 269          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 270          Reserve (Interrupt_ID (Unmasked (J))) := True;
 271       end loop;
 272
 273       --  Add target-specific reserved signals
 274
 275       for J in Reserved'Range loop
 276          Reserve (Interrupt_ID (Reserved (J))) := True;
 277       end loop;
 278
 279       --  Process pragma Unreserve_All_Interrupts. This overrides any
 280       --  settings due to pragma Interrupt_State:
 281
 282       if Unreserve_All_Interrupts /= 0 then
 283          Keep_Unmasked (SIGINT) := False;
 284          Reserve (SIGINT) := False;
 285       end if;
 286
 287       --  We do not have Signal 0 in reality. We just use this value
 288       --  to identify non-existent signals (see s-intnam.ads). Therefore,
 289       --  Signal 0 should not be used in all signal related operations hence
 290       --  mark it as reserved.
 291
 292       Reserve (0) := True;
 293    end Initialize;
 294
 295 end System.Interrupt_Management;