configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libbacktrace \
 156                 target-libgloss \
 157                 target-newlib \
 158                 target-libgomp \
 159                 target-libatomic \
 160                 target-libitm \
 161                 target-libstdc++-v3 \
 162                 target-libmudflap \
 163                 target-libsanitizer \
 164                 target-libssp \
 165                 target-libquadmath \
 166                 target-libgfortran \
 167                 target-boehm-gc \
 168                 ${libgcj} \
 169                 target-libobjc \
 170                 target-libada \
 171                 target-libgo"
 172
 173 # these tools are built using the target libraries, and are intended to
 174 # run only in the target environment
 175 #
 176 # note: any program that *uses* libraries that are in the "target_libraries"
 177 # list belongs in this list.
 178 #
 179 target_tools="target-rda"
 180
 181 ################################################################################
 182
 183 ## All tools belong in one of the four categories, and are assigned above
 184 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 185 ## is important because configure will choke if they ever get through.
 186 ## ${configdirs} is directories we build using the host tools.
 187 ## ${target_configdirs} is directories we build using the target tools.
 188 configdirs=`echo ${host_libs} ${host_tools}`
 189 target_configdirs=`echo ${target_libraries} ${target_tools}`
 190 build_configdirs=`echo ${build_libs} ${build_tools}`
 191
 192 m4_divert_text([PARSE_ARGS],
 193 [case $srcdir in
 194   *" "*)
 195 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 196     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 197 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 198     ;;
 199 esac
 200 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 201 ])
 202
 203 ################################################################################
 204
 205 srcname="gnu development package"
 206
 207 # This gets set non-empty for some net releases of packages.
 208 appdirs=""
 209
 210 # Define is_cross_compiler to save on calls to 'test'.
 211 is_cross_compiler=
 212 if test x"${host}" = x"${target}" ; then
 213   is_cross_compiler=no
 214 else
 215   is_cross_compiler=yes
 216 fi
 217
 218 # Find the build and target subdir names.
 219 GCC_TOPLEV_SUBDIRS
 220 # Be sure to cover against remnants of an in-tree build.
 221 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 222   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 223 Use a pristine source tree when building in a separate tree])
 224 fi
 225
 226 # Skipdirs are removed silently.
 227 skipdirs=
 228 # Noconfigdirs are removed loudly.
 229 noconfigdirs=""
 230
 231 use_gnu_ld=
 232 # Make sure we don't let GNU ld be added if we didn't want it.
 233 if test x$with_gnu_ld = xno ; then
 234   use_gnu_ld=no
 235   noconfigdirs="$noconfigdirs ld gold"
 236 fi
 237
 238 use_gnu_as=
 239 # Make sure we don't let GNU as be added if we didn't want it.
 240 if test x$with_gnu_as = xno ; then
 241   use_gnu_as=no
 242   noconfigdirs="$noconfigdirs gas"
 243 fi
 244
 245 use_included_zlib=
 246 # Make sure we don't let ZLIB be added if we didn't want it.
 247 if test x$with_system_zlib = xyes ; then
 248   use_included_zlib=no
 249   noconfigdirs="$noconfigdirs zlib"
 250 fi
 251
 252 # some tools are so dependent upon X11 that if we're not building with X,
 253 # it's not even worth trying to configure, much less build, that tool.
 254
 255 case ${with_x} in
 256   yes | "") ;; # the default value for this tree is that X11 is available
 257   no)
 258     skipdirs="${skipdirs} tk itcl libgui"
 259     # We won't be able to build gdbtk without X.
 260     enable_gdbtk=no
 261     ;;
 262   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 263 esac
 264
 265 # Some are only suitable for cross toolchains.
 266 # Remove these if host=target.
 267 cross_only="target-libgloss target-newlib target-opcodes"
 268
 269 case $is_cross_compiler in
 270   no) skipdirs="${skipdirs} ${cross_only}" ;;
 271 esac
 272
 273 # If both --with-headers and --with-libs are specified, default to
 274 # --without-newlib.
 275 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 276    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 277   if test x"${with_newlib}" = x ; then
 278     with_newlib=no
 279   fi
 280 fi
 281
 282 # Recognize --with-newlib/--without-newlib.
 283 case ${with_newlib} in
 284   no) skipdirs="${skipdirs} target-newlib" ;;
 285   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 286 esac
 287
 288 # Handle --enable-gold, --enable-ld.
 289 # --disable-gold [--enable-ld]
 290 #     Build only ld.  Default option.
 291 # --enable-gold [--enable-ld]
 292 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 293 #     as "ld.bfd" and "ld".
 294 # --enable-gold=default [--enable-ld]
 295 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 296 #     install ld as "ld.bfd".
 297 # --enable-gold[=default] --disable-ld
 298 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 299 # --enable-gold --enable-ld=default
 300 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 301 #     and ld.bfd).
 302 #     In other words, ld is default
 303 # --enable-gold=default --enable-ld=default
 304 #     Error.
 305
 306 default_ld=
 307 AC_ARG_ENABLE(gold,
 308 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 309                 [build gold @<:@ARG={default,yes,no}@:>@])],
 310 ENABLE_GOLD=$enableval,
 311 ENABLE_GOLD=no)
 312 case "${ENABLE_GOLD}" in
 313   yes|default)
 314     # Check for ELF target.
 315     is_elf=no
 316     case "${target}" in
 317       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 318       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 319       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 320       | *-*-solaris2* | *-*-nto*)
 321         case "${target}" in
 322           *-*-linux*aout* | *-*-linux*oldld*)
 323             ;;
 324           *)
 325             is_elf=yes
 326             ;;
 327         esac
 328     esac
 329
 330     if test "$is_elf" = "yes"; then
 331       # Check for target supported by gold.
 332       case "${target}" in
 333         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*)
 334           configdirs="$configdirs gold"
 335           if test x${ENABLE_GOLD} = xdefault; then
 336             default_ld=gold
 337           fi
 338           ENABLE_GOLD=yes
 339           ;;
 340       esac
 341     fi
 342     ;;
 343   no)
 344     ;;
 345   *)
 346     AC_MSG_ERROR([invalid --enable-gold argument])
 347     ;;
 348 esac
 349
 350 AC_ARG_ENABLE(ld,
 351 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 352                 [build ld @<:@ARG={default,yes,no}@:>@])],
 353 ENABLE_LD=$enableval,
 354 ENABLE_LD=yes)
 355
 356 case "${ENABLE_LD}" in
 357   default)
 358     if test x${default_ld} != x; then
 359       AC_MSG_ERROR([either gold or ld can be the default ld])
 360     fi
 361     ;;
 362   yes)
 363     ;;
 364   no)
 365     if test x${ENABLE_GOLD} != xyes; then
 366       AC_MSG_WARN([neither ld nor gold are enabled])
 367     fi
 368     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 369     ;;
 370   *)
 371     AC_MSG_ERROR([invalid --enable-ld argument])
 372     ;;
 373 esac
 374
 375 # Configure extra directories which are host specific
 376
 377 case "${host}" in
 378   *-cygwin*)
 379     configdirs="$configdirs libtermcap" ;;
 380 esac
 381
 382 # A target can indicate whether a language isn't supported for some reason.
 383 # Only spaces may be used in this macro; not newlines or tabs.
 384 unsupported_languages=
 385
 386 # Remove more programs from consideration, based on the host or
 387 # target this usually means that a port of the program doesn't
 388 # exist yet.
 389
 390 case "${host}" in
 391   i[[3456789]]86-*-msdosdjgpp*)
 392     noconfigdirs="$noconfigdirs tcl tk itcl"
 393     ;;
 394 esac
 395
 396
 397 AC_ARG_ENABLE(libquadmath,
 398 AS_HELP_STRING([--disable-libquadmath],
 399   [do not build libquadmath directory]),
 400 ENABLE_LIBQUADMATH=$enableval,
 401 ENABLE_LIBQUADMATH=yes)
 402 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 403   noconfigdirs="$noconfigdirs target-libquadmath"
 404 fi
 405
 406
 407 AC_ARG_ENABLE(libquadmath-support,
 408 AS_HELP_STRING([--disable-libquadmath-support],
 409   [disable libquadmath support for Fortran]),
 410 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 411 ENABLE_LIBQUADMATH_SUPPORT=yes)
 412 enable_libquadmath_support=
 413 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 414   enable_libquadmath_support=no
 415 fi
 416
 417
 418 AC_ARG_ENABLE(libada,
 419 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 420 ENABLE_LIBADA=$enableval,
 421 ENABLE_LIBADA=yes)
 422 if test "${ENABLE_LIBADA}" != "yes" ; then
 423   noconfigdirs="$noconfigdirs gnattools"
 424 fi
 425
 426 AC_ARG_ENABLE(libssp,
 427 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 428 ENABLE_LIBSSP=$enableval,
 429 ENABLE_LIBSSP=yes)
 430
 431 # Save it here so that, even in case of --enable-libgcj, if the Java
 432 # front-end isn't enabled, we still get libgcj disabled.
 433 libgcj_saved=$libgcj
 434 case $enable_libgcj in
 435 yes)
 436   # If we reset it here, it won't get added to noconfigdirs in the
 437   # target-specific build rules, so it will be forcibly enabled
 438   # (unless the Java language itself isn't enabled).
 439   libgcj=
 440   ;;
 441 no)
 442   # Make sure we get it printed in the list of not supported target libs.
 443   # Don't disable libffi, though, other languages use it.
 444   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 445   # Clear libgcj_saved so that even if java is enabled libffi won't be
 446   # built.
 447   libgcj_saved=
 448   ;;
 449 esac
 450
 451 AC_ARG_ENABLE(static-libjava,
 452 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 453                 [build static libjava @<:@default=no@:>@])],
 454 ENABLE_STATIC_LIBJAVA=$enableval,
 455 ENABLE_STATIC_LIBJAVA=no)
 456 enable_static_libjava=
 457 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 458   enable_static_libjava=yes
 459 fi
 460
 461 if test x$enable_static_libjava != xyes ; then
 462   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 463 fi
 464 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 465
 466 # Disable libmudflap on some systems.
 467 if test x$enable_libmudflap = x ; then
 468     case "${target}" in
 469     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 470         # Enable libmudflap by default in GNU and friends.
 471         ;;
 472     *-*-freebsd*)
 473         # Enable libmudflap by default in FreeBSD.
 474         ;;
 475     *)
 476         # Disable it by default everywhere else.
 477         noconfigdirs="$noconfigdirs target-libmudflap"
 478         ;;
 479     esac
 480 fi
 481
 482 # Disable libgomp on non POSIX hosted systems.
 483 if test x$enable_libgomp = x ; then
 484     # Enable libgomp by default on hosted POSIX systems.
 485     case "${target}" in
 486     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 487         ;;
 488     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 489         ;;
 490     *-*-solaris2* | *-*-hpux11*)
 491         ;;
 492     *-*-darwin* | *-*-aix*)
 493         ;;
 494     *)
 495         noconfigdirs="$noconfigdirs target-libgomp"
 496         ;;
 497     esac
 498 fi
 499
 500 # Disable libatomic on unsupported systems.
 501 if test -d ${srcdir}/libatomic; then
 502     if test x$enable_libatomic = x; then
 503         AC_MSG_CHECKING([for libatomic support])
 504         if (srcdir=${srcdir}/libatomic; \
 505                 . ${srcdir}/configure.tgt; \
 506                 test -n "$UNSUPPORTED")
 507         then
 508             AC_MSG_RESULT([no])
 509             noconfigdirs="$noconfigdirs target-libatomic"
 510         else
 511             AC_MSG_RESULT([yes])
 512         fi
 513     fi
 514 fi
 515
 516 # Disable libitm on unsupported systems.
 517 if test -d ${srcdir}/libitm; then
 518     if test x$enable_libitm = x; then
 519         AC_MSG_CHECKING([for libitm support])
 520         if (srcdir=${srcdir}/libitm; \
 521                 . ${srcdir}/configure.tgt; \
 522                 test -n "$UNSUPPORTED")
 523         then
 524             AC_MSG_RESULT([no])
 525             noconfigdirs="$noconfigdirs target-libitm"
 526         else
 527             AC_MSG_RESULT([yes])
 528         fi
 529     fi
 530 fi
 531
 532 # Disable libquadmath for some systems.
 533 case "${target}" in
 534   # libquadmath is unused on AIX and libquadmath build process use of
 535   # LD_LIBRARY_PATH can break AIX bootstrap.
 536   powerpc-*-aix* | rs6000-*-aix*)
 537     noconfigdirs="$noconfigdirs target-libquadmath"
 538     ;;
 539 esac
 540
 541 # Disable libssp for some systems.
 542 case "${target}" in
 543   avr-*-*)
 544     # No hosted I/O support.
 545     noconfigdirs="$noconfigdirs target-libssp"
 546     ;;
 547   powerpc-*-aix* | rs6000-*-aix*)
 548     noconfigdirs="$noconfigdirs target-libssp"
 549     ;;
 550   rl78-*-*)
 551     # libssp uses a misaligned load to trigger a fault, but the RL78
 552     # doesn't fault for those - instead, it gives a build-time error
 553     # for explicit misaligned loads.
 554     noconfigdirs="$noconfigdirs target-libssp"
 555     ;;
 556 esac
 557
 558 # Disable libquadmath for some systems.
 559 case "${target}" in
 560   avr-*-*)
 561     noconfigdirs="$noconfigdirs target-libquadmath"
 562     ;;
 563 esac
 564
 565 # Disable libstdc++-v3 for some systems.
 566 case "${target}" in
 567   *-*-vxworks*)
 568     # VxWorks uses the Dinkumware C++ library.
 569     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 570     ;;
 571   arm*-wince-pe*)
 572     # the C++ libraries don't build on top of CE's C libraries
 573     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 574     ;;
 575   avr-*-*)
 576     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 577     ;;
 578 esac
 579
 580 # Disable Fortran for some systems.
 581 case "${target}" in
 582   mmix-*-*)
 583     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 584     unsupported_languages="$unsupported_languages fortran"
 585     ;;
 586 esac
 587
 588 # Disable Java if libffi is not supported.
 589 case "${target}" in
 590   alpha*-*-*)
 591     ;;
 592   arm*-*-*)
 593     ;;
 594   cris-*-*)
 595     ;;
 596   frv-*-*)
 597     ;;
 598   hppa*-*-linux*)
 599     ;;
 600   hppa*-*-hpux*)
 601     ;;
 602   i?86-*-*)
 603     ;;
 604   ia64*-*-*)
 605     ;;
 606   m32r*-*-*)
 607     ;;
 608   m68k-*-*)
 609     ;;
 610   mips*-*-rtems*)
 611     ;;
 612   mips*-*-linux*)
 613     ;;
 614   powerpc*-*-linux*)
 615     ;;
 616   powerpc-*-darwin*)
 617     ;;
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     ;;
 620   powerpc-*-freebsd*)
 621     ;;
 622   powerpc64-*-freebsd*)
 623     ;;
 624   powerpc*-*-rtems*)
 625     ;;
 626   s390-*-* | s390x-*-*)
 627     ;;
 628   sh-*-* | sh[[34]]*-*-*)
 629     ;;
 630   sh64-*-* | sh5*-*-*)
 631     ;;
 632   sparc*-*-*)
 633     ;;
 634   x86_64-*-*)
 635     ;;
 636   *-*-*)
 637     unsupported_languages="$unsupported_languages java"
 638     ;;
 639 esac
 640
 641 # Disable Java, libgcj or related libraries for some systems.
 642 case "${target}" in
 643   powerpc-*-darwin*)
 644     ;;
 645   i[[3456789]]86-*-darwin*)
 646     ;;
 647   x86_64-*-darwin[[912]]*)
 648     ;;
 649   *-*-darwin*)
 650     noconfigdirs="$noconfigdirs ${libgcj}"
 651     ;;
 652   *-*-netware*)
 653     noconfigdirs="$noconfigdirs ${libgcj}"
 654     ;;
 655   *-*-rtems*)
 656     noconfigdirs="$noconfigdirs ${libgcj}"
 657     ;;
 658   *-*-tpf*)
 659     noconfigdirs="$noconfigdirs ${libgcj}"
 660     ;;
 661   *-*-uclinux*)
 662     noconfigdirs="$noconfigdirs ${libgcj}"
 663     ;;
 664   *-*-vxworks*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   alpha*-*-*vms*)
 668     noconfigdirs="$noconfigdirs ${libgcj}"
 669     ;;
 670   arm-wince-pe)
 671     noconfigdirs="$noconfigdirs ${libgcj}"
 672     ;;
 673   arm*-*-symbianelf*)
 674     noconfigdirs="$noconfigdirs ${libgcj}"
 675     ;;
 676   bfin-*-*)
 677     noconfigdirs="$noconfigdirs target-boehm-gc"
 678     ;;
 679   cris-*-* | crisv32-*-*)
 680     unsupported_languages="$unsupported_languages java"
 681     case "${target}" in
 682       *-*-linux*)
 683         ;;
 684       *) # See PR46792 regarding target-libffi.
 685         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 686     esac
 687     ;;
 688   hppa*64*-*-linux*)
 689     # In this case, it's because the hppa64-linux target is for
 690     # the kernel only at this point and has no libc, and thus no
 691     # headers, crt*.o, etc., all of which are needed by these.
 692     unsupported_languages="$unsupported_languages java"
 693     ;;
 694   hppa*64*-*-hpux*)
 695     noconfigdirs="$noconfigdirs ${libgcj}"
 696     ;;
 697   hppa*-hp-hpux11*)
 698     ;;
 699   hppa*-*-hpux*)
 700     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 701     # build on HP-UX 10.20.
 702     noconfigdirs="$noconfigdirs ${libgcj}"
 703     ;;
 704   ia64*-*-*vms*)
 705     noconfigdirs="$noconfigdirs ${libgcj}"
 706     ;;
 707   i[[3456789]]86-w64-mingw*)
 708     noconfigdirs="$noconfigdirs ${libgcj}"
 709     ;;
 710   i[[3456789]]86-*-mingw*)
 711     noconfigdirs="$noconfigdirs ${libgcj}"
 712     ;;
 713   x86_64-*-mingw*)
 714     noconfigdirs="$noconfigdirs ${libgcj}"
 715     ;;
 716   mmix-*-*)
 717     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 718     ;;
 719   powerpc-*-aix*)
 720     # copied from rs6000-*-* entry
 721     noconfigdirs="$noconfigdirs ${libgcj}"
 722     ;;
 723   rs6000-*-aix*)
 724     noconfigdirs="$noconfigdirs ${libgcj}"
 725     ;;
 726   *-*-lynxos*)
 727     noconfigdirs="$noconfigdirs ${libgcj}"
 728     ;;
 729 esac
 730
 731 # Default libgloss CPU subdirectory.
 732 libgloss_dir="$target_cpu"
 733
 734 case "${target}" in
 735   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 736     libgloss_dir=wince
 737     ;;
 738   arm*-*-*)
 739     libgloss_dir=arm
 740     ;;
 741   cris-*-* | crisv32-*-*)
 742     libgloss_dir=cris
 743     ;;
 744   hppa*-*-*)
 745     libgloss_dir=pa
 746     ;;
 747   i[[3456789]]86-*-*)
 748     libgloss_dir=i386
 749     ;;
 750   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 751     libgloss_dir=m68hc11
 752     ;;
 753   m68*-*-* | fido-*-*)
 754     libgloss_dir=m68k
 755     ;;
 756   mips*-*-*)
 757     libgloss_dir=mips
 758     ;;
 759   powerpc*-*-*)
 760     libgloss_dir=rs6000
 761     ;;
 762   sparc*-*-*)
 763     libgloss_dir=sparc
 764     ;;
 765 esac
 766
 767 # Disable newlib and libgloss for various target OSes.
 768 case "${target}" in
 769   alpha*-dec-osf*)
 770     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 771     ;;
 772   i[[3456789]]86-*-linux*)
 773     # This section makes it possible to build newlib natively on linux.
 774     # If we are using a cross compiler then don't configure newlib.
 775     if test x${is_cross_compiler} != xno ; then
 776       noconfigdirs="$noconfigdirs target-newlib"
 777     fi
 778     noconfigdirs="$noconfigdirs target-libgloss"
 779     # If we are not using a cross compiler, do configure newlib.
 780     # Note however, that newlib will only be configured in this situation
 781     # if the --with-newlib option has been given, because otherwise
 782     # 'target-newlib' will appear in skipdirs.
 783     ;;
 784   i[[3456789]]86-*-rdos*)
 785     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 786     ;;
 787   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 789     ;;
 790   sparc-*-sunos4*)
 791     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 792     ;;
 793   *-*-aix*)
 794     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 795     ;;
 796   *-*-beos*)
 797     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 798     ;;
 799   *-*-chorusos)
 800     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 801     ;;
 802   *-*-dragonfly*)
 803     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 804     ;;
 805   *-*-freebsd*)
 806     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 807     ;;
 808   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 809     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 810     ;;
 811   *-*-lynxos*)
 812     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 813     ;;
 814   *-*-mingw*)
 815     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 816     ;;
 817   *-*-netbsd*)
 818     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 819     ;;
 820   *-*-netware*)
 821     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 822     ;;
 823   *-*-tpf*)
 824     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 825     ;;
 826   *-*-uclinux*)
 827     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 828     ;;
 829   *-*-vxworks*)
 830     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 831     ;;
 832 esac
 833
 834 case "${target}" in
 835   *-*-chorusos)
 836     ;;
 837   powerpc-*-darwin*)
 838     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 839     noconfigdirs="$noconfigdirs sim target-rda"
 840     ;;
 841   i[[3456789]]86-*-darwin*)
 842     noconfigdirs="$noconfigdirs ld gprof"
 843     noconfigdirs="$noconfigdirs sim target-rda"
 844     ;;
 845   x86_64-*-darwin[[912]]*)
 846     noconfigdirs="$noconfigdirs ld gas gprof"
 847     noconfigdirs="$noconfigdirs sim target-rda"
 848     ;;
 849   *-*-darwin*)
 850     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 851     noconfigdirs="$noconfigdirs sim target-rda"
 852     ;;
 853   *-*-dragonfly*)
 854     ;;
 855   *-*-freebsd*)
 856     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 857         && test -f /usr/local/include/gmp.h; then
 858       with_gmp=/usr/local
 859     fi
 860     ;;
 861   *-*-kaos*)
 862     # Remove unsupported stuff on all kaOS configurations.
 863     noconfigdirs="$noconfigdirs target-libgloss"
 864     ;;
 865   *-*-netbsd*)
 866     ;;
 867   *-*-netware*)
 868     ;;
 869   *-*-rtems*)
 870     noconfigdirs="$noconfigdirs target-libgloss"
 871     ;;
 872     # The tpf target doesn't support gdb yet.
 873   *-*-tpf*)
 874     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 875     ;;
 876   *-*-uclinux*)
 877     noconfigdirs="$noconfigdirs target-rda"
 878     ;;
 879   *-*-vxworks*)
 880     ;;
 881   alpha*-dec-osf*)
 882     # ld works, but does not support shared libraries.
 883     # gas doesn't generate exception information.
 884     noconfigdirs="$noconfigdirs gas ld"
 885     ;;
 886   alpha*-*-*vms*)
 887     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 888     ;;
 889   alpha*-*-*)
 890     # newlib is not 64 bit ready
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 894     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 895     ;;
 896   arc-*-*)
 897     noconfigdirs="$noconfigdirs target-libgloss"
 898     ;;
 899   arm-*-pe*)
 900     noconfigdirs="$noconfigdirs target-libgloss"
 901     ;;
 902   arm-*-riscix*)
 903     noconfigdirs="$noconfigdirs ld target-libgloss"
 904     ;;
 905   avr-*-rtems*)
 906     ;;
 907   avr-*-*)
 908     if test x${with_avrlibc} != xno; then
 909       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     fi
 911     ;;
 912   c4x-*-* | tic4x-*-*)
 913     noconfigdirs="$noconfigdirs target-libgloss"
 914     ;;
 915   tic54x-*-*)
 916     noconfigdirs="$noconfigdirs target-libgloss gdb"
 917     ;;
 918   d10v-*-*)
 919     noconfigdirs="$noconfigdirs target-libgloss"
 920     ;;
 921   d30v-*-*)
 922     noconfigdirs="$noconfigdirs gdb"
 923     ;;
 924   fr30-*-elf*)
 925     noconfigdirs="$noconfigdirs gdb"
 926     ;;
 927   moxie-*-*)
 928     noconfigdirs="$noconfigdirs gprof"
 929     ;;
 930   h8300*-*-*)
 931     noconfigdirs="$noconfigdirs target-libgloss"
 932     ;;
 933   h8500-*-*)
 934     noconfigdirs="$noconfigdirs target-libgloss"
 935     ;;
 936   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 937     ;;
 938   hppa*64*-*-linux*)
 939     ;;
 940   hppa*-*-linux*)
 941     ;;
 942   hppa*-*-*elf* | \
 943   hppa*-*-lites* | \
 944   hppa*-*-openbsd* | \
 945   hppa*64*-*-*)
 946     ;;
 947   hppa*-hp-hpux11*)
 948     noconfigdirs="$noconfigdirs ld"
 949     ;;
 950   hppa*-*-pro*)
 951     ;;
 952   hppa*-*-*)
 953     noconfigdirs="$noconfigdirs ld"
 954     ;;
 955   i960-*-*)
 956     noconfigdirs="$noconfigdirs gdb"
 957     ;;
 958   ia64*-*-elf*)
 959     # No gdb support yet.
 960     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 961     ;;
 962   ia64*-**-hpux*)
 963     # No ld support yet.
 964     noconfigdirs="$noconfigdirs libgui itcl ld"
 965     ;;
 966   ia64*-*-*vms*)
 967     # No ld support yet.
 968     noconfigdirs="$noconfigdirs libgui itcl ld"
 969     ;;
 970   i[[3456789]]86-w64-mingw*)
 971     ;;
 972   i[[3456789]]86-*-mingw*)
 973     target_configdirs="$target_configdirs target-winsup"
 974     ;;
 975   *-*-cygwin*)
 976     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 977     noconfigdirs="$noconfigdirs target-libgloss"
 978     # always build newlib if winsup directory is present.
 979     if test -d "$srcdir/winsup/cygwin"; then
 980       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 981     elif test -d "$srcdir/newlib"; then
 982       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 983     fi
 984     ;;
 985   i[[3456789]]86-*-pe)
 986     noconfigdirs="$noconfigdirs target-libgloss"
 987     ;;
 988   i[[3456789]]86-*-sco3.2v5*)
 989     # The linker does not yet know about weak symbols in COFF,
 990     # and is not configured to handle mixed ELF and COFF.
 991     noconfigdirs="$noconfigdirs ld target-libgloss"
 992     ;;
 993   i[[3456789]]86-*-sco*)
 994     noconfigdirs="$noconfigdirs gprof target-libgloss"
 995     ;;
 996   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 997     noconfigdirs="$noconfigdirs target-libgloss"
 998     ;;
 999   i[[3456789]]86-*-sysv4*)
1000     noconfigdirs="$noconfigdirs target-libgloss"
1001     ;;
1002   i[[3456789]]86-*-beos*)
1003     noconfigdirs="$noconfigdirs gdb"
1004     ;;
1005   i[[3456789]]86-*-rdos*)
1006     noconfigdirs="$noconfigdirs gdb"
1007     ;;
1008   mmix-*-*)
1009     noconfigdirs="$noconfigdirs gdb"
1010     ;;
1011   mt-*-*)
1012     noconfigdirs="$noconfigdirs sim"
1013     ;;
1014   powerpc-*-aix*)
1015     # copied from rs6000-*-* entry
1016     noconfigdirs="$noconfigdirs gprof"
1017     ;;
1018   powerpc*-*-winnt* | powerpc*-*-pe*)
1019     target_configdirs="$target_configdirs target-winsup"
1020     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1021     # always build newlib.
1022     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1023     ;;
1024     # This is temporary until we can link against shared libraries
1025   powerpcle-*-solaris*)
1026     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1027     ;;
1028   powerpc-*-beos*)
1029     noconfigdirs="$noconfigdirs gdb"
1030     ;;
1031   rs6000-*-lynxos*)
1032     noconfigdirs="$noconfigdirs gprof"
1033     ;;
1034   rs6000-*-aix*)
1035     noconfigdirs="$noconfigdirs gprof"
1036     ;;
1037   rs6000-*-*)
1038     noconfigdirs="$noconfigdirs gprof"
1039     ;;
1040   m68k-apollo-*)
1041     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1042     ;;
1043   microblaze*)
1044     noconfigdirs="$noconfigdirs gprof"
1045     ;;
1046   mips*-sde-elf* | mips*-mti-elf*)
1047     if test x$with_newlib = xyes; then
1048       noconfigdirs="$noconfigdirs gprof"
1049     fi
1050     ;;
1051   mips*-*-irix5*)
1052     noconfigdirs="$noconfigdirs gprof target-libgloss"
1053     ;;
1054   mips*-*-irix6*)
1055     noconfigdirs="$noconfigdirs gprof target-libgloss"
1056     ;;
1057   mips*-*-bsd*)
1058     noconfigdirs="$noconfigdirs gprof target-libgloss"
1059     ;;
1060   mips*-*-linux*)
1061     ;;
1062   mips*-*-*)
1063     noconfigdirs="$noconfigdirs gprof"
1064     ;;
1065   sh-*-* | sh64-*-*)
1066     case "${target}" in
1067       sh*-*-elf)
1068          ;;
1069       *)
1070          noconfigdirs="$noconfigdirs target-libgloss" ;;
1071     esac
1072     ;;
1073   sparc-*-sunos4*)
1074     if test x${is_cross_compiler} = xno ; then
1075            use_gnu_ld=no
1076     fi
1077     ;;
1078   tic6x-*-*)
1079     noconfigdirs="$noconfigdirs sim"
1080     ;;
1081   tilepro-*-* | tilegx-*-*)
1082     noconfigdirs="$noconfigdirs sim"
1083     ;;
1084   v810-*-*)
1085     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1086     ;;
1087   vax-*-*)
1088     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1089     ;;
1090 esac
1091
1092 # If we aren't building newlib, then don't build libgloss, since libgloss
1093 # depends upon some newlib header files.
1094 case "${noconfigdirs}" in
1095   *target-libgloss*) ;;
1096   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1097 esac
1098
1099 # Work in distributions that contain no compiler tools, like Autoconf.
1100 host_makefile_frag=/dev/null
1101 if test -d ${srcdir}/config ; then
1102 case "${host}" in
1103   i[[3456789]]86-*-msdosdjgpp*)
1104     host_makefile_frag="config/mh-djgpp"
1105     ;;
1106   *-cygwin*)
1107     ACX_CHECK_CYGWIN_CAT_WORKS
1108     host_makefile_frag="config/mh-cygwin"
1109     ;;
1110   *-mingw*)
1111     host_makefile_frag="config/mh-mingw"
1112     ;;
1113   hppa*-hp-hpux10*)
1114     host_makefile_frag="config/mh-pa-hpux10"
1115     ;;
1116   hppa*-hp-hpux*)
1117     host_makefile_frag="config/mh-pa"
1118     ;;
1119   hppa*-*)
1120     host_makefile_frag="config/mh-pa"
1121     ;;
1122   *-*-darwin*)
1123     host_makefile_frag="config/mh-darwin"
1124     ;;
1125   powerpc-*-aix*)
1126     host_makefile_frag="config/mh-ppc-aix"
1127     ;;
1128   rs6000-*-aix*)
1129     host_makefile_frag="config/mh-ppc-aix"
1130     ;;
1131 esac
1132 fi
1133
1134 if test "${build}" != "${host}" ; then
1135   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1136   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1137   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1138   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1139   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1140   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1141   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1142   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1143   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1144   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1145   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1146   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1147   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1148 else
1149   AR_FOR_BUILD="\$(AR)"
1150   AS_FOR_BUILD="\$(AS)"
1151   CC_FOR_BUILD="\$(CC)"
1152   CXX_FOR_BUILD="\$(CXX)"
1153   GCJ_FOR_BUILD="\$(GCJ)"
1154   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1155   GOC_FOR_BUILD="\$(GOC)"
1156   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1157   LD_FOR_BUILD="\$(LD)"
1158   NM_FOR_BUILD="\$(NM)"
1159   RANLIB_FOR_BUILD="\$(RANLIB)"
1160   WINDRES_FOR_BUILD="\$(WINDRES)"
1161   WINDMC_FOR_BUILD="\$(WINDMC)"
1162 fi
1163
1164 AC_PROG_CC
1165 AC_PROG_CXX
1166
1167 # We must set the default linker to the linker used by gcc for the correct
1168 # operation of libtool.  If LD is not defined and we are using gcc, try to
1169 # set the LD default to the ld used by gcc.
1170 if test -z "$LD"; then
1171   if test "$GCC" = yes; then
1172     case $build in
1173     *-*-mingw*)
1174       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1175     *)
1176       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1177     esac
1178     case $gcc_prog_ld in
1179     # Accept absolute paths.
1180     [[\\/]* | [A-Za-z]:[\\/]*)]
1181       LD="$gcc_prog_ld" ;;
1182     esac
1183   fi
1184 fi
1185
1186 # Check whether -static-libstdc++ -static-libgcc is supported.
1187 have_static_libs=no
1188 if test "$GCC" = yes; then
1189   saved_LDFLAGS="$LDFLAGS"
1190
1191   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1192   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1193   AC_LANG_PUSH(C++)
1194   AC_LINK_IFELSE([
1195 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1196 #error -static-libstdc++ not implemented
1197 #endif
1198 int main() {}],
1199     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1200     [AC_MSG_RESULT([no])])
1201   AC_LANG_POP(C++)
1202
1203   LDFLAGS="$saved_LDFLAGS"
1204 fi
1205
1206 ACX_PROG_GNAT
1207 ACX_PROG_CMP_IGNORE_INITIAL
1208
1209 AC_ARG_ENABLE([bootstrap],
1210 [AS_HELP_STRING([--enable-bootstrap],
1211                 [enable bootstrapping @<:@yes if native build@:>@])],,
1212 enable_bootstrap=default)
1213
1214 # Issue errors and warnings for invalid/strange bootstrap combinations.
1215 if test -r $srcdir/gcc/configure; then
1216   have_compiler=yes
1217 else
1218   have_compiler=no
1219 fi
1220
1221 case "$have_compiler:$host:$target:$enable_bootstrap" in
1222   *:*:*:no) ;;
1223
1224   # Default behavior.  Enable bootstrap if we have a compiler
1225   # and we are in a native configuration.
1226   yes:$build:$build:default)
1227     enable_bootstrap=yes ;;
1228
1229   *:*:*:default)
1230     enable_bootstrap=no ;;
1231
1232   # We have a compiler and we are in a native configuration, bootstrap is ok
1233   yes:$build:$build:yes)
1234     ;;
1235
1236   # Other configurations, but we have a compiler.  Assume the user knows
1237   # what he's doing.
1238   yes:*:*:yes)
1239     AC_MSG_WARN([trying to bootstrap a cross compiler])
1240     ;;
1241
1242   # No compiler: if they passed --enable-bootstrap explicitly, fail
1243   no:*:*:yes)
1244     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1245
1246   # Fail if wrong command line
1247   *)
1248     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1249     ;;
1250 esac
1251
1252 # Used for setting $lt_cv_objdir
1253 _LT_CHECK_OBJDIR
1254
1255 # Check for GMP, MPFR and MPC
1256 gmplibs="-lmpc -lmpfr -lgmp"
1257 gmpinc=
1258 have_gmp=no
1259
1260 # Specify a location for mpc
1261 # check for this first so it ends up on the link line before mpfr.
1262 AC_ARG_WITH(mpc,
1263 [AS_HELP_STRING([--with-mpc=PATH],
1264                 [specify prefix directory for installed MPC package.
1265                  Equivalent to --with-mpc-include=PATH/include
1266                  plus --with-mpc-lib=PATH/lib])])
1267 AC_ARG_WITH(mpc-include,
1268 [AS_HELP_STRING([--with-mpc-include=PATH],
1269                 [specify directory for installed MPC include files])])
1270 AC_ARG_WITH(mpc-lib,
1271 [AS_HELP_STRING([--with-mpc-lib=PATH],
1272                 [specify directory for the installed MPC library])])
1273
1274 if test "x$with_mpc" != x; then
1275   gmplibs="-L$with_mpc/lib $gmplibs"
1276   gmpinc="-I$with_mpc/include $gmpinc"
1277 fi
1278 if test "x$with_mpc_include" != x; then
1279   gmpinc="-I$with_mpc_include $gmpinc"
1280 fi
1281 if test "x$with_mpc_lib" != x; then
1282   gmplibs="-L$with_mpc_lib $gmplibs"
1283 fi
1284 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1285   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1286   gmpinc='-I$$s/mpc/src '"$gmpinc"
1287   # Do not test the mpc version.  Assume that it is sufficient, since
1288   # it is in the source tree, and the library has not been built yet
1289   # but it would be included on the link line in the version check below
1290   # hence making the test fail.
1291   have_gmp=yes
1292 fi
1293
1294 # Specify a location for mpfr
1295 # check for this first so it ends up on the link line before gmp.
1296 AC_ARG_WITH(mpfr-dir,
1297 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1298 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1299 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1300
1301 AC_ARG_WITH(mpfr,
1302 [AS_HELP_STRING([--with-mpfr=PATH],
1303                 [specify prefix directory for installed MPFR package.
1304                  Equivalent to --with-mpfr-include=PATH/include
1305                  plus --with-mpfr-lib=PATH/lib])])
1306 AC_ARG_WITH(mpfr-include,
1307 [AS_HELP_STRING([--with-mpfr-include=PATH],
1308                 [specify directory for installed MPFR include files])])
1309 AC_ARG_WITH(mpfr-lib,
1310 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1311                 [specify directory for the installed MPFR library])])
1312
1313 if test "x$with_mpfr" != x; then
1314   gmplibs="-L$with_mpfr/lib $gmplibs"
1315   gmpinc="-I$with_mpfr/include $gmpinc"
1316 fi
1317 if test "x$with_mpfr_include" != x; then
1318   gmpinc="-I$with_mpfr_include $gmpinc"
1319 fi
1320 if test "x$with_mpfr_lib" != x; then
1321   gmplibs="-L$with_mpfr_lib $gmplibs"
1322 fi
1323 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1324   # MPFR v3.1.0 moved the sources into a src sub-directory.
1325   if test -d ${srcdir}/mpfr/src; then
1326     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1327     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1328     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1329   else
1330     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1331     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1332     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1333   fi
1334   # Do not test the mpfr version.  Assume that it is sufficient, since
1335   # it is in the source tree, and the library has not been built yet
1336   # but it would be included on the link line in the version check below
1337   # hence making the test fail.
1338   have_gmp=yes
1339 fi
1340
1341 # Specify a location for gmp
1342 AC_ARG_WITH(gmp-dir,
1343 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1344 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1345 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1346
1347 AC_ARG_WITH(gmp,
1348 [AS_HELP_STRING([--with-gmp=PATH],
1349                 [specify prefix directory for the installed GMP package.
1350                  Equivalent to --with-gmp-include=PATH/include
1351                  plus --with-gmp-lib=PATH/lib])])
1352 AC_ARG_WITH(gmp-include,
1353 [AS_HELP_STRING([--with-gmp-include=PATH],
1354                 [specify directory for installed GMP include files])])
1355 AC_ARG_WITH(gmp-lib,
1356 [AS_HELP_STRING([--with-gmp-lib=PATH],
1357                 [specify directory for the installed GMP library])])
1358
1359
1360 if test "x$with_gmp" != x; then
1361   gmplibs="-L$with_gmp/lib $gmplibs"
1362   gmpinc="-I$with_gmp/include $gmpinc"
1363 fi
1364 if test "x$with_gmp_include" != x; then
1365   gmpinc="-I$with_gmp_include $gmpinc"
1366 fi
1367 if test "x$with_gmp_lib" != x; then
1368   gmplibs="-L$with_gmp_lib $gmplibs"
1369 fi
1370 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1371   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1372   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1373   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1374   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1375   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1376   # Do not test the gmp version.  Assume that it is sufficient, since
1377   # it is in the source tree, and the library has not been built yet
1378   # but it would be included on the link line in the version check below
1379   # hence making the test fail.
1380   have_gmp=yes
1381 fi
1382
1383 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1384   have_gmp=yes
1385   saved_CFLAGS="$CFLAGS"
1386   CFLAGS="$CFLAGS $gmpinc"
1387   # Check for the recommended and required versions of GMP.
1388   AC_MSG_CHECKING([for the correct version of gmp.h])
1389   AC_TRY_COMPILE([#include "gmp.h"],[
1390   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1391   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1392   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1393   choke me
1394   #endif
1395   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1396   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1397   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1398   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1399   choke me
1400   #endif
1401   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1402    [AC_MSG_RESULT([no]); have_gmp=no])
1403
1404   # If we have GMP, check the MPFR version.
1405   if test x"$have_gmp" = xyes; then
1406     # Check for the recommended and required versions of MPFR.
1407     AC_MSG_CHECKING([for the correct version of mpfr.h])
1408     AC_TRY_COMPILE([#include <gmp.h>
1409     #include <mpfr.h>],[
1410     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1411     choke me
1412     #endif
1413     ], [AC_TRY_COMPILE([#include <gmp.h>
1414     #include <mpfr.h>],[
1415     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1416     choke me
1417     #endif
1418     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1419      [AC_MSG_RESULT([no]); have_gmp=no])
1420   fi
1421
1422   # Check for the MPC header version.
1423   if test x"$have_gmp" = xyes ; then
1424     # Check for the recommended and required versions of MPC.
1425     AC_MSG_CHECKING([for the correct version of mpc.h])
1426     AC_TRY_COMPILE([#include <mpc.h>],[
1427     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1428     choke me
1429     #endif
1430     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1431     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1432     choke me
1433     #endif
1434     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1435      [AC_MSG_RESULT([no]); have_gmp=no])
1436   fi
1437
1438   # Now check the MPFR library.
1439   if test x"$have_gmp" = xyes; then
1440     saved_LIBS="$LIBS"
1441     LIBS="$LIBS $gmplibs"
1442     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1443     AC_TRY_LINK([#include <mpc.h>],[
1444     mpfr_t n;
1445     mpfr_t x;
1446     mpc_t c;
1447     int t;
1448     mpfr_init (n);
1449     mpfr_init (x);
1450     mpfr_atan2 (n, n, x, GMP_RNDN);
1451     mpfr_erfc (n, x, GMP_RNDN);
1452     mpfr_subnormalize (x, t, GMP_RNDN);
1453     mpfr_clear(n);
1454     mpfr_clear(x);
1455     mpc_init2 (c, 53);
1456     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1457     mpc_cosh (c, c, MPC_RNDNN);
1458     mpc_pow (c, c, c, MPC_RNDNN);
1459     mpc_acosh (c, c, MPC_RNDNN);
1460     mpc_clear (c);
1461     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1462     LIBS="$saved_LIBS"
1463   fi
1464
1465   CFLAGS="$saved_CFLAGS"
1466
1467 # The library versions listed in the error message below should match
1468 # the HARD-minimums enforced above.
1469   if test x$have_gmp != xyes; then
1470     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1471 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1472 their locations.  Source code for these libraries can be found at
1473 their respective hosting sites as well as at
1474 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1475 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1476 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1477 make sure that you have installed both the libraries and the header
1478 files.  They may be located in separate packages.])
1479   fi
1480 fi
1481
1482 # Flags needed for both GMP, MPFR and/or MPC.
1483 AC_SUBST(gmplibs)
1484 AC_SUBST(gmpinc)
1485 AC_SUBST(extra_mpfr_configure_flags)
1486 AC_SUBST(extra_mpc_gmp_configure_flags)
1487 AC_SUBST(extra_mpc_mpfr_configure_flags)
1488 AC_SUBST(extra_isl_gmp_configure_flags)
1489
1490 # Allow host libstdc++ to be specified for static linking with PPL.
1491 AC_ARG_WITH(host-libstdcxx,
1492 [AS_HELP_STRING([--with-host-libstdcxx=L],
1493                 [use linker arguments L to link with libstdc++
1494                  when linking with PPL])])
1495
1496 case $with_host_libstdcxx in
1497   no|yes)
1498     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1499     ;;
1500 esac
1501
1502 # Libraries to use for stage1 or when not bootstrapping.
1503 AC_ARG_WITH(stage1-libs,
1504 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1505 [if test "$withval" = "no" -o "$withval" = "yes"; then
1506    stage1_libs=
1507  else
1508    stage1_libs=$withval
1509  fi],
1510 [stage1_libs=$with_host_libstdcxx])
1511 AC_SUBST(stage1_libs)
1512
1513 # Linker flags to use for stage1 or when not bootstrapping.
1514 AC_ARG_WITH(stage1-ldflags,
1515 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1516 [if test "$withval" = "no" -o "$withval" = "yes"; then
1517    stage1_ldflags=
1518  else
1519    stage1_ldflags=$withval
1520  fi],
1521 [stage1_ldflags=
1522  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1523  # if supported.  But if the user explicitly specified the libraries to use,
1524  # trust that they are doing what they want.
1525  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1526    stage1_ldflags="-static-libstdc++ -static-libgcc"
1527  fi])
1528 AC_SUBST(stage1_ldflags)
1529
1530 # Libraries to use for stage2 and later builds.  This defaults to the
1531 # argument passed to --with-host-libstdcxx.
1532 AC_ARG_WITH(boot-libs,
1533 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1534 [if test "$withval" = "no" -o "$withval" = "yes"; then
1535    poststage1_libs=
1536  else
1537    poststage1_libs=$withval
1538  fi],
1539 [poststage1_libs=$with_host_libstdcxx])
1540 AC_SUBST(poststage1_libs)
1541
1542 # Linker flags to use for stage2 and later builds.
1543 AC_ARG_WITH(boot-ldflags,
1544 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1545                 [linker flags for stage2 and later])],
1546 [if test "$withval" = "no" -o "$withval" = "yes"; then
1547    poststage1_ldflags=
1548  else
1549    poststage1_ldflags=$withval
1550  fi],
1551 [poststage1_ldflags=
1552  # In stages 2 and 3, default to linking libstdc++ and libgcc
1553  # statically.  But if the user explicitly specified the libraries to
1554  # use, trust that they are doing what they want.
1555  if test "$poststage1_libs" = ""; then
1556    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1557  fi])
1558 AC_SUBST(poststage1_ldflags)
1559
1560 # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL.
1561 # Basic setup is inlined here, actual checks are in config/cloog.m4 and
1562 # config/isl.m4
1563
1564 AC_ARG_WITH(cloog,
1565   [AS_HELP_STRING(
1566     [--with-cloog=PATH],
1567     [Specify prefix directory for the installed CLooG-ISL package.
1568      Equivalent to --with-cloog-include=PATH/include
1569      plus --with-cloog-lib=PATH/lib])])
1570 AC_ARG_WITH(isl,
1571   [AS_HELP_STRING(
1572    [--with-isl=PATH],
1573    [Specify prefix directory for the installed ISL package.
1574     Equivalent to --with-isl-include=PATH/include
1575     plus --with-isl-lib=PATH/lib])])
1576
1577 # Treat either --without-cloog or --without-isl as a request to disable
1578 # GRAPHITE support and skip all following checks.
1579 if test "x$with_isl" != "xno" &&
1580    test "x$with_cloog" != "xno"; then
1581   # Check for ISL
1582   dnl Provide configure switches and initialize islinc & isllibs
1583   dnl with user input.
1584   ISL_INIT_FLAGS
1585   dnl The minimal version of ISL required for Graphite.
1586   ISL_CHECK_VERSION(0,10)
1587   dnl Only execute fail-action, if ISL has been requested.
1588   ISL_IF_FAILED([
1589     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1590
1591   if test "x$gcc_cv_isl" != "xno"; then
1592     # Check for CLOOG
1593     dnl Provide configure switches and initialize clooginc & clooglibs
1594     dnl with user input.
1595     CLOOG_INIT_FLAGS
1596     dnl The minimal version of CLooG required for Graphite.
1597     dnl
1598     dnl If we use CLooG-Legacy, the provided version information is
1599     dnl ignored.
1600     CLOOG_CHECK_VERSION(0,17,0)
1601
1602     dnl Only execute fail-action, if CLooG has been requested.
1603     CLOOG_IF_FAILED([
1604       AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1605   fi
1606 fi
1607
1608 # If either the ISL or the CLooG check failed, disable builds of in-tree
1609 # variants of both
1610 if test "x$with_isl" = xno ||
1611    test "x$with_cloog" = xno ||
1612    test "x$gcc_cv_cloog" = xno ||
1613    test "x$gcc_cv_isl" = xno; then
1614   noconfigdirs="$noconfigdirs cloog isl"
1615   islinc=
1616   clooginc=
1617   clooglibs=
1618 fi
1619
1620 AC_SUBST(islinc)
1621 AC_SUBST(clooglibs)
1622 AC_SUBST(clooginc)
1623
1624
1625 # Check for LTO support.
1626 AC_ARG_ENABLE(lto,
1627 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1628 enable_lto=$enableval,
1629 enable_lto=yes; default_enable_lto=yes)
1630
1631 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1632   build_lto_plugin=yes
1633 ],[if test x"$default_enable_lto" = x"yes" ; then
1634     case $target in
1635       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1636       # On other non-ELF platforms, LTO has yet to be validated.
1637       *) enable_lto=no ;;
1638     esac
1639   else
1640   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1641   # It would also be nice to check the binutils support, but we don't
1642   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1643   # warn during gcc/ subconfigure; unless you're bootstrapping with
1644   # -flto it won't be needed until after installation anyway.
1645     case $target in
1646       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1647       *) if test x"$enable_lto" = x"yes"; then
1648         AC_MSG_ERROR([LTO support is not enabled for this target.])
1649         fi
1650       ;;
1651     esac
1652   fi
1653   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1654   # Build it unless LTO was explicitly disabled.
1655   case $target in
1656     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1657     *) ;;
1658   esac
1659 ])
1660
1661
1662 # By default, C and C++ are the only stage 1 languages.
1663 stage1_languages=,c,
1664
1665 # Target libraries that we bootstrap.
1666 bootstrap_target_libs=,target-libgcc,
1667
1668 # Figure out what language subdirectories are present.
1669 # Look if the user specified --enable-languages="..."; if not, use
1670 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1671 # go away some day.
1672 # NB:  embedded tabs in this IF block -- do not untabify
1673 if test -d ${srcdir}/gcc; then
1674   if test x"${enable_languages+set}" != xset; then
1675     if test x"${LANGUAGES+set}" = xset; then
1676       enable_languages="${LANGUAGES}"
1677         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1678     else
1679       enable_languages=all
1680     fi
1681   else
1682     if test x"${enable_languages}" = x ||
1683        test x"${enable_languages}" = xyes;
1684        then
1685       echo configure.in: --enable-languages needs at least one language argument 1>&2
1686       exit 1
1687     fi
1688   fi
1689   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1690
1691   # 'f95' is the old name for the 'fortran' language. We issue a warning
1692   # and make the substitution.
1693   case ,${enable_languages}, in
1694     *,f95,*)
1695       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1696       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1697       ;;
1698   esac
1699
1700   # If bootstrapping, C++ must be enabled.
1701   case ",$enable_languages,:$enable_bootstrap" in
1702     *,c++,*:*) ;;
1703     *:yes)
1704       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1705         enable_languages="${enable_languages},c++"
1706       else
1707         AC_MSG_ERROR([bootstrapping requires c++ sources])
1708       fi
1709       ;;
1710   esac
1711
1712   # First scan to see if an enabled language requires some other language.
1713   # We assume that a given config-lang.in will list all the language
1714   # front ends it requires, even if some are required indirectly.
1715   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1716     case ${lang_frag} in
1717       ..) ;;
1718       # The odd quoting in the next line works around
1719       # an apparent bug in bash 1.12 on linux.
1720       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1721       *)
1722         # From the config-lang.in, get $language, $lang_requires, and
1723         # $lang_requires_boot_languages.
1724         language=
1725         lang_requires=
1726         lang_requires_boot_languages=
1727         . ${lang_frag}
1728         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1729           case ,${enable_languages}, in
1730             *,$other,*) ;;
1731             *,all,*) ;;
1732             *,$language,*)
1733               echo " \`$other' language required by \`$language'; enabling" 1>&2
1734               enable_languages="${enable_languages},${other}"
1735               ;;
1736           esac
1737         done
1738         for other in ${lang_requires_boot_languages} ; do
1739           if test "$other" != "c"; then
1740             case ,${enable_stage1_languages}, in
1741               *,$other,*) ;;
1742               *,all,*) ;;
1743               *)
1744                 case ,${enable_languages}, in
1745                   *,$language,*)
1746                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1747                     enable_stage1_languages="$enable_stage1_languages,${other}"
1748                     ;;
1749                 esac
1750                 ;;
1751             esac
1752           fi
1753         done
1754         ;;
1755     esac
1756   done
1757
1758   new_enable_languages=,c,
1759
1760   # If LTO is enabled, add the LTO front end.
1761   extra_host_libiberty_configure_flags=
1762   if test "$enable_lto" = "yes" ; then
1763     case ,${enable_languages}, in
1764       *,lto,*) ;;
1765       *) enable_languages="${enable_languages},lto" ;;
1766     esac
1767     if test "${build_lto_plugin}" = "yes" ; then
1768       configdirs="$configdirs lto-plugin"
1769       extra_host_libiberty_configure_flags=--enable-shared
1770     fi
1771   fi
1772   AC_SUBST(extra_host_libiberty_configure_flags)
1773
1774   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1775   potential_languages=,c,
1776
1777   enabled_target_libs=
1778   disabled_target_libs=
1779
1780   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1781     case ${lang_frag} in
1782       ..) ;;
1783       # The odd quoting in the next line works around
1784       # an apparent bug in bash 1.12 on linux.
1785       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1786       *)
1787         # From the config-lang.in, get $language, $target_libs,
1788         # $lang_dirs, $boot_language, and $build_by_default
1789         language=
1790         target_libs=
1791         lang_dirs=
1792         subdir_requires=
1793         boot_language=no
1794         build_by_default=yes
1795         . ${lang_frag}
1796         if test x${language} = x; then
1797           echo "${lang_frag} doesn't set \$language." 1>&2
1798           exit 1
1799         fi
1800
1801         if test "$language" = "c++"; then
1802           boot_language=yes
1803         fi
1804
1805         add_this_lang=no
1806         case ,${enable_languages}, in
1807           *,${language},*)
1808             # Language was explicitly selected; include it
1809             # unless it is C, which is enabled by default.
1810             if test "$language" != "c"; then
1811               add_this_lang=yes
1812             fi
1813             ;;
1814           *,all,*)
1815             # 'all' was selected, select it if it is a default language
1816             if test "$language" != "c"; then
1817               add_this_lang=${build_by_default}
1818             fi
1819             ;;
1820         esac
1821
1822         # Disable languages that need other directories if these aren't available.
1823         for i in $subdir_requires; do
1824           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1825           case ,${enable_languages}, in
1826             *,${language},*)
1827               # Specifically requested language; tell them.
1828               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1829               ;;
1830             *)
1831               # Silently disable.
1832               add_this_lang=unsupported
1833               ;;
1834           esac
1835         done
1836
1837         # Disable Ada if no preexisting GNAT is available.
1838         case ,${enable_languages},:${language}:${have_gnat} in
1839           *,${language},*:ada:no)
1840             # Specifically requested language; tell them.
1841             AC_MSG_ERROR([GNAT is required to build $language])
1842             ;;
1843           *:ada:no)
1844             # Silently disable.
1845             add_this_lang=unsupported
1846             ;;
1847         esac
1848
1849         # Disable a language that is unsupported by the target.
1850         case " $unsupported_languages " in
1851           *" $language "*)
1852             add_this_lang=unsupported
1853             ;;
1854         esac
1855
1856         case $add_this_lang in
1857           unsupported)
1858             # Remove language-dependent dirs.
1859             disabled_target_libs="$disabled_target_libs $target_libs"
1860             noconfigdirs="$noconfigdirs $lang_dirs"
1861             ;;
1862           no)
1863             # Remove language-dependent dirs; still show language as supported.
1864             disabled_target_libs="$disabled_target_libs $target_libs"
1865             noconfigdirs="$noconfigdirs $lang_dirs"
1866             potential_languages="${potential_languages}${language},"
1867             ;;
1868           yes)
1869             new_enable_languages="${new_enable_languages}${language},"
1870             potential_languages="${potential_languages}${language},"
1871             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1872             enabled_target_libs="$enabled_target_libs $target_libs"
1873             case "${boot_language}:,$enable_stage1_languages," in
1874               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1875                 # Add to (comma-separated) list of stage 1 languages.
1876                 case ",$stage1_languages," in
1877                   *,$language,* | ,yes, | ,all,) ;;
1878                   *) stage1_languages="${stage1_languages}${language}," ;;
1879                 esac
1880                 # We need to bootstrap any supporting libraries.
1881                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1882                 ;;
1883             esac
1884             ;;
1885         esac
1886         ;;
1887     esac
1888   done
1889
1890   # Add target libraries which are only needed for disabled languages
1891   # to noconfigdirs.
1892   if test -n "$disabled_target_libs"; then
1893     for dir in $disabled_target_libs; do
1894       case " $enabled_target_libs " in
1895       *" ${dir} "*) ;;
1896       *) noconfigdirs="$noconfigdirs $dir" ;;
1897       esac
1898     done
1899   fi
1900
1901   AC_ARG_ENABLE(stage1-languages,
1902   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1903                   [choose additional languages to build during
1904                   stage1.  Mostly useful for compiler development])],
1905   [case ,${enable_stage1_languages}, in
1906     ,no,|,,)
1907       # Set it to something that will have no effect in the loop below
1908       enable_stage1_languages=c ;;
1909     ,yes,)
1910       enable_stage1_languages=`echo $new_enable_languages | \
1911         sed -e "s/^,//" -e "s/,$//" ` ;;
1912     *,all,*)
1913       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1914         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1915   esac
1916
1917   # Add "good" languages from enable_stage1_languages to stage1_languages,
1918   # while "bad" languages go in missing_languages.  Leave no duplicates.
1919   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1920     case $potential_languages in
1921       *,$i,*)
1922         case $stage1_languages in
1923           *,$i,*) ;;
1924           *) stage1_languages="$stage1_languages$i," ;;
1925         esac ;;
1926       *)
1927         case $missing_languages in
1928           *,$i,*) ;;
1929           *) missing_languages="$missing_languages$i," ;;
1930         esac ;;
1931      esac
1932   done])
1933
1934   # Remove leading/trailing commas that were added for simplicity
1935   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1936   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1937   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1938   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1939
1940   if test "x$missing_languages" != x; then
1941     AC_MSG_ERROR([
1942 The following requested languages could not be built: ${missing_languages}
1943 Supported languages are: ${potential_languages}])
1944   fi
1945   if test "x$new_enable_languages" != "x$enable_languages"; then
1946     echo The following languages will be built: ${new_enable_languages}
1947     enable_languages="$new_enable_languages"
1948   fi
1949
1950   AC_SUBST(stage1_languages)
1951   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1952 fi
1953
1954 # Handle --disable-<component> generically.
1955 for dir in $configdirs $build_configdirs $target_configdirs ; do
1956   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1957   varname=`echo $dirname | sed -e s/+/_/g`
1958   if eval test x\${enable_${varname}} "=" xno ; then
1959     noconfigdirs="$noconfigdirs $dir"
1960   fi
1961 done
1962
1963 # Check for Boehm's garbage collector
1964 AC_ARG_ENABLE(objc-gc,
1965 [AS_HELP_STRING([--enable-objc-gc],
1966                 [enable use of Boehm's garbage collector with the
1967                  GNU Objective-C runtime])],
1968 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1969   *,objc,*:*:yes:*target-boehm-gc*)
1970     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1971     ;;
1972 esac])
1973
1974 # Make sure we only build Boehm's garbage collector if required.
1975 case ,${enable_languages},:${enable_objc_gc} in
1976   *,objc,*:yes)
1977     # Keep target-boehm-gc if requested for Objective-C.
1978     ;;
1979   *)
1980     # Otherwise remove target-boehm-gc depending on target-libjava.
1981     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1982       noconfigdirs="$noconfigdirs target-boehm-gc"
1983     fi
1984     ;;
1985 esac
1986
1987 # Disable libitm if we're not building C++
1988 case ,${enable_languages}, in
1989   *,c++,*) ;;
1990   *)
1991     noconfigdirs="$noconfigdirs target-libitm"
1992     ;;
1993 esac
1994
1995 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1996 # $build_configdirs and $target_configdirs.
1997 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1998
1999 notsupp=""
2000 for dir in . $skipdirs $noconfigdirs ; do
2001   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2002   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2003     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2004     if test -r $srcdir/$dirname/configure ; then
2005       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2006         true
2007       else
2008         notsupp="$notsupp $dir"
2009       fi
2010     fi
2011   fi
2012   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2013     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2014     if test -r $srcdir/$dirname/configure ; then
2015       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2016         true
2017       else
2018         notsupp="$notsupp $dir"
2019       fi
2020     fi
2021   fi
2022   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2023     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2024     if test -r $srcdir/$dirname/configure ; then
2025       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2026         true
2027       else
2028         notsupp="$notsupp $dir"
2029       fi
2030     fi
2031   fi
2032 done
2033
2034 # Quietly strip out all directories which aren't configurable in this tree.
2035 # This relies on all configurable subdirectories being autoconfiscated, which
2036 # is now the case.
2037 build_configdirs_all="$build_configdirs"
2038 build_configdirs=
2039 for i in ${build_configdirs_all} ; do
2040   j=`echo $i | sed -e s/build-//g`
2041   if test -f ${srcdir}/$j/configure ; then
2042     build_configdirs="${build_configdirs} $i"
2043   fi
2044 done
2045
2046 configdirs_all="$configdirs"
2047 configdirs=
2048 for i in ${configdirs_all} ; do
2049   if test -f ${srcdir}/$i/configure ; then
2050     configdirs="${configdirs} $i"
2051   fi
2052 done
2053
2054 target_configdirs_all="$target_configdirs"
2055 target_configdirs=
2056 for i in ${target_configdirs_all} ; do
2057   j=`echo $i | sed -e s/target-//g`
2058   if test -f ${srcdir}/$j/configure ; then
2059     target_configdirs="${target_configdirs} $i"
2060   fi
2061 done
2062
2063 # Produce a warning message for the subdirs we can't configure.
2064 # This isn't especially interesting in the Cygnus tree, but in the individual
2065 # FSF releases, it's important to let people know when their machine isn't
2066 # supported by the one or two programs in a package.
2067
2068 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2069   # If $appdirs is non-empty, at least one of those directories must still
2070   # be configured, or we error out.  (E.g., if the gas release supports a
2071   # specified target in some subdirs but not the gas subdir, we shouldn't
2072   # pretend that all is well.)
2073   if test -n "$appdirs" ; then
2074     for dir in $appdirs ; do
2075       if test -r $dir/Makefile.in ; then
2076         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2077           appdirs=""
2078           break
2079         fi
2080         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2081           appdirs=""
2082           break
2083         fi
2084       fi
2085     done
2086     if test -n "$appdirs" ; then
2087       echo "*** This configuration is not supported by this package." 1>&2
2088       exit 1
2089     fi
2090   fi
2091   # Okay, some application will build, or we don't care to check.  Still
2092   # notify of subdirs not getting built.
2093   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2094   echo "    ${notsupp}" 1>&2
2095   echo "    (Any other directories should still work fine.)" 1>&2
2096 fi
2097
2098 case "$host" in
2099   *msdosdjgpp*)
2100     enable_gdbtk=no ;;
2101 esac
2102
2103 # To find our prefix, in gcc_cv_tool_prefix.
2104 ACX_TOOL_DIRS
2105
2106 copy_dirs=
2107
2108 AC_ARG_WITH([build-sysroot],
2109   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2110                   [use sysroot as the system root during the build])],
2111   [if test x"$withval" != x ; then
2112      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2113    fi],
2114   [SYSROOT_CFLAGS_FOR_TARGET=])
2115 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2116
2117 AC_ARG_WITH([debug-prefix-map],
2118   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2119                   [map A to B, C to D ... in debug information])],
2120   [if test x"$withval" != x; then
2121      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2122      for debug_map in $withval; do
2123        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2124      done
2125    fi],
2126   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2127 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2128
2129 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2130 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2131 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2132 # We want to ensure that TARGET libraries (which we know are built with
2133 # gcc) are built with "-O2 -g", so include those options when setting
2134 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2135 if test "x$CFLAGS_FOR_TARGET" = x; then
2136   CFLAGS_FOR_TARGET=$CFLAGS
2137   case " $CFLAGS " in
2138     *" -O2 "*) ;;
2139     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2140   esac
2141   case " $CFLAGS " in
2142     *" -g "* | *" -g3 "*) ;;
2143     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2144   esac
2145 fi
2146 AC_SUBST(CFLAGS_FOR_TARGET)
2147
2148 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2149   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2150   case " $CXXFLAGS " in
2151     *" -O2 "*) ;;
2152     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2153   esac
2154   case " $CXXFLAGS " in
2155     *" -g "* | *" -g3 "*) ;;
2156     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2157   esac
2158 fi
2159 AC_SUBST(CXXFLAGS_FOR_TARGET)
2160
2161 AC_SUBST(LDFLAGS_FOR_TARGET)
2162
2163 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2164 # the named directory are copied to $(tooldir)/sys-include.
2165 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2166   if test x${is_cross_compiler} = xno ; then
2167     echo 1>&2 '***' --with-headers is only supported when cross compiling
2168     exit 1
2169   fi
2170   if test x"${with_headers}" != xyes ; then
2171     x=${gcc_cv_tool_prefix}
2172     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2173   fi
2174 fi
2175
2176 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2177 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2178 # are permitted.
2179 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2180   if test x${is_cross_compiler} = xno ; then
2181     echo 1>&2 '***' --with-libs is only supported when cross compiling
2182     exit 1
2183   fi
2184   if test x"${with_libs}" != xyes ; then
2185     # Copy the libraries in reverse order, so that files in the first named
2186     # library override files in subsequent libraries.
2187     x=${gcc_cv_tool_prefix}
2188     for l in ${with_libs}; do
2189       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2190     done
2191   fi
2192 fi
2193
2194 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2195 #
2196 # This is done by determining whether or not the appropriate directory
2197 # is available, and by checking whether or not specific configurations
2198 # have requested that this magic not happen.
2199 #
2200 # The command line options always override the explicit settings in
2201 # configure.in, and the settings in configure.in override this magic.
2202 #
2203 # If the default for a toolchain is to use GNU as and ld, and you don't
2204 # want to do that, then you should use the --without-gnu-as and
2205 # --without-gnu-ld options for the configure script.  Similarly, if
2206 # the default is to use the included zlib and you don't want to do that,
2207 # you should use the --with-system-zlib option for the configure script.
2208
2209 if test x${use_gnu_as} = x &&
2210    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2211   with_gnu_as=yes
2212   extra_host_args="$extra_host_args --with-gnu-as"
2213 fi
2214
2215 if test x${use_gnu_ld} = x &&
2216    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2217   with_gnu_ld=yes
2218   extra_host_args="$extra_host_args --with-gnu-ld"
2219 fi
2220
2221 if test x${use_included_zlib} = x &&
2222    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2223   :
2224 else
2225   with_system_zlib=yes
2226   extra_host_args="$extra_host_args --with-system-zlib"
2227 fi
2228
2229 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2230 # can detect this case.
2231
2232 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2233   with_newlib=yes
2234   extra_host_args="$extra_host_args --with-newlib"
2235 fi
2236
2237 # Handle ${copy_dirs}
2238 set fnord ${copy_dirs}
2239 shift
2240 while test $# != 0 ; do
2241   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2242     :
2243   else
2244     echo Copying $1 to $2
2245
2246     # Use the install script to create the directory and all required
2247     # parent directories.
2248     if test -d $2 ; then
2249       :
2250     else
2251       echo >config.temp
2252       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2253     fi
2254
2255     # Copy the directory, assuming we have tar.
2256     # FIXME: Should we use B in the second tar?  Not all systems support it.
2257     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2258
2259     # It is the responsibility of the user to correctly adjust all
2260     # symlinks.  If somebody can figure out how to handle them correctly
2261     # here, feel free to add the code.
2262
2263     echo $1 > $2/COPIED
2264   fi
2265   shift; shift
2266 done
2267
2268 # Determine a target-dependent exec_prefix that the installed
2269 # gcc will search in.  Keep this list sorted by triplet, with
2270 # the *-*-osname triplets last.
2271 md_exec_prefix=
2272 case "${target}" in
2273   i[[34567]]86-pc-msdosdjgpp*)
2274     md_exec_prefix=/dev/env/DJDIR/bin
2275     ;;
2276   *-*-hpux* | \
2277   *-*-nto-qnx* | \
2278   *-*-solaris2*)
2279     md_exec_prefix=/usr/ccs/bin
2280     ;;
2281 esac
2282
2283 extra_arflags_for_target=
2284 extra_nmflags_for_target=
2285 extra_ranlibflags_for_target=
2286 target_makefile_frag=/dev/null
2287 case "${target}" in
2288   spu-*-*)
2289     target_makefile_frag="config/mt-spu"
2290     ;;
2291   mips*-sde-elf* | mips*-mti-elf*)
2292     target_makefile_frag="config/mt-sde"
2293     ;;
2294   mipsisa*-*-elfoabi*)
2295     target_makefile_frag="config/mt-mips-elfoabi"
2296     ;;
2297   mips*-*-*linux* | mips*-*-gnu*)
2298     target_makefile_frag="config/mt-mips-gnu"
2299     ;;
2300   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2301     target_makefile_frag="config/mt-gnu"
2302     ;;
2303   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2304     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2305     # commands to handle both 32-bit and 64-bit objects.  These flags are
2306     # harmless if we're using GNU nm or ar.
2307     extra_arflags_for_target=" -X32_64"
2308     extra_nmflags_for_target=" -B -X32_64"
2309     ;;
2310 esac
2311
2312 alphaieee_frag=/dev/null
2313 case $target in
2314   alpha*-*-*)
2315     # This just makes sure to use the -mieee option to build target libs.
2316     # This should probably be set individually by each library.
2317     alphaieee_frag="config/mt-alphaieee"
2318     ;;
2319 esac
2320
2321 # If --enable-target-optspace always use -Os instead of -O2 to build
2322 # the target libraries, similarly if it is not specified, use -Os
2323 # on selected platforms.
2324 ospace_frag=/dev/null
2325 case "${enable_target_optspace}:${target}" in
2326   yes:*)
2327     ospace_frag="config/mt-ospace"
2328     ;;
2329   :d30v-*)
2330     ospace_frag="config/mt-d30v"
2331     ;;
2332   :m32r-* | :d10v-* | :fr30-*)
2333     ospace_frag="config/mt-ospace"
2334     ;;
2335   no:* | :*)
2336     ;;
2337   *)
2338     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2339     ;;
2340 esac
2341
2342 # Some systems (e.g., one of the i386-aix systems the gas testers are
2343 # using) don't handle "\$" correctly, so don't use it here.
2344 tooldir='${exec_prefix}'/${target_noncanonical}
2345 build_tooldir=${tooldir}
2346
2347 # Create a .gdbinit file which runs the one in srcdir
2348 # and tells GDB to look there for source files.
2349
2350 if test -r ${srcdir}/.gdbinit ; then
2351   case ${srcdir} in
2352     .) ;;
2353     *) cat > ./.gdbinit <<EOF
2354 # ${NO_EDIT}
2355 dir ${srcdir}
2356 dir .
2357 source ${srcdir}/.gdbinit
2358 EOF
2359     ;;
2360   esac
2361 fi
2362
2363 # Make sure that the compiler is able to generate an executable.  If it
2364 # can't, we are probably in trouble.  We don't care whether we can run the
2365 # executable--we might be using a cross compiler--we only care whether it
2366 # can be created.  At this point the main configure script has set CC.
2367 we_are_ok=no
2368 echo "int main () { return 0; }" > conftest.c
2369 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2370 if test $? = 0 ; then
2371   if test -s conftest || test -s conftest.exe ; then
2372     we_are_ok=yes
2373   fi
2374 fi
2375 case $we_are_ok in
2376   no)
2377     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2378     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2379     rm -f conftest*
2380     exit 1
2381     ;;
2382 esac
2383 rm -f conftest*
2384
2385 # Decide which environment variable is used to find dynamic libraries.
2386 case "${host}" in
2387   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2388   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2389   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2390   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2391 esac
2392
2393 # On systems where the dynamic library environment variable is PATH,
2394 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2395 # built executables to PATH.
2396 if test "$RPATH_ENVVAR" = PATH; then
2397   GCC_SHLIB_SUBDIR=/shlib
2398 else
2399   GCC_SHLIB_SUBDIR=
2400 fi
2401
2402 # Record target_configdirs and the configure arguments for target and
2403 # build configuration in Makefile.
2404 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2405 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2406
2407 # If we are building libgomp, bootstrap it.
2408 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2409   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2410 fi
2411
2412 # Determine whether gdb needs tk/tcl or not.
2413 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2414 # and in that case we want gdb to be built without tk.  Ugh!
2415 # In fact I believe gdb is the *only* package directly dependent on tk,
2416 # so we should be able to put the 'maybe's in unconditionally and
2417 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2418 # 100% sure that that's safe though.
2419
2420 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2421 case "$enable_gdbtk" in
2422   no)
2423     GDB_TK="" ;;
2424   yes)
2425     GDB_TK="${gdb_tk}" ;;
2426   *)
2427     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2428     # distro.  Eventually someone will fix this and move Insight, nee
2429     # gdbtk to a separate directory.
2430     if test -d ${srcdir}/gdb/gdbtk ; then
2431       GDB_TK="${gdb_tk}"
2432     else
2433       GDB_TK=""
2434     fi
2435     ;;
2436 esac
2437 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2438 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2439
2440 # Strip out unwanted targets.
2441
2442 # While at that, we remove Makefiles if we were started for recursive
2443 # configuration, so that the top-level Makefile reconfigures them,
2444 # like we used to do when configure itself was recursive.
2445
2446 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2447 # but now we're fixing up the Makefile ourselves with the additional
2448 # commands passed to AC_CONFIG_FILES.  Use separate variables
2449 # extrasub-{build,host,target} not because there is any reason to split
2450 # the substitutions up that way, but only to remain below the limit of
2451 # 99 commands in a script, for HP-UX sed.
2452 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2453
2454 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2455   yes:yes:*\ gold\ *:*,c++,*) ;;
2456   yes:yes:*\ gold\ *:*)
2457     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2458     ;;
2459 esac
2460
2461 # Adjust the toplevel makefile according to whether bootstrap was selected.
2462 case $enable_bootstrap in
2463   yes)
2464     bootstrap_suffix=bootstrap
2465     BUILD_CONFIG=bootstrap-debug
2466     ;;
2467   no)
2468     bootstrap_suffix=no-bootstrap
2469     BUILD_CONFIG=
2470     ;;
2471 esac
2472
2473 AC_MSG_CHECKING(for default BUILD_CONFIG)
2474
2475 AC_ARG_WITH([build-config],
2476   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2477                   [use config/NAME.mk build configuration])],
2478   [case $with_build_config in
2479    yes) with_build_config= ;;
2480    no) with_build_config= BUILD_CONFIG= ;;
2481    esac])
2482
2483 if test "x${with_build_config}" != x; then
2484   BUILD_CONFIG=$with_build_config
2485 else
2486   case $BUILD_CONFIG in
2487   bootstrap-debug)
2488     if echo "int f (void) { return 0; }" > conftest.c &&
2489        ${CC} -c conftest.c &&
2490        mv conftest.o conftest.o.g0 &&
2491        ${CC} -c -g conftest.c &&
2492        mv conftest.o conftest.o.g &&
2493        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2494       :
2495     else
2496       BUILD_CONFIG=
2497     fi
2498     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2499     ;;
2500   esac
2501 fi
2502 AC_MSG_RESULT($BUILD_CONFIG)
2503 AC_SUBST(BUILD_CONFIG)
2504
2505 extrasub_build=
2506 for module in ${build_configdirs} ; do
2507   if test -z "${no_recursion}" \
2508      && test -f ${build_subdir}/${module}/Makefile; then
2509     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2510     rm -f ${build_subdir}/${module}/Makefile
2511   fi
2512   extrasub_build="$extrasub_build
2513 /^@if build-$module\$/d
2514 /^@endif build-$module\$/d
2515 /^@if build-$module-$bootstrap_suffix\$/d
2516 /^@endif build-$module-$bootstrap_suffix\$/d"
2517 done
2518 extrasub_host=
2519 for module in ${configdirs} ; do
2520   if test -z "${no_recursion}"; then
2521     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2522       if test -f ${file}; then
2523         echo 1>&2 "*** removing ${file} to force reconfigure"
2524         rm -f ${file}
2525       fi
2526     done
2527   fi
2528   extrasub_host="$extrasub_host
2529 /^@if $module\$/d
2530 /^@endif $module\$/d
2531 /^@if $module-$bootstrap_suffix\$/d
2532 /^@endif $module-$bootstrap_suffix\$/d"
2533 done
2534 extrasub_target=
2535 for module in ${target_configdirs} ; do
2536   if test -z "${no_recursion}" \
2537      && test -f ${target_subdir}/${module}/Makefile; then
2538     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2539     rm -f ${target_subdir}/${module}/Makefile
2540   fi
2541
2542   # We only bootstrap target libraries listed in bootstrap_target_libs.
2543   case $bootstrap_target_libs in
2544     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2545     *) target_bootstrap_suffix=no-bootstrap ;;
2546   esac
2547
2548   extrasub_target="$extrasub_target
2549 /^@if target-$module\$/d
2550 /^@endif target-$module\$/d
2551 /^@if target-$module-$target_bootstrap_suffix\$/d
2552 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2553 done
2554
2555 # Do the final fixup along with target modules.
2556 extrasub_target="$extrasub_target
2557 /^@if /,/^@endif /d"
2558
2559 # Create the serialization dependencies.  This uses a temporary file.
2560
2561 AC_ARG_ENABLE([serial-configure],
2562 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2563                 [force sequential configuration of
2564                  sub-packages for the host, target or build
2565                  machine, or all sub-packages])])
2566
2567 case ${enable_serial_configure} in
2568   yes)
2569     enable_serial_build_configure=yes
2570     enable_serial_host_configure=yes
2571     enable_serial_target_configure=yes
2572     ;;
2573 esac
2574
2575 # These force 'configure's to be done one at a time, to avoid problems
2576 # with contention over a shared config.cache.
2577 rm -f serdep.tmp
2578 echo '# serdep.tmp' > serdep.tmp
2579 olditem=
2580 test "x${enable_serial_build_configure}" = xyes &&
2581 for item in ${build_configdirs} ; do
2582   case ${olditem} in
2583     "") ;;
2584     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2585   esac
2586   olditem=${item}
2587 done
2588 olditem=
2589 test "x${enable_serial_host_configure}" = xyes &&
2590 for item in ${configdirs} ; do
2591   case ${olditem} in
2592     "") ;;
2593     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2594   esac
2595   olditem=${item}
2596 done
2597 olditem=
2598 test "x${enable_serial_target_configure}" = xyes &&
2599 for item in ${target_configdirs} ; do
2600   case ${olditem} in
2601     "") ;;
2602     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2603   esac
2604   olditem=${item}
2605 done
2606 serialization_dependencies=serdep.tmp
2607 AC_SUBST_FILE(serialization_dependencies)
2608
2609 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2610 # target, nonopt, and variable assignments.  These are the ones we
2611 # might not want to pass down to subconfigures.  The exception being
2612 # --cache-file=/dev/null, which is used to turn off the use of cache
2613 # files altogether, and which should be passed on to subconfigures.
2614 # Also strip program-prefix, program-suffix, and program-transform-name,
2615 # so that we can pass down a consistent program-transform-name.
2616 baseargs=
2617 tbaseargs=
2618 keep_next=no
2619 skip_next=no
2620 eval "set -- $ac_configure_args"
2621 for ac_arg
2622 do
2623   if test X"$skip_next" = X"yes"; then
2624     skip_next=no
2625     continue
2626   fi
2627   if test X"$keep_next" = X"yes"; then
2628     case $ac_arg in
2629       *\'*)
2630         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2631     esac
2632     baseargs="$baseargs '$ac_arg'"
2633     tbaseargs="$tbaseargs '$ac_arg'"
2634     keep_next=no
2635     continue
2636   fi
2637
2638   # Handle separated arguments.  Based on the logic generated by
2639   # autoconf 2.59.
2640   case $ac_arg in
2641     *=* | --config-cache | -C | -disable-* | --disable-* \
2642       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2643       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2644       | -with-* | --with-* | -without-* | --without-* | --x)
2645       separate_arg=no
2646       ;;
2647     -*)
2648       separate_arg=yes
2649       ;;
2650     *)
2651       separate_arg=no
2652       ;;
2653   esac
2654
2655   skip_targ=no
2656   case $ac_arg in
2657 changequote(,)
2658   --with-* | --without-*)
2659     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2660
2661     case $libopt in
2662     *[-_]include)
2663       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2664       ;;
2665     *[-_]lib)
2666       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2667       ;;
2668     *)
2669       lib=$libopt
2670       ;;
2671     esac
2672 changequote([,])
2673
2674     case $lib in
2675     mpc | mpfr | gmp | cloog)
2676       # If we're processing --with-$lib, --with-$lib-include or
2677       # --with-$lib-lib, for one of the libs above, and target is
2678       # different from host, don't pass the current argument to any
2679       # target library's configure.
2680       if test x$is_cross_compiler = xyes; then
2681         skip_targ=yes
2682       fi
2683       ;;
2684     esac
2685     ;;
2686   esac
2687
2688   case "$ac_arg" in
2689     --cache-file=/dev/null | \
2690     -cache-file=/dev/null )
2691       # Handled here to avoid the test to skip args below.
2692       baseargs="$baseargs '$ac_arg'"
2693       tbaseargs="$tbaseargs '$ac_arg'"
2694       # Assert: $separate_arg should always be no.
2695       keep_next=$separate_arg
2696       ;;
2697     --no*)
2698       continue
2699       ;;
2700     --c* | \
2701     --sr* | \
2702     --ho* | \
2703     --bu* | \
2704     --t* | \
2705     --program-* | \
2706     -cache_file* | \
2707     -srcdir* | \
2708     -host* | \
2709     -build* | \
2710     -target* | \
2711     -program-prefix* | \
2712     -program-suffix* | \
2713     -program-transform-name* )
2714       skip_next=$separate_arg
2715       continue
2716       ;;
2717     -*)
2718       # An option.  Add it.
2719       case $ac_arg in
2720         *\'*)
2721           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2722       esac
2723       baseargs="$baseargs '$ac_arg'"
2724       if test X"$skip_targ" = Xno; then
2725         tbaseargs="$tbaseargs '$ac_arg'"
2726       fi
2727       keep_next=$separate_arg
2728       ;;
2729     *)
2730       # Either a variable assignment, or a nonopt (triplet).  Don't
2731       # pass it down; let the Makefile handle this.
2732       continue
2733       ;;
2734   esac
2735 done
2736 # Remove the initial space we just introduced and, as these will be
2737 # expanded by make, quote '$'.
2738 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2739
2740 # Add in --program-transform-name, after --program-prefix and
2741 # --program-suffix have been applied to it.  Autoconf has already
2742 # doubled dollar signs and backslashes in program_transform_name; we want
2743 # the backslashes un-doubled, and then the entire thing wrapped in single
2744 # quotes, because this will be expanded first by make and then by the shell.
2745 # Also, because we want to override the logic in subdir configure scripts to
2746 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2747 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2748 ${program_transform_name}
2749 EOF_SED
2750 gcc_transform_name=`cat conftestsed.out`
2751 rm -f conftestsed.out
2752 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2753 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2754 if test "$silent" = yes; then
2755   baseargs="$baseargs --silent"
2756   tbaseargs="$tbaseargs --silent"
2757 fi
2758 baseargs="$baseargs --disable-option-checking"
2759 tbaseargs="$tbaseargs --disable-option-checking"
2760
2761 # Record and document user additions to sub configure arguments.
2762 AC_ARG_VAR([build_configargs],
2763            [additional configure arguments for build directories])
2764 AC_ARG_VAR([host_configargs],
2765            [additional configure arguments for host directories])
2766 AC_ARG_VAR([target_configargs],
2767            [additional configure arguments for target directories])
2768
2769 # For the build-side libraries, we just need to pretend we're native,
2770 # and not use the same cache file.  Multilibs are neither needed nor
2771 # desired.
2772 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2773
2774 # For host modules, accept cache file option, or specification as blank.
2775 case "${cache_file}" in
2776 "") # empty
2777   cache_file_option="" ;;
2778 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2779   cache_file_option="--cache-file=${cache_file}" ;;
2780 *) # relative path
2781   cache_file_option="--cache-file=../${cache_file}" ;;
2782 esac
2783
2784 # Host dirs don't like to share a cache file either, horribly enough.
2785 # This seems to be due to autoconf 2.5x stupidity.
2786 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2787
2788 target_configargs="$target_configargs ${tbaseargs}"
2789
2790 # Passing a --with-cross-host argument lets the target libraries know
2791 # whether they are being built with a cross-compiler or being built
2792 # native.  However, it would be better to use other mechanisms to make the
2793 # sorts of decisions they want to make on this basis.  Please consider
2794 # this option to be deprecated.  FIXME.
2795 if test x${is_cross_compiler} = xyes ; then
2796   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2797 fi
2798
2799 # Default to --enable-multilib.
2800 if test x${enable_multilib} = x ; then
2801   target_configargs="--enable-multilib ${target_configargs}"
2802 fi
2803
2804 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2805 # changed from the earlier setting of with_newlib.
2806 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2807   target_configargs="--with-newlib ${target_configargs}"
2808 fi
2809
2810 # Different target subdirs use different values of certain variables
2811 # (notably CXX).  Worse, multilibs use *lots* of different values.
2812 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2813 # it doesn't automatically accept command-line overrides of them.
2814 # This means it's not safe for target subdirs to share a cache file,
2815 # which is disgusting, but there you have it.  Hopefully this can be
2816 # fixed in future.  It's still worthwhile to use a cache file for each
2817 # directory.  I think.
2818
2819 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2820 # We need to pass --target, as newer autoconf's requires consistency
2821 # for target_alias and gcc doesn't manage it consistently.
2822 target_configargs="--cache-file=./config.cache ${target_configargs}"
2823
2824 FLAGS_FOR_TARGET=
2825 case " $target_configdirs " in
2826  *" newlib "*)
2827   case " $target_configargs " in
2828   *" --with-newlib "*)
2829    case "$target" in
2830     *-cygwin*)
2831       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2832       ;;
2833    esac
2834
2835    # If we're not building GCC, don't discard standard headers.
2836    if test -d ${srcdir}/gcc; then
2837      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2838
2839      if test "${build}" != "${host}"; then
2840        # On Canadian crosses, CC_FOR_TARGET will have already been set
2841        # by `configure', so we won't have an opportunity to add -Bgcc/
2842        # to it.  This is right: we don't want to search that directory
2843        # for binaries, but we want the header files in there, so add
2844        # them explicitly.
2845        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2846
2847        # Someone might think of using the pre-installed headers on
2848        # Canadian crosses, in case the installed compiler is not fully
2849        # compatible with the compiler being built.  In this case, it
2850        # would be better to flag an error than risking having
2851        # incompatible object files being constructed.  We can't
2852        # guarantee that an error will be flagged, but let's hope the
2853        # compiler will do it, when presented with incompatible header
2854        # files.
2855      fi
2856    fi
2857
2858    case "${target}-${is_cross_compiler}" in
2859    i[[3456789]]86-*-linux*-no)
2860       # Here host == target, so we don't need to build gcc,
2861       # so we don't want to discard standard headers.
2862       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2863       ;;
2864    *)
2865       # If we're building newlib, use its generic headers last, but search
2866       # for any libc-related directories first (so make it the last -B
2867       # switch).
2868       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2869
2870       # If we're building libgloss, find the startup file, simulator library
2871       # and linker script.
2872       case " $target_configdirs " in
2873         *" libgloss "*)
2874         # Look for startup file, simulator library and maybe linker script.
2875         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2876         # Look for libnosys.a in case the target needs it.
2877         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2878         # Most targets have the linker script in the source directory.
2879         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2880         ;;
2881       esac
2882       ;;
2883    esac
2884    ;;
2885   esac
2886   ;;
2887 esac
2888
2889 case "$target" in
2890   x86_64-*mingw* | *-w64-mingw*)
2891   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2892   # however, use a symlink named 'mingw' in ${prefix} .
2893     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2894     ;;
2895   *-mingw*)
2896   # MinGW can't be handled as Cygwin above since it does not use newlib.
2897     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2898     ;;
2899 esac
2900
2901 # Allow the user to override the flags for
2902 # our build compiler if desired.
2903 if test x"${build}" = x"${host}" ; then
2904   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2905   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2906   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2907 fi
2908
2909 # On Canadian crosses, we'll be searching the right directories for
2910 # the previously-installed cross compiler, so don't bother to add
2911 # flags for directories within the install tree of the compiler
2912 # being built; programs in there won't even run.
2913 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2914   # Search for pre-installed headers if nothing else fits.
2915   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2916 fi
2917
2918 if test "x${use_gnu_ld}" = x &&
2919    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2920   # Arrange for us to find uninstalled linker scripts.
2921   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2922 fi
2923
2924 # Search for other target-specific linker scripts and such.
2925 case "${target}" in
2926   mep*)
2927     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2928     ;;
2929 esac
2930
2931 # Makefile fragments.
2932 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2933 do
2934   eval fragval=\$$frag
2935   if test $fragval != /dev/null; then
2936     eval $frag=${srcdir}/$fragval
2937   fi
2938 done
2939 AC_SUBST_FILE(host_makefile_frag)
2940 AC_SUBST_FILE(target_makefile_frag)
2941 AC_SUBST_FILE(alphaieee_frag)
2942 AC_SUBST_FILE(ospace_frag)
2943
2944 # Miscellanea: directories, flags, etc.
2945 AC_SUBST(RPATH_ENVVAR)
2946 AC_SUBST(GCC_SHLIB_SUBDIR)
2947 AC_SUBST(tooldir)
2948 AC_SUBST(build_tooldir)
2949 AC_SUBST(CONFIGURE_GDB_TK)
2950 AC_SUBST(GDB_TK)
2951 AC_SUBST(INSTALL_GDB_TK)
2952
2953 # Build module lists & subconfigure args.
2954 AC_SUBST(build_configargs)
2955 AC_SUBST(build_configdirs)
2956
2957 # Host module lists & subconfigure args.
2958 AC_SUBST(host_configargs)
2959 AC_SUBST(configdirs)
2960 AC_SUBST(target_configdirs)
2961
2962 # Target module lists & subconfigure args.
2963 AC_SUBST(target_configargs)
2964
2965
2966 # Build tools.
2967 AC_SUBST(AR_FOR_BUILD)
2968 AC_SUBST(AS_FOR_BUILD)
2969 AC_SUBST(CC_FOR_BUILD)
2970 AC_SUBST(CFLAGS_FOR_BUILD)
2971 AC_SUBST(CXXFLAGS_FOR_BUILD)
2972 AC_SUBST(CXX_FOR_BUILD)
2973 AC_SUBST(DLLTOOL_FOR_BUILD)
2974 AC_SUBST(GCJ_FOR_BUILD)
2975 AC_SUBST(GFORTRAN_FOR_BUILD)
2976 AC_SUBST(GOC_FOR_BUILD)
2977 AC_SUBST(LDFLAGS_FOR_BUILD)
2978 AC_SUBST(LD_FOR_BUILD)
2979 AC_SUBST(NM_FOR_BUILD)
2980 AC_SUBST(RANLIB_FOR_BUILD)
2981 AC_SUBST(WINDMC_FOR_BUILD)
2982 AC_SUBST(WINDRES_FOR_BUILD)
2983
2984 # Generate default definitions for YACC, M4, LEX and other programs that run
2985 # on the build machine.  These are used if the Makefile can't locate these
2986 # programs in objdir.
2987 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2988
2989 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2990 case " $build_configdirs " in
2991   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2992 esac
2993
2994 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2995 case " $build_configdirs " in
2996   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2997 esac
2998
2999 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3000 case " $build_configdirs " in
3001   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3002 esac
3003
3004 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3005 case " $build_configdirs " in
3006   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3007   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3008 esac
3009
3010 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3011 case " $build_configdirs " in
3012   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3013 esac
3014
3015 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3016 case " $build_configdirs " in
3017   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3018   *)
3019 changequote(,)
3020     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3021     # higher, else we use the "missing" dummy.
3022     if ${MAKEINFO} --version \
3023        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3024       :
3025     else
3026       MAKEINFO="$MISSING makeinfo"
3027     fi
3028     ;;
3029 changequote([,])
3030 esac
3031
3032 # FIXME: expect and dejagnu may become build tools?
3033
3034 AC_CHECK_PROGS(EXPECT, expect, expect)
3035 case " $configdirs " in
3036   *" expect "*)
3037     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3038     ;;
3039 esac
3040
3041 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3042 case " $configdirs " in
3043   *" dejagnu "*)
3044     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3045     ;;
3046 esac
3047
3048
3049 # Host tools.
3050 NCN_STRICT_CHECK_TOOLS(AR, ar)
3051 NCN_STRICT_CHECK_TOOLS(AS, as)
3052 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3053 NCN_STRICT_CHECK_TOOLS(LD, ld)
3054 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3055 NCN_STRICT_CHECK_TOOLS(NM, nm)
3056 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3057 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3058 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3059 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3060 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3061 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3062 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3063 AC_SUBST(CC)
3064 AC_SUBST(CXX)
3065 AC_SUBST(CFLAGS)
3066 AC_SUBST(CXXFLAGS)
3067
3068 # Target tools.
3069 AC_ARG_WITH([build-time-tools],
3070   [AS_HELP_STRING([--with-build-time-tools=PATH],
3071                   [use given path to find target tools during the build])],
3072   [case x"$withval" in
3073      x/*) ;;
3074      *)
3075        with_build_time_tools=
3076        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3077        ;;
3078    esac],
3079   [with_build_time_tools=])
3080
3081 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3082 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3083 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3084 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3085 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3086 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3087
3088 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3089 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3095 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3096 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3097 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3098 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3099 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3100
3101 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3102
3103 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3104 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3105 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3106 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3107 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3108                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3109                 c++)
3110 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3111                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3112                 c++)
3113 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3114 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3115 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3116                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3117 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3118                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3119 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3120                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3121 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3122 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3123 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3124 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3125 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3126 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3127 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3128 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3129 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3130
3131 AC_SUBST(FLAGS_FOR_TARGET)
3132 AC_SUBST(RAW_CXX_FOR_TARGET)
3133
3134 # Certain tools may need extra flags.
3135 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3136 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3137 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3138
3139 # When building target libraries, except in a Canadian cross, we use
3140 # the same toolchain as the compiler we just built.
3141 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3142 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3143 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3144 if test $host = $build; then
3145   case " $configdirs " in
3146     *" gcc "*)
3147       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3148       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3149       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3150       ;;
3151   esac
3152 fi
3153
3154 AC_SUBST(COMPILER_AS_FOR_TARGET)
3155 AC_SUBST(COMPILER_LD_FOR_TARGET)
3156 AC_SUBST(COMPILER_NM_FOR_TARGET)
3157
3158 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3159 AC_ARG_ENABLE(maintainer-mode,
3160 [AS_HELP_STRING([--enable-maintainer-mode],
3161                 [enable make rules and dependencies not useful
3162                  (and sometimes confusing) to the casual installer])],
3163       USE_MAINTAINER_MODE=$enableval,
3164       USE_MAINTAINER_MODE=no)
3165 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3166 AC_SUBST(MAINTAINER_MODE_TRUE)
3167 AC_SUBST(MAINTAINER_MODE_FALSE)
3168 if test "$USE_MAINTAINER_MODE" = yes; then
3169   MAINTAINER_MODE_TRUE=
3170   MAINTAINER_MODE_FALSE='#'
3171 else
3172   MAINTAINER_MODE_TRUE='#'
3173   MAINTAINER_MODE_FALSE=
3174 fi
3175 MAINT=$MAINTAINER_MODE_TRUE
3176 AC_SUBST(MAINT)dnl
3177
3178 # ---------------------
3179 # GCC bootstrap support
3180 # ---------------------
3181
3182 # Stage specific cflags for build.
3183 stage1_cflags="-g"
3184 case $build in
3185   vax-*-*)
3186     case ${GCC} in
3187       yes) stage1_cflags="-g -Wa,-J" ;;
3188       *) stage1_cflags="-g -J" ;;
3189     esac ;;
3190 esac
3191
3192 AC_SUBST(stage1_cflags)
3193
3194 # Enable --enable-checking in stage1 of the compiler.
3195 AC_ARG_ENABLE(stage1-checking,
3196 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3197                 [choose additional checking for stage1 of the compiler])],
3198 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3199 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3200   stage1_checking=--enable-checking=yes,types
3201 else
3202   stage1_checking=--enable-checking=$enable_checking,types
3203 fi])
3204 AC_SUBST(stage1_checking)
3205
3206 # Enable -Werror in bootstrap stage2 and later.
3207 AC_ARG_ENABLE(werror,
3208 [AS_HELP_STRING([--enable-werror],
3209                 [enable -Werror in bootstrap stage2 and later])], [],
3210 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3211   enable_werror=yes
3212 else
3213   enable_werror=no
3214 fi])
3215 case ${enable_werror} in
3216   yes) stage2_werror_flag="--enable-werror-always" ;;
3217   *) stage2_werror_flag="" ;;
3218 esac
3219 AC_SUBST(stage2_werror_flag)
3220
3221 # Specify what files to not compare during bootstrap.
3222
3223 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3224 case "$target" in
3225   hppa*64*-*-hpux*) ;;
3226   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3227   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3228 esac
3229 AC_SUBST(compare_exclusions)
3230
3231 AC_CONFIG_FILES([Makefile],
3232   [sed "$extrasub_build" Makefile |
3233    sed "$extrasub_host" |
3234    sed "$extrasub_target" > mf$$
3235    mv -f mf$$ Makefile],
3236   [extrasub_build="$extrasub_build"
3237    extrasub_host="$extrasub_host"
3238    extrasub_target="$extrasub_target"])
3239 AC_OUTPUT