gcc/ada/mlib-tgt-specific-vms-alpha.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                    M L I B . T G T . S P E C I F I C                     --
   6 --                           (Alpha VMS Version)                            --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2003-2008, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  20 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This is the Alpha VMS version of the body
  28
  29 with Ada.Characters.Handling; use Ada.Characters.Handling;
  30
  31 with MLib.Fil;
  32 with MLib.Utl;
  33
  34 with MLib.Tgt.VMS_Common;
  35 pragma Warnings (Off, MLib.Tgt.VMS_Common);
  36 --  MLib.Tgt.VMS_Common is with'ed only for elaboration purposes
  37
  38 with Opt;      use Opt;
  39 with Output;   use Output;
  40
  41 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  42
  43 with System;           use System;
  44 with System.Case_Util; use System.Case_Util;
  45 with System.CRTL;      use System.CRTL;
  46
  47 package body MLib.Tgt.Specific is
  48
  49    --  Non default subprogram. See comment in mlib-tgt.ads.
  50
  51    procedure Build_Dynamic_Library
  52      (Ofiles       : Argument_List;
  53       Options      : Argument_List;
  54       Interfaces   : Argument_List;
  55       Lib_Filename : String;
  56       Lib_Dir      : String;
  57       Symbol_Data  : Symbol_Record;
  58       Driver_Name  : Name_Id := No_Name;
  59       Lib_Version  : String  := "";
  60       Auto_Init    : Boolean := False);
  61
  62    --  Local variables
  63
  64    Empty_Argument_List : aliased Argument_List := (1 .. 0 => null);
  65    Additional_Objects  : Argument_List_Access := Empty_Argument_List'Access;
  66    --  Used to add the generated auto-init object files for auto-initializing
  67    --  stand-alone libraries.
  68
  69    Macro_Name : constant String := "mcr gnu:[bin]gcc -c -x assembler";
  70    --  The name of the command to invoke the macro-assembler
  71
  72    VMS_Options : Argument_List := (1 .. 1 => null);
  73
  74    Gnatsym_Name : constant String := "gnatsym";
  75
  76    Gnatsym_Path : String_Access;
  77
  78    Arguments : Argument_List_Access := null;
  79    Last_Argument : Natural := 0;
  80
  81    Success : Boolean := False;
  82
  83    Shared_Libgcc : aliased String := "-shared-libgcc";
  84
  85    Shared_Libgcc_Switch : constant Argument_List :=
  86                             (1 => Shared_Libgcc'Access);
  87
  88    ---------------------------
  89    -- Build_Dynamic_Library --
  90    ---------------------------
  91
  92    procedure Build_Dynamic_Library
  93      (Ofiles       : Argument_List;
  94       Options      : Argument_List;
  95       Interfaces   : Argument_List;
  96       Lib_Filename : String;
  97       Lib_Dir      : String;
  98       Symbol_Data  : Symbol_Record;
  99       Driver_Name  : Name_Id := No_Name;
 100       Lib_Version  : String  := "";
 101       Auto_Init    : Boolean := False)
 102    is
 103
 104       Lib_File : constant String :=
 105                    Lib_Dir & Directory_Separator & "lib" &
 106                    Fil.Ext_To (Lib_Filename, DLL_Ext);
 107
 108       Opts      : Argument_List := Options;
 109       Last_Opt  : Natural       := Opts'Last;
 110       Opts2     : Argument_List (Options'Range);
 111       Last_Opt2 : Natural       := Opts2'First - 1;
 112
 113       Inter : constant Argument_List := Interfaces;
 114
 115       function Is_Interface (Obj_File : String) return Boolean;
 116       --  For a Stand-Alone Library, returns True if Obj_File is the object
 117       --  file name of an interface of the SAL. For other libraries, always
 118       --  return True.
 119
 120       function Option_File_Name return String;
 121       --  Returns Symbol_File, if not empty. Otherwise, returns "symvec.opt"
 122
 123       function Version_String return String;
 124       --  Returns Lib_Version if not empty and if Symbol_Data.Symbol_Policy is
 125       --  not Autonomous, otherwise returns "". When Symbol_Data.Symbol_Policy
 126       --  is Autonomous, fails gnatmake if Lib_Version is not the image of a
 127       --  positive number.
 128
 129       ------------------
 130       -- Is_Interface --
 131       ------------------
 132
 133       function Is_Interface (Obj_File : String) return Boolean is
 134          ALI : constant String :=
 135                  Fil.Ext_To
 136                   (Filename => To_Lower (Base_Name (Obj_File)),
 137                    New_Ext  => "ali");
 138
 139       begin
 140          if Inter'Length = 0 then
 141             return True;
 142
 143          elsif ALI'Length > 2 and then
 144                ALI (ALI'First .. ALI'First + 2) = "b__"
 145          then
 146             return True;
 147
 148          else
 149             for J in Inter'Range loop
 150                if Inter (J).all = ALI then
 151                   return True;
 152                end if;
 153             end loop;
 154
 155             return False;
 156          end if;
 157       end Is_Interface;
 158
 159       ----------------------
 160       -- Option_File_Name --
 161       ----------------------
 162
 163       function Option_File_Name return String is
 164       begin
 165          if Symbol_Data.Symbol_File = No_Path then
 166             return "symvec.opt";
 167          else
 168             Get_Name_String (Symbol_Data.Symbol_File);
 169             To_Lower (Name_Buffer (1 .. Name_Len));
 170             return Name_Buffer (1 .. Name_Len);
 171          end if;
 172       end Option_File_Name;
 173
 174       --------------------
 175       -- Version_String --
 176       --------------------
 177
 178       function Version_String return String is
 179          Version : Integer := 0;
 180
 181       begin
 182          if Lib_Version = ""
 183            or else Symbol_Data.Symbol_Policy /= Autonomous
 184          then
 185             return "";
 186
 187          else
 188             begin
 189                Version := Integer'Value (Lib_Version);
 190
 191                if Version <= 0 then
 192                   raise Constraint_Error;
 193                end if;
 194
 195                return Lib_Version;
 196
 197             exception
 198                when Constraint_Error =>
 199                   Fail ("illegal version """, Lib_Version,
 200                         """ (on VMS version must be a positive number)");
 201                   return "";
 202             end;
 203          end if;
 204       end Version_String;
 205
 206       ---------------------
 207       -- Local Variables --
 208       ---------------------
 209
 210       Opt_File_Name  : constant String := Option_File_Name;
 211       Version        : constant String := Version_String;
 212       For_Linker_Opt : String_Access;
 213
 214    --  Start of processing for Build_Dynamic_Library
 215
 216    begin
 217       --  If option file name does not ends with ".opt", append "/OPTIONS"
 218       --  to its specification for the VMS linker.
 219
 220       if Opt_File_Name'Length > 4
 221         and then
 222           Opt_File_Name (Opt_File_Name'Last - 3 .. Opt_File_Name'Last) = ".opt"
 223       then
 224          For_Linker_Opt := new String'("--for-linker=" & Opt_File_Name);
 225       else
 226          For_Linker_Opt :=
 227            new String'("--for-linker=" & Opt_File_Name & "/OPTIONS");
 228       end if;
 229
 230       VMS_Options (VMS_Options'First) := For_Linker_Opt;
 231
 232       for J in Inter'Range loop
 233          To_Lower (Inter (J).all);
 234       end loop;
 235
 236       --  "gnatsym" is necessary for building the option file
 237
 238       if Gnatsym_Path = null then
 239          Gnatsym_Path := Locate_Exec_On_Path (Gnatsym_Name);
 240
 241          if Gnatsym_Path = null then
 242             Fail (Gnatsym_Name, " not found in path");
 243          end if;
 244       end if;
 245
 246       --  For auto-initialization of a stand-alone library, we create
 247       --  a macro-assembly file and we invoke the macro-assembler.
 248
 249       if Auto_Init then
 250          declare
 251             Macro_File_Name : constant String := Lib_Filename & "__init.asm";
 252             Macro_File      : File_Descriptor;
 253             Init_Proc       : String := Lib_Filename & "INIT";
 254             Popen_Result    : System.Address;
 255             Pclose_Result   : Integer;
 256             Len             : Natural;
 257             OK              : Boolean := True;
 258
 259             command  : constant String :=
 260                          Macro_Name & " " & Macro_File_Name & ASCII.NUL;
 261             --  The command to invoke the assembler on the generated auto-init
 262             --  assembly file.
 263
 264             mode : constant String := "r" & ASCII.NUL;
 265             --  The mode for the invocation of Popen
 266
 267          begin
 268             To_Upper (Init_Proc);
 269
 270             if Verbose_Mode then
 271                Write_Str ("Creating auto-init assembly file """);
 272                Write_Str (Macro_File_Name);
 273                Write_Line ("""");
 274             end if;
 275
 276             --  Create and write the auto-init assembly file
 277
 278             declare
 279                First_Line : constant String :=
 280                               ASCII.HT & ".section LIB$INITIALIZE,GBL,NOWRT" &
 281                ASCII.LF;
 282                Second_Line : constant String :=
 283                                ASCII.HT & ".long " & Init_Proc & ASCII.LF;
 284                --  First and second lines of the auto-init assembly file
 285
 286             begin
 287                Macro_File := Create_File (Macro_File_Name, Text);
 288                OK := Macro_File /= Invalid_FD;
 289
 290                if OK then
 291                   Len := Write
 292                     (Macro_File, First_Line (First_Line'First)'Address,
 293                      First_Line'Length);
 294                   OK := Len = First_Line'Length;
 295                end if;
 296
 297                if OK then
 298                   Len := Write
 299                     (Macro_File, Second_Line (Second_Line'First)'Address,
 300                      Second_Line'Length);
 301                   OK := Len = Second_Line'Length;
 302                end if;
 303
 304                if OK then
 305                   Close (Macro_File, OK);
 306                end if;
 307
 308                if not OK then
 309                   Fail ("creation of auto-init assembly file """,
 310                         Macro_File_Name, """ failed");
 311                end if;
 312             end;
 313
 314             --  Invoke the macro-assembler
 315
 316             if Verbose_Mode then
 317                Write_Str ("Assembling auto-init assembly file """);
 318                Write_Str (Macro_File_Name);
 319                Write_Line ("""");
 320             end if;
 321
 322             Popen_Result := popen (command (command'First)'Address,
 323                                    mode (mode'First)'Address);
 324
 325             if Popen_Result = Null_Address then
 326                Fail ("assembly of auto-init assembly file """,
 327                      Macro_File_Name, """ failed");
 328             end if;
 329
 330             --  Wait for the end of execution of the macro-assembler
 331
 332             Pclose_Result := pclose (Popen_Result);
 333
 334             if Pclose_Result < 0 then
 335                Fail ("assembly of auto init assembly file """,
 336                      Macro_File_Name, """ failed");
 337             end if;
 338
 339             --  Add the generated object file to the list of objects to be
 340             --  included in the library.
 341
 342             Additional_Objects :=
 343               new Argument_List'
 344                 (1 => new String'(Lib_Filename & "__init.obj"));
 345          end;
 346       end if;
 347
 348       --  Allocate the argument list and put the symbol file name, the
 349       --  reference (if any) and the policy (if not autonomous).
 350
 351       Arguments := new Argument_List (1 .. Ofiles'Length + 8);
 352
 353       Last_Argument := 0;
 354
 355       --  Verbosity
 356
 357       if Verbose_Mode then
 358          Last_Argument := Last_Argument + 1;
 359          Arguments (Last_Argument) := new String'("-v");
 360       end if;
 361
 362       --  Version number (major ID)
 363
 364       if Lib_Version /= "" then
 365          Last_Argument := Last_Argument + 1;
 366          Arguments (Last_Argument) := new String'("-V");
 367          Last_Argument := Last_Argument + 1;
 368          Arguments (Last_Argument) := new String'(Version);
 369       end if;
 370
 371       --  Symbol file
 372
 373       Last_Argument := Last_Argument + 1;
 374       Arguments (Last_Argument) := new String'("-s");
 375       Last_Argument := Last_Argument + 1;
 376       Arguments (Last_Argument) := new String'(Opt_File_Name);
 377
 378       --  Reference Symbol File
 379
 380       if Symbol_Data.Reference /= No_Path then
 381          Last_Argument := Last_Argument + 1;
 382          Arguments (Last_Argument) := new String'("-r");
 383          Last_Argument := Last_Argument + 1;
 384          Arguments (Last_Argument) :=
 385            new String'(Get_Name_String (Symbol_Data.Reference));
 386       end if;
 387
 388       --  Policy
 389
 390       case Symbol_Data.Symbol_Policy is
 391          when Autonomous =>
 392             null;
 393
 394          when Compliant =>
 395             Last_Argument := Last_Argument + 1;
 396             Arguments (Last_Argument) := new String'("-c");
 397
 398          when Controlled =>
 399             Last_Argument := Last_Argument + 1;
 400             Arguments (Last_Argument) := new String'("-C");
 401
 402          when Restricted =>
 403             Last_Argument := Last_Argument + 1;
 404             Arguments (Last_Argument) := new String'("-R");
 405
 406          when Direct =>
 407             Last_Argument := Last_Argument + 1;
 408             Arguments (Last_Argument) := new String'("-D");
 409
 410       end case;
 411
 412       --  Add each relevant object file
 413
 414       for Index in Ofiles'Range loop
 415          if Is_Interface (Ofiles (Index).all) then
 416             Last_Argument := Last_Argument + 1;
 417             Arguments (Last_Argument) := new String'(Ofiles (Index).all);
 418          end if;
 419       end loop;
 420
 421       --  Spawn gnatsym
 422
 423       Spawn (Program_Name => Gnatsym_Path.all,
 424              Args         => Arguments (1 .. Last_Argument),
 425              Success      => Success);
 426
 427       if not Success then
 428          Fail ("unable to create symbol file for library """,
 429                Lib_Filename, """");
 430       end if;
 431
 432       Free (Arguments);
 433
 434       --  Move all the -l switches from Opts to Opts2
 435
 436       declare
 437          Index : Natural := Opts'First;
 438          Opt   : String_Access;
 439
 440       begin
 441          while Index <= Last_Opt loop
 442             Opt := Opts (Index);
 443
 444             if Opt'Length > 2 and then
 445               Opt (Opt'First .. Opt'First + 1) = "-l"
 446             then
 447                if Index < Last_Opt then
 448                   Opts (Index .. Last_Opt - 1) :=
 449                     Opts (Index + 1 .. Last_Opt);
 450                end if;
 451
 452                Last_Opt := Last_Opt - 1;
 453
 454                Last_Opt2 := Last_Opt2 + 1;
 455                Opts2 (Last_Opt2) := Opt;
 456
 457             else
 458                Index := Index + 1;
 459             end if;
 460          end loop;
 461       end;
 462
 463       --  Invoke gcc to build the library
 464
 465       Utl.Gcc
 466         (Output_File => Lib_File,
 467          Objects     => Ofiles & Additional_Objects.all,
 468          Options     => VMS_Options,
 469          Options_2   => Shared_Libgcc_Switch &
 470                         Opts (Opts'First .. Last_Opt) &
 471                         Opts2 (Opts2'First .. Last_Opt2),
 472          Driver_Name => Driver_Name);
 473
 474       --  The auto-init object file need to be deleted, so that it will not
 475       --  be included in the library as a regular object file, otherwise
 476       --  it will be included twice when the library will be built next
 477       --  time, which may lead to errors.
 478
 479       if Auto_Init then
 480          declare
 481             Auto_Init_Object_File_Name : constant String :=
 482                                            Lib_Filename & "__init.obj";
 483             Disregard : Boolean;
 484
 485          begin
 486             if Verbose_Mode then
 487                Write_Str ("deleting auto-init object file """);
 488                Write_Str (Auto_Init_Object_File_Name);
 489                Write_Line ("""");
 490             end if;
 491
 492             Delete_File (Auto_Init_Object_File_Name, Success => Disregard);
 493          end;
 494       end if;
 495    end Build_Dynamic_Library;
 496
 497 --  Package initialization
 498
 499 begin
 500    Build_Dynamic_Library_Ptr    := Build_Dynamic_Library'Access;
 501 end MLib.Tgt.Specific;