gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     libstdcxx_incdir='c++/$(version)'
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # With demangler in GNU ld
 215 AC_ARG_WITH(demangler-in-ld,
 216 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 217 demangler_in_ld="$with_demangler_in_ld",
 218 demangler_in_ld=no)
 219
 220 # ----------------------
 221 # Find default assembler
 222 # ----------------------
 223
 224 # With GNU as
 225 AC_ARG_WITH(gnu-as,
 226 [  --with-gnu-as           arrange to work with GNU as],
 227 gas_flag="$with_gnu_as",
 228 gas_flag=no)
 229
 230 AC_ARG_WITH(as,
 231 [  --with-as               arrange to use the specified as (full pathname)],
 232 DEFAULT_ASSEMBLER="$with_as")
 233 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 234   if test ! -x "$DEFAULT_ASSEMBLER"; then
 235     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 236   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 237     gas_flag=yes
 238   fi
 239   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 240         [Define to enable the use of a default assembler.])
 241 fi
 242
 243 AC_MSG_CHECKING([whether a default assembler was specified])
 244 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 245   if test x"$gas_flag" = x"no"; then
 246     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 247   else
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 249   fi
 250 else
 251   AC_MSG_RESULT(no)
 252 fi
 253
 254 # ---------------
 255 # Find C compiler
 256 # ---------------
 257
 258 # If a non-executable a.out is present (e.g. created by GNU as above even if
 259 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 260 # file, even when creating an executable, so an execution test fails.
 261 # Remove possible default executable files to avoid this.
 262 #
 263 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 264 # Autoconf includes it.
 265 rm -f a.out a.exe b.out
 266
 267 # Find the native compiler
 268 AC_PROG_CC
 269 AM_PROG_CC_C_O
 270 # autoconf is lame and doesn't give us any substitution variable for this.
 271 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 272   NO_MINUS_C_MINUS_O=yes
 273 else
 274   OUTPUT_OPTION='-o $@'
 275 fi
 276 AC_SUBST(NO_MINUS_C_MINUS_O)
 277 AC_SUBST(OUTPUT_OPTION)
 278
 279 # -------------------------
 280 # Check C compiler features
 281 # -------------------------
 282
 283 AC_PROG_CPP
 284 AC_C_INLINE
 285
 286 gcc_AC_C_LONG_LONG
 287
 288 # sizeof(char) is 1 by definition.
 289 AC_CHECK_SIZEOF(void *)
 290 AC_CHECK_SIZEOF(short)
 291 AC_CHECK_SIZEOF(int)
 292 AC_CHECK_SIZEOF(long)
 293 if test $ac_cv_c_long_long = yes; then
 294   AC_CHECK_SIZEOF(long long)
 295 fi
 296 if test $ac_cv_c___int64 = yes; then
 297   AC_CHECK_SIZEOF(__int64)
 298 fi
 299
 300 # ---------------------
 301 # Warnings and checking
 302 # ---------------------
 303
 304 # Check $CC warning features (if it's GCC).
 305 # We want to use -pedantic, but we don't want warnings about
 306 # * 'long long'
 307 # * variadic macros
 308 # So, we only use -pedantic if we can disable those warnings.
 309
 310 AC_CACHE_CHECK(
 311   [whether ${CC} accepts -Wno-long-long],
 312   [ac_cv_prog_cc_w_no_long_long],
 313   [save_CFLAGS="$CFLAGS"
 314   CFLAGS="-Wno-long-long"
 315   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 316                     [ac_cv_prog_cc_w_no_long_long=yes],
 317                     [ac_cv_prog_cc_w_no_long_long=no])
 318   CFLAGS="$save_CFLAGS"
 319   ])
 320
 321 AC_CACHE_CHECK(
 322   [whether ${CC} accepts -Wno-variadic-macros],
 323   [ac_cv_prog_cc_w_no_variadic_macros],
 324   [save_CFLAGS="$CFLAGS"
 325   CFLAGS="-Wno-variadic-macros"
 326   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 327                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 328                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 329   CFLAGS="$save_CFLAGS"
 330   ])
 331
 332 strict1_warn=
 333 if test $ac_cv_prog_cc_w_no_long_long = yes \
 334    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 335   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 336 fi
 337 AC_SUBST(strict1_warn)
 338
 339 # Add -Wold-style-definition if it's accepted
 340 AC_CACHE_CHECK(
 341   [whether ${CC} accepts -Wold-style-definition],
 342   [ac_cv_prog_cc_w_old_style_definition],
 343   [save_CFLAGS="$CFLAGS"
 344   CFLAGS="-Wold-style-definition"
 345   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 346                     [ac_cv_prog_cc_w_old_style_definition=yes],
 347                     [ac_cv_prog_cc_w_old_style_definition=no])
 348   CFLAGS="$save_CFLAGS"
 349   ])
 350 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 351   strict1_warn="${strict1_warn} -Wold-style-definition"
 352 fi
 353
 354 # Enable -Werror, period.
 355 AC_ARG_ENABLE(werror_always,
 356 [  --enable-werror-always         enable -Werror always], [],
 357 [enable_werror_always=no])
 358 if test x${enable_werror_always} = xyes ; then
 359   strict1_warn="${strict1_warn} -Werror"
 360   WERROR=-Werror
 361 fi
 362
 363 # If the native compiler is GCC, we can enable warnings even in stage1.
 364 # That's useful for people building cross-compilers, or just running a
 365 # quick `make'.
 366 warn_cflags=
 367 if test "x$GCC" = "xyes"; then
 368   warn_cflags='$(GCC_WARN_CFLAGS)'
 369 fi
 370 AC_SUBST(warn_cflags)
 371
 372 # Enable -Werror in bootstrap stage2 and later.
 373 is_release=
 374 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 375   is_release=yes
 376 fi
 377 AC_ARG_ENABLE(werror,
 378 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 379 [if test x$is_release = x ; then
 380   # Default to "yes" on development branches.
 381   enable_werror=yes
 382 else
 383   # Default to "no" on release branches.
 384   enable_werror=no
 385 fi])
 386 if test x$enable_werror = xyes ; then
 387   WERROR=-Werror
 388 fi
 389 AC_SUBST(WERROR)
 390
 391 # Enable expensive internal checks
 392 AC_ARG_ENABLE(checking,
 393 [  --enable-checking[=LIST]
 394                           enable expensive run-time checks.  With LIST,
 395                           enable only specific categories of checks.
 396                           Categories are: yes,no,all,none,release.
 397                           Flags are: assert,fold,gc,gcac,misc,
 398                           rtlflag,rtl,runtime,tree,valgrind.],
 399 [ac_checking_flags="${enableval}"],[
 400 # Determine the default checks.
 401 if test x$is_release = x ; then
 402   ac_checking_flags=yes
 403 else
 404   ac_checking_flags=release
 405 fi])
 406 ac_assert_checking=1
 407 ac_checking=
 408 ac_fold_checking=
 409 ac_gc_checking=
 410 ac_gc_always_collect=
 411 ac_rtl_checking=
 412 ac_rtlflag_checking=
 413 ac_runtime_checking=1
 414 ac_tree_checking=
 415 ac_valgrind_checking=
 416 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 417 for check in $ac_checking_flags
 418 do
 419         case $check in
 420         # these set all the flags to specific states
 421         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 422                         ac_fold_checking= ; ac_gc_checking=1 ;
 423                         ac_gc_always_collect= ; ac_rtl_checking= ;
 424                         ac_rtlflag_checking=1 ; ac_runtime_chacking=1 ;
 425                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 426         no|none)        ac_assert_checking= ; ac_checking= ;
 427                         ac_fold_checking= ; ac_gc_checking= ;
 428                         ac_gc_always_collect= ; ac_rtl_checking= ;
 429                         ac_rtlflag_checking= ; ac_runtime_chacking= ;
 430                         ac_tree_checking= ; ac_valgrind_checking= ;;
 431         all)            ac_assert_checking=1 ; ac_checking=1 ;
 432                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 433                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 434                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 435                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 436         release)        ac_assert_checking=1 ; ac_checking= ;
 437                         ac_fold_checking= ; ac_gc_checking= ;
 438                         ac_gc_always_collect= ; ac_rtl_checking= ;
 439                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 440                         ac_tree_checking= ; ac_valgrind_checking= ;;
 441         # these enable particular checks
 442         assert)         ac_assert_checking=1 ;;
 443         fold)           ac_fold_checking=1 ;;
 444         gc)             ac_gc_checking=1 ;;
 445         gcac)           ac_gc_always_collect=1 ;;
 446         misc)           ac_checking=1 ;;
 447         rtl)            ac_rtl_checking=1 ;;
 448         rtlflag)        ac_rtlflag_checking=1 ;;
 449         runtime)        ac_runtime_checking=1 ;;
 450         tree)           ac_tree_checking=1 ;;
 451         valgrind)       ac_valgrind_checking=1 ;;
 452         *)      AC_MSG_ERROR(unknown check category $check) ;;
 453         esac
 454 done
 455 IFS="$ac_save_IFS"
 456
 457 nocommon_flag=""
 458 if test x$ac_checking != x ; then
 459   AC_DEFINE(ENABLE_CHECKING, 1,
 460 [Define if you want more run-time sanity checks.  This one gets a grab
 461    bag of miscellaneous but relatively cheap checks.])
 462   nocommon_flag=-fno-common
 463 fi
 464 AC_SUBST(nocommon_flag)
 465 if test x$ac_assert_checking != x ; then
 466   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 467 [Define if you want assertions enabled.  This is a cheap check.])
 468 fi
 469 if test x$ac_runtime_checking != x ; then
 470   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 471 [Define if you want runtime assertions enabled.  This is a cheap check.])
 472 fi
 473 if test x$ac_tree_checking != x ; then
 474   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 475 [Define if you want all operations on trees (the basic data
 476    structure of the front ends) to be checked for dynamic type safety
 477    at runtime.  This is moderately expensive.  The tree browser debugging
 478    routines will also be enabled by this option.
 479    ])
 480   TREEBROWSER=tree-browser.o
 481 fi
 482 AC_SUBST(TREEBROWSER)
 483 if test x$ac_rtl_checking != x ; then
 484   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 485 [Define if you want all operations on RTL (the basic data structure
 486    of the optimizer and back end) to be checked for dynamic type safety
 487    at runtime.  This is quite expensive.])
 488 fi
 489 if test x$ac_rtlflag_checking != x ; then
 490   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 491 [Define if you want RTL flag accesses to be checked against the RTL
 492    codes that are supported for each access macro.  This is relatively
 493    cheap.])
 494 fi
 495 if test x$ac_gc_checking != x ; then
 496   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 497 [Define if you want the garbage collector to do object poisoning and
 498    other memory allocation checks.  This is quite expensive.])
 499 fi
 500 if test x$ac_gc_always_collect != x ; then
 501   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 502 [Define if you want the garbage collector to operate in maximally
 503    paranoid mode, validating the entire heap and collecting garbage at
 504    every opportunity.  This is extremely expensive.])
 505 fi
 506 if test x$ac_fold_checking != x ; then
 507   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 508 [Define if you want fold checked that it never destructs its argument.
 509    This is quite expensive.])
 510 fi
 511 valgrind_path_defines=
 512 valgrind_command=
 513
 514 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 515 dnl # an if statement.  This was the source of very frustrating bugs
 516 dnl # in converting to autoconf 2.5x!
 517 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 518
 519 if test x$ac_valgrind_checking != x ; then
 520   # It is certainly possible that there's valgrind but no valgrind.h.
 521   # GCC relies on making annotations so we must have both.
 522   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 523   AC_TRY_CPP(
 524     [#include <valgrind/memcheck.h>
 525 #ifndef VALGRIND_DISCARD
 526 #error VALGRIND_DISCARD not defined
 527 #endif],
 528   [gcc_cv_header_valgrind_memcheck_h=yes],
 529   [gcc_cv_header_valgrind_memcheck_h=no])
 530   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 531   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 532   AC_TRY_CPP(
 533     [#include <memcheck.h>
 534 #ifndef VALGRIND_DISCARD
 535 #error VALGRIND_DISCARD not defined
 536 #endif],
 537   [gcc_cv_header_memcheck_h=yes],
 538   gcc_cv_header_memcheck_h=no)
 539   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 540   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 541         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 542   if test "x$valgrind_path" = "x" \
 543     || (test $have_valgrind_h = no \
 544         && test $gcc_cv_header_memcheck_h = no \
 545         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 546         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 547   fi
 548   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 549   valgrind_command="$valgrind_path -q"
 550   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 551 [Define if you want to run subprograms and generated programs
 552    through valgrind (a memory checker).  This is extremely expensive.])
 553   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 554     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 555         [Define if valgrind's valgrind/memcheck.h header is installed.])
 556   fi
 557   if test $gcc_cv_header_memcheck_h = yes; then
 558     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 559         [Define if valgrind's memcheck.h header is installed.])
 560   fi
 561 fi
 562 AC_SUBST(valgrind_path_defines)
 563 AC_SUBST(valgrind_command)
 564
 565 AC_ARG_ENABLE(mapped-location,
 566 [  --enable-mapped-location   location_t is fileline integer cookie],,
 567 enable_mapped_location=no)
 568
 569 if test "$enable_mapped_location" = yes ; then
 570   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 571 [Define if location_t is fileline integer cookie.])
 572 fi
 573
 574 # Enable code coverage collection
 575 AC_ARG_ENABLE(coverage,
 576 [  --enable-coverage[=LEVEL]
 577                           enable compiler's code coverage collection.
 578                           Use to measure compiler performance and locate
 579                           unused parts of the compiler. With LEVEL, specify
 580                           optimization. Values are opt, noopt,
 581                           default is noopt],
 582 [case "${enableval}" in
 583   yes|noopt)
 584     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 585     ;;
 586   opt)
 587     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 588     ;;
 589   no)
 590     # a.k.a. --disable-coverage
 591     coverage_flags=""
 592     ;;
 593   *)
 594     AC_MSG_ERROR(unknown coverage setting $enableval)
 595     ;;
 596 esac],
 597 [coverage_flags=""])
 598 AC_SUBST(coverage_flags)
 599
 600 AC_ARG_ENABLE(gather-detailed-mem-stats,
 601 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 602 [enable_gather_detailed_mem_stats=no])
 603 if test x$enable_gather_detailed_mem_stats = xyes ; then
 604   AC_DEFINE(GATHER_STATISTICS, 1,
 605         [Define to enable detailed memory allocation stats gathering.])
 606 fi
 607
 608 # -------------------------------
 609 # Miscenalleous configure options
 610 # -------------------------------
 611
 612 # With stabs
 613 AC_ARG_WITH(stabs,
 614 [  --with-stabs            arrange to use stabs instead of host debug format],
 615 stabs="$with_stabs",
 616 stabs=no)
 617
 618 # Determine whether or not multilibs are enabled.
 619 AC_ARG_ENABLE(multilib,
 620 [  --enable-multilib       enable library support for multiple ABIs],
 621 [], [enable_multilib=yes])
 622 AC_SUBST(enable_multilib)
 623
 624 # Enable __cxa_atexit for C++.
 625 AC_ARG_ENABLE(__cxa_atexit,
 626 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 627 [], [])
 628
 629 # Enable threads
 630 # Pass with no value to take the default
 631 # Pass with a value to specify a thread package
 632 AC_ARG_ENABLE(threads,
 633 [  --enable-threads        enable thread usage for target GCC
 634   --enable-threads=LIB    use LIB thread package for target GCC],,
 635 [enable_threads=''])
 636
 637 AC_ARG_ENABLE(objc-gc,
 638 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 639                           the GNU Objective-C runtime],
 640 if test x$enable_objc_gc = xno; then
 641         objc_boehm_gc=''
 642 else
 643         objc_boehm_gc=1
 644 fi,
 645 objc_boehm_gc='')
 646
 647 AC_ARG_WITH(dwarf2,
 648 [  --with-dwarf2           force the default debug format to be DWARF 2],
 649 dwarf2="$with_dwarf2",
 650 dwarf2=no)
 651
 652 AC_ARG_ENABLE(shared,
 653 [  --disable-shared        don't provide a shared libgcc],
 654 [
 655   case $enable_shared in
 656   yes | no) ;;
 657   *)
 658     enable_shared=no
 659     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 660     for pkg in $enableval; do
 661       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 662         enable_shared=yes
 663       fi
 664     done
 665     IFS="$ac_save_ifs"
 666     ;;
 667   esac
 668 ], [enable_shared=yes])
 669 AC_SUBST(enable_shared)
 670
 671 AC_ARG_WITH(sysroot,
 672 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 673 [
 674  case ${with_sysroot} in
 675  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 676  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 677  esac
 678
 679  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 680  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 681
 682  if test "x$exec_prefix" = xNONE; then
 683   if test "x$prefix" = xNONE; then
 684    test_prefix=/usr/local
 685   else
 686    test_prefix=$prefix
 687   fi
 688  else
 689   test_prefix=$exec_prefix
 690  fi
 691  case ${TARGET_SYSTEM_ROOT} in
 692  "${test_prefix}"|"${test_prefix}/"*|\
 693  '${exec_prefix}'|'${exec_prefix}/'*)
 694    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 695    TARGET_SYSTEM_ROOT_DEFINE="$t"
 696    ;;
 697  esac
 698 ], [
 699  TARGET_SYSTEM_ROOT=
 700  TARGET_SYSTEM_ROOT_DEFINE=
 701  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 702 ])
 703 AC_SUBST(TARGET_SYSTEM_ROOT)
 704 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 705 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 706
 707 # Build with intermodule optimisations
 708 AC_ARG_ENABLE(intermodule,
 709 [  --enable-intermodule    build the compiler in one step],
 710 [case ${enable_intermodule} in
 711   yes) onestep="-onestep";;
 712   *) onestep="";;
 713 esac],
 714 [onestep=""])
 715 AC_SUBST(onestep)
 716
 717 # Sanity check enable_languages in case someone does not run the toplevel
 718 # configure # script.
 719 AC_ARG_ENABLE(languages,
 720 [  --enable-languages=LIST specify which front-ends to build],
 721 [case ,${enable_languages}, in
 722        ,,|,yes,)
 723                 # go safe -- we cannot be much sure without the toplevel
 724                 # configure's
 725                 # analysis of which target libs are present and usable
 726                 enable_languages=c
 727                 ;;
 728          *,all,*)
 729                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 730                 ;;
 731         *,c,*)
 732                 ;;
 733         *)
 734                 enable_languages=c,${enable_languages}
 735                 ;;
 736 esac],
 737 [enable_languages=c])
 738
 739 subdirs=
 740 for lang in ${srcdir}/*/config-lang.in
 741 do
 742         case $lang in
 743         # The odd quoting in the next line works around
 744         # an apparent bug in bash 1.12 on linux.
 745 changequote(,)dnl
 746         ${srcdir}/[*]/config-lang.in) ;;
 747         *)
 748           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 749           if test "x$lang_alias" = x
 750           then
 751                 echo "$lang doesn't set \$language." 1>&2
 752                 exit 1
 753           fi
 754           case ",$enable_languages," in
 755           *,$lang_alias,*)
 756             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 757           esac
 758           ;;
 759 changequote([,])dnl
 760         esac
 761 done
 762
 763
 764 # -------------------------
 765 # Checks for other programs
 766 # -------------------------
 767
 768 AC_PROG_MAKE_SET
 769
 770 # Find some useful tools
 771 AC_PROG_AWK
 772 # We need awk to create options.c and options.h.
 773 # Bail out if it's missing.
 774 case ${AWK} in
 775   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 776 esac
 777
 778 gcc_AC_PROG_LN_S
 779 ACX_PROG_LN($LN_S)
 780 AC_PROG_RANLIB
 781 case "${host}" in
 782 *-*-darwin*)
 783   # By default, the Darwin ranlib will not treat common symbols as
 784   # definitions when  building the archive table of contents.  Other
 785   # ranlibs do that; pass an option to the Darwin ranlib that makes
 786   # it behave similarly.
 787   ranlib_flags="-c"
 788   ;;
 789 *)
 790   ranlib_flags=""
 791 esac
 792 AC_SUBST(ranlib_flags)
 793
 794 gcc_AC_PROG_INSTALL
 795
 796 # See if cmp has --ignore-initial.
 797 gcc_AC_PROG_CMP_IGNORE_INITIAL
 798
 799 # See if we have the mktemp command.
 800 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 801
 802 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 803
 804 # See if makeinfo has been installed and is modern enough
 805 # that we can use it.
 806 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 807   [GNU texinfo.* \([0-9][0-9.]*\)],
 808   [4.[2-9]*])
 809 if test $gcc_cv_prog_makeinfo_modern = no; then
 810   MAKEINFO="$MISSING makeinfo"
 811   AC_MSG_WARN([
 812 *** Makeinfo is missing or too old.
 813 *** Info documentation will not be built.])
 814   BUILD_INFO=
 815 else
 816   BUILD_INFO=info
 817 fi
 818 AC_SUBST(BUILD_INFO)
 819
 820 # Is pod2man recent enough to regenerate manpages?
 821 AC_MSG_CHECKING([for recent Pod::Man])
 822 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 823   AC_MSG_RESULT(yes)
 824   GENERATED_MANPAGES=generated-manpages
 825 else
 826   AC_MSG_RESULT(no)
 827   GENERATED_MANPAGES=
 828 fi
 829 AC_SUBST(GENERATED_MANPAGES)
 830
 831 # How about lex?
 832 dnl Don't use AC_PROG_LEX; we insist on flex.
 833 dnl LEXLIB is not useful in gcc.
 834 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 835
 836 # Bison?
 837 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 838
 839 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 840 # check for build == host before using them.
 841
 842 # NM
 843 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 844   && test -d ../binutils ; then
 845   NM='$(objdir)/../binutils/nm-new'
 846 else
 847   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 848 fi
 849
 850 # AR
 851 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 852   && test -d ../binutils ; then
 853   AR='$(objdir)/../binutils/ar'
 854 else
 855   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 856 fi
 857
 858
 859 # --------------------
 860 # Checks for C headers
 861 # --------------------
 862
 863 AC_MSG_CHECKING(for GNU C library)
 864 AC_CACHE_VAL(gcc_cv_glibc,
 865 [AC_TRY_COMPILE(
 866   [#include <features.h>],[
 867 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 868 #error Not a GNU C library system
 869 #endif],
 870   [gcc_cv_glibc=yes],
 871   gcc_cv_glibc=no)])
 872 AC_MSG_RESULT($gcc_cv_glibc)
 873 if test $gcc_cv_glibc = yes; then
 874   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 875 fi
 876
 877 # Need to reject headers which give warnings, so that the -Werror bootstrap
 878 # works later. *sigh*  This needs to come before all header checks.
 879 AC_PROG_CPP_WERROR
 880
 881 AC_HEADER_STDC
 882 AC_HEADER_TIME
 883 ACX_HEADER_STRING
 884 AC_HEADER_SYS_WAIT
 885 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 886                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 887                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 888                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 889
 890 # Check for thread headers.
 891 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 892 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 893
 894 # These tests can't be done till we know if we have limits.h.
 895 gcc_AC_C_CHAR_BIT
 896 AC_C_BIGENDIAN_CROSS
 897
 898 # --------
 899 # UNSORTED
 900 # --------
 901
 902 # Stage specific cflags for build.
 903 stage1_cflags=
 904 case $build in
 905 vax-*-*)
 906   if test x$GCC = xyes
 907   then
 908     stage1_cflags="-Wa,-J"
 909   else
 910     stage1_cflags="-J"
 911   fi
 912   ;;
 913 powerpc-*-darwin*)
 914   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 915   # sources; use -no-cpp-precomp to get to GNU cpp.
 916   # Apple's GCC has bugs in designated initializer handling, so disable
 917   # that too.
 918   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 919   ;;
 920 esac
 921 AC_SUBST(stage1_cflags)
 922
 923 # These libraries may be used by collect2.
 924 # We may need a special search path to get them linked.
 925 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 926 [save_LIBS="$LIBS"
 927 for libs in '' -lld -lmld \
 928                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 929                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 930 do
 931         LIBS="$libs"
 932         AC_TRY_LINK_FUNC(ldopen,
 933                 [gcc_cv_collect2_libs="$libs"; break])
 934 done
 935 LIBS="$save_LIBS"
 936 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 937 case $gcc_cv_collect2_libs in
 938         "none required")        ;;
 939         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 940 esac
 941 AC_SUBST(COLLECT2_LIBS)
 942
 943 # When building Ada code on Alpha, we need exc_resume which is usually in
 944 # -lexc.  So test for it.
 945 save_LIBS="$LIBS"
 946 LIBS=
 947 AC_SEARCH_LIBS(exc_resume, exc)
 948 GNAT_LIBEXC="$LIBS"
 949 LIBS="$save_LIBS"
 950 AC_SUBST(GNAT_LIBEXC)
 951
 952 # Some systems put ldexp and frexp in libm instead of libc; assume
 953 # they're both in the same place.  jcf-dump needs them.
 954 save_LIBS="$LIBS"
 955 LIBS=
 956 AC_SEARCH_LIBS(ldexp, m)
 957 LDEXP_LIB="$LIBS"
 958 LIBS="$save_LIBS"
 959 AC_SUBST(LDEXP_LIB)
 960
 961 # Use <inttypes.h> only if it exists,
 962 # doesn't clash with <sys/types.h>, and declares intmax_t.
 963 AC_MSG_CHECKING(for inttypes.h)
 964 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 965 [AC_TRY_COMPILE(
 966   [#include <sys/types.h>
 967 #include <inttypes.h>],
 968   [intmax_t i = -1;],
 969   [gcc_cv_header_inttypes_h=yes],
 970   gcc_cv_header_inttypes_h=no)])
 971 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 972 if test $gcc_cv_header_inttypes_h = yes; then
 973   AC_DEFINE(HAVE_INTTYPES_H, 1,
 974         [Define if you have a working <inttypes.h> header file.])
 975 fi
 976
 977 dnl Disabled until we have a complete test for buggy enum bitfields.
 978 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 979
 980 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 981         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 982         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 983         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 984         setlocale)
 985
 986 if test x$ac_cv_func_mbstowcs = xyes; then
 987   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 988 [    AC_TRY_RUN([#include <stdlib.h>
 989 int main()
 990 {
 991   mbstowcs(0, "", 0);
 992   return 0;
 993 }],
 994     gcc_cv_func_mbstowcs_works=yes,
 995     gcc_cv_func_mbstowcs_works=no,
 996     gcc_cv_func_mbstowcs_works=yes)])
 997   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 998     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 999   [Define this macro if mbstowcs does not crash when its
1000    first argument is NULL.])
1001   fi
1002 fi
1003
1004 AC_CHECK_TYPE(ssize_t, int)
1005
1006 # Try to determine the array type of the second argument of getgroups
1007 # for the target system (int or gid_t).
1008 AC_TYPE_GETGROUPS
1009 if test "${target}" = "${build}"; then
1010   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1011 else
1012   case "${target}" in
1013         # This condition may need some tweaking.  It should include all
1014         # targets where the array type of the second argument of getgroups
1015         # is int and the type of gid_t is not equivalent to int.
1016         *-*-sunos* | *-*-ultrix*)
1017                 TARGET_GETGROUPS_T=int
1018                 ;;
1019         *)
1020                 TARGET_GETGROUPS_T=gid_t
1021                 ;;
1022   esac
1023 fi
1024 AC_SUBST(TARGET_GETGROUPS_T)
1025
1026 gcc_AC_FUNC_PRINTF_PTR
1027 gcc_AC_FUNC_MMAP_BLACKLIST
1028
1029 case "${host}" in
1030 *-*-*vms*)
1031   # Under VMS, vfork works very differently than on Unix. The standard test
1032   # won't work, and it isn't easily adaptable. It makes more sense to
1033   # just force it.
1034   ac_cv_func_vfork_works=yes
1035   ;;
1036 esac
1037 AC_FUNC_VFORK
1038
1039 AM_ICONV
1040 # Until we have in-tree GNU iconv:
1041 LIBICONV_DEP=
1042 AC_SUBST(LIBICONV_DEP)
1043
1044 AM_LC_MESSAGES
1045
1046 AM_LANGINFO_CODESET
1047
1048 # We will need to find libiberty.h and ansidecl.h
1049 saved_CFLAGS="$CFLAGS"
1050 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1051 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1052         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1053         fprintf_unlocked strstr errno snprintf vasprintf \
1054         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1055 #include "ansidecl.h"
1056 #include "system.h"])
1057
1058 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1059 #include "ansidecl.h"
1060 #include "system.h"
1061 #ifdef HAVE_SYS_RESOURCE_H
1062 #include <sys/resource.h>
1063 #endif
1064 ])
1065
1066 AC_TRY_COMPILE([
1067 #include "ansidecl.h"
1068 #include "system.h"
1069 #ifdef HAVE_SYS_RESOURCE_H
1070 #include <sys/resource.h>
1071 #endif
1072 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1073 [Define to \`long' if <sys/resource.h> doesn't define.])])
1074
1075 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1076 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1077 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1078 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1079 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_LDFCN_H
1083 #undef FREAD
1084 #undef FWRITE
1085 #include <ldfcn.h>
1086 #endif
1087 ])
1088
1089 gcc_AC_CHECK_DECLS(times, , ,[
1090 #include "ansidecl.h"
1091 #include "system.h"
1092 #ifdef HAVE_SYS_TIMES_H
1093 #include <sys/times.h>
1094 #endif
1095 ])
1096
1097 # More time-related stuff.
1098 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1099 AC_TRY_COMPILE([
1100 #include "ansidecl.h"
1101 #include "system.h"
1102 #ifdef HAVE_SYS_TIMES_H
1103 #include <sys/times.h>
1104 #endif
1105 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1106 if test $ac_cv_struct_tms = yes; then
1107   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1108   [Define if <sys/times.h> defines struct tms.])
1109 fi
1110
1111 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1112 # revisit after autoconf 2.50.
1113 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1114 AC_TRY_COMPILE([
1115 #include "ansidecl.h"
1116 #include "system.h"
1117 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1118 if test $gcc_cv_type_clock_t = yes; then
1119   AC_DEFINE(HAVE_CLOCK_T, 1,
1120   [Define if <time.h> defines clock_t.])
1121 fi
1122
1123 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1124 CFLAGS="$saved_CFLAGS"
1125
1126 gcc_AC_INITFINI_ARRAY
1127
1128 # mkdir takes a single argument on some systems.
1129 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1130
1131 # File extensions
1132 manext='.1'
1133 objext='.o'
1134 AC_SUBST(manext)
1135 AC_SUBST(objext)
1136
1137 # With Setjmp/Longjmp based exception handling.
1138 AC_ARG_ENABLE(sjlj-exceptions,
1139 [  --enable-sjlj-exceptions
1140                           arrange to use setjmp/longjmp exception handling],
1141 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1142 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1143   [Define 0/1 to force the choice for exception handling model.])])
1144
1145 # For platforms with the unwind ABI which includes an unwind library,
1146 # libunwind, we can choose to use the system libunwind.
1147 AC_ARG_WITH(system-libunwind,
1148 [  --with-system-libunwind use installed libunwind])
1149
1150 # --------------------------------------------------------
1151 # Build, host, and target specific configuration fragments
1152 # --------------------------------------------------------
1153
1154 # Collect build-machine-specific information.
1155 . ${srcdir}/config.build
1156
1157 # Collect host-machine-specific information.
1158 . ${srcdir}/config.host
1159
1160 target_gtfiles=
1161
1162 # Collect target-machine-specific information.
1163 . ${srcdir}/config.gcc
1164
1165 extra_objs="${host_extra_objs} ${extra_objs}"
1166 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1167
1168 # Default the target-machine variables that were not explicitly set.
1169 if test x"$tm_file" = x
1170 then tm_file=$cpu_type/$cpu_type.h; fi
1171
1172 if test x"$extra_headers" = x
1173 then extra_headers=; fi
1174
1175 if test x$md_file = x
1176 then md_file=$cpu_type/$cpu_type.md; fi
1177
1178 if test x$out_file = x
1179 then out_file=$cpu_type/$cpu_type.c; fi
1180
1181 if test x"$tmake_file" = x
1182 then tmake_file=$cpu_type/t-$cpu_type
1183 fi
1184
1185 if test x"$dwarf2" = xyes
1186 then tm_file="$tm_file tm-dwarf2.h"
1187 fi
1188
1189 # Say what files are being used for the output code and MD file.
1190 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1191 echo "Using \`$srcdir/config/$md_file' as machine description file."
1192
1193 # If any of the xm_file variables contain nonexistent files, warn
1194 # about them and drop them.
1195
1196 bx=
1197 for x in $build_xm_file; do
1198   if    test -f $srcdir/config/$x
1199   then      bx="$bx $x"
1200   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1201   fi
1202 done
1203 build_xm_file="$bx"
1204
1205 hx=
1206 for x in $host_xm_file; do
1207   if    test -f $srcdir/config/$x
1208   then      hx="$hx $x"
1209   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1210   fi
1211 done
1212 host_xm_file="$hx"
1213
1214 tx=
1215 for x in $xm_file; do
1216   if    test -f $srcdir/config/$x
1217   then      tx="$tx $x"
1218   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1219   fi
1220 done
1221 xm_file="$tx"
1222
1223 count=a
1224 for f in $tm_file; do
1225         count=${count}x
1226 done
1227 if test $count = ax; then
1228         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1229 else
1230         echo "Using the following target machine macro files:"
1231         for f in $tm_file; do
1232                 echo "  $srcdir/config/$f"
1233         done
1234 fi
1235
1236 if test x$need_64bit_hwint = xyes; then
1237         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1238 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1239 fi
1240
1241 if test x$use_long_long_for_widest_fast_int = xyes; then
1242         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1243 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1244 efficiently supported by the host hardware.])
1245 fi
1246
1247 count=a
1248 for f in $host_xm_file; do
1249         count=${count}x
1250 done
1251 if test $count = a; then
1252         :
1253 elif test $count = ax; then
1254         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1255 else
1256         echo "Using the following host machine macro files:"
1257         for f in $host_xm_file; do
1258                 echo "  $srcdir/config/$f"
1259         done
1260 fi
1261 echo "Using ${out_host_hook_obj} for host machine hooks."
1262
1263 if test "$host_xm_file" != "$build_xm_file"; then
1264         count=a
1265         for f in $build_xm_file; do
1266                 count=${count}x
1267         done
1268         if test $count = a; then
1269                 :
1270         elif test $count = ax; then
1271                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1272         else
1273                 echo "Using the following build machine macro files:"
1274                 for f in $build_xm_file; do
1275                         echo "  $srcdir/config/$f"
1276                 done
1277         fi
1278 fi
1279
1280 # ---------
1281 # Threading
1282 # ---------
1283
1284 # Check if a valid thread package
1285 case ${enable_threads} in
1286   "" | no)
1287     # No threads
1288     target_thread_file='single'
1289     ;;
1290   yes)
1291     # default
1292     target_thread_file='single'
1293     ;;
1294   aix | dce | gnat | irix | posix | posix95 | rtems | \
1295   single | solaris | vxworks | win32 )
1296     target_thread_file=${enable_threads}
1297     ;;
1298   *)
1299     echo "${enable_threads} is an unknown thread package" 1>&2
1300     exit 1
1301     ;;
1302 esac
1303
1304 if test x${thread_file} = x; then
1305   # No thread file set by target-specific clauses in config.gcc,
1306   # so use file chosen by default logic above
1307   thread_file=${target_thread_file}
1308 fi
1309
1310 # Make gthr-default.h if we have a thread file.
1311 gthread_flags=
1312 if test $thread_file != single; then
1313   rm -f gthr-default.h
1314   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1315   gthread_flags=-DHAVE_GTHR_DEFAULT
1316 fi
1317 AC_SUBST(gthread_flags)
1318
1319 # --------
1320 # UNSORTED
1321 # --------
1322
1323 use_cxa_atexit=no
1324 if test x$enable___cxa_atexit = xyes || \
1325    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1326   if test x$host = x$target; then
1327     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1328         [echo "__cxa_atexit can't be enabled on this target"])
1329   else
1330     # We can't check for __cxa_atexit when building a cross, so assume
1331     # it is available
1332     use_cxa_atexit=yes
1333   fi
1334   if test x$use_cxa_atexit = xyes; then
1335     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1336       [Define if you want to use __cxa_atexit, rather than atexit, to
1337       register C++ destructors for local statics and global objects.
1338       This is essential for fully standards-compliant handling of
1339       destructors, but requires __cxa_atexit in libc.])
1340   fi
1341 fi
1342
1343 # Look for a file containing extra machine modes.
1344 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1345   extra_modes_file='$(srcdir)'/config/${extra_modes}
1346   AC_SUBST(extra_modes_file)
1347   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1348   [Define to the name of a file containing a list of extra machine modes
1349    for this architecture.])
1350 fi
1351
1352 # Convert extra_options into a form suitable for Makefile use.
1353 extra_opt_files=
1354 for f in $extra_options; do
1355   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1356 done
1357 AC_SUBST(extra_opt_files)
1358
1359 # auto-host.h is the file containing items generated by autoconf and is
1360 # the first file included by config.h.
1361 # If host=build, it is correct to have bconfig include auto-host.h
1362 # as well.  If host!=build, we are in error and need to do more
1363 # work to find out the build config parameters.
1364 if test x$host = x$build
1365 then
1366         build_auto=auto-host.h
1367 else
1368         # We create a subdir, then run autoconf in the subdir.
1369         # To prevent recursion we set host and build for the new
1370         # invocation of configure to the build for this invocation
1371         # of configure.
1372         tempdir=build.$$
1373         rm -rf $tempdir
1374         mkdir $tempdir
1375         cd $tempdir
1376         case ${srcdir} in
1377         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1378         *) realsrcdir=../${srcdir};;
1379         esac
1380         saved_CFLAGS="${CFLAGS}"
1381         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1382         ${realsrcdir}/configure \
1383                 --enable-languages=${enable_languages-all} \
1384                 --target=$target_alias --host=$build_alias --build=$build_alias
1385         CFLAGS="${saved_CFLAGS}"
1386
1387         # We just finished tests for the build machine, so rename
1388         # the file auto-build.h in the gcc directory.
1389         mv auto-host.h ../auto-build.h
1390         cd ..
1391         rm -rf $tempdir
1392         build_auto=auto-build.h
1393 fi
1394 AC_SUBST(build_subdir)
1395
1396 tm_file="${tm_file} defaults.h"
1397 tm_p_file="${tm_p_file} tm-preds.h"
1398 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1399 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1400 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1401 # put this back in temporarily.
1402 xm_file="ansidecl.h ${xm_file}"
1403
1404 # --------
1405 # UNSORTED
1406 # --------
1407
1408 changequote(,)dnl
1409 # Compile in configure arguments.
1410 if test -f configargs.h ; then
1411         # Being re-configured.
1412         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1413         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1414 else
1415         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1416 fi
1417
1418 # Double all backslashes and backslash all quotes to turn
1419 # gcc_config_arguments into a C string.
1420 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1421 $gcc_config_arguments
1422 EOF
1423 gcc_config_arguments_str=`cat conftest.out`
1424 rm -f conftest.out
1425
1426 cat > configargs.h <<EOF
1427 /* Generated automatically. */
1428 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1429 static const char thread_model[] = "$thread_file";
1430
1431 static const struct {
1432   const char *name, *value;
1433 } configure_default_options[] = $configure_default_options;
1434 EOF
1435 changequote([,])dnl
1436
1437 # Internationalization
1438 ZW_GNU_GETTEXT_SISTER_DIR
1439
1440 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1441 # -liconv on the link line twice.
1442 case "$LIBINTL" in *$LIBICONV*)
1443         LIBICONV= ;;
1444 esac
1445
1446 # Windows32 Registry support for specifying GCC installation paths.
1447 AC_ARG_ENABLE(win32-registry,
1448 [  --disable-win32-registry
1449                           disable lookup of installation paths in the
1450                           Registry on Windows hosts
1451   --enable-win32-registry enable registry lookup (default)
1452   --enable-win32-registry=KEY
1453                           use KEY instead of GCC version as the last portion
1454                           of the registry key],,)
1455
1456 case $host_os in
1457   win32 | pe | cygwin* | mingw32* | uwin*)
1458     if test "x$enable_win32_registry" != xno; then
1459       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1460     fi
1461
1462     if test "x$enable_win32_registry" != xno; then
1463       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1464   [Define to 1 if installation paths should be looked up in the Windows
1465    Registry. Ignored on non-Windows hosts.])
1466
1467       if test "x$enable_win32_registry" != xyes \
1468          && test "x$enable_win32_registry" != x; then
1469         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1470   [Define to be the last component of the Windows registry key under which
1471    to look for installation paths.  The full key used will be
1472    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1473    The default is the GCC version number.])
1474       fi
1475     fi
1476   ;;
1477 esac
1478
1479 # Get an absolute path to the GCC top-level source directory
1480 holddir=`${PWDCMD-pwd}`
1481 cd $srcdir
1482 topdir=`${PWDCMD-pwd}`
1483 cd $holddir
1484
1485 # Conditionalize the makefile for this host machine.
1486 xmake_file=
1487 for f in ${host_xmake_file}
1488 do
1489         if test -f ${srcdir}/config/$f
1490         then
1491                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1492         fi
1493 done
1494
1495 # Conditionalize the makefile for this target machine.
1496 tmake_file_=
1497 for f in ${tmake_file}
1498 do
1499         if test -f ${srcdir}/config/$f
1500         then
1501                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1502         fi
1503 done
1504 tmake_file="${tmake_file_}"
1505
1506 # If the host doesn't support symlinks, modify CC in
1507 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1508 # Otherwise, we can use "CC=$(CC)".
1509 rm -f symtest.tem
1510 case "$LN_S" in
1511         *-s*)
1512                 cc_set_by_configure="\$(CC)"
1513                 quoted_cc_set_by_configure="\$(CC)"
1514                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1515                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1516                 ;;
1517         *)
1518                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1519                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1520                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1521                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1522                 ;;
1523 esac
1524
1525 # This is a terrible hack which will go away some day.
1526 host_cc_for_libada=${CC}
1527 AC_SUBST(host_cc_for_libada)
1528
1529 out_object_file=`basename $out_file .c`.o
1530
1531 tm_file_list="options.h"
1532 tm_include_list="options.h"
1533 for f in $tm_file; do
1534   case $f in
1535     defaults.h )
1536        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1537        tm_include_list="${tm_include_list} $f"
1538        ;;
1539     * )
1540        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1541        tm_include_list="${tm_include_list} config/$f"
1542        ;;
1543   esac
1544 done
1545
1546 tm_p_file_list=
1547 tm_p_include_list=
1548 for f in $tm_p_file; do
1549   case $f in
1550     tm-preds.h )
1551        tm_p_file_list="${tm_p_file_list} $f"
1552        tm_p_include_list="${tm_p_include_list} $f"
1553        ;;
1554     * )
1555        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1556        tm_p_include_list="${tm_p_include_list} config/$f"
1557   esac
1558 done
1559
1560 xm_file_list=
1561 xm_include_list=
1562 for f in $xm_file; do
1563   case $f in
1564     ansidecl.h )
1565        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1566        xm_include_list="${xm_include_list} $f"
1567        ;;
1568     auto-host.h )
1569        xm_file_list="${xm_file_list} $f"
1570        xm_include_list="${xm_include_list} $f"
1571        ;;
1572     * )
1573        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1574        xm_include_list="${xm_include_list} config/$f"
1575        ;;
1576   esac
1577 done
1578
1579 host_xm_file_list=
1580 host_xm_include_list=
1581 for f in $host_xm_file; do
1582   case $f in
1583     ansidecl.h )
1584        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1585        host_xm_include_list="${host_xm_include_list} $f"
1586        ;;
1587     auto-host.h )
1588        host_xm_file_list="${host_xm_file_list} $f"
1589        host_xm_include_list="${host_xm_include_list} $f"
1590        ;;
1591     * )
1592        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1593        host_xm_include_list="${host_xm_include_list} config/$f"
1594        ;;
1595   esac
1596 done
1597
1598 build_xm_file_list=
1599 for f in $build_xm_file; do
1600   case $f in
1601     ansidecl.h )
1602        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1603        build_xm_include_list="${build_xm_include_list} $f"
1604        ;;
1605     auto-build.h | auto-host.h )
1606        build_xm_file_list="${build_xm_file_list} $f"
1607        build_xm_include_list="${build_xm_include_list} $f"
1608        ;;
1609     * )
1610        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1611        build_xm_include_list="${build_xm_include_list} config/$f"
1612        ;;
1613   esac
1614 done
1615
1616 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1617 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1618 CROSS=                                          AC_SUBST(CROSS)
1619 ALL=all.internal                                AC_SUBST(ALL)
1620 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1621 if test x$host != x$target
1622 then
1623         CROSS="-DCROSS_COMPILE"
1624         ALL=all.cross
1625         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1626         case "$host","$target" in
1627         # Darwin crosses can use the host system's libraries and headers,
1628         # because of the fat library support.  Of course, it must be the
1629         # same version of Darwin on both sides.  Allow the user to
1630         # just say --target=foo-darwin without a version number to mean
1631         # "the version on this system".
1632             *-*-darwin*,*-*-darwin*)
1633                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1634                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1635                 if test $hostos = $targetos -o $targetos = darwin ; then
1636                     CROSS=
1637                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1638                     with_headers=yes
1639                 fi
1640                 ;;
1641
1642             i?86-*-*,x86_64-*-* \
1643             | powerpc*-*-*,powerpc64*-*-*)
1644                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1645         esac
1646 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1647         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1648         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1649 fi
1650
1651 # If this is a cross-compiler that does not
1652 # have its own set of headers then define
1653 # inhibit_libc
1654
1655 # If this is using newlib, without having the headers available now,
1656 # then define inhibit_libc in LIBGCC2_CFLAGS.
1657 # This prevents libgcc2 from containing any code which requires libc
1658 # support.
1659 inhibit_libc=
1660 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1661        test x$with_newlib = xyes ; } &&
1662      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1663        inhibit_libc=-Dinhibit_libc
1664 fi
1665 AC_SUBST(inhibit_libc)
1666
1667 # When building gcc with a cross-compiler, we need to adjust things so
1668 # that the generator programs are still built with the native compiler.
1669 # Also, we cannot run fixincludes or fix-header.
1670
1671 # These are the normal (build=host) settings:
1672 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1673 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1674 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1675
1676 # Possibly disable fixproto, on a per-target basis.
1677 case ${use_fixproto} in
1678   no)
1679     STMP_FIXPROTO=
1680     ;;
1681   yes)
1682     STMP_FIXPROTO=stmp-fixproto
1683     ;;
1684 esac
1685 AC_SUBST(STMP_FIXPROTO)
1686
1687 # And these apply if build != host, or we are generating coverage data
1688 if test x$build != x$host || test "x$coverage_flags" != x
1689 then
1690     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1691
1692     if test "x$TARGET_SYSTEM_ROOT" = x; then
1693         if [ "x$STMP_FIXPROTO" != x ] ; then
1694           STMP_FIXPROTO=stmp-install-fixproto
1695         fi
1696     fi
1697 fi
1698
1699 # Expand extra_headers to include complete path.
1700 # This substitutes for lots of t-* files.
1701 extra_headers_list=
1702 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1703 for file in ${extra_headers} ; do
1704   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1705 done
1706
1707 # Define collect2 in Makefile.
1708 case $host_can_use_collect2 in
1709   no) collect2= ;;
1710   *) collect2='collect2$(exeext)' ;;
1711 esac
1712 AC_SUBST([collect2])
1713
1714 # Add a definition of USE_COLLECT2 if system wants one.
1715 case $use_collect2 in
1716   no) use_collect2= ;;
1717   "") ;;
1718   *)
1719     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1720     xm_defines="${xm_defines} USE_COLLECT2"
1721     case $host_can_use_collect2 in
1722       no)
1723         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1724         ;;
1725     esac
1726     ;;
1727 esac
1728
1729 # ---------------------------
1730 # Assembler & linker features
1731 # ---------------------------
1732
1733 # Identify the assembler which will work hand-in-glove with the newly
1734 # built GCC, so that we can examine its features.  This is the assembler
1735 # which will be driven by the driver program.
1736 #
1737 # If build != host, and we aren't building gas in-tree, we identify a
1738 # build->target assembler and hope that it will have the same features
1739 # as the host->target assembler we'll be using.
1740 AC_MSG_CHECKING(what assembler to use)
1741 in_tree_gas=no
1742 gcc_cv_as=
1743 gcc_cv_gas_major_version=
1744 gcc_cv_gas_minor_version=
1745 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1746 if test -x "$DEFAULT_ASSEMBLER"; then
1747         gcc_cv_as="$DEFAULT_ASSEMBLER"
1748 elif test -x as$build_exeext; then
1749         # Build using assembler in the current directory.
1750         gcc_cv_as=./as$build_exeext
1751 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1752      && test -f ../gas/Makefile \
1753      && test x$build = x$host; then
1754   # Single tree build which includes gas.  We want to prefer it
1755   # over whatever linker top-level may have detected, since
1756   # we'll use what we're building after installation anyway.
1757   in_tree_gas=yes
1758   _gcc_COMPUTE_GAS_VERSION
1759   rm -f as$build_exeext
1760   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1761   in_tree_gas_is_elf=no
1762   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1763      || (grep 'obj_format = multi' ../gas/Makefile \
1764          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1765   then
1766     in_tree_gas_is_elf=yes
1767   fi
1768 m4_pattern_allow([AS_FOR_TARGET])dnl
1769 elif test -x "$AS_FOR_TARGET"; then
1770         gcc_cv_as="$AS_FOR_TARGET"
1771 elif test -x "$AS" && test x$host = x$target; then
1772         gcc_cv_as="$AS"
1773 fi
1774
1775 gcc_version=`cat $srcdir/BASE-VER`
1776
1777 if test "x$gcc_cv_as" = x; then
1778         # Search the same directories that the installed compiler will
1779         # search.  Else we may find the wrong assembler and lose.  If we
1780         # do not find a suitable assembler binary, then try the user's
1781         # path.
1782         #
1783         # Also note we have to check MD_EXEC_PREFIX before checking the
1784         # user's path.  Unfortunately, there is no good way to get at the
1785         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1786         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1787         # to be fixed as part of the make/configure rewrite too.
1788
1789         if test "x$exec_prefix" = xNONE; then
1790                 if test "x$prefix" = xNONE; then
1791                         test_prefix=/usr/local
1792                 else
1793                         test_prefix=$prefix
1794                 fi
1795         else
1796                 test_prefix=$exec_prefix
1797         fi
1798
1799         # If the loop below does not find an assembler, then use whatever
1800         # one we can find in the users's path.  We are looking for a
1801         # ${build} -> ${target} assembler.
1802         if test "x$program_prefix" != xNONE; then
1803                 gcc_cv_as=${program_prefix}as$build_exeext
1804         elif test x$build != x$host && test x$build != x$target; then
1805                 gcc_cv_as=${target_noncanonical}-as$build_exeext
1806         else
1807                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1808         fi
1809
1810         if test x$host = x$build; then
1811             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1812                        $test_prefix/libexec/gcc/$target_noncanonical \
1813                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1814                        /usr/lib/gcc/$target_noncanonical \
1815                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1816                        $test_prefix/$target_noncanonical/bin"
1817         else
1818             test_dirs=
1819         fi
1820
1821         if test x$build = x$target; then
1822             test_dirs="$test_dirs \
1823                    /usr/libexec \
1824                    /usr/ccs/gcc \
1825                    /usr/ccs/bin \
1826                    /udk/usr/ccs/bin \
1827                    /bsd43/usr/lib/cmplrs/cc \
1828                    /usr/cross64/usr/bin \
1829                    /usr/lib/cmplrs/cc \
1830                    /sysv/usr/lib/cmplrs/cc \
1831                    /svr4/usr/lib/cmplrs/cc \
1832                    /usr/bin"
1833         fi
1834
1835         for dir in $test_dirs; do
1836                 if test -x $dir/as$build_exeext; then
1837                         gcc_cv_as=$dir/as$build_exeext
1838                         break;
1839                 fi
1840         done
1841 fi
1842 case $in_tree_gas in
1843   yes)
1844     AC_MSG_RESULT("newly built gas")
1845     ;;
1846   no)
1847     AC_MSG_RESULT($gcc_cv_as)
1848     ;;
1849 esac
1850
1851 # Identify the linker which will work hand-in-glove with the newly
1852 # built GCC, so that we can examine its features.  This is the linker
1853 # which will be driven by the driver program.
1854 #
1855 # If build != host, and we aren't building gas in-tree, we identify a
1856 # build->target linker and hope that it will have the same features
1857 # as the host->target linker we'll be using.
1858 AC_MSG_CHECKING(what linker to use)
1859 in_tree_ld=no
1860 gcc_cv_ld=
1861 gcc_cv_gld_major_version=
1862 gcc_cv_gld_minor_version=
1863 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1864 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1865 if test -x "$DEFAULT_LINKER"; then
1866         gcc_cv_ld="$DEFAULT_LINKER"
1867 elif test -x collect-ld$build_exeext; then
1868         # Build using linker in the current directory.
1869         gcc_cv_ld=./collect-ld$build_exeext
1870 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1871      && test -f ../ld/Makefile \
1872      && test x$build = x$host; then
1873         # Single tree build which includes ld.  We want to prefer it
1874         # over whatever linker top-level may have detected, since
1875         # we'll use what we're building after installation anyway.
1876         in_tree_ld=yes
1877         in_tree_ld_is_elf=no
1878         if (grep 'EMUL = .*elf' ../ld/Makefile \
1879             || grep 'EMUL = .*linux' ../ld/Makefile \
1880             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1881           in_tree_ld_is_elf=yes
1882         fi
1883         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1884         do
1885 changequote(,)dnl
1886                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1887 changequote([,])dnl
1888                 if test x$gcc_cv_gld_version != x; then
1889                         break
1890                 fi
1891         done
1892 changequote(,)dnl
1893         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1894         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1895 changequote([,])dnl
1896         rm -f collect-ld$build_exeext
1897         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1898 elif test -x "$LD_FOR_TARGET"; then
1899         gcc_cv_ld="$LD_FOR_TARGET"
1900 elif test -x "$LD" && test x$host = x$target; then
1901         gcc_cv_ld="$LD"
1902 fi
1903
1904 if test "x$gcc_cv_ld" = x; then
1905         # Search the same directories that the installed compiler will
1906         # search.  Else we may find the wrong linker and lose.  If we
1907         # do not find a suitable linker binary, then try the user's
1908         # path.
1909         #
1910         # Also note we have to check MD_EXEC_PREFIX before checking the
1911         # user's path.  Unfortunately, there is no good way to get at the
1912         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1913         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1914         # to be fixed as part of the make/configure rewrite too.
1915
1916         if test "x$exec_prefix" = xNONE; then
1917                 if test "x$prefix" = xNONE; then
1918                         test_prefix=/usr/local
1919                 else
1920                         test_prefix=$prefix
1921                 fi
1922         else
1923                 test_prefix=$exec_prefix
1924         fi
1925
1926         # If the loop below does not find a linker, then use whatever
1927         # one we can find in the users's path.  We are looking for a
1928         # ${build} -> ${target} linker.
1929         if test "x$program_prefix" != xNONE; then
1930                 gcc_cv_ld=${program_prefix}ld$build_exeext
1931         elif test x$build != x$host && test x$build != x$target; then
1932                 gcc_cv_ld=${target_noncanonical}-ld$build_exeext
1933         else
1934                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1935         fi
1936
1937         if test x$host = x$build; then
1938             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1939                        $test_prefix/libexec/gcc/$target_noncanonical \
1940                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1941                        /usr/lib/gcc/$target_noncanonical \
1942                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1943                        $test_prefix/$target_noncanonical/bin"
1944         else
1945             test_dirs=
1946         fi
1947
1948         if test x$build = x$target; then
1949             test_dirs="$test_dirs \
1950                    /usr/libexec \
1951                    /usr/ccs/gcc \
1952                    /usr/ccs/bin \
1953                    /udk/usr/ccs/bin \
1954                    /bsd43/usr/lib/cmplrs/cc \
1955                    /usr/cross64/usr/bin \
1956                    /usr/lib/cmplrs/cc \
1957                    /sysv/usr/lib/cmplrs/cc \
1958                    /svr4/usr/lib/cmplrs/cc \
1959                    /usr/bin"
1960         fi
1961
1962         for dir in $test_dirs; do
1963                 if test -x $dir/ld$build_exeext; then
1964                         gcc_cv_ld=$dir/ld$build_exeext
1965                         break;
1966                 fi
1967         done
1968 fi
1969 case $in_tree_ld in
1970   yes)
1971     AC_MSG_RESULT("newly built ld")
1972     ;;
1973   no)
1974     AC_MSG_RESULT($gcc_cv_ld)
1975     ;;
1976 esac
1977
1978 # Figure out what nm we will be using.
1979 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1980 AC_MSG_CHECKING(what nm to use)
1981 in_tree_nm=no
1982 if test -x nm$build_exeext; then
1983         gcc_cv_nm=./nm$build_exeext
1984 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1985      && test -f ../binutils/Makefile; then
1986         # Single tree build which includes binutils.
1987         in_tree_nm=yes
1988         gcc_cv_nm=./nm$build_exeext
1989         rm -f nm$build_exeext
1990         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1991 elif test "x$program_prefix" != xNONE; then
1992         gcc_cv_nm=${program_prefix}nm$build_exeext
1993 elif test x$build != x$host && test x$build != x$target; then
1994         gcc_cv_nm=${target_noncanonical}-nm$build_exeext
1995 else
1996         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1997 fi
1998 case $in_tree_nm in
1999   yes) AC_MSG_RESULT("newly built nm") ;;
2000   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
2001 esac
2002
2003 # Figure out what objdump we will be using.
2004 AC_MSG_CHECKING(what objdump to use)
2005 in_tree_objdump=no
2006 if test -x objdump$build_exeext; then
2007         gcc_cv_objdump=./objdump$build_exeext
2008 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2009      && test -f ../binutils/Makefile; then
2010         # Single tree build which includes binutils.
2011         in_tree_objdump=yes
2012         gcc_cv_objdump=./objdump$build_exeext
2013         rm -f objdump$build_exeext
2014         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2015 elif test "x$program_prefix" != xNONE; then
2016         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2017 elif test x$build != x$host && test x$build != x$target; then
2018         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
2019 else
2020         gcc_cv_objdump=`echo objdump | \
2021                 sed "${program_transform_name}"`$build_exeext
2022 fi
2023 case $in_tree_objdump in
2024   yes) AC_MSG_RESULT("newly built objdump") ;;
2025   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2026 esac
2027
2028 # Figure out what assembler alignment features are present.
2029 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2030  [2,6,0],,
2031 [.balign 4
2032 .p2align 2],,
2033 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2034   [Define if your assembler supports .balign and .p2align.])])
2035
2036 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2037  [2,8,0],,
2038  [.p2align 4,,7],,
2039 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2040   [Define if your assembler supports specifying the maximum number
2041    of bytes to skip when using the GAS .p2align command.])])
2042
2043 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2044  [elf,2,9,0],,
2045  [conftest_label1: .word 0
2046 .subsection -1
2047 conftest_label2: .word 0
2048 .previous],
2049  [if test x$gcc_cv_nm != x; then
2050     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2051     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2052     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2053     then :
2054     else gcc_cv_as_subsection_m1=yes
2055     fi
2056     rm -f conftest.nm1 conftest.nm2
2057   fi],
2058  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2059   [Define if your assembler supports .subsection and .subsection -1 starts
2060    emitting at the beginning of your section.])])
2061
2062 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2063  [2,2,0],,
2064  [      .weak foobar],,
2065 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2066
2067 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2068  [2,15,91],,
2069  [      .SPACE $TEXT$
2070         .NSUBSPA $CODE$,COMDAT],,
2071 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2072
2073 # .hidden needs to be supported in both the assembler and the linker,
2074 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2075 # This is irritatingly difficult to feature test for; we have to check the
2076 # date string after the version number.  If we've got an in-tree
2077 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2078 # to be safe.
2079 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2080 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2081  [elf,2,13,0],,
2082 [       .hidden foobar
2083 foobar:])
2084
2085 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2086 [if test $in_tree_ld = yes ; then
2087   gcc_cv_ld_hidden=no
2088   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2089      && test $in_tree_ld_is_elf = yes; then
2090      gcc_cv_ld_hidden=yes
2091   fi
2092 else
2093   gcc_cv_ld_hidden=yes
2094   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2095   if echo "$ld_ver" | grep GNU > /dev/null; then
2096 changequote(,)dnl
2097     ld_vers=`echo $ld_ver | sed -n \
2098         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2099         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2100         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2101         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2102         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2103         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2104     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2105     if test 0"$ld_date" -lt 20020404; then
2106       if test -n "$ld_date"; then
2107         # If there was date string, but was earlier than 2002-04-04, fail
2108         gcc_cv_ld_hidden=no
2109       elif test -z "$ld_vers"; then
2110         # If there was no date string nor ld version number, something is wrong
2111         gcc_cv_ld_hidden=no
2112       else
2113         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2114         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2115         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2116         test -z "$ld_vers_patch" && ld_vers_patch=0
2117         if test "$ld_vers_major" -lt 2; then
2118           gcc_cv_ld_hidden=no
2119         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2120           gcc_cv_ld_hidden="no"
2121         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2122           gcc_cv_ld_hidden=no
2123         fi
2124       fi
2125 changequote([,])dnl
2126     fi
2127   else
2128     case "${target}" in
2129       hppa64*-*-hpux* | ia64*-*-hpux*)
2130         gcc_cv_ld_hidden=yes
2131         ;;
2132       *)
2133         gcc_cv_ld_hidden=no
2134         ;;
2135     esac
2136   fi
2137 fi])
2138 libgcc_visibility=no
2139 AC_SUBST(libgcc_visibility)
2140 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2141   libgcc_visibility=yes
2142   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2143   [Define if your assembler and linker support .hidden.])
2144 fi
2145
2146 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2147 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2148   [elf,2,11,0],,
2149 [       .data
2150         .uleb128 L2 - L1
2151 L1:
2152         .uleb128 1280
2153         .sleb128 -1010
2154 L2:],
2155  [# GAS versions before 2.11 do not support uleb128,
2156   # despite appearing to.
2157   # ??? There exists an elf-specific test that will crash
2158   # the assembler.  Perhaps it's better to figure out whether
2159   # arbitrary sections are supported and try the test.
2160   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2161   if echo "$as_ver" | grep GNU > /dev/null; then
2162 changequote(,)dnl
2163     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2164     as_major=`echo $as_ver | sed 's/\..*//'`
2165     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2166 changequote([,])dnl
2167     if test $as_major -eq 2 && test $as_minor -lt 11
2168     then :
2169     else gcc_cv_as_leb128=yes
2170     fi
2171   fi],
2172   [AC_DEFINE(HAVE_AS_LEB128, 1,
2173     [Define if your assembler supports .sleb128 and .uleb128.])])
2174
2175 # GAS versions up to and including 2.11.0 may mis-optimize
2176 # .eh_frame data.
2177 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2178   [elf,2,12,0],,
2179 [       .text
2180 .LFB1:
2181         .4byte  0
2182 .L1:
2183         .4byte  0
2184 .LFE1:
2185         .section        .eh_frame,"aw",@progbits
2186 __FRAME_BEGIN__:
2187         .4byte  .LECIE1-.LSCIE1
2188 .LSCIE1:
2189         .4byte  0x0
2190         .byte   0x1
2191         .ascii "z\0"
2192         .byte   0x1
2193         .byte   0x78
2194         .byte   0x1a
2195         .byte   0x0
2196         .byte   0x4
2197         .4byte  1
2198         .p2align 1
2199 .LECIE1:
2200 .LSFDE1:
2201         .4byte  .LEFDE1-.LASFDE1
2202 .LASFDE1:
2203         .4byte  .LASFDE1-__FRAME_BEGIN__
2204         .4byte  .LFB1
2205         .4byte  .LFE1-.LFB1
2206         .byte   0x4
2207         .4byte  .LFE1-.LFB1
2208         .byte   0x4
2209         .4byte  .L1-.LFB1
2210 .LEFDE1:],
2211 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2212 cat > conftest.lit <<EOF
2213  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2214  0010 01000000 12000000 18000000 00000000  ................
2215  0020 08000000 04080000 0044               .........D      @&t@
2216 EOF
2217 cat > conftest.big <<EOF
2218  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2219  0010 00000001 00000012 00000018 00000000  ................
2220  0020 00000008 04000000 0844               .........D      @&t@
2221 EOF
2222   # If the assembler didn't choke, and we can objdump,
2223   # and we got the correct data, then succeed.
2224   if test x$gcc_cv_objdump != x \
2225   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2226      | tail -3 > conftest.got \
2227   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2228     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2229   then
2230     gcc_cv_as_eh_frame=yes
2231   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2232     gcc_cv_as_eh_frame=buggy
2233   else
2234     # Uh oh, what do we do now?
2235     gcc_cv_as_eh_frame=no
2236   fi])
2237
2238 if test $gcc_cv_as_eh_frame = buggy; then
2239   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2240   [Define if your assembler mis-optimizes .eh_frame data.])
2241 fi
2242
2243 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2244  [elf,2,12,0], [--fatal-warnings],
2245  [.section .rodata.str, "aMS", @progbits, 1])
2246 if test $gcc_cv_as_shf_merge = no; then
2247   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2248     [elf,2,12,0], [--fatal-warnings],
2249     [.section .rodata.str, "aMS", %progbits, 1])
2250 fi
2251 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2252   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2253 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2254
2255 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2256  [elf,2,15,91], [--fatal-warnings],
2257  [.section .text,"axG",@progbits,.foo,comdat])
2258 if test $gcc_cv_as_comdat_group = yes; then
2259   gcc_cv_as_comdat_group_percent=no
2260 else
2261  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2262    [elf,2,15,91], [--fatal-warnings],
2263    [.section .text,"axG",%progbits,.foo,comdat])
2264 fi
2265 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2266   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2267 [Define 0/1 if your assembler supports COMDAT group.])
2268
2269 # Thread-local storage - the check is heavily parametrized.
2270 conftest_s=
2271 tls_first_major=
2272 tls_first_minor=
2273 tls_as_opt=
2274 case "$target" in
2275 changequote(,)dnl
2276   alpha*-*-*)
2277     conftest_s='
2278         .section ".tdata","awT",@progbits
2279 foo:    .long   25
2280         .text
2281         ldq     $27,__tls_get_addr($29)         !literal!1
2282         lda     $16,foo($29)                    !tlsgd!1
2283         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2284         ldq     $27,__tls_get_addr($29)         !literal!2
2285         lda     $16,foo($29)                    !tlsldm!2
2286         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2287         ldq     $1,foo($29)                     !gotdtprel
2288         ldah    $2,foo($29)                     !dtprelhi
2289         lda     $3,foo($2)                      !dtprello
2290         lda     $4,foo($29)                     !dtprel
2291         ldq     $1,foo($29)                     !gottprel
2292         ldah    $2,foo($29)                     !tprelhi
2293         lda     $3,foo($2)                      !tprello
2294         lda     $4,foo($29)                     !tprel'
2295         tls_first_major=2
2296         tls_first_minor=13
2297         tls_as_opt=--fatal-warnings
2298         ;;
2299   frv*-*-*)
2300     conftest_s='
2301         .section ".tdata","awT",@progbits
2302 x:      .long   25
2303         .text
2304         call    #gettlsoff(x)'
2305         tls_first_major=2
2306         tls_first_minor=14
2307         ;;
2308   i[34567]86-*-*)
2309     conftest_s='
2310         .section ".tdata","awT",@progbits
2311 foo:    .long   25
2312         .text
2313         movl    %gs:0, %eax
2314         leal    foo@TLSGD(,%ebx,1), %eax
2315         leal    foo@TLSLDM(%ebx), %eax
2316         leal    foo@DTPOFF(%eax), %edx
2317         movl    foo@GOTTPOFF(%ebx), %eax
2318         subl    foo@GOTTPOFF(%ebx), %eax
2319         addl    foo@GOTNTPOFF(%ebx), %eax
2320         movl    foo@INDNTPOFF, %eax
2321         movl    $foo@TPOFF, %eax
2322         subl    $foo@TPOFF, %eax
2323         leal    foo@NTPOFF(%ecx), %eax'
2324         tls_first_major=2
2325         tls_first_minor=14
2326         tls_as_opt=--fatal-warnings
2327         ;;
2328   x86_64-*-*)
2329     conftest_s='
2330         .section ".tdata","awT",@progbits
2331 foo:    .long   25
2332         .text
2333         movq    %fs:0, %rax
2334         leaq    foo@TLSGD(%rip), %rdi
2335         leaq    foo@TLSLD(%rip), %rdi
2336         leaq    foo@DTPOFF(%rax), %rdx
2337         movq    foo@GOTTPOFF(%rip), %rax
2338         movq    $foo@TPOFF, %rax'
2339         tls_first_major=2
2340         tls_first_minor=14
2341         tls_as_opt=--fatal-warnings
2342         ;;
2343   ia64-*-*)
2344     conftest_s='
2345         .section ".tdata","awT",@progbits
2346 foo:    data8   25
2347         .text
2348         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2349         addl    r17 = @ltoff(@dtprel(foo#)), gp
2350         addl    r18 = @ltoff(@tprel(foo#)), gp
2351         addl    r19 = @dtprel(foo#), gp
2352         adds    r21 = @dtprel(foo#), r13
2353         movl    r23 = @dtprel(foo#)
2354         addl    r20 = @tprel(foo#), gp
2355         adds    r22 = @tprel(foo#), r13
2356         movl    r24 = @tprel(foo#)'
2357         tls_first_major=2
2358         tls_first_minor=13
2359         tls_as_opt=--fatal-warnings
2360         ;;
2361   mips*-*-*)
2362     conftest_s='
2363         .section .tdata,"awT",@progbits
2364 x:
2365         .word 2
2366         .text
2367         addiu $4, $28, %tlsgd(x)
2368         addiu $4, $28, %tlsldm(x)
2369         lui $4, %dtprel_hi(x)
2370         addiu $4, $4, %dtprel_lo(x)
2371         lw $4, %gottprel(x)($28)
2372         lui $4, %tprel_hi(x)
2373         addiu $4, $4, %tprel_lo(x)'
2374         tls_first_major=2
2375         tls_first_minor=16
2376         tls_as_opt='-32 --fatal-warnings'
2377         ;;
2378   powerpc-*-*)
2379     conftest_s='
2380         .section ".tdata","awT",@progbits
2381         .align 2
2382 ld0:    .space 4
2383 ld1:    .space 4
2384 x1:     .space 4
2385 x2:     .space 4
2386 x3:     .space 4
2387         .text
2388         addi 3,31,ld0@got@tlsgd
2389         bl __tls_get_addr
2390         addi 3,31,x1@got@tlsld
2391         bl __tls_get_addr
2392         addi 9,3,x1@dtprel
2393         addis 9,3,x2@dtprel@ha
2394         addi 9,9,x2@dtprel@l
2395         lwz 9,x3@got@tprel(31)
2396         add 9,9,x@tls
2397         addi 9,2,x1@tprel
2398         addis 9,2,x2@tprel@ha
2399         addi 9,9,x2@tprel@l'
2400         tls_first_major=2
2401         tls_first_minor=14
2402         tls_as_opt="-a32 --fatal-warnings"
2403         ;;
2404   powerpc64-*-*)
2405     conftest_s='
2406         .section ".tdata","awT",@progbits
2407         .align 3
2408 ld0:    .space 8
2409 ld1:    .space 8
2410 x1:     .space 8
2411 x2:     .space 8
2412 x3:     .space 8
2413         .text
2414         addi 3,2,ld0@got@tlsgd
2415         bl .__tls_get_addr
2416         nop
2417         addi 3,2,ld1@toc
2418         bl .__tls_get_addr
2419         nop
2420         addi 3,2,x1@got@tlsld
2421         bl .__tls_get_addr
2422         nop
2423         addi 9,3,x1@dtprel
2424         bl .__tls_get_addr
2425         nop
2426         addis 9,3,x2@dtprel@ha
2427         addi 9,9,x2@dtprel@l
2428         bl .__tls_get_addr
2429         nop
2430         ld 9,x3@got@dtprel(2)
2431         add 9,9,3
2432         bl .__tls_get_addr
2433         nop'
2434         tls_first_major=2
2435         tls_first_minor=14
2436         tls_as_opt="-a64 --fatal-warnings"
2437         ;;
2438   s390-*-*)
2439     conftest_s='
2440         .section ".tdata","awT",@progbits
2441 foo:    .long   25
2442         .text
2443         .long   foo@TLSGD
2444         .long   foo@TLSLDM
2445         .long   foo@DTPOFF
2446         .long   foo@NTPOFF
2447         .long   foo@GOTNTPOFF
2448         .long   foo@INDNTPOFF
2449         l       %r1,foo@GOTNTPOFF(%r12)
2450         l       %r1,0(%r1):tls_load:foo
2451         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2452         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2453         tls_first_major=2
2454         tls_first_minor=14
2455         tls_as_opt="-m31 --fatal-warnings"
2456         ;;
2457   s390x-*-*)
2458     conftest_s='
2459         .section ".tdata","awT",@progbits
2460 foo:    .long   25
2461         .text
2462         .quad   foo@TLSGD
2463         .quad   foo@TLSLDM
2464         .quad   foo@DTPOFF
2465         .quad   foo@NTPOFF
2466         .quad   foo@GOTNTPOFF
2467         lg      %r1,foo@GOTNTPOFF(%r12)
2468         larl    %r1,foo@INDNTPOFF
2469         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2470         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2471         tls_first_major=2
2472         tls_first_minor=14
2473         tls_as_opt="-m64 -Aesame --fatal-warnings"
2474         ;;
2475   sh-*-* | sh[34]-*-*)
2476     conftest_s='
2477         .section ".tdata","awT",@progbits
2478 foo:    .long   25
2479         .text
2480         .long   foo@TLSGD
2481         .long   foo@TLSLDM
2482         .long   foo@DTPOFF
2483         .long   foo@GOTTPOFF
2484         .long   foo@TPOFF'
2485         tls_first_major=2
2486         tls_first_minor=13
2487         tls_as_opt=--fatal-warnings
2488         ;;
2489   sparc*-*-*)
2490     case "$target" in
2491       sparc*-sun-solaris2.*)
2492         on_solaris=yes
2493         ;;
2494       *)
2495         on_solaris=no
2496         ;;
2497     esac
2498     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2499       conftest_s='
2500         .section ".tdata",#alloc,#write,#tls
2501 foo:    .long   25
2502         .text
2503         sethi   %tgd_hi22(foo), %o0
2504         add     %o0, %tgd_lo10(foo), %o1
2505         add     %l7, %o1, %o0, %tgd_add(foo)
2506         call    __tls_get_addr, %tgd_call(foo)
2507         sethi   %tldm_hi22(foo), %l1
2508         add     %l1, %tldm_lo10(foo), %l2
2509         add     %l7, %l2, %o0, %tldm_add(foo)
2510         call    __tls_get_addr, %tldm_call(foo)
2511         sethi   %tldo_hix22(foo), %l3
2512         xor     %l3, %tldo_lox10(foo), %l4
2513         add     %o0, %l4, %l5, %tldo_add(foo)
2514         sethi   %tie_hi22(foo), %o3
2515         add     %o3, %tie_lo10(foo), %o3
2516         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2517         add     %g7, %o2, %o4, %tie_add(foo)
2518         sethi   %tle_hix22(foo), %l1
2519         xor     %l1, %tle_lox10(foo), %o5
2520         ld      [%g7 + %o5], %o1'
2521         tls_first_major=0
2522         tls_first_minor=0
2523     else
2524       conftest_s='
2525         .section ".tdata","awT",@progbits
2526 foo:    .long   25
2527         .text
2528         sethi   %tgd_hi22(foo), %o0
2529         add     %o0, %tgd_lo10(foo), %o1
2530         add     %l7, %o1, %o0, %tgd_add(foo)
2531         call    __tls_get_addr, %tgd_call(foo)
2532         sethi   %tldm_hi22(foo), %l1
2533         add     %l1, %tldm_lo10(foo), %l2
2534         add     %l7, %l2, %o0, %tldm_add(foo)
2535         call    __tls_get_addr, %tldm_call(foo)
2536         sethi   %tldo_hix22(foo), %l3
2537         xor     %l3, %tldo_lox10(foo), %l4
2538         add     %o0, %l4, %l5, %tldo_add(foo)
2539         sethi   %tie_hi22(foo), %o3
2540         add     %o3, %tie_lo10(foo), %o3
2541         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2542         add     %g7, %o2, %o4, %tie_add(foo)
2543         sethi   %tle_hix22(foo), %l1
2544         xor     %l1, %tle_lox10(foo), %o5
2545         ld      [%g7 + %o5], %o1'
2546         tls_first_major=2
2547         tls_first_minor=14
2548         tls_as_opt="-32 --fatal-warnings"
2549       fi
2550         ;;
2551 changequote([,])dnl
2552 esac
2553 if test -z "$tls_first_major"; then
2554   : # If we don't have a check, assume no support.
2555 else
2556   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2557   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2558   [AC_DEFINE(HAVE_AS_TLS, 1,
2559             [Define if your assembler supports thread-local storage.])])
2560 fi
2561
2562 # Target-specific assembler checks.
2563
2564 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2565 gcc_cv_ld_static_dynamic=no
2566 if test $in_tree_ld = yes ; then
2567   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2568     gcc_cv_ld_static_dynamic=yes
2569   fi
2570 elif test x$gcc_cv_ld != x; then
2571         # Check if linker supports -Bstatic/-Bdynamic option
2572         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2573           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2574                 gcc_cv_ld_static_dynamic=yes
2575         fi
2576 fi
2577 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2578         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2579 [Define if your linker supports -Bstatic/-Bdynamic option.])
2580 fi
2581 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2582
2583 if test x"$demangler_in_ld" = xyes; then
2584   AC_MSG_CHECKING(linker --demangle support)
2585   gcc_cv_ld_demangle=no
2586   if test $in_tree_ld = yes; then
2587     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2588       gcc_cv_ld_demangle=yes
2589     fi
2590   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2591     # Check if the GNU linker supports --demangle option
2592     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2593       gcc_cv_ld_demangle=yes
2594     fi
2595   fi
2596   if test x"$gcc_cv_ld_demangle" = xyes; then
2597     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2598 [Define if your linker supports --demangle option.])
2599   fi
2600   AC_MSG_RESULT($gcc_cv_ld_demangle)
2601 fi
2602
2603 case "$target" in
2604   # All TARGET_ABI_OSF targets.
2605   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2606     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2607         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2608 [       .set nomacro
2609         .text
2610         extbl   $3, $2, $3      !lituse_bytoff!1
2611         ldq     $2, a($29)      !literal!1
2612         ldq     $4, b($29)      !literal!2
2613         ldq_u   $3, 0($2)       !lituse_base!1
2614         ldq     $27, f($29)     !literal!5
2615         jsr     $26, ($27), f   !lituse_jsr!5
2616         ldah    $29, 0($26)     !gpdisp!3
2617         lda     $0, c($29)      !gprel
2618         ldah    $1, d($29)      !gprelhigh
2619         lda     $1, d($1)       !gprellow
2620         lda     $29, 0($29)     !gpdisp!3],,
2621     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2622   [Define if your assembler supports explicit relocations.])])
2623     ;;
2624
2625   cris-*-*)
2626     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2627       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2628       [-no-mul-bug-abort], [.text],,
2629       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2630                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2631     ;;
2632
2633   sparc*-*-*)
2634     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2635       [.register %g2, #scratch],,
2636       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2637                 [Define if your assembler supports .register.])])
2638
2639     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2640       [-relax], [.text],,
2641       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2642                 [Define if your assembler supports -relax option.])])
2643
2644     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2645       gcc_cv_as_sparc_ua_pcrel,,
2646       [-K PIC],
2647 [.text
2648 foo:
2649         nop
2650 .data
2651 .align 4
2652 .byte 0
2653 .uaword %r_disp32(foo)],
2654       [if test x$gcc_cv_ld != x \
2655        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2656          gcc_cv_as_sparc_ua_pcrel=yes
2657        fi
2658        rm -f conftest],
2659       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2660                 [Define if your assembler and linker support unaligned PC relative relocs.])
2661
2662       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2663         gcc_cv_as_sparc_ua_pcrel_hidden,,
2664         [-K PIC],
2665 [.data
2666 .align 4
2667 .byte 0x31
2668 .uaword %r_disp32(foo)
2669 .byte 0x32, 0x33, 0x34
2670 .global foo
2671 .hidden foo
2672 foo:
2673 .skip 4],
2674         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2675          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2676          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2677             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2678             if $gcc_cv_objdump -R conftest 2> /dev/null \
2679                | grep 'DISP32' > /dev/null 2>&1; then
2680                 :
2681             else
2682                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2683             fi
2684          fi
2685          rm -f conftest],
2686          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2687                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2688     ]) # unaligned pcrel relocs
2689
2690     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2691       gcc_cv_as_sparc_offsetable_lo10,,
2692       [-xarch=v9],
2693 [.text
2694         or %g1, %lo(ab) + 12, %g1
2695         or %g1, %lo(ab + 12), %g1],
2696       [if test x$gcc_cv_objdump != x \
2697        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2698           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2699          gcc_cv_as_sparc_offsetable_lo10=yes
2700        fi],
2701        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2702                  [Define if your assembler supports offsetable %lo().])])
2703     ;;
2704
2705 changequote(,)dnl
2706   i[34567]86-*-* | x86_64-*-*)
2707 changequote([,])dnl
2708     case $target_os in
2709       cygwin* | pe | mingw32*)
2710         # Used for DWARF 2 in PE
2711         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2712           gcc_cv_as_ix86_pe_secrel32,
2713           [2,15,91],,
2714 [.text
2715 foo:    nop
2716 .data
2717         .secrel32 foo],
2718           [if test x$gcc_cv_ld != x \
2719            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2720              gcc_cv_as_ix86_pe_secrel32=yes
2721            fi
2722            rm -f conftest],
2723           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2724             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2725         ;;
2726     esac
2727
2728     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2729        gcc_cv_as_ix86_filds_fists,
2730       [2,9,0],, [filds mem; fists mem],,
2731       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2732         [Define if your assembler uses the new HImode fild and fist notation.])])
2733
2734     gcc_GAS_CHECK_FEATURE([cmov syntax],
2735       gcc_cv_as_ix86_cmov_sun_syntax,,,
2736       [cmovl.l %edx, %eax],,
2737       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2738         [Define if your assembler supports the Sun syntax for cmov.])])
2739
2740     # This one is used unconditionally by i386.[ch]; it is to be defined
2741     # to 1 if the feature is present, 0 otherwise.
2742     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2743         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2744 [       .text
2745 .L0:
2746         nop
2747         .data
2748         .long .L0@GOTOFF])
2749     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2750       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2751       [Define true if the assembler supports '.long foo@GOTOFF'.])
2752     ;;
2753
2754   ia64*-*-*)
2755     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2756         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2757 [       .text
2758         addl r15 = @ltoffx(x#), gp
2759         ;;
2760         ld8.mov r16 = [[r15]], x#],,
2761     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2762           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2763
2764     ;;
2765
2766   powerpc*-*-*)
2767     case $target in
2768       *-*-aix*) conftest_s='    .csect .text[[PR]]
2769         mfcr 3,128';;
2770       *-*-darwin*)
2771         gcc_GAS_CHECK_FEATURE([.machine directive support],
2772           gcc_cv_as_machine_directive,,,
2773           [     .machine ppc7400])
2774         if test x$gcc_cv_as_machine_directive != xyes; then
2775           echo "*** This target requires an assembler supporting \".machine\"" >&2
2776           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2777           test x$build = x$target && exit 1
2778         fi
2779         conftest_s='    .text
2780         mfcr r3,128';;
2781       *) conftest_s='   .machine power4
2782         .text
2783         mfcr 3,128';;
2784     esac
2785
2786     gcc_GAS_CHECK_FEATURE([mfcr field support],
2787       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2788       [$conftest_s],,
2789       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2790           [Define if your assembler supports mfcr field.])])
2791     ;;
2792
2793   mips*-*-*)
2794     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2795       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2796 [       lw $4,%gp_rel(foo)($4)],,
2797       [if test x$target_cpu_default = x
2798        then target_cpu_default=MASK_EXPLICIT_RELOCS
2799        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2800        fi])
2801
2802     if test x$gas_flag = xyes \
2803        || test x"$host" != x"$build" \
2804        || test ! -x "$gcc_cv_as" \
2805        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2806       :
2807     else
2808       echo "*** This configuration requires the GNU assembler" >&2
2809       exit 1
2810     fi
2811     ;;
2812 esac
2813 # ??? Not all targets support dwarf2 debug_line, even within a version
2814 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2815 # info to the output file.  So, as supported targets are added to gas 2.11,
2816 # add some instruction here to (also) show we expect this might work.
2817 # ??? Once 2.11 is released, probably need to add first known working
2818 # version to the per-target configury.
2819 case "$target" in
2820   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2821   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2822   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2823     insn="nop"
2824     ;;
2825   ia64*-*-* | s390*-*-*)
2826     insn="nop 0"
2827     ;;
2828   mmix-*-*)
2829     insn="swym 0"
2830     ;;
2831 esac
2832 if test x"$insn" != x; then
2833  conftest_s="\
2834         .file 1 \"conftest.s\"
2835         .loc 1 3 0
2836         $insn"
2837  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2838   gcc_cv_as_dwarf2_debug_line,
2839   [elf,2,11,0],, [$conftest_s],
2840   [if test x$gcc_cv_objdump != x \
2841    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2842       | grep debug_line > /dev/null 2>&1; then
2843      gcc_cv_as_dwarf2_debug_line=yes
2844    fi])
2845
2846 # The .debug_line file table must be in the exact order that
2847 # we specified the files, since these indices are also used
2848 # by DW_AT_decl_file.  Approximate this test by testing if
2849 # the assembler bitches if the same index is assigned twice.
2850  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2851   gcc_cv_as_dwarf2_file_buggy,,,
2852 [       .file 1 "foo.s"
2853         .file 1 "bar.s"])
2854
2855  if test $gcc_cv_as_dwarf2_debug_line = yes \
2856  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2857         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2858   [Define if your assembler supports dwarf2 .file/.loc directives,
2859    and preserves file table indices exactly as given.])
2860  fi
2861
2862  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2863   gcc_cv_as_gdwarf2_flag,
2864   [elf,2,11,0], [--gdwarf2], [$insn],,
2865   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2866 [Define if your assembler supports the --gdwarf2 option.])])
2867
2868  gcc_GAS_CHECK_FEATURE([--gstabs option],
2869   gcc_cv_as_gstabs_flag,
2870   [elf,2,11,0], [--gstabs], [$insn],
2871   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2872    # and warns about it, but still exits successfully.  So check for
2873    # this.
2874    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2875    then :
2876    else gcc_cv_as_gstabs_flag=yes
2877    fi],
2878   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2879 [Define if your assembler supports the --gstabs option.])])
2880 fi
2881
2882 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2883 gcc_cv_ld_ro_rw_mix=unknown
2884 if test $in_tree_ld = yes ; then
2885   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2886      && test $in_tree_ld_is_elf = yes; then
2887     gcc_cv_ld_ro_rw_mix=read-write
2888   fi
2889 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2890   echo '.section myfoosect, "a"' > conftest1.s
2891   echo '.section myfoosect, "aw"' > conftest2.s
2892   echo '.byte 1' >> conftest2.s
2893   echo '.section myfoosect, "a"' > conftest3.s
2894   echo '.byte 0' >> conftest3.s
2895   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2896      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2897      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2898      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2899         conftest2.o conftest3.o > /dev/null 2>&1; then
2900     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2901                          | sed -e '/myfoosect/!d' -e N`
2902     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2903       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2904         gcc_cv_ld_ro_rw_mix=read-only
2905       else
2906         gcc_cv_ld_ro_rw_mix=read-write
2907       fi
2908     fi
2909   fi
2910 changequote(,)dnl
2911   rm -f conftest.* conftest[123].*
2912 changequote([,])dnl
2913 fi
2914 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2915         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2916   [Define if your linker links a mix of read-only
2917    and read-write sections into a read-write section.])
2918 fi
2919 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2920
2921 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2922 gcc_cv_ld_eh_frame_hdr=no
2923 if test $in_tree_ld = yes ; then
2924   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2925      && test $in_tree_ld_is_elf = yes; then
2926     gcc_cv_ld_eh_frame_hdr=yes
2927   fi
2928 elif test x$gcc_cv_ld != x; then
2929         # Check if linker supports --eh-frame-hdr option
2930         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2931                 gcc_cv_ld_eh_frame_hdr=yes
2932         fi
2933 fi
2934 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2935         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2936 [Define if your linker supports --eh-frame-hdr option.])
2937 fi
2938 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2939
2940 AC_MSG_CHECKING(linker position independent executable support)
2941 gcc_cv_ld_pie=no
2942 if test $in_tree_ld = yes ; then
2943   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2944      && test $in_tree_ld_is_elf = yes; then
2945     gcc_cv_ld_pie=yes
2946   fi
2947 elif test x$gcc_cv_ld != x; then
2948         # Check if linker supports -pie option
2949         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2950                 gcc_cv_ld_pie=yes
2951         fi
2952 fi
2953 if test x"$gcc_cv_ld_pie" = xyes; then
2954         AC_DEFINE(HAVE_LD_PIE, 1,
2955 [Define if your linker supports -pie option.])
2956 fi
2957 AC_MSG_RESULT($gcc_cv_ld_pie)
2958
2959 # --------
2960 # UNSORTED
2961 # --------
2962
2963 AC_CACHE_CHECK(linker --as-needed support,
2964 gcc_cv_ld_as_needed,
2965 [gcc_cv_ld_as_needed=no
2966 if test $in_tree_ld = yes ; then
2967   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2968      && test $in_tree_ld_is_elf = yes; then
2969     gcc_cv_ld_as_needed=yes
2970   fi
2971 elif test x$gcc_cv_ld != x; then
2972         # Check if linker supports --as-needed and --no-as-needed options
2973         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2974                 gcc_cv_ld_as_needed=yes
2975         fi
2976 fi
2977 ])
2978 if test x"$gcc_cv_ld_as_needed" = xyes; then
2979         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2980 [Define if your linker supports --as-needed and --no-as-needed options.])
2981 fi
2982
2983 case "$target" in
2984   powerpc64*-*-linux*)
2985     AC_CACHE_CHECK(linker support for omitting dot symbols,
2986     gcc_cv_ld_no_dot_syms,
2987     [gcc_cv_ld_no_dot_syms=no
2988     if test $in_tree_ld = yes ; then
2989       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2990         gcc_cv_ld_no_dot_syms=yes
2991       fi
2992     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2993       cat > conftest1.s <<EOF
2994         .text
2995         bl .foo
2996 EOF
2997       cat > conftest2.s <<EOF
2998         .section ".opd","aw"
2999         .align 3
3000         .globl foo
3001         .type foo,@function
3002 foo:
3003         .quad .LEfoo,.TOC.@tocbase,0
3004         .text
3005 .LEfoo:
3006         blr
3007         .size foo,.-.LEfoo
3008 EOF
3009       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3010          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3011          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3012         gcc_cv_ld_no_dot_syms=yes
3013       fi
3014       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3015     fi
3016     ])
3017     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3018       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3019     [Define if your PowerPC64 linker only needs function descriptor syms.])
3020     fi
3021     ;;
3022 esac
3023
3024 if test x$with_sysroot = x && test x$host = x$target \
3025    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3026   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3027 [Define to PREFIX/include if cpp should also search that directory.])
3028 fi
3029
3030 # Find out what GC implementation we want, or may, use.
3031 AC_ARG_WITH(gc,
3032 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3033                           with the compiler],
3034 [case "$withval" in
3035   page)
3036     GGC=ggc-$withval
3037     ;;
3038   zone)
3039     GGC=ggc-$withval
3040     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3041     ;;
3042   *)
3043     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3044     ;;
3045 esac],
3046 [GGC=ggc-page])
3047 AC_SUBST(GGC)
3048 echo "Using $GGC for garbage collection."
3049
3050 # Use the system's zlib library.
3051 zlibdir=-L../zlib
3052 zlibinc="-I\$(srcdir)/../zlib"
3053 AC_ARG_WITH(system-zlib,
3054 [  --with-system-zlib      use installed libz],
3055 zlibdir=
3056 zlibinc=
3057 )
3058 AC_SUBST(zlibdir)
3059 AC_SUBST(zlibinc)
3060
3061 dnl Very limited version of automake's enable-maintainer-mode
3062
3063 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3064   dnl maintainer-mode is disabled by default
3065   AC_ARG_ENABLE(maintainer-mode,
3066 [  --enable-maintainer-mode
3067                           enable make rules and dependencies not useful
3068                           (and sometimes confusing) to the casual installer],
3069       maintainer_mode=$enableval,
3070       maintainer_mode=no)
3071
3072 AC_MSG_RESULT($maintainer_mode)
3073
3074 if test "$maintainer_mode" = "yes"; then
3075   MAINT=''
3076 else
3077   MAINT='#'
3078 fi
3079 AC_SUBST(MAINT)dnl
3080
3081 # --------------
3082 # Language hooks
3083 # --------------
3084
3085 # Make empty files to contain the specs and options for each language.
3086 # Then add #include lines to for a compiler that has specs and/or options.
3087
3088 lang_opt_files=
3089 lang_specs_files=
3090 lang_tree_files=
3091 for subdir in . $subdirs
3092 do
3093         if test -f $srcdir/$subdir/lang.opt; then
3094             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3095         fi
3096         if test -f $srcdir/$subdir/lang-specs.h; then
3097             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3098         fi
3099         if test -f $srcdir/$subdir/$subdir-tree.def; then
3100             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3101         fi
3102 done
3103
3104 # These (without "all_") are set in each config-lang.in.
3105 # `language' must be a single word so is spelled singularly.
3106 all_languages=
3107 all_boot_languages=
3108 all_compilers=
3109 all_stagestuff=
3110 all_outputs='Makefile gccbug mklibgcc libada-mk'
3111 # List of language makefile fragments.
3112 all_lang_makefrags=
3113 # List of language subdirectory makefiles.  Deprecated.
3114 all_lang_makefiles=
3115 # Files for gengtype
3116 all_gtfiles="$target_gtfiles"
3117 # Files for gengtype with language
3118 all_gtfiles_files_langs=
3119 all_gtfiles_files_files=
3120
3121 # Add the language fragments.
3122 # Languages are added via two mechanisms.  Some information must be
3123 # recorded in makefile variables, these are defined in config-lang.in.
3124 # We accumulate them and plug them into the main Makefile.
3125 # The other mechanism is a set of hooks for each of the main targets
3126 # like `clean', `install', etc.
3127
3128 language_hooks="Make-hooks"
3129
3130 for s in $subdirs
3131 do
3132                 language=
3133                 boot_language=
3134                 compilers=
3135                 stagestuff=
3136                 outputs=
3137                 gtfiles=
3138                 . ${srcdir}/$s/config-lang.in
3139                 if test "x$language" = x
3140                 then
3141                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3142                         exit 1
3143                 fi
3144                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3145                 if test -f ${srcdir}/$s/Makefile.in
3146                 then all_lang_makefiles="$s/Makefile"
3147                 fi
3148                 all_languages="$all_languages $language"
3149                 if test "x$boot_language" = xyes
3150                 then
3151                         all_boot_languages="$all_boot_languages $language"
3152                 fi
3153                 all_compilers="$all_compilers $compilers"
3154                 all_stagestuff="$all_stagestuff $stagestuff"
3155                 all_outputs="$all_outputs $outputs"
3156                 all_gtfiles="$all_gtfiles $gtfiles"
3157                 for f in $gtfiles
3158                 do
3159                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3160                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3161                 done
3162 done
3163
3164 # Pick up gtfiles for c
3165 gtfiles=
3166 s="c"
3167 . ${srcdir}/c-config-lang.in
3168 all_gtfiles="$all_gtfiles $gtfiles"
3169 for f in $gtfiles
3170 do
3171         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3172         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3173 done
3174
3175 check_languages=
3176 for language in $all_languages
3177 do
3178                 check_languages="$check_languages check-$language"
3179 done
3180
3181 # We link each language in with a set of hooks, reached indirectly via
3182 # lang.${target}.
3183
3184 rm -f Make-hooks
3185 touch Make-hooks
3186 target_list="all.build all.cross start.encap rest.encap tags \
3187         install-normal install-common install-man \
3188         uninstall info man srcextra srcman srcinfo \
3189         mostlyclean clean distclean maintainer-clean \
3190         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3191 for t in $target_list
3192 do
3193         x=
3194         for lang in $all_languages
3195         do
3196                         x="$x $lang.$t"
3197         done
3198         echo "lang.$t: $x" >> Make-hooks
3199 done
3200
3201 # --------
3202 # UNSORTED
3203 # --------
3204
3205 # Create .gdbinit.
3206
3207 echo "dir ." > .gdbinit
3208 echo "dir ${srcdir}" >> .gdbinit
3209 if test x$gdb_needs_out_file_path = xyes
3210 then
3211         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3212 fi
3213 if test "x$subdirs" != x; then
3214         for s in $subdirs
3215         do
3216                 echo "dir ${srcdir}/$s" >> .gdbinit
3217         done
3218 fi
3219 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3220
3221 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3222 # absolute path for gcc_tooldir based on inserting the number of up-directory
3223 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3224 # $(libsubdir)/@(unlibsubdir) based path.
3225 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3226 # make and thus we'd get different behavior depending on where we built the
3227 # sources.
3228 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3229     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3230 else
3231 changequote(<<, >>)dnl
3232 # An explanation of the sed strings:
3233 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3234 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3235 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3236 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3237 #
3238 # (*) Note this pattern overwrites the first character of the string
3239 # with a forward slash if one is not already present.  This is not a
3240 # problem because the exact names of the sub-directories concerned is
3241 # unimportant, just the number of them matters.
3242 #
3243 # The practical upshot of these patterns is like this:
3244 #
3245 #  prefix     exec_prefix        result
3246 #  ------     -----------        ------
3247 #   /foo        /foo/bar          ../
3248 #   /foo/       /foo/bar          ../
3249 #   /foo        /foo/bar/         ../
3250 #   /foo/       /foo/bar/         ../
3251 #   /foo        /foo/bar/ugg      ../../
3252 #
3253     dollar='$$'
3254     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3255 changequote([, ])dnl
3256 fi
3257 AC_SUBST(gcc_tooldir)
3258 AC_SUBST(dollar)
3259
3260 # Find a directory in which to install a shared libgcc.
3261
3262 AC_ARG_ENABLE(version-specific-runtime-libs,
3263 [  --enable-version-specific-runtime-libs
3264                           specify that runtime libraries should be
3265                           installed in a compiler-specific directory])
3266
3267 AC_ARG_WITH(slibdir,
3268 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3269 slibdir="$with_slibdir",
3270 if test "${enable_version_specific_runtime_libs+set}" = set; then
3271   slibdir='$(libsubdir)'
3272 elif test "$host" != "$target"; then
3273   slibdir='$(build_tooldir)/lib'
3274 else
3275   slibdir='$(libdir)'
3276 fi)
3277 AC_SUBST(slibdir)
3278
3279 objdir=`${PWDCMD-pwd}`
3280 AC_SUBST(objdir)
3281
3282 # Substitute configuration variables
3283 AC_SUBST(subdirs)
3284 AC_SUBST(srcdir)
3285 AC_SUBST(all_boot_languages)
3286 AC_SUBST(all_compilers)
3287 AC_SUBST(all_gtfiles)
3288 AC_SUBST(all_gtfiles_files_langs)
3289 AC_SUBST(all_gtfiles_files_files)
3290 AC_SUBST(all_lang_makefrags)
3291 AC_SUBST(all_lang_makefiles)
3292 AC_SUBST(all_languages)
3293 AC_SUBST(all_stagestuff)
3294 AC_SUBST(build_exeext)
3295 AC_SUBST(build_install_headers_dir)
3296 AC_SUBST(build_xm_file_list)
3297 AC_SUBST(build_xm_include_list)
3298 AC_SUBST(build_xm_defines)
3299 AC_SUBST(check_languages)
3300 AC_SUBST(cc_set_by_configure)
3301 AC_SUBST(quoted_cc_set_by_configure)
3302 AC_SUBST(cpp_install_dir)
3303 AC_SUBST(xmake_file)
3304 AC_SUBST(tmake_file)
3305 AC_SUBST(extra_gcc_objs)
3306 AC_SUBST(extra_headers_list)
3307 AC_SUBST(extra_objs)
3308 AC_SUBST(extra_parts)
3309 AC_SUBST(extra_passes)
3310 AC_SUBST(extra_programs)
3311 AC_SUBST(float_h_file)
3312 AC_SUBST(gcc_config_arguments)
3313 AC_SUBST(gcc_gxx_include_dir)
3314 AC_SUBST(libstdcxx_incdir)
3315 AC_SUBST(host_exeext)
3316 AC_SUBST(host_xm_file_list)
3317 AC_SUBST(host_xm_include_list)
3318 AC_SUBST(host_xm_defines)
3319 AC_SUBST(out_host_hook_obj)
3320 AC_SUBST(install)
3321 AC_SUBST(lang_opt_files)
3322 AC_SUBST(lang_specs_files)
3323 AC_SUBST(lang_tree_files)
3324 AC_SUBST(local_prefix)
3325 AC_SUBST(md_file)
3326 AC_SUBST(objc_boehm_gc)
3327 AC_SUBST(out_file)
3328 AC_SUBST(out_object_file)
3329 AC_SUBST(stage_prefix_set_by_configure)
3330 AC_SUBST(quoted_stage_prefix_set_by_configure)
3331 AC_SUBST(thread_file)
3332 AC_SUBST(tm_file_list)
3333 AC_SUBST(tm_include_list)
3334 AC_SUBST(tm_defines)
3335 AC_SUBST(tm_p_file_list)
3336 AC_SUBST(tm_p_include_list)
3337 AC_SUBST(xm_file_list)
3338 AC_SUBST(xm_include_list)
3339 AC_SUBST(xm_defines)
3340 AC_SUBST(c_target_objs)
3341 AC_SUBST(cxx_target_objs)
3342 AC_SUBST(target_cpu_default)
3343
3344 AC_SUBST_FILE(language_hooks)
3345
3346 # Echo link setup.
3347 if test x${build} = x${host} ; then
3348   if test x${host} = x${target} ; then
3349     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3350   else
3351     echo "Links are now set up to build a cross-compiler" 1>&2
3352     echo " from ${host} to ${target}." 1>&2
3353   fi
3354 else
3355   if test x${host} = x${target} ; then
3356     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3357     echo " for ${target}." 1>&2
3358   else
3359     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3360     echo " from ${host} to ${target}." 1>&2
3361   fi
3362 fi
3363
3364 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3365 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3366
3367 # Configure the subdirectories
3368 # AC_CONFIG_SUBDIRS($subdirs)
3369
3370 # Create the Makefile
3371 # and configure language subdirectories
3372 AC_CONFIG_FILES($all_outputs)
3373
3374 AC_CONFIG_COMMANDS([default],
3375 [
3376 case ${CONFIG_HEADERS} in
3377   *auto-host.h:config.in*)
3378   echo > cstamp-h ;;
3379 esac
3380 # Make sure all the subdirs exist.
3381 for d in $subdirs doc build
3382 do
3383     test -d $d || mkdir $d
3384 done
3385 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3386 # bootstrapping and the installation procedure can still use
3387 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3388 # FLAGS_TO_PASS has been modified to solve the problem there.
3389 # This is virtually a duplicate of what happens in configure.lang; we do
3390 # an extra check to make sure this only happens if ln -s can be used.
3391 case "$LN_S" in
3392   *-s*)
3393     for d in ${subdirs} ; do
3394         STARTDIR=`${PWDCMD-pwd}`
3395         cd $d
3396         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3397         do
3398                 rm -f $t
3399                 $LN_S ../$t $t 2>/dev/null
3400         done
3401         cd $STARTDIR
3402     done
3403   ;;
3404 esac
3405 ],
3406 [subdirs='$subdirs'])
3407 AC_OUTPUT