gcc/ada/s-wchstw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . W C H _ S T W                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.WCh_Con; use System.WCh_Con;
  35 with System.WCh_Cnv; use System.WCh_Cnv;
  36
  37 package body System.WCh_StW is
  38
  39    -----------------------
  40    -- Local Subprograms --
  41    -----------------------
  42
  43    procedure Get_Next_Code
  44      (S  : String;
  45       P  : in out Natural;
  46       V  : out UTF_32_Code;
  47       EM : WC_Encoding_Method);
  48    --  Scans next character starting at S(P) and returns its value in V. On
  49    --  exit P is updated past the last character read. Raises Constraint_Error
  50    --  if the string is not well formed. Raises Constraint_Error if the code
  51    --  value is greater than 16#7FFF_FFFF#. On entry P <= S'Last.
  52
  53    -------------------
  54    -- Get_Next_Code --
  55    -------------------
  56
  57    procedure Get_Next_Code
  58      (S  : String;
  59       P  : in out Natural;
  60       V  : out UTF_32_Code;
  61       EM : WC_Encoding_Method)
  62    is
  63       function In_Char return Character;
  64       --  Function to return a character, bumping P, raises Constraint_Error
  65       --  if P > S'Last on entry.
  66
  67       function Get_UTF_32 is new Char_Sequence_To_UTF_32 (In_Char);
  68       --  Function to get next UFT_32 value
  69
  70       -------------
  71       -- In_Char --
  72       -------------
  73
  74       function In_Char return Character is
  75       begin
  76          if P > S'Last then
  77             raise Constraint_Error with "badly formed wide character code";
  78          else
  79             P := P + 1;
  80             return S (P - 1);
  81          end if;
  82       end In_Char;
  83
  84    --  Start of processing for Get_Next_Code
  85
  86    begin
  87       --  Check for wide character encoding
  88
  89       case EM is
  90          when WCEM_Hex =>
  91             if S (P) = ASCII.ESC then
  92                V := Get_UTF_32 (In_Char, EM);
  93                return;
  94             end if;
  95
  96          when WCEM_Upper | WCEM_Shift_JIS | WCEM_EUC | WCEM_UTF8 =>
  97             if S (P) >= Character'Val (16#80#) then
  98                V := Get_UTF_32 (In_Char, EM);
  99                return;
 100             end if;
 101
 102          when WCEM_Brackets =>
 103             if P + 2 <= S'Last
 104               and then S (P) = '['
 105               and then S (P + 1) = '"'
 106               and then S (P + 2) /= '"'
 107             then
 108                V := Get_UTF_32 (In_Char, EM);
 109                return;
 110             end if;
 111       end case;
 112
 113       --  If it is not a wide character code, just get it
 114
 115       V := Character'Pos (S (P));
 116       P := P + 1;
 117    end Get_Next_Code;
 118
 119    ---------------------------
 120    -- String_To_Wide_String --
 121    ---------------------------
 122
 123    procedure String_To_Wide_String
 124      (S  : String;
 125       R  : out Wide_String;
 126       L  : out Natural;
 127       EM : System.WCh_Con.WC_Encoding_Method)
 128    is
 129       SP : Natural;
 130       V  : UTF_32_Code;
 131
 132    begin
 133       pragma Assert (S'First = 1);
 134
 135       SP := S'First;
 136       L  := 0;
 137       while SP <= S'Last loop
 138          Get_Next_Code (S, SP, V, EM);
 139
 140          if V > 16#FFFF# then
 141             raise Constraint_Error with
 142               "out of range value for wide character";
 143          end if;
 144
 145          L := L + 1;
 146          R (L) := Wide_Character'Val (V);
 147       end loop;
 148    end String_To_Wide_String;
 149
 150    --------------------------------
 151    -- String_To_Wide_Wide_String --
 152    --------------------------------
 153
 154    procedure String_To_Wide_Wide_String
 155      (S  : String;
 156       R  : out Wide_Wide_String;
 157       L  : out Natural;
 158       EM : System.WCh_Con.WC_Encoding_Method)
 159    is
 160       pragma Assert (S'First = 1);
 161
 162       SP : Natural;
 163       V  : UTF_32_Code;
 164
 165    begin
 166       SP := S'First;
 167       L := 0;
 168       while SP <= S'Last loop
 169          Get_Next_Code (S, SP, V, EM);
 170          L := L + 1;
 171          R (L) := Wide_Wide_Character'Val (V);
 172       end loop;
 173    end String_To_Wide_Wide_String;
 174
 175 end System.WCh_StW;