gcc/ada/a-elchha.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --    A D A . E X C E P T I O N S . L A S T _ C H A N C E _ H A N D L E R   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2003-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Default version for most targets
  35
  36 pragma Warnings (Off);
  37 pragma Compiler_Unit;
  38 pragma Warnings (On);
  39
  40 with System.Standard_Library; use System.Standard_Library;
  41 with System.Soft_Links;
  42
  43 procedure Ada.Exceptions.Last_Chance_Handler
  44   (Except : Exception_Occurrence)
  45 is
  46    procedure Unhandled_Terminate;
  47    pragma No_Return (Unhandled_Terminate);
  48    pragma Import (C, Unhandled_Terminate, "__gnat_unhandled_terminate");
  49    --  Perform system dependent shutdown code
  50
  51    function Exception_Message_Length
  52      (X : Exception_Occurrence) return Natural;
  53    pragma Import (Ada, Exception_Message_Length, "__gnat_exception_msg_len");
  54
  55    procedure Append_Info_Exception_Message
  56      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  57    pragma Import
  58      (Ada, Append_Info_Exception_Message, "__gnat_append_info_e_msg");
  59
  60    procedure Append_Info_Exception_Information
  61      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  62    pragma Import
  63      (Ada, Append_Info_Exception_Information, "__gnat_append_info_e_info");
  64
  65    procedure To_Stderr (S : String);
  66    pragma Import (Ada, To_Stderr, "__gnat_to_stderr");
  67    --  Little routine to output string to stderr
  68
  69    Ptr   : Natural := 0;
  70    Nobuf : String (1 .. 0);
  71
  72    Nline : constant String := String'(1 => ASCII.LF);
  73    --  Convenient shortcut
  74
  75 begin
  76    --  Do not execute any task termination code when shutting down the system.
  77    --  The Adafinal procedure would execute the task termination routine for
  78    --  normal termination, but we have already executed the task termination
  79    --  procedure because of an unhandled exception.
  80
  81    System.Soft_Links.Task_Termination_Handler :=
  82      System.Soft_Links.Task_Termination_NT'Access;
  83
  84    --  Let's shutdown the runtime now. The rest of the procedure needs to be
  85    --  careful not to use anything that would require runtime support. In
  86    --  particular, functions returning strings are banned since the sec stack
  87    --  is no longer functional. This is particularly important to note for the
  88    --  Exception_Information output. We used to allow the tailored version to
  89    --  show up here, which turned out to be a bad idea as it might involve a
  90    --  traceback decorator the length of which we don't control. Potentially
  91    --  heavy primary/secondary stack use or dynamic allocations right before
  92    --  this point are not welcome, moving the output before the finalization
  93    --  raises order of outputs concerns, and decorators are intended to only
  94    --  be used with exception traces, which should have been issued already.
  95
  96    System.Standard_Library.Adafinal;
  97
  98    --  Check for special case of raising _ABORT_SIGNAL, which is not
  99    --  really an exception at all. We recognize this by the fact that
 100    --  it is the only exception whose name starts with underscore.
 101
 102    if To_Ptr (Except.Id.Full_Name) (1) = '_' then
 103       To_Stderr (Nline);
 104       To_Stderr ("Execution terminated by abort of environment task");
 105       To_Stderr (Nline);
 106
 107    --  If no tracebacks, we print the unhandled exception in the old style
 108    --  (i.e. the style used before ZCX was implemented). We do this to
 109    --  retain compatibility.
 110
 111    elsif Except.Num_Tracebacks = 0 then
 112       To_Stderr (Nline);
 113       To_Stderr ("raised ");
 114       To_Stderr
 115         (To_Ptr (Except.Id.Full_Name) (1 .. Except.Id.Name_Length - 1));
 116
 117       if Exception_Message_Length (Except) /= 0 then
 118          To_Stderr (" : ");
 119          Append_Info_Exception_Message (Except, Nobuf, Ptr);
 120       end if;
 121
 122       To_Stderr (Nline);
 123
 124    --  Traceback exists
 125
 126    else
 127       To_Stderr (Nline);
 128       To_Stderr ("Execution terminated by unhandled exception");
 129       To_Stderr (Nline);
 130
 131       Append_Info_Exception_Information (Except, Nobuf, Ptr);
 132    end if;
 133
 134    Unhandled_Terminate;
 135 end Ada.Exceptions.Last_Chance_Handler;