libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 for package in gnu/gcj/tools/gc_analyze ; do
 300     echo $package >> standard.omit
 301     echo $package >> vm-tools-packages
 302 done
 303
 304 if test -z "${with_multisubdir}"; then
 305    builddotdot=.
 306 else
 307    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 308 fi
 309
 310 NATIVE=yes
 311
 312 # Which gcj and host gcj (for ecjx) do we use?
 313 which_gcj=default
 314 host_exeext=${ac_exeext}
 315 GCJ_FOR_ECJX=
 316 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 317 if test -n "${with_cross_host}"; then
 318   # We are being configured with a cross compiler. We can't
 319   # use ac_exeext, because that is for the target platform.
 320   NATIVE=no
 321   cross_host_exeext=
 322   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 323   case "${with_cross_host}" in
 324      *mingw* | *cygwin*)
 325          cross_host_exeext=.exe
 326      ;;
 327   esac
 328   host_exeext=${cross_host_exeext}
 329   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 330      if test x"$build_noncanonical" = x"$with_cross_host"; then
 331         # Ordinary cross (host!=target and host=build)
 332         which_gcj=built
 333      else
 334         # Canadian cross (host!=target and host!=build)
 335         which_gcj=cross
 336      fi
 337   else
 338      which_gcj=cross
 339   fi
 340 else
 341   # We are being configured with a native or crossed-native compiler
 342   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 343      if test x"$build" = x"$host"; then
 344         # True native build (host=target and host=build)
 345         which_gcj=built
 346      else
 347         # Crossed-native build (host=target and host!=build)
 348         which_gcj=cross
 349      fi
 350   else
 351      which_gcj=path
 352   fi
 353 fi
 354 case "${which_gcj}" in
 355    built)
 356       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 357       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 358    ;;
 359    cross)
 360       if test "x${with_newlib}" = "xyes"; then
 361          # FIXME (comment): Why is this needed?
 362          GCC_UNWIND_INCLUDE=
 363          GCJ="${target_noncanonical}-gcj"
 364       else
 365          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 366       fi
 367       GCJH='$(target_noncanonical)-gcjh'
 368    ;;
 369    path)
 370       GCJ="gcj -B`${PWDCMD-pwd}`/"
 371       GCJH=gcjh
 372    ;;
 373 esac
 374
 375 AC_SUBST(GCJ_FOR_ECJX)
 376 AC_SUBST(GCJH)
 377 AC_SUBST(host_exeext)
 378
 379 # Create it, so that compile/link tests don't fail
 380 test -f libgcj.spec || touch libgcj.spec
 381
 382
 383
 384 # Set up to configure Classpath.
 385 # FIXME: no supported way to pass args in autoconf.
 386 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 387 # Disable tool wrappers to avoid ltdl.h configure check.
 388 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 389 ac_configure_args="$ac_configure_args --disable-load-library"
 390 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 391 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 392 dir1=`cd $srcdir && pwd`
 393 dir2=`pwd`
 394 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 395 ac_configure_args="$ac_configure_args --disable-core-jni"
 396 dnl FIXME?
 397 ac_configure_args="$ac_configure_args --disable-examples"
 398 ac_configure_args="$ac_configure_args --with-glibj=build"
 399 if test "$plugin_enabled" != yes; then
 400   ac_configure_args="$ac_configure_args --disable-plugin"
 401 fi
 402 if test "$gconf_enabled" != yes; then
 403   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 404   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 405 fi
 406 if test "$use_gtk_awt" != yes; then
 407   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 408 fi
 409 if test "$use_qt_awt" != yes; then
 410   ac_configure_args="$ac_configure_args --disable-qt-peer"
 411 else
 412   # We need this as qt is disabled by default in classpath.
 413   ac_configure_args="$ac_configure_args --enable-qt-peer"
 414 fi
 415 if test "$use_x_awt" != yes; then
 416   ac_configure_args="$ac_configure_args --without-escher"
 417 else
 418   # We need this as escher is disabled by default in classpath.
 419   if test "$use_escher" != true; then
 420     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 421   else
 422     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 423   fi
 424 fi
 425 # -Werror causes unavoidable problems in code using alsa.
 426 ac_configure_args="$ac_configure_args --disable-Werror"
 427 dnl --with-gcj=$GCJ
 428 dnl --with-javah=$GCJH
 429 dnl gjdoc?
 430 dnl gtk-cairo -- just export here...
 431 dnl --enable-regen-headers?
 432
 433 # Only use libltdl for non-newlib builds.
 434 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 435    AC_LIBLTDL_CONVENIENCE
 436    AC_LIBTOOL_DLOPEN
 437    DIRLTDL=libltdl
 438    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 439    # Sigh.  Libtool's macro doesn't do the right thing.
 440    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 441    # FIXME: this is a hack.
 442    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 443    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 444 fi
 445 AC_SUBST(INCLTDL)
 446 AC_SUBST(LIBLTDL)
 447 AC_SUBST(DIRLTDL)
 448 AC_PROG_LIBTOOL
 449 AM_PROG_GCJ
 450 AM_PROG_CC_C_O
 451
 452 AC_CONFIG_SUBDIRS(classpath libltdl)
 453
 454 # The -no-testsuite modules omit the test subdir.
 455 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 456
 457 # Should the runtime set system properties by examining the
 458 # environment variable GCJ_PROPERTIES?
 459 AC_ARG_ENABLE(getenv-properties,
 460   AS_HELP_STRING([--disable-getenv-properties],
 461                  [don't set system properties from GCJ_PROPERTIES]))
 462
 463 # Whether GCJ_PROPERTIES is used depends on the target.
 464 if test -z "$enable_getenv_properties"; then
 465    enable_getenv_properties=${enable_getenv_properties_default-yes}
 466 fi
 467 if test "$enable_getenv_properties" = no; then
 468    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 469      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 470 fi
 471
 472 # Whether we should use arguments to main()
 473 if test -z "$enable_main_args"; then
 474    enable_main_args=${enable_main_args_default-yes}
 475 fi
 476 if test "$enable_main_args" = no; then
 477    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 478 fi
 479
 480
 481 # Should we use hashtable-based synchronization?
 482 # Currently works only for Linux X86/ia64
 483 # Typically faster and more space-efficient
 484 AC_ARG_ENABLE(hash-synchronization,
 485   AS_HELP_STRING([--enable-hash-synchronization],
 486                  [use global hash table for monitor locks]))
 487
 488 if test -z "$enable_hash_synchronization"; then
 489    enable_hash_synchronization=$enable_hash_synchronization_default
 490 fi
 491
 492
 493 install_ecj_jar=no
 494 ECJ_BUILD_JAR=
 495 ECJ_JAR=
 496 AC_ARG_WITH(ecj-jar,
 497         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 498         [ECJ_JAR=$withval],
 499         [if test -f $multi_basedir/ecj.jar; then
 500            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 501            ECJ_JAR='$(jardir)/ecj.jar'
 502            install_ecj_jar=yes
 503          fi])
 504 AC_SUBST(ECJ_BUILD_JAR)
 505 AC_SUBST(ECJ_JAR)
 506 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 507 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 508
 509 AC_ARG_WITH(java-home,
 510   AS_HELP_STRING([--with-java-home=DIRECTORY],
 511                  [value of java.home system property]),
 512                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 513 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 514 AC_SUBST(JAVA_HOME)
 515
 516 # What is the native OS API for MinGW?
 517 AC_ARG_WITH(win32-nlsapi,
 518   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 519                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 520 [case "${withval}" in
 521   ansi) with_win32_nlsapi=ansi ;;
 522   unicows) with_win32_nlsapi=unicows ;;
 523   unicode) with_win32_nlsapi=unicode ;;
 524   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 525 esac],[with_win32_nlsapi=ansi])
 526
 527 case "${with_win32_nlsapi}" in
 528   unicows | unicode)
 529     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 530       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 531     ;;
 532 esac
 533
 534 # configure.host sets slow_pthread_self if the synchronization code should
 535 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 536 if test "${slow_pthread_self}" = "yes"; then
 537   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 538     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 539 fi
 540
 541 # Check for gc debugging.  This option is handled both here and in the GC.
 542 AC_ARG_ENABLE(gc-debug,
 543    AS_HELP_STRING([--enable-gc-debug],
 544                   [include full support for pointer backtracing etc.]),
 545 [ if test "$enable_gc_debug" = "yes"; then
 546     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 547               [Define if we want to use debug calls into the garbage collector.])
 548   fi])
 549
 550 # See if the user has the interpreter included.
 551 AC_ARG_ENABLE(interpreter,
 552   AS_HELP_STRING([--enable-interpreter],
 553                  [enable interpreter]),
 554   [if test "$enable_interpreter" = yes; then
 555     # This can also be set in configure.host.
 556     libgcj_interpreter=yes
 557   elif test "$enable_interpreter" = no; then
 558     libgcj_interpreter=no
 559   fi])
 560
 561 if test "$libgcj_interpreter" = yes; then
 562    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 563 fi
 564 INTERPRETER="$libgcj_interpreter"
 565 AC_SUBST(INTERPRETER)
 566
 567 AC_MSG_CHECKING([for exception model to use])
 568 AC_LANG_PUSH(C++)
 569 AC_ARG_ENABLE(sjlj-exceptions,
 570   AS_HELP_STRING([--enable-sjlj-exceptions],
 571                  [force use of builtin_setjmp for exceptions]),
 572 [:],
 573 [dnl Botheration.  Now we've got to detect the exception model.
 574 dnl Link tests against libgcc.a are problematic since -- at least
 575 dnl as of this writing -- we've not been given proper -L bits for
 576 dnl single-tree newlib and libgloss.
 577 dnl
 578 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 579 dnl conftest files before we got a change to grep them first.
 580 cat > conftest.$ac_ext << EOF
 581 [#]line __oline__ "configure"
 582 struct S { ~S(); };
 583 void bar();
 584 void foo()
 585 {
 586   S s;
 587   bar();
 588 }
 589 EOF
 590 old_CXXFLAGS="$CXXFLAGS"
 591 CXXFLAGS=-S
 592 if AC_TRY_EVAL(ac_compile); then
 593   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 594     enable_sjlj_exceptions=yes
 595   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 596     enable_sjlj_exceptions=no
 597   fi
 598 fi
 599 CXXFLAGS="$old_CXXFLAGS"
 600 rm -f conftest*])
 601 if test x$enable_sjlj_exceptions = xyes; then
 602   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 603         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 604   ac_exception_model_name=sjlj
 605 elif test x$enable_sjlj_exceptions = xno; then
 606   ac_exception_model_name="call frame"
 607 else
 608   AC_MSG_ERROR([unable to detect exception model])
 609 fi
 610 AC_LANG_POP(C++)
 611 AC_MSG_RESULT($ac_exception_model_name)
 612
 613 # If we are non using SJLJ exceptions, and this host does not have support
 614 # for unwinding from a signal handler, enable checked dereferences and divides.
 615 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 616   CHECKREFSPEC=-fcheck-references
 617   DIVIDESPEC=-fuse-divide-subroutine
 618   EXCEPTIONSPEC=
 619 fi
 620
 621 # See if the user wants to disable java.net.  This is the mildly
 622 # ugly way that we admit that target-side configuration sucks.
 623 AC_ARG_ENABLE(java-net,
 624   AS_HELP_STRING([--disable-java-net],
 625                  [disable java.net]))
 626
 627 # Whether java.net is built by default can depend on the target.
 628 if test -z "$enable_java_net"; then
 629    enable_java_net=${enable_java_net_default-yes}
 630 fi
 631 if test "$enable_java_net" = no; then
 632    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 633 fi
 634
 635 # See if the user wants to configure without libffi.  Some
 636 # architectures don't support it, and default values are set in
 637 # configure.host.
 638 AC_ARG_WITH(libffi,
 639   AS_HELP_STRING([--without-libffi],
 640                  [don't use libffi]),
 641   [:],
 642   [with_libffi=${with_libffi_default-yes}])
 643
 644 LIBFFI=
 645 LIBFFIINCS=
 646 if test "$with_libffi" != no; then
 647    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 648    LIBFFI=../libffi/libffi_convenience.la
 649    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 650 fi
 651 AC_SUBST(LIBFFI)
 652 AC_SUBST(LIBFFIINCS)
 653
 654 # See if the user wants to disable JVMPI support.
 655 AC_ARG_ENABLE(jvmpi,
 656   AS_HELP_STRING([--disable-jvmpi],
 657                  [disable JVMPI support]))
 658
 659 if test "$enable_jvmpi" != no; then
 660     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 661 fi
 662
 663 # If the target is an eCos system, use the appropriate eCos
 664 # I/O routines.
 665 # FIXME: this should not be a local option but a global target
 666 # system; at present there is no eCos target.
 667 TARGET_ECOS=${PROCESS-"no"}
 668 AC_ARG_WITH(ecos,
 669 [  --with-ecos             enable runtime eCos target support],
 670 TARGET_ECOS="$with_ecos"
 671 )
 672
 673 case "$TARGET_ECOS" in
 674    no) case "$host" in
 675       *mingw*)
 676             PLATFORM=Win32
 677             PLATFORMNET=Win32
 678             PLATFORMH=win32.h
 679         CHECK_FOR_BROKEN_MINGW_LD
 680       ;;
 681       *)
 682             PLATFORM=Posix
 683             PLATFORMNET=Posix
 684             PLATFORMH=posix.h
 685       ;;
 686       esac
 687       ;;
 688    *)
 689       PLATFORM=Ecos
 690       PLATFORMNET=NoNet
 691       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 692       PLATFORMH=posix.h
 693       ;;
 694 esac
 695 AC_SUBST(PLATFORM)
 696 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 697
 698 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 699                                       [Define if you have int32_t and uint32_t.]))
 700 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 701                                         [Define if you have int32_t and uint32_t.]))
 702 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 703                                           [Define if you have u_int32_t]))
 704 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 705                                            [Define if you have u_int32_t]))
 706
 707 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 708 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 709
 710 case "$host" in
 711   *-darwin*) DARWIN_CRT=true ;;
 712   *) DARWIN_CRT=false ;;
 713 esac
 714 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 715
 716 # These may not be defined in a non-ANS conformant embedded system.
 717 # FIXME: Should these case a runtime exception in that case?
 718 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 719                                   [Define is you have 'mktime' in <time.h>]))
 720 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 721                                   [Define is you have 'localtime' in <time.h>]))
 722
 723 # Create the subdirectory for natFile.cc, or the attempt
 724 # to create the link will fail.
 725 test -d java || mkdir java
 726 test -d java/io || mkdir java/io
 727 test -d gnu || mkdir gnu
 728 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 729
 730 # Likewise for natConcreteProcess.cc.
 731 test -d java/lang || mkdir java/lang
 732 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 733
 734 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 735 test -d java/net || mkdir java/net
 736 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 737 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 738
 739 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 740 test -d gnu/java || mkdir gnu/java
 741 test -d gnu/java/net || mkdir gnu/java/net
 742 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 743 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 744
 745 # Likewise for natVMPipe.cc and natVMSelector.cc.
 746 test -d gnu/java/nio || mkdir gnu/java/nio
 747 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 748 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 749
 750 # Likewise for natFileChannelImpl.cc
 751 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 752 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 753
 754 case "${host}" in
 755     *mingw*)
 756       SYSTEMSPEC="-lgdi32 -lws2_32"
 757       if test "${with_win32_nlsapi}" = "unicows"; then
 758         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 759       fi
 760     ;;
 761     *)
 762       SYSTEMSPEC=
 763     ;;
 764 esac
 765 AC_SUBST(SYSTEMSPEC)
 766
 767 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 768 AC_SUBST(LIBGCJTESTSPEC)
 769
 770 AC_ARG_WITH(system-zlib,
 771   AS_HELP_STRING([--with-system-zlib],
 772                  [use installed libz]))
 773 ZLIBSPEC=
 774 AC_SUBST(ZLIBSPEC)
 775 ZLIBTESTSPEC=
 776 AC_SUBST(ZLIBTESTSPEC)
 777
 778 AC_PATH_XTRA
 779
 780 # FIXME: this should be _libs on some hosts.
 781 libsubdir=.libs
 782
 783 # extra LD Flags which are required for targets
 784 case "${host}" in
 785 *-*-darwin[[0-7]].*)
 786     # For now we have to disable it on darwin[8-9] because it slows down
 787     # the linking phase. A possible bug in ld?
 788     # on Darwin -single_module speeds up loading of the dynamic libraries.
 789     extra_ldflags_libjava=-Wl,-single_module
 790     ;;
 791 esac
 792 AC_SUBST(extra_ldflags_libjava)
 793
 794 # Allow the GC to be disabled.  Can be useful when debugging.
 795 AC_MSG_CHECKING([for garbage collector to use])
 796 AC_ARG_ENABLE(java-gc,
 797   AS_HELP_STRING([--enable-java-gc=TYPE],
 798                  [choose garbage collector (default is boehm)]),
 799   [GC=$enableval],
 800   [GC=boehm])
 801 GCLIBS=
 802 GCINCS=
 803 GCDEPS=
 804 GCSPEC=
 805 JC1GCSPEC=
 806 GCTESTSPEC=
 807 case "$GC" in
 808  boehm)
 809     AC_MSG_RESULT(boehm)
 810     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 811     JC1GCSPEC='-fuse-boehm-gc'
 812     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 813     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 814     GCOBJS=boehm.lo
 815     GCHDR=boehm-gc.h
 816     # The POSIX thread support needs to know this.
 817     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 818     ;;
 819  no)
 820     AC_MSG_RESULT(none)
 821     GCHDR=no-gc.h
 822     ;;
 823  *)
 824     AC_MSG_ERROR([unrecognized collector "$GC"])
 825     ;;
 826 esac
 827 AC_SUBST(GCLIBS)
 828 AC_SUBST(GCINCS)
 829 AC_SUBST(GCDEPS)
 830 AC_SUBST(GCSPEC)
 831 AC_SUBST(JC1GCSPEC)
 832 AC_SUBST(GCTESTSPEC)
 833 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 834 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 835 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 836
 837
 838 AC_MSG_CHECKING([for thread model used by GCC])
 839 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 840 AC_MSG_RESULT([$THREADS])
 841
 842 case "$THREADS" in
 843  no | none | single)
 844     THREADS=none
 845     ;;
 846  posix | posix95 | pthreads)
 847     THREADS=posix
 848     case "$host" in
 849      *-*-linux*)
 850         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 851         ;;
 852     esac
 853     ;;
 854  win32)
 855     ;;
 856  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 857     AC_MSG_ERROR(thread package $THREADS not yet supported)
 858     ;;
 859  *)
 860     AC_MSG_ERROR($THREADS is an unknown thread package)
 861     ;;
 862 esac
 863
 864 THREADCXXFLAGS=
 865 THREADLDFLAGS=
 866 THREADLIBS=
 867 THREADINCS=
 868 THREADDEPS=
 869 THREADH=
 870 THREADSPEC=
 871 THREADSTARTFILESPEC=
 872 case "$THREADS" in
 873  posix)
 874     case "$host" in
 875      *-*-cygwin*)
 876         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 877         ;;
 878      *-*-freebsd[[1234]]*)
 879         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 880         # merely adds pthread_* functions) but it does have a -pthread switch
 881         # which is required at link-time to select -lc_r *instead* of -lc.
 882         THREADLDFLAGS=-pthread
 883         # Don't set THREADSPEC here as might be expected since -pthread is
 884         # not processed when found within a spec file, it must come from
 885         # the command line.  For now, the user must provide the -pthread
 886         # switch to link code compiled with gcj.  In future, consider adding
 887         # support for weak references to pthread_* functions ala gthr.h API.
 888         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 889         ;;
 890      *-*-freebsd*)
 891         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 892         # systems which support threads and -lpthread.
 893         THREADLDFLAGS=-pthread
 894         THREADSPEC=-lpthread
 895         ;;
 896      alpha*-dec-osf* | hppa*-hp-hpux*)
 897         THREADCXXFLAGS=-pthread
 898         # boehm-gc needs some functions from librt, so link that too.
 899         THREADLIBS='-lpthread -lrt'
 900         THREADSPEC='-lpthread -lrt'
 901         ;;
 902      *)
 903         THREADLIBS=-lpthread
 904         THREADSPEC=-lpthread
 905         ;;
 906     esac
 907     THREADH=posix-threads.h
 908     # MIT pthreads doesn't seem to have the mutexattr functions.
 909     # But for now we don't check for it.  We just assume you aren't
 910     # using MIT pthreads.
 911     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 912
 913     # If we're using the Boehm GC, then we happen to know that it
 914     # defines _REENTRANT, so we don't bother.  Eww.
 915     if test "$GC" != boehm; then
 916        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 917     fi
 918     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 919     ;;
 920
 921  win32)
 922     THREADH=win32-threads.h
 923     THREADCXXFLAGS=-mthreads
 924     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 925     # But we do not want the executables created to be dependent on
 926     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 927     # exception handling contexts.  The following kludge achieves this effect
 928     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 929     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 930     # A workaround is to explicitly use -mthreads while linking Java programs.
 931     # See PR libgcj/28263.
 932     #
 933     # FIXME: In Java we are able to detect thread death at the end of
 934     # Thread.run() so we should be able to clean up the exception handling
 935     # contexts ourselves.
 936     THREADSTARTFILESPEC='crtmt%O%s'
 937     ;;
 938
 939  none)
 940     THREADH=no-threads.h
 941     ;;
 942 esac
 943 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 944 AC_SUBST(THREADLIBS)
 945 AC_SUBST(THREADINCS)
 946 AC_SUBST(THREADDEPS)
 947 AC_SUBST(THREADSPEC)
 948 AC_SUBST(THREADSTARTFILESPEC)
 949 AC_SUBST(THREADLDFLAGS)
 950 AC_SUBST(THREADCXXFLAGS)
 951 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 952 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 953 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 954 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 955
 956 if test -d sysdep; then true; else mkdir sysdep; fi
 957 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 958 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 959 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 960
 961 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 962 if test "$use_libgcj_bc" = yes; then
 963   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 964 fi
 965 AC_SUBST(LIBGCJ_SPEC)
 966
 967 HASH_SYNC_SPEC=
 968 # Hash synchronization is only useful with posix threads right now.
 969 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 970    HASH_SYNC_SPEC=-fhash-synchronization
 971    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 972 fi
 973 AC_SUBST(HASH_SYNC_SPEC)
 974
 975 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 976
 977 # We're in the tree with gcc, and need to include some of its headers.
 978 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
 979
 980 if test "x${with_newlib}" = "xyes"; then
 981    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 982    # may not work correctly, because the compiler may not be able to
 983    # link executables.
 984
 985    # We assume newlib.  This lets us hard-code the functions we know
 986    # we'll have.
 987    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 988    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 989    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 990    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 991    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 992    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 993    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 994    # This is only for POSIX threads.
 995    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 996    # We also assume we are using gcc, which provides alloca.
 997    AC_DEFINE(HAVE_ALLOCA)
 998
 999    # Assume we do not have getuid and friends.
1000    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1001    PLATFORMNET=NoNet
1002 else
1003    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
1004                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
1005                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1006                    nl_langinfo setlocale \
1007                    inet_pton uname inet_ntoa \
1008                    fork execvp pipe sigaction ftruncate mmap \
1009                    getifaddrs])
1010    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1011    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
1012    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1013    AC_CHECK_LIB(dl, dladdr, [
1014        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1015        AC_CHECK_LIB(dld, dladdr, [
1016        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1017
1018    if test x"$cross_compiling" = x"no"; then
1019      AC_CHECK_FILES(/proc/self/exe, [
1020        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1021      AC_CHECK_FILES(/proc/self/maps, [
1022        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1023          [Define if you have /proc/self/maps])])
1024    else
1025      case $host in
1026      *-linux*)
1027        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1028        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1029        ;;
1030      esac
1031    fi
1032
1033    AM_ICONV
1034    AM_LC_MESSAGES
1035    AC_STRUCT_TIMEZONE
1036
1037    AC_CHECK_FUNCS(gethostbyname_r, [
1038      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1039        [Define if you have the 'gethostbyname_r' function.])
1040      # There are two different kinds of gethostbyname_r.
1041      # We look for the one that returns `int'.
1042      # Hopefully this check is robust enough.
1043      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1044        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1045
1046      case " $GCINCS " in
1047      *" -D_REENTRANT "*) ;;
1048      *)
1049         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1050         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1051         [libjava_cv_gethostbyname_r_needs_reentrant],
1052         [ AC_LANG_PUSH(C++)
1053           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1054             [[gethostbyname_r("", 0, 0);]])],
1055             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1056                 CPPFLAGS_SAVE="$CPPFLAGS"
1057                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1058                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1059                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1060                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1061                 CPPFLAGS="$CPPFLAGS_SAVE"
1062           ])
1063           AC_LANG_POP(C++)
1064         ])
1065         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1066           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1067         fi
1068      ;;
1069      esac
1070
1071      AC_CACHE_CHECK([for struct hostent_data],
1072         [libjava_cv_struct_hostent_data], [dnl
1073         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1074 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1075 # define _REENTRANT 1
1076 #endif
1077 #include <netdb.h>]], [[struct hostent_data data;]])],
1078           [libjava_cv_struct_hostent_data=yes],
1079           [libjava_cv_struct_hostent_data=no])])
1080      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1081        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1082          [Define if struct hostent_data is defined in netdb.h])
1083      fi
1084    ])
1085
1086    # FIXME: libjava source code expects to find a prototype for
1087    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1088    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1089    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1090    # linkage check is enough, yet C++ code requires proper prototypes.)
1091    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1092    AC_CHECK_FUNCS(gethostbyaddr_r, [
1093      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1094        [Define if you have the 'gethostbyaddr_r' function.])
1095      # There are two different kinds of gethostbyaddr_r.
1096      # We look for the one that returns `int'.
1097      # Hopefully this check is robust enough.
1098      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1099        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1100          [Define if gethostbyaddr_r returns 'int'.])])])])
1101
1102    AC_CHECK_FUNCS(gethostname, [
1103      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1104        [Define if you have the 'gethostname' function.])
1105      AC_EGREP_HEADER(gethostname, unistd.h, [
1106        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1107          [Define if gethostname is declared in <unistd.h>.])])])
1108
1109    AC_CHECK_FUNCS(usleep, [
1110      AC_EGREP_HEADER(usleep, unistd.h, [
1111        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1112           [Define if usleep is declared in <unistd.h>.])])])
1113
1114    # Look for these functions in the thread library, but only bother
1115    # if using POSIX threads.
1116    if test "$THREADS" = posix; then
1117       save_LIBS="$LIBS"
1118       LIBS="$LIBS $THREADLIBS"
1119       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1120       # E.g., Solaris.
1121       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1122
1123       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1124       # Solaris 7 the name librt is preferred.
1125       AC_CHECK_FUNCS(sched_yield, , [
1126         AC_CHECK_LIB(rt, sched_yield, [
1127           AC_DEFINE(HAVE_SCHED_YIELD)
1128           THREADLIBS="$THREADLIBS -lrt"
1129           THREADSPEC="$THREADSPEC -lrt"], [
1130           AC_CHECK_LIB(posix4, sched_yield, [
1131             AC_DEFINE(HAVE_SCHED_YIELD)
1132             THREADLIBS="$THREADLIBS -lposix4"
1133             THREADSPEC="$THREADSPEC -lposix4"])])])
1134
1135       AC_CHECK_LIB(rt, clock_gettime, [
1136          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1137          case "$THREADSPEC" in
1138            *-lrt*) ;;
1139            *)
1140              THREADSPEC="$THREADSPEC -lrt"
1141              THREADLIBS="$THREADLIBS -lrt"
1142              ;;
1143          esac])
1144
1145       LIBS="$save_LIBS"
1146
1147       # We can save a little space at runtime if the mutex has m_count
1148       # or __m_count.  This is a nice hack for Linux.
1149       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1150           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1151         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1152              [Define if pthread_mutex_t has m_count member.]), [
1153         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1154             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1155           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1156             [Define if pthread_mutex_t has __m_count member.]))])
1157    fi
1158
1159    # We require a way to get the time.
1160    time_found=no
1161    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1162    if test "$time_found" = no; then
1163       AC_MSG_ERROR([no function found to get the time])
1164    fi
1165
1166    AC_CHECK_FUNCS(memmove)
1167
1168    # We require memcpy.
1169    memcpy_found=no
1170    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1171    if test "$memcpy_found" = no; then
1172       AC_MSG_ERROR([memcpy is required])
1173    fi
1174    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1175    AC_CHECK_LIB(dl, dlopen, [
1176        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1177        AC_CHECK_LIB(dld, dlopen, [
1178        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1179
1180    # Some library-finding code we stole from Tcl.
1181    #--------------------------------------------------------------------
1182    #    Check for the existence of the -lsocket and -lnsl libraries.
1183    #    The order here is important, so that they end up in the right
1184    #    order in the command line generated by make.  Here are some
1185    #    special considerations:
1186    #    1. Use "connect" and "accept" to check for -lsocket, and
1187    #       "gethostbyname" to check for -lnsl.
1188    #    2. Use each function name only once:  can't redo a check because
1189    #       autoconf caches the results of the last check and won't redo it.
1190    #    3. Use -lnsl and -lsocket only if they supply procedures that
1191    #       aren't already present in the normal libraries.  This is because
1192    #       IRIX 5.2 has libraries, but they aren't needed and they're
1193    #       bogus:  they goof up name resolution if used.
1194    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1195    #       To get around this problem, check for both libraries together
1196    #       if -lsocket doesn't work by itself.
1197    #--------------------------------------------------------------------
1198
1199    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1200     [gcj_cv_lib_sockets=
1201      gcj_checkBoth=0
1202      unset ac_cv_func_connect
1203      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1204      if test "$gcj_checkSocket" = 1; then
1205          unset ac_cv_func_connect
1206          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1207                       gcj_checkBoth=1)
1208      fi
1209      if test "$gcj_checkBoth" = 1; then
1210          gcj_oldLibs=$LIBS
1211          LIBS="$LIBS -lsocket -lnsl"
1212          unset ac_cv_func_accept
1213          AC_CHECK_FUNC(accept,
1214                        [gcj_checkNsl=0
1215                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1216          unset ac_cv_func_accept
1217          LIBS=$gcj_oldLibs
1218      fi
1219      unset ac_cv_func_gethostbyname
1220      gcj_oldLibs=$LIBS
1221      LIBS="$LIBS $gcj_cv_lib_sockets"
1222      AC_CHECK_FUNC(gethostbyname, ,
1223                    [AC_CHECK_LIB(nsl, main,
1224                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1225      unset ac_cv_func_gethostbyname
1226      LIBS=$gcj_oldLIBS
1227    ])
1228    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1229
1230    if test "$with_system_zlib" = yes; then
1231       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1232    fi
1233
1234    # Test for Gtk stuff, if asked for.
1235    if test "$use_gtk_awt" = yes; then
1236       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1237       AC_SUBST(GTK_CFLAGS)
1238       AC_SUBST(GTK_LIBS)
1239
1240       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1241       AC_SUBST(GLIB_CFLAGS)
1242       AC_SUBST(GLIB_LIBS)
1243
1244       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1245       AC_SUBST(LIBART_CFLAGS)
1246       AC_SUBST(LIBART_LIBS)
1247
1248       # We require the XTest Extension to support java.awt.Robot.
1249       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1250                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1251                    [${X_LIBS}])
1252    fi
1253
1254    # On Solaris, and maybe other architectures, the Boehm collector
1255    # requires -ldl.
1256    if test "$GC" = boehm; then
1257       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1258    fi
1259 fi
1260
1261 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1262 case $build in
1263     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1264     *)         CLASSPATH_SEPARATOR=':' ;;
1265 esac
1266 AC_SUBST(CLASSPATH_SEPARATOR)
1267
1268 # We must search the source tree for java.lang, since we still don't
1269 # have libgcj.jar nor java/lang/*.class
1270 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1271 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1272
1273 # Since some classes depend on this one, we need its source available
1274 # before we can do any GCJ compilation test :-(
1275 if test ! -f gnu/classpath/Configuration.java; then
1276   test -d gnu || mkdir gnu
1277   test -d gnu/classpath || mkdir gnu/classpath
1278   # Note that it is not crucial that all the values here be correct.
1279   sed -e "s,@prefix@,$prefix," \
1280       -e "s,@VERSION@,$VERSION," \
1281       -e "s,@LIBDEBUG@,false," \
1282       -e "s,@INIT_LOAD_LIBRARY@,false," \
1283       -e "s,@@,$LIBGCJDEBUG," \
1284       -e "s,@default_toolkit@,$TOOLKIT," \
1285       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1286       -e "s,@GTK_CAIRO_ENABLED@,false," \
1287         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1288         > gnu/classpath/Configuration.java
1289   # We do not want to redirect the output of the grep below to /dev/null,
1290   # but we add /dev/null to the input list so that grep will print the
1291   # filename of Configuration.java in case it finds any matches.
1292   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1293     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1294   fi
1295 fi
1296
1297 LT_AC_PROG_GCJ
1298
1299 # Now remove it.
1300 rm -f gnu/classpath/Configuration.java
1301
1302 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1303
1304 AC_CHECK_SIZEOF(void *)
1305
1306 AC_C_BIGENDIAN
1307
1308 ZLIBS=
1309 SYS_ZLIBS=
1310 ZINCS=
1311
1312 if test -z "$ZLIBSPEC"; then
1313    # Use zlib from the GCC tree.
1314    ZINCS='-I$(top_srcdir)/../zlib'
1315    ZLIBS=../zlib/libzgcj_convenience.la
1316 else
1317    # System's zlib.
1318    SYS_ZLIBS="$ZLIBSPEC"
1319 fi
1320 AC_SUBST(ZLIBS)
1321 AC_SUBST(SYS_ZLIBS)
1322 AC_SUBST(ZINCS)
1323 AC_SUBST(DIVIDESPEC)
1324 AC_SUBST(CHECKREFSPEC)
1325 AC_SUBST(EXCEPTIONSPEC)
1326 AC_SUBST(BACKTRACESPEC)
1327 AC_SUBST(IEEESPEC)
1328
1329 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1330 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1331 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1332 AC_SUBST(GCC_UNWIND_INCLUDE)
1333
1334 # Process the option "--enable-version-specific-runtime-libs"
1335 # Calculate toolexeclibdir
1336 case ${version_specific_libs} in
1337   yes)
1338     # Need the gcc compiler version to know where to install libraries
1339     # and header files if --enable-version-specific-runtime-libs option
1340     # is selected.
1341     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1342     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1343     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1344     toolexeclibdir=$toolexecmainlibdir
1345     ;;
1346   no)
1347     if test -n "$with_cross_host" &&
1348        test x"$with_cross_host" != x"no"; then
1349       # Install a library built with a cross compiler in tooldir, not libdir.
1350       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1351       toolexecmainlibdir='$(toolexecdir)/lib'
1352     else
1353       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1354       toolexecmainlibdir='$(libdir)'
1355     fi
1356     multi_os_directory=`$CC -print-multi-os-directory`
1357     case $multi_os_directory in
1358       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1359       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1360     esac
1361     ;;
1362 esac
1363 AC_SUBST(toolexecdir)
1364 AC_SUBST(toolexecmainlibdir)
1365 AC_SUBST(toolexeclibdir)
1366
1367 # Determine where the standard .db file and GNU Classpath JNI
1368 # libraries are found.
1369 multi_os_directory=`$CC -print-multi-os-directory`
1370 case $multi_os_directory in
1371   .)
1372    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1373    ;;
1374   *)
1375    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1376    ;;
1377 esac
1378 AC_SUBST(dbexecdir)
1379
1380 # Determine gcj version number.
1381 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1382 GCJVERSION=$gcjversion
1383 AC_SUBST(GCJVERSION)
1384 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1385
1386 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1387 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1388
1389 TL_AC_GXX_INCLUDE_DIR
1390
1391 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1392 # On that system, sys/ioctl.h will not include sys/filio.h unless
1393 # BSD_COMP is defined; just including sys/filio.h is simpler.
1394 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1395 # for now.  If you change this, you also must update natFile.cc.
1396 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1397                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1398                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1399                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1400                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1401 AC_CHECK_HEADERS(inttypes.h, [
1402     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1403     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1404 ])
1405 AC_HEADER_SYS_WAIT
1406
1407 AC_CHECK_TYPE([ssize_t], [int])
1408 AC_CHECK_TYPE([magic_t], [
1409     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1410 #ifdef HAVE_MAGIC_H
1411 #include <magic.h>
1412 #endif])
1413
1414 AC_MSG_CHECKING([for in_addr_t])
1415 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1416 #if STDC_HEADERS
1417 #include <stdlib.h>
1418 #include <stddef.h>
1419 #endif
1420 #if HAVE_NETINET_IN_H
1421 #include <netinet/in.h>
1422 #endif]], [[in_addr_t foo;]])],
1423   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1424      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1425    AC_MSG_RESULT(yes)],
1426   [AC_MSG_RESULT(no)])
1427
1428 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1429 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1430   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1431      [Define if struct ip_mreq is defined in netinet/in.h.])
1432    AC_MSG_RESULT(yes)],
1433   [AC_MSG_RESULT(no)])
1434
1435 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1436 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1437   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1438      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1439    AC_MSG_RESULT(yes)],
1440   [AC_MSG_RESULT(no)])
1441
1442 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1443 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1444   [AC_DEFINE(HAVE_INET6, 1,
1445      [Define if inet6 structures are defined in netinet/in.h.])
1446    AC_MSG_RESULT(yes)],
1447   [AC_MSG_RESULT(no)])
1448
1449 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1450 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1451 #include <sys/types.h>
1452 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1453   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1454    AC_MSG_RESULT(yes)],
1455   [AC_MSG_RESULT(no)])
1456
1457 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1458 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1459   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1460    AC_MSG_RESULT(yes)],
1461   [AC_MSG_RESULT(no)
1462    AC_MSG_CHECKING([for global timezone variable])
1463    dnl FIXME: we don't want a link check here because that won't work
1464    dnl when cross-compiling.  So instead we make an assumption that
1465    dnl the header file will mention timezone if it exists.
1466    dnl Don't find the win32 function timezone
1467    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1468      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1469       AC_MSG_RESULT(yes)],
1470      [AC_MSG_RESULT(no)
1471        AC_MSG_CHECKING([for global _timezone variable])
1472        dnl FIXME: As above, don't want link check
1473        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1474          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1475             [Define if your platform has the global _timezone variable.])
1476           AC_MSG_RESULT(yes)],
1477           [AC_MSG_RESULT(no)])])])
1478
1479 AC_FUNC_ALLOCA
1480
1481 AC_CHECK_PROGS(PERL, perl, false)
1482
1483 SYSDEP_SOURCES=
1484 SIGNAL_HANDLER_AUX=
1485
1486 case "${host}" in
1487  i?86-*-linux*)
1488     SIGNAL_HANDLER=include/i386-signal.h
1489     ;;
1490  sparc*-sun-solaris*)
1491     SIGNAL_HANDLER=include/sparc-signal.h
1492     ;;
1493 # ia64-*)
1494 #    SYSDEP_SOURCES=sysdep/ia64.c
1495 #    test -d sysdep || mkdir sysdep
1496 #    ;;
1497  hppa*-*-linux*)
1498     SIGNAL_HANDLER=include/pa-signal.h
1499     ;;
1500  hppa*-hp-hpux*)
1501     SIGNAL_HANDLER=include/hppa-signal.h
1502     ;;
1503  ia64-*-linux*)
1504     SIGNAL_HANDLER=include/dwarf2-signal.h
1505     ;;
1506  powerpc*-*-linux*)
1507     SIGNAL_HANDLER=include/powerpc-signal.h
1508     ;;
1509  alpha*-*-linux*)
1510     SIGNAL_HANDLER=include/dwarf2-signal.h
1511     ;;
1512  s390*-*-linux*)
1513     SIGNAL_HANDLER=include/s390-signal.h
1514     ;;
1515  x86_64*-*-linux*)
1516     SIGNAL_HANDLER=include/x86_64-signal.h
1517     SIGNAL_HANDLER_AUX=include/i386-signal.h
1518     ;;
1519  sparc*-*-linux*)
1520     SIGNAL_HANDLER=include/dwarf2-signal.h
1521     ;;
1522  sh*-*-linux*)
1523     SIGNAL_HANDLER=include/sh-signal.h
1524     ;;
1525  *mingw*)
1526     SIGNAL_HANDLER=include/win32-signal.h
1527     ;;
1528  mips*-*-linux*)
1529     SIGNAL_HANDLER=include/mips-signal.h
1530     ;;
1531  powerpc*-*-darwin*)
1532     SIGNAL_HANDLER=include/darwin-signal.h
1533     ;;
1534  *)
1535     SIGNAL_HANDLER=include/default-signal.h
1536     ;;
1537 esac
1538
1539 # If we're using sjlj exceptions, forget what we just learned.
1540 if test "$enable_sjlj_exceptions" = yes; then
1541    SIGNAL_HANDLER=include/default-signal.h
1542    SIGNAL_HANDLER_AUX=
1543 fi
1544
1545 AC_SUBST(SYSDEP_SOURCES)
1546
1547 if test -z "$SIGNAL_HANDLER_AUX"; then
1548   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1549 fi
1550
1551 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1552                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1553
1554 if test "${multilib}" = "yes"; then
1555   multilib_arg="--enable-multilib"
1556 else
1557   multilib_arg=
1558 fi
1559
1560 # See if we support thread-local storage.
1561 GCC_CHECK_TLS
1562
1563 # For _Unwind_GetIPInfo.
1564 GCC_CHECK_UNWIND_GETIPINFO
1565
1566 # See if linker supports anonymous version scripts.
1567 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1568   [libjava_cv_anon_version_script],
1569   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1570    libjava_cv_anon_version_script=no
1571    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1572    echo '{ global: globalsymb*; local: *; };' > conftest.map
1573    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1574                [libjava_cv_anon_version_script=yes], [])
1575    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1576   ])
1577 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1578
1579 # Check if linker supports static linking on a per library basis
1580 LD_START_STATIC_SPEC=
1581 LD_FINISH_STATIC_SPEC=
1582 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1583   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1584     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1585     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1586   fi
1587 fi
1588 AC_SUBST(LD_START_STATIC_SPEC)
1589 AC_SUBST(LD_FINISH_STATIC_SPEC)
1590
1591 here=`${PWDCMD-pwd}`
1592 AC_SUBST(here)
1593
1594 # We get this from the environment.
1595 AC_SUBST(GCJFLAGS)
1596
1597 AC_CONFIG_FILES([
1598 Makefile
1599 libgcj.pc
1600 libgcj.spec
1601 libgcj-test.spec
1602 gcj/Makefile
1603 include/Makefile
1604 testsuite/Makefile
1605 ])
1606
1607 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1608
1609 AC_CONFIG_COMMANDS([default],
1610 [# Only add multilib support code if we just rebuilt top-level Makefile.
1611 case " $CONFIG_FILES " in
1612  *" Makefile "*)
1613    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1614    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1615    ;;
1616 esac
1617 for ac_multi_file in $CONFIG_FILES; do
1618   case $ac_multi_file in
1619   */Makefile)
1620     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1621   esac
1622 done
1623 ],
1624 srcdir=${srcdir}
1625 host=${host}
1626 target=${target}
1627 with_multisubdir=${with_multisubdir}
1628 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1629 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1630 multi_basedir=${multi_basedir}
1631 CC="${CC}"
1632 CXX="${CXX}"
1633 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1634 )
1635
1636 AC_OUTPUT