gcc/ada/s-taspri-posix.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                  GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                 S Y S T E M . T A S K _ P R I M I T I V E S              --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --                     Copyright (C) 1995-2008, AdaCore                     --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is a POSIX-like version of this package
  36
  37 --  Note: this file can only be used for POSIX compliant systems
  38
  39 pragma Polling (Off);
  40 --  Turn off polling, we do not want ATC polling to take place during tasking
  41 --  operations. It causes infinite loops and other problems.
  42
  43 with System.OS_Interface;
  44
  45 package System.Task_Primitives is
  46    pragma Preelaborate;
  47
  48    type Lock is limited private;
  49    --  Should be used for implementation of protected objects
  50
  51    type RTS_Lock is limited private;
  52    --  Should be used inside the runtime system. The difference between Lock
  53    --  and the RTS_Lock is that the later one serves only as a semaphore so
  54    --  that do not check for ceiling violations.
  55
  56    type Suspension_Object is limited private;
  57    --  Should be used for the implementation of Ada.Synchronous_Task_Control
  58
  59    type Task_Body_Access is access procedure;
  60    --  Pointer to the task body's entry point (or possibly a wrapper declared
  61    --  local to the GNARL).
  62
  63    type Private_Data is limited private;
  64    --  Any information that the GNULLI needs maintained on a per-task basis.
  65    --  A component of this type is guaranteed to be included in the
  66    --  Ada_Task_Control_Block.
  67
  68    subtype Task_Address is System.Address;
  69    --  In some versions of Task_Primitives, notably for VMS, Task_Address is
  70    --  the short version of address defined in System.Aux_DEC. To avoid
  71    --  dragging Aux_DEC into tasking packages a tasking specific subtype is
  72    --  defined here.
  73
  74    Task_Address_Size : constant := Standard'Address_Size;
  75    --  The size of Task_Address
  76
  77    Alternate_Stack_Size : constant := System.OS_Interface.Alternate_Stack_Size;
  78    --  Import value from System.OS_Interface
  79
  80 private
  81
  82    type Lock is new System.OS_Interface.pthread_mutex_t;
  83    type RTS_Lock is new System.OS_Interface.pthread_mutex_t;
  84
  85    type Suspension_Object is record
  86       State : Boolean;
  87       pragma Atomic (State);
  88       --  Boolean that indicates whether the object is open. This field is
  89       --  marked Atomic to ensure that we can read its value without locking
  90       --  the access to the Suspension_Object.
  91
  92       Waiting : Boolean;
  93       --  Flag showing if there is a task already suspended on this object
  94
  95       L : aliased System.OS_Interface.pthread_mutex_t;
  96       --  Protection for ensuring mutual exclusion on the Suspension_Object
  97
  98       CV : aliased System.OS_Interface.pthread_cond_t;
  99       --  Condition variable used to queue threads until condition is signaled
 100    end record;
 101
 102    type Private_Data is record
 103       Thread : aliased System.OS_Interface.pthread_t;
 104       pragma Atomic (Thread);
 105       --  Thread field may be updated by two different threads of control.
 106       --  (See, Enter_Task and Create_Task in s-taprop.adb). They put the same
 107       --  value (thr_self value). We do not want to use lock on those
 108       --  operations and the only thing we have to make sure is that they are
 109       --  updated in atomic fashion.
 110
 111       LWP : aliased System.Address;
 112       --  The purpose of this field is to provide a better tasking support on
 113       --  gdb. The order of the two first fields (Thread and LWP) is important.
 114       --  On targets where lwp is not relevant, this is equivalent to Thread.
 115
 116       CV : aliased System.OS_Interface.pthread_cond_t;
 117       --  Should be commented ??? (in all versions of taspri)
 118
 119       L : aliased RTS_Lock;
 120       --  Protection for all components is lock L
 121    end record;
 122
 123 end System.Task_Primitives;