configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-* | amdgcn*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable liboffloadmic on unsupported systems.
 541 if test -d ${srcdir}/liboffloadmic; then
 542     if test x$enable_liboffloadmic != xno; then
 543         AC_MSG_CHECKING([for liboffloadmic support])
 544         if (srcdir=${srcdir}/liboffloadmic; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-liboffloadmic"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable libitm on unsupported systems.
 557 if test -d ${srcdir}/libitm; then
 558     if test x$enable_libitm = x; then
 559         AC_MSG_CHECKING([for libitm support])
 560         if (srcdir=${srcdir}/libitm; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-libitm"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libsanitizer on unsupported systems.
 573 if test -d ${srcdir}/libsanitizer; then
 574     if test x$enable_libsanitizer = x; then
 575         AC_MSG_CHECKING([for libsanitizer support])
 576         if (srcdir=${srcdir}/libsanitizer; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libsanitizer"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libvtv on unsupported systems.
 589 if test -d ${srcdir}/libvtv; then
 590     if test x$enable_libvtv = x; then
 591         AC_MSG_CHECKING([for libvtv support])
 592         if (srcdir=${srcdir}/libvtv; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test "$VTV_SUPPORTED" != "yes")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libvtv"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604
 605 # Disable libhsail-rt on unsupported systems.
 606 if test -d ${srcdir}/libhsail-rt; then
 607     if test x$enable_libhsail_rt = x; then
 608         AC_MSG_CHECKING([for libhsail-rt support])
 609         if (srcdir=${srcdir}/libhsail-rt; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             unsupported_languages="$unsupported_languages brig"
 615             # This implicitly disables also target-libhsail-rt as it won't
 616             # get added to the build without BRIG FE.
 617         else
 618             AC_MSG_RESULT([yes])
 619         fi
 620     fi
 621 fi
 622
 623
 624 # Disable libquadmath for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     noconfigdirs="$noconfigdirs target-libquadmath"
 628     ;;
 629   # libquadmath is unused on AIX and libquadmath build process use of
 630   # LD_LIBRARY_PATH can break AIX bootstrap.
 631   powerpc-*-aix* | rs6000-*-aix*)
 632     noconfigdirs="$noconfigdirs target-libquadmath"
 633     ;;
 634 esac
 635
 636 # Disable libssp for some systems.
 637 case "${target}" in
 638   avr-*-*)
 639     # No hosted I/O support.
 640     noconfigdirs="$noconfigdirs target-libssp"
 641     ;;
 642   bpf-*-*)
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libssp"
 647     ;;
 648   pru-*-*)
 649     # No hosted I/O support.
 650     noconfigdirs="$noconfigdirs target-libssp"
 651     ;;
 652   rl78-*-*)
 653     # libssp uses a misaligned load to trigger a fault, but the RL78
 654     # doesn't fault for those - instead, it gives a build-time error
 655     # for explicit misaligned loads.
 656     noconfigdirs="$noconfigdirs target-libssp"
 657     ;;
 658   visium-*-*)
 659     # No hosted I/O support.
 660     noconfigdirs="$noconfigdirs target-libssp"
 661     ;;
 662 esac
 663
 664 # Disable libstdc++-v3 for some systems.
 665 # Allow user to override this if they pass --enable-libstdc++-v3
 666 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 667   case "${target}" in
 668     *-*-vxworks*)
 669       # VxWorks uses the Dinkumware C++ library.
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     amdgcn*-*-*)
 673       # Not ported/fails to build when using newlib.
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     arm*-wince-pe*)
 677       # the C++ libraries don't build on top of CE's C libraries
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     avr-*-*)
 681       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 682       ;;
 683     bpf-*-*)
 684       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 685       ;;
 686     ft32-*-*)
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689   esac
 690 fi
 691
 692 # Disable C++ on systems where it is known to not work.
 693 # For testing, you can override this with --enable-languages=c++.
 694 case ,${enable_languages}, in
 695   *,c++,*)
 696     ;;
 697   *)
 698       case "${target}" in
 699         bpf-*-*)
 700           unsupported_languages="$unsupported_languages c++"
 701           ;;
 702       esac
 703       ;;
 704 esac
 705
 706 # Disable Objc on systems where it is known to not work.
 707 # For testing, you can override this with --enable-languages=objc.
 708 case ,${enable_languages}, in
 709   *,objc,*)
 710     ;;
 711   *)
 712       case "${target}" in
 713         bpf-*-*)
 714           unsupported_languages="$unsupported_languages objc"
 715           ;;
 716       esac
 717       ;;
 718 esac
 719
 720 # Disable D on systems where it is known to not work.
 721 # For testing, you can override this with --enable-languages=d.
 722 case ,${enable_languages}, in
 723   *,d,*)
 724     ;;
 725   *)
 726     case "${target}" in
 727       *-*-darwin*)
 728         unsupported_languages="$unsupported_languages d"
 729         ;;
 730       bpf-*-*)
 731         unsupported_languages="$unsupported_languages d"
 732         ;;
 733     esac
 734     ;;
 735 esac
 736
 737 # Disable libphobos on unsupported systems.
 738 # For testing, you can override this with --enable-libphobos.
 739 if test -d ${srcdir}/libphobos; then
 740     if test x$enable_libphobos = x; then
 741         AC_MSG_CHECKING([for libphobos support])
 742         if (srcdir=${srcdir}/libphobos; \
 743                 . ${srcdir}/configure.tgt; \
 744                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 745         then
 746             AC_MSG_RESULT([no])
 747             noconfigdirs="$noconfigdirs target-libphobos"
 748         else
 749             AC_MSG_RESULT([yes])
 750         fi
 751     fi
 752 fi
 753
 754 # Disable Fortran for some systems.
 755 case "${target}" in
 756   mmix-*-*)
 757     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 758     unsupported_languages="$unsupported_languages fortran"
 759     ;;
 760   bpf-*-*)
 761     unsupported_languages="$unsupported_languages fortran"
 762     ;;
 763 esac
 764
 765 # Disable libffi for some systems.
 766 case "${target}" in
 767   powerpc-*-darwin*)
 768     ;;
 769   i[[3456789]]86-*-darwin*)
 770     ;;
 771   x86_64-*-darwin[[912]]*)
 772     ;;
 773   *-*-darwin*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-netware*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   *-*-phoenix*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-rtems*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   *-*-tpf*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   *-*-uclinux*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-vxworks*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   aarch64*-*-freebsd*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   alpha*-*-*vms*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   arm*-*-freebsd*)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803   arm-wince-pe)
 804     noconfigdirs="$noconfigdirs target-libffi"
 805     ;;
 806   arm*-*-symbianelf*)
 807     noconfigdirs="$noconfigdirs target-libffi"
 808     ;;
 809   bpf-*-*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   cris-*-* | crisv32-*-*)
 813     case "${target}" in
 814       *-*-linux*)
 815         ;;
 816       *) # See PR46792 regarding target-libffi.
 817         noconfigdirs="$noconfigdirs target-libffi";;
 818     esac
 819     ;;
 820   hppa*64*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   hppa*-hp-hpux11*)
 824     ;;
 825   hppa*-*-hpux*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   ia64*-*-*vms*)
 829     noconfigdirs="$noconfigdirs target-libffi"
 830     ;;
 831   i[[3456789]]86-w64-mingw*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   i[[3456789]]86-*-mingw*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837   x86_64-*-mingw*)
 838     noconfigdirs="$noconfigdirs target-libffi"
 839     ;;
 840   mmix-*-*)
 841     noconfigdirs="$noconfigdirs target-libffi"
 842     ;;
 843   powerpc-*-aix*)
 844     ;;
 845   rs6000-*-aix*)
 846     ;;
 847   ft32-*-*)
 848     noconfigdirs="$noconfigdirs target-libffi"
 849     ;;
 850   *-*-lynxos*)
 851     noconfigdirs="$noconfigdirs target-libffi"
 852     ;;
 853 esac
 854
 855 # Disable the go frontend on systems where it is known to not work. Please keep
 856 # this in sync with contrib/config-list.mk.
 857 case "${target}" in
 858 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 859     unsupported_languages="$unsupported_languages go"
 860     ;;
 861 esac
 862
 863 # Only allow gdbserver on some systems.
 864 if test -d ${srcdir}/gdbserver; then
 865     if test x$enable_gdbserver = x; then
 866         AC_MSG_CHECKING([for gdbserver support])
 867         if (srcdir=${srcdir}/gdbserver; \
 868                 . ${srcdir}/configure.srv; \
 869                 test -n "$UNSUPPORTED")
 870         then
 871             AC_MSG_RESULT([no])
 872             noconfigdirs="$noconfigdirs gdbserver"
 873         else
 874             AC_MSG_RESULT([yes])
 875         fi
 876     fi
 877 fi
 878
 879 # Disable libgo for some systems where it is known to not work.
 880 # For testing, you can easily override this with --enable-libgo.
 881 if test x$enable_libgo = x; then
 882     case "${target}" in
 883     *-*-darwin*)
 884         # PR 46986
 885         noconfigdirs="$noconfigdirs target-libgo"
 886         ;;
 887     *-*-cygwin* | *-*-mingw*)
 888         noconfigdirs="$noconfigdirs target-libgo"
 889         ;;
 890     bpf-*-*)
 891         noconfigdirs="$noconfigdirs target-libgo"
 892         ;;
 893     esac
 894 fi
 895
 896 # Default libgloss CPU subdirectory.
 897 libgloss_dir="$target_cpu"
 898
 899 case "${target}" in
 900   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 901     libgloss_dir=wince
 902     ;;
 903   aarch64*-*-* )
 904     libgloss_dir=aarch64
 905     ;;
 906   arm*-*-*)
 907     libgloss_dir=arm
 908     ;;
 909   cris-*-* | crisv32-*-*)
 910     libgloss_dir=cris
 911     ;;
 912   hppa*-*-*)
 913     libgloss_dir=pa
 914     ;;
 915   i[[3456789]]86-*-*)
 916     libgloss_dir=i386
 917     ;;
 918   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 919     libgloss_dir=m68hc11
 920     ;;
 921   m68*-*-* | fido-*-*)
 922     libgloss_dir=m68k
 923     ;;
 924   mips*-*-*)
 925     libgloss_dir=mips
 926     ;;
 927   powerpc*-*-*)
 928     libgloss_dir=rs6000
 929     ;;
 930   pru-*-*)
 931     libgloss_dir=pru
 932     ;;
 933   sparc*-*-*)
 934     libgloss_dir=sparc
 935     ;;
 936 esac
 937
 938 # Disable newlib and libgloss for various target OSes.
 939 case "${target}" in
 940   alpha*-dec-osf*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   i[[3456789]]86-*-linux*)
 944     # This section makes it possible to build newlib natively on linux.
 945     # If we are using a cross compiler then don't configure newlib.
 946     if test x${is_cross_compiler} != xno ; then
 947       noconfigdirs="$noconfigdirs target-newlib"
 948     fi
 949     noconfigdirs="$noconfigdirs target-libgloss"
 950     # If we are not using a cross compiler, do configure newlib.
 951     # Note however, that newlib will only be configured in this situation
 952     # if the --with-newlib option has been given, because otherwise
 953     # 'target-newlib' will appear in skipdirs.
 954     ;;
 955   i[[3456789]]86-*-rdos*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   sparc-*-sunos4*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   bpf-*-*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-aix*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-beos*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-chorusos)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-dragonfly*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-freebsd*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-lynxos*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-mingw*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netbsd*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-netware*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-tpf*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-uclinux*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003   *-*-vxworks*)
1004     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1005     ;;
1006 esac
1007
1008 case "${target}" in
1009   *-*-chorusos)
1010     ;;
1011   aarch64-*-darwin*)
1012     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1013     noconfigdirs="$noconfigdirs sim target-rda"
1014     ;;
1015   amdgcn*-*-*)
1016     ;;
1017   arm-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   powerpc-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1023     noconfigdirs="$noconfigdirs sim target-rda"
1024     ;;
1025   i[[3456789]]86-*-darwin*)
1026     noconfigdirs="$noconfigdirs ld gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   x86_64-*-darwin[[912]]*)
1030     noconfigdirs="$noconfigdirs ld gas gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   *-*-darwin*)
1034     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1035     noconfigdirs="$noconfigdirs sim target-rda"
1036     ;;
1037   *-*-dragonfly*)
1038     ;;
1039   *-*-freebsd*)
1040     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1041         && test -f /usr/local/include/gmp.h; then
1042       with_gmp=/usr/local
1043     fi
1044     ;;
1045   *-*-kaos*)
1046     # Remove unsupported stuff on all kaOS configurations.
1047     noconfigdirs="$noconfigdirs target-libgloss"
1048     ;;
1049   *-*-netbsd*)
1050     ;;
1051   *-*-netware*)
1052     ;;
1053   *-*-phoenix*)
1054     noconfigdirs="$noconfigdirs target-libgloss"
1055     ;;
1056   *-*-rtems*)
1057     noconfigdirs="$noconfigdirs target-libgloss"
1058     ;;
1059     # The tpf target doesn't support gdb yet.
1060   *-*-tpf*)
1061     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1062     ;;
1063   *-*-uclinux*)
1064     noconfigdirs="$noconfigdirs target-rda"
1065     ;;
1066   *-*-vxworks*)
1067     ;;
1068   alpha*-dec-osf*)
1069     # ld works, but does not support shared libraries.
1070     # gas doesn't generate exception information.
1071     noconfigdirs="$noconfigdirs gas ld"
1072     ;;
1073   alpha*-*-*vms*)
1074     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1075     ;;
1076   alpha*-*-*)
1077     # newlib is not 64 bit ready
1078     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1079     ;;
1080   bpf-*-*)
1081     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1082     ;;
1083   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1084     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1085     ;;
1086   arc*-*-*)
1087     noconfigdirs="$noconfigdirs sim"
1088     ;;
1089   arm-*-pe*)
1090     noconfigdirs="$noconfigdirs target-libgloss"
1091     ;;
1092   arm-*-riscix*)
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   avr-*-*)
1096     if test x${with_avrlibc} != xno; then
1097       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1098     fi
1099     ;;
1100   c4x-*-* | tic4x-*-*)
1101     noconfigdirs="$noconfigdirs target-libgloss"
1102     ;;
1103   tic54x-*-*)
1104     noconfigdirs="$noconfigdirs target-libgloss gdb"
1105     ;;
1106   d10v-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   d30v-*-*)
1110     noconfigdirs="$noconfigdirs gdb"
1111     ;;
1112   fr30-*-elf*)
1113     noconfigdirs="$noconfigdirs gdb"
1114     ;;
1115   ft32-*-*)
1116     noconfigdirs="$noconfigdirs target-rda gprof"
1117     ;;
1118   moxie-*-*)
1119     noconfigdirs="$noconfigdirs"
1120     ;;
1121   h8300*-*-*)
1122     noconfigdirs="$noconfigdirs target-libgloss"
1123     ;;
1124   h8500-*-*)
1125     noconfigdirs="$noconfigdirs target-libgloss"
1126     ;;
1127   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1128     ;;
1129   hppa*64*-*-hpux*)
1130     noconfigdirs="$noconfigdirs gdb"
1131     ;;
1132   hppa*-*-hpux11*)
1133     noconfigdirs="$noconfigdirs gdb ld"
1134     ;;
1135   hppa*64*-*-linux*)
1136     ;;
1137   hppa*-*-linux*)
1138     ;;
1139   hppa*-*-*elf* | \
1140   hppa*-*-lites* | \
1141   hppa*-*-openbsd* | \
1142   hppa*64*-*-*)
1143     ;;
1144   hppa*-*-pro*)
1145     ;;
1146   hppa*-*-*)
1147     noconfigdirs="$noconfigdirs ld"
1148     ;;
1149   i960-*-*)
1150     noconfigdirs="$noconfigdirs gdb"
1151     ;;
1152   ia64*-*-elf*)
1153     # No gdb support yet.
1154     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1155     ;;
1156   ia64*-**-hpux*)
1157     # No ld support yet.
1158     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1159     ;;
1160   ia64*-*-*vms*)
1161     # No ld support yet.
1162     noconfigdirs="$noconfigdirs libgui itcl ld"
1163     ;;
1164   i[[3456789]]86-w64-mingw*)
1165     ;;
1166   i[[3456789]]86-*-mingw*)
1167     target_configdirs="$target_configdirs target-winsup"
1168     ;;
1169   *-*-cygwin*)
1170     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1171     noconfigdirs="$noconfigdirs target-libgloss"
1172     # always build newlib if winsup directory is present.
1173     if test -d "$srcdir/winsup/cygwin"; then
1174       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1175     elif test -d "$srcdir/newlib"; then
1176       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1177     fi
1178     ;;
1179   i[[3456789]]86-*-pe)
1180     noconfigdirs="$noconfigdirs target-libgloss"
1181     ;;
1182   i[[3456789]]86-*-sco3.2v5*)
1183     # The linker does not yet know about weak symbols in COFF,
1184     # and is not configured to handle mixed ELF and COFF.
1185     noconfigdirs="$noconfigdirs ld target-libgloss"
1186     ;;
1187   i[[3456789]]86-*-sco*)
1188     noconfigdirs="$noconfigdirs gprof target-libgloss"
1189     ;;
1190   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1191     noconfigdirs="$noconfigdirs target-libgloss"
1192     ;;
1193   i[[3456789]]86-*-sysv4*)
1194     noconfigdirs="$noconfigdirs target-libgloss"
1195     ;;
1196   i[[3456789]]86-*-beos*)
1197     noconfigdirs="$noconfigdirs gdb"
1198     ;;
1199   i[[3456789]]86-*-rdos*)
1200     noconfigdirs="$noconfigdirs gdb"
1201     ;;
1202   mmix-*-*)
1203     noconfigdirs="$noconfigdirs gdb"
1204     ;;
1205   mt-*-*)
1206     noconfigdirs="$noconfigdirs sim"
1207     ;;
1208   nfp-*-*)
1209     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1210     noconfigdirs="$noconfigdirs $target_libraries"
1211     ;;
1212   pdp11-*-*)
1213     noconfigdirs="$noconfigdirs gdb gprof"
1214     ;;
1215   powerpc-*-aix*)
1216     # copied from rs6000-*-* entry
1217     noconfigdirs="$noconfigdirs gprof"
1218     ;;
1219   powerpc*-*-winnt* | powerpc*-*-pe*)
1220     target_configdirs="$target_configdirs target-winsup"
1221     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1222     # always build newlib.
1223     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1224     ;;
1225     # This is temporary until we can link against shared libraries
1226   powerpcle-*-solaris*)
1227     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1228     ;;
1229   powerpc-*-beos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   rs6000-*-lynxos*)
1233     noconfigdirs="$noconfigdirs gprof"
1234     ;;
1235   rs6000-*-aix*)
1236     noconfigdirs="$noconfigdirs gprof"
1237     ;;
1238   rs6000-*-*)
1239     noconfigdirs="$noconfigdirs gprof"
1240     ;;
1241   m68k-apollo-*)
1242     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1243     ;;
1244   microblaze*)
1245     noconfigdirs="$noconfigdirs gprof"
1246     ;;
1247   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1248     if test x$with_newlib = xyes; then
1249       noconfigdirs="$noconfigdirs gprof"
1250     fi
1251     ;;
1252   mips*-*-irix5*)
1253     noconfigdirs="$noconfigdirs gprof target-libgloss"
1254     ;;
1255   mips*-*-irix6*)
1256     noconfigdirs="$noconfigdirs gprof target-libgloss"
1257     ;;
1258   mips*-*-bsd*)
1259     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1260     ;;
1261   mips*-*-linux*)
1262     ;;
1263   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1264   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1265     noconfigdirs="$noconfigdirs ld gas gprof"
1266     ;;
1267   mips*-*-*)
1268     noconfigdirs="$noconfigdirs gprof"
1269     ;;
1270   nvptx*-*-*)
1271     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1272     ;;
1273   sh-*-*)
1274     case "${target}" in
1275       sh*-*-elf)
1276          ;;
1277       *)
1278          noconfigdirs="$noconfigdirs target-libgloss" ;;
1279     esac
1280     ;;
1281   sparc-*-sunos4*)
1282     if test x${is_cross_compiler} = xno ; then
1283            use_gnu_ld=no
1284     fi
1285     ;;
1286   tic6x-*-*)
1287     noconfigdirs="$noconfigdirs sim"
1288     ;;
1289   tilepro*-*-* | tilegx*-*-*)
1290     noconfigdirs="$noconfigdirs sim"
1291     ;;
1292   v810-*-*)
1293     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1294     ;;
1295   vax-*-*)
1296     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1297     ;;
1298   wasm32-*-*)
1299     noconfigdirs="$noconfigdirs ld"
1300     ;;
1301 esac
1302
1303 # If we aren't building newlib, then don't build libgloss, since libgloss
1304 # depends upon some newlib header files.
1305 case "${noconfigdirs}" in
1306   *target-libgloss*) ;;
1307   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1308 esac
1309
1310 # Work in distributions that contain no compiler tools, like Autoconf.
1311 host_makefile_frag=/dev/null
1312 if test -d ${srcdir}/config ; then
1313 case "${host}" in
1314   i[[3456789]]86-*-msdosdjgpp*)
1315     host_makefile_frag="config/mh-djgpp"
1316     ;;
1317   *-cygwin*)
1318     ACX_CHECK_CYGWIN_CAT_WORKS
1319     host_makefile_frag="config/mh-cygwin"
1320     ;;
1321   *-mingw*)
1322     host_makefile_frag="config/mh-mingw"
1323     ;;
1324   alpha*-linux*)
1325     host_makefile_frag="config/mh-alpha-linux"
1326     ;;
1327   hppa*-hp-hpux10*)
1328     host_makefile_frag="config/mh-pa-hpux10"
1329     ;;
1330   hppa*-hp-hpux*)
1331     host_makefile_frag="config/mh-pa"
1332     ;;
1333   hppa*-*)
1334     host_makefile_frag="config/mh-pa"
1335     ;;
1336   *-*-darwin*)
1337     host_makefile_frag="config/mh-darwin"
1338     ;;
1339   powerpc-*-aix*)
1340     host_makefile_frag="config/mh-ppc-aix"
1341     ;;
1342   rs6000-*-aix*)
1343     host_makefile_frag="config/mh-ppc-aix"
1344     ;;
1345 esac
1346 fi
1347
1348 if test "${build}" != "${host}" ; then
1349   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1350   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1351   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1352   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1353   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1354   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1355   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1356   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1357   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1358   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1359   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1360   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1361   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1362 else
1363   AR_FOR_BUILD="\$(AR)"
1364   AS_FOR_BUILD="\$(AS)"
1365   CC_FOR_BUILD="\$(CC)"
1366   CXX_FOR_BUILD="\$(CXX)"
1367   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1368   GOC_FOR_BUILD="\$(GOC)"
1369   GDC_FOR_BUILD="\$(GDC)"
1370   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1371   LD_FOR_BUILD="\$(LD)"
1372   NM_FOR_BUILD="\$(NM)"
1373   RANLIB_FOR_BUILD="\$(RANLIB)"
1374   WINDRES_FOR_BUILD="\$(WINDRES)"
1375   WINDMC_FOR_BUILD="\$(WINDMC)"
1376 fi
1377
1378 AC_PROG_CC
1379 AC_PROG_CXX
1380
1381 # We must set the default linker to the linker used by gcc for the correct
1382 # operation of libtool.  If LD is not defined and we are using gcc, try to
1383 # set the LD default to the ld used by gcc.
1384 if test -z "$LD"; then
1385   if test "$GCC" = yes; then
1386     case $build in
1387     *-*-mingw*)
1388       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1389     *)
1390       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1391     esac
1392     case $gcc_prog_ld in
1393     # Accept absolute paths.
1394     [[\\/]* | [A-Za-z]:[\\/]*)]
1395       LD="$gcc_prog_ld" ;;
1396     esac
1397   fi
1398 fi
1399
1400 # Check whether -static-libstdc++ -static-libgcc is supported.
1401 have_static_libs=no
1402 if test "$GCC" = yes; then
1403   saved_LDFLAGS="$LDFLAGS"
1404
1405   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1406   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1407   AC_LANG_PUSH(C++)
1408   AC_LINK_IFELSE([AC_LANG_SOURCE([
1409 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1410 #error -static-libstdc++ not implemented
1411 #endif
1412 int main() {}])],
1413     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1414     [AC_MSG_RESULT([no])])
1415   AC_LANG_POP(C++)
1416
1417   LDFLAGS="$saved_LDFLAGS"
1418 fi
1419
1420 ACX_PROG_GNAT
1421 ACX_PROG_CMP_IGNORE_INITIAL
1422
1423 AC_ARG_ENABLE([bootstrap],
1424 [AS_HELP_STRING([--enable-bootstrap],
1425                 [enable bootstrapping @<:@yes if native build@:>@])],,
1426 enable_bootstrap=default)
1427
1428 # Issue errors and warnings for invalid/strange bootstrap combinations.
1429 if test -r $srcdir/gcc/configure; then
1430   have_compiler=yes
1431 else
1432   have_compiler=no
1433 fi
1434
1435 case "$have_compiler:$host:$target:$enable_bootstrap" in
1436   *:*:*:no) ;;
1437
1438   # Default behavior.  Enable bootstrap if we have a compiler
1439   # and we are in a native configuration.
1440   yes:$build:$build:default)
1441     enable_bootstrap=yes ;;
1442
1443   *:*:*:default)
1444     enable_bootstrap=no ;;
1445
1446   # We have a compiler and we are in a native configuration, bootstrap is ok
1447   yes:$build:$build:yes)
1448     ;;
1449
1450   # Other configurations, but we have a compiler.  Assume the user knows
1451   # what he's doing.
1452   yes:*:*:yes)
1453     AC_MSG_WARN([trying to bootstrap a cross compiler])
1454     ;;
1455
1456   # No compiler: if they passed --enable-bootstrap explicitly, fail
1457   no:*:*:yes)
1458     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1459
1460   # Fail if wrong command line
1461   *)
1462     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1463     ;;
1464 esac
1465
1466 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1467 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1468 # require C++11 (or higher).
1469 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1470   CXX="$CXX -std=c++11"
1471 elif test "$have_compiler" = yes; then
1472   AX_CXX_COMPILE_STDCXX(11)
1473 fi
1474
1475 # Used for setting $lt_cv_objdir
1476 _LT_CHECK_OBJDIR
1477
1478 # Check for GMP, MPFR and MPC
1479 gmplibs="-lmpc -lmpfr -lgmp"
1480 gmpinc=
1481 have_gmp=no
1482
1483 # Specify a location for mpc
1484 # check for this first so it ends up on the link line before mpfr.
1485 AC_ARG_WITH(mpc,
1486 [AS_HELP_STRING([--with-mpc=PATH],
1487                 [specify prefix directory for installed MPC package.
1488                  Equivalent to --with-mpc-include=PATH/include
1489                  plus --with-mpc-lib=PATH/lib])])
1490 AC_ARG_WITH(mpc-include,
1491 [AS_HELP_STRING([--with-mpc-include=PATH],
1492                 [specify directory for installed MPC include files])])
1493 AC_ARG_WITH(mpc-lib,
1494 [AS_HELP_STRING([--with-mpc-lib=PATH],
1495                 [specify directory for the installed MPC library])])
1496
1497 if test "x$with_mpc" != x; then
1498   gmplibs="-L$with_mpc/lib $gmplibs"
1499   gmpinc="-I$with_mpc/include $gmpinc"
1500 fi
1501 if test "x$with_mpc_include" != x; then
1502   gmpinc="-I$with_mpc_include $gmpinc"
1503 fi
1504 if test "x$with_mpc_lib" != x; then
1505   gmplibs="-L$with_mpc_lib $gmplibs"
1506 fi
1507 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1508   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1509   gmpinc='-I$$s/mpc/src '"$gmpinc"
1510   # Do not test the mpc version.  Assume that it is sufficient, since
1511   # it is in the source tree, and the library has not been built yet
1512   # but it would be included on the link line in the version check below
1513   # hence making the test fail.
1514   have_gmp=yes
1515 fi
1516
1517 # Specify a location for mpfr
1518 # check for this first so it ends up on the link line before gmp.
1519 AC_ARG_WITH(mpfr-dir,
1520 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1521 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1522 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1523
1524 AC_ARG_WITH(mpfr,
1525 [AS_HELP_STRING([--with-mpfr=PATH],
1526                 [specify prefix directory for installed MPFR package.
1527                  Equivalent to --with-mpfr-include=PATH/include
1528                  plus --with-mpfr-lib=PATH/lib])])
1529 AC_ARG_WITH(mpfr-include,
1530 [AS_HELP_STRING([--with-mpfr-include=PATH],
1531                 [specify directory for installed MPFR include files])])
1532 AC_ARG_WITH(mpfr-lib,
1533 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1534                 [specify directory for the installed MPFR library])])
1535
1536 if test "x$with_mpfr" != x; then
1537   gmplibs="-L$with_mpfr/lib $gmplibs"
1538   gmpinc="-I$with_mpfr/include $gmpinc"
1539 fi
1540 if test "x$with_mpfr_include" != x; then
1541   gmpinc="-I$with_mpfr_include $gmpinc"
1542 fi
1543 if test "x$with_mpfr_lib" != x; then
1544   gmplibs="-L$with_mpfr_lib $gmplibs"
1545 fi
1546 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1547   # MPFR v3.1.0 moved the sources into a src sub-directory.
1548   if ! test -d ${srcdir}/mpfr/src; then
1549     AC_MSG_ERROR([dnl
1550 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1551   fi
1552   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1553   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1554   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1555   # Do not test the mpfr version.  Assume that it is sufficient, since
1556   # it is in the source tree, and the library has not been built yet
1557   # but it would be included on the link line in the version check below
1558   # hence making the test fail.
1559   have_gmp=yes
1560 fi
1561
1562 # Specify a location for gmp
1563 AC_ARG_WITH(gmp-dir,
1564 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1565 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1566 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1567
1568 AC_ARG_WITH(gmp,
1569 [AS_HELP_STRING([--with-gmp=PATH],
1570                 [specify prefix directory for the installed GMP package.
1571                  Equivalent to --with-gmp-include=PATH/include
1572                  plus --with-gmp-lib=PATH/lib])])
1573 AC_ARG_WITH(gmp-include,
1574 [AS_HELP_STRING([--with-gmp-include=PATH],
1575                 [specify directory for installed GMP include files])])
1576 AC_ARG_WITH(gmp-lib,
1577 [AS_HELP_STRING([--with-gmp-lib=PATH],
1578                 [specify directory for the installed GMP library])])
1579
1580
1581 if test "x$with_gmp" != x; then
1582   gmplibs="-L$with_gmp/lib $gmplibs"
1583   gmpinc="-I$with_gmp/include $gmpinc"
1584 fi
1585 if test "x$with_gmp_include" != x; then
1586   gmpinc="-I$with_gmp_include $gmpinc"
1587 fi
1588 if test "x$with_gmp_lib" != x; then
1589   gmplibs="-L$with_gmp_lib $gmplibs"
1590 fi
1591 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1592   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1593   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1594   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1595   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1596   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1597   # Do not test the gmp version.  Assume that it is sufficient, since
1598   # it is in the source tree, and the library has not been built yet
1599   # but it would be included on the link line in the version check below
1600   # hence making the test fail.
1601   have_gmp=yes
1602 fi
1603
1604 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1605   have_gmp=yes
1606   saved_CFLAGS="$CFLAGS"
1607   CFLAGS="$CFLAGS $gmpinc"
1608   # Check for the recommended and required versions of GMP.
1609   AC_MSG_CHECKING([for the correct version of gmp.h])
1610   AC_TRY_COMPILE([#include "gmp.h"],[
1611   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1612   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1613   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1614   choke me
1615   #endif
1616   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1617   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1618   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1619   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1620   choke me
1621   #endif
1622   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1623    [AC_MSG_RESULT([no]); have_gmp=no])
1624
1625   # If we have GMP, check the MPFR version.
1626   if test x"$have_gmp" = xyes; then
1627     # Check for the recommended and required versions of MPFR.
1628     AC_MSG_CHECKING([for the correct version of mpfr.h])
1629     AC_TRY_COMPILE([#include <gmp.h>
1630     #include <mpfr.h>],[
1631     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1632     choke me
1633     #endif
1634     ], [AC_TRY_COMPILE([#include <gmp.h>
1635     #include <mpfr.h>],[
1636     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1637     choke me
1638     #endif
1639     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1640      [AC_MSG_RESULT([no]); have_gmp=no])
1641   fi
1642
1643   # Check for the MPC header version.
1644   if test x"$have_gmp" = xyes ; then
1645     # Check for the recommended and required versions of MPC.
1646     AC_MSG_CHECKING([for the correct version of mpc.h])
1647     AC_TRY_COMPILE([#include <mpc.h>],[
1648     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1649     choke me
1650     #endif
1651     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1652     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1653     choke me
1654     #endif
1655     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1656      [AC_MSG_RESULT([no]); have_gmp=no])
1657   fi
1658
1659   # Now check the MPFR library.
1660   if test x"$have_gmp" = xyes; then
1661     saved_LIBS="$LIBS"
1662     LIBS="$LIBS $gmplibs"
1663     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1664     AC_TRY_LINK([#include <mpc.h>],[
1665     mpfr_t n;
1666     mpfr_t x;
1667     mpc_t c;
1668     int t;
1669     mpfr_init (n);
1670     mpfr_init (x);
1671     mpfr_atan2 (n, n, x, MPFR_RNDN);
1672     mpfr_erfc (n, x, MPFR_RNDN);
1673     mpfr_subnormalize (x, t, MPFR_RNDN);
1674     mpfr_clear(n);
1675     mpfr_clear(x);
1676     mpc_init2 (c, 53);
1677     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1678     mpc_cosh (c, c, MPC_RNDNN);
1679     mpc_pow (c, c, c, MPC_RNDNN);
1680     mpc_acosh (c, c, MPC_RNDNN);
1681     mpc_clear (c);
1682     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1683     LIBS="$saved_LIBS"
1684   fi
1685
1686   CFLAGS="$saved_CFLAGS"
1687
1688 # The library versions listed in the error message below should match
1689 # the HARD-minimums enforced above.
1690   if test x$have_gmp != xyes; then
1691     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1692 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1693 their locations.  Source code for these libraries can be found at
1694 their respective hosting sites as well as at
1695 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1696 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1697 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1698 make sure that you have installed both the libraries and the header
1699 files.  They may be located in separate packages.])
1700   fi
1701 fi
1702
1703 # Flags needed for both GMP, MPFR and/or MPC.
1704 AC_SUBST(gmplibs)
1705 AC_SUBST(gmpinc)
1706 AC_SUBST(extra_mpfr_configure_flags)
1707 AC_SUBST(extra_mpc_gmp_configure_flags)
1708 AC_SUBST(extra_mpc_mpfr_configure_flags)
1709 AC_SUBST(extra_isl_gmp_configure_flags)
1710
1711 # Libraries to use for stage1 or when not bootstrapping.
1712 AC_ARG_WITH(stage1-libs,
1713 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1714 [if test "$withval" = "no" -o "$withval" = "yes"; then
1715    stage1_libs=
1716  else
1717    stage1_libs=$withval
1718  fi],
1719 [stage1_libs=])
1720 AC_SUBST(stage1_libs)
1721
1722 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1723 # default is yes if gcc is being built; no otherwise.  The reason for
1724 # this default is that gdb is sometimes linked against GNU Source
1725 # Highlight, which is a shared library that uses C++ exceptions.  In
1726 # this case, -static-libstdc++ will cause crashes.
1727 AC_ARG_WITH(static-standard-libraries,
1728 [AS_HELP_STRING([--with-static-standard-libraries],
1729                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1730 [], [with_static_standard_libraries=auto])
1731 if test "$with_static_standard_libraries" = auto; then
1732   with_static_standard_libraries=$have_compiler
1733 fi
1734
1735 # Linker flags to use for stage1 or when not bootstrapping.
1736 AC_ARG_WITH(stage1-ldflags,
1737 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1738 [if test "$withval" = "no" -o "$withval" = "yes"; then
1739    stage1_ldflags=
1740  else
1741    stage1_ldflags=$withval
1742  fi],
1743 [stage1_ldflags=
1744  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1745  # if supported.  But if the user explicitly specified the libraries to use,
1746  # trust that they are doing what they want.
1747  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1748      -a "$have_static_libs" = yes; then
1749    stage1_ldflags="-static-libstdc++ -static-libgcc"
1750  fi])
1751 AC_SUBST(stage1_ldflags)
1752
1753 # Libraries to use for stage2 and later builds.
1754 AC_ARG_WITH(boot-libs,
1755 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1756 [if test "$withval" = "no" -o "$withval" = "yes"; then
1757    poststage1_libs=
1758  else
1759    poststage1_libs=$withval
1760  fi],
1761 [poststage1_libs=])
1762 AC_SUBST(poststage1_libs)
1763
1764 # Linker flags to use for stage2 and later builds.
1765 AC_ARG_WITH(boot-ldflags,
1766 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1767                 [linker flags for stage2 and later])],
1768 [if test "$withval" = "no" -o "$withval" = "yes"; then
1769    poststage1_ldflags=
1770  else
1771    poststage1_ldflags=$withval
1772  fi],
1773 [poststage1_ldflags=
1774  # In stages 2 and 3, default to linking libstdc++ and libgcc
1775  # statically.  But if the user explicitly specified the libraries to
1776  # use, trust that they are doing what they want.
1777  if test "$poststage1_libs" = ""; then
1778    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1779  fi])
1780 AC_SUBST(poststage1_ldflags)
1781
1782 # GCC GRAPHITE dependency isl.
1783 # Basic setup is inlined here, actual checks are in config/isl.m4
1784
1785 AC_ARG_WITH(isl,
1786   [AS_HELP_STRING(
1787    [--with-isl=PATH],
1788    [Specify prefix directory for the installed isl package.
1789     Equivalent to --with-isl-include=PATH/include
1790     plus --with-isl-lib=PATH/lib])])
1791
1792 # Treat --without-isl as a request to disable
1793 # GRAPHITE support and skip all following checks.
1794 if test "x$with_isl" != "xno"; then
1795   # Check for isl
1796   dnl Provide configure switches and initialize islinc & isllibs
1797   dnl with user input.
1798   ISL_INIT_FLAGS
1799   dnl The versions of isl that work for Graphite
1800   ISL_CHECK_VERSION()
1801   dnl Only execute fail-action, if isl has been requested.
1802   ISL_IF_FAILED([
1803     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1804 fi
1805
1806 # If the isl check failed, disable builds of in-tree variant of isl
1807 if test "x$with_isl" = xno ||
1808    test "x$gcc_cv_isl" = xno; then
1809   noconfigdirs="$noconfigdirs isl"
1810   islinc=
1811 fi
1812
1813 AC_SUBST(isllibs)
1814 AC_SUBST(islinc)
1815
1816 # Check for LTO support.
1817 AC_ARG_ENABLE(lto,
1818 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1819 enable_lto=$enableval,
1820 enable_lto=yes; default_enable_lto=yes)
1821
1822 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1823   build_lto_plugin=yes
1824 ],[if test x"$default_enable_lto" = x"yes" ; then
1825     case $target in
1826       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1827       # On other non-ELF platforms, LTO has yet to be validated.
1828       *) enable_lto=no ;;
1829     esac
1830   else
1831   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1832   # It would also be nice to check the binutils support, but we don't
1833   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1834   # warn during gcc/ subconfigure; unless you're bootstrapping with
1835   # -flto it won't be needed until after installation anyway.
1836     case $target in
1837       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1838       *) if test x"$enable_lto" = x"yes"; then
1839         AC_MSG_ERROR([LTO support is not enabled for this target.])
1840         fi
1841       ;;
1842     esac
1843   fi
1844   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1845   # Build it unless LTO was explicitly disabled.
1846   case $target in
1847     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1848     *) ;;
1849   esac
1850 ])
1851
1852 AC_ARG_ENABLE(linker-plugin-configure-flags,
1853   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1854     [additional flags for configuring linker plugins @<:@none@:>@])],
1855   extra_linker_plugin_configure_flags=$enableval,
1856   extra_linker_plugin_configure_flags=)
1857 AC_SUBST(extra_linker_plugin_configure_flags)
1858 AC_ARG_ENABLE(linker-plugin-flags,
1859   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1860     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1861   extra_linker_plugin_flags=$enableval,
1862   extra_linker_plugin_flags=)
1863 AC_SUBST(extra_linker_plugin_flags)
1864
1865 # Enable --enable-host-shared.
1866 # Checked early to determine whether jit is an 'all' language
1867 AC_ARG_ENABLE(host-shared,
1868 [AS_HELP_STRING([--enable-host-shared],
1869                 [build host code as shared libraries])],
1870 [host_shared=$enableval], [host_shared=no])
1871 AC_SUBST(host_shared)
1872
1873 # By default, C and C++ are the only stage 1 languages.
1874 stage1_languages=,c,
1875
1876 # Target libraries that we bootstrap.
1877 bootstrap_target_libs=,target-libgcc,
1878
1879 # Figure out what language subdirectories are present.
1880 # Look if the user specified --enable-languages="..."; if not, use
1881 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1882 # go away some day.
1883 # NB:  embedded tabs in this IF block -- do not untabify
1884 if test -d ${srcdir}/gcc; then
1885   if test x"${enable_languages+set}" != xset; then
1886     if test x"${LANGUAGES+set}" = xset; then
1887       enable_languages="${LANGUAGES}"
1888         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1889     else
1890       enable_languages=default
1891     fi
1892   else
1893     if test x"${enable_languages}" = x ||
1894        test x"${enable_languages}" = xyes;
1895        then
1896       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1897       exit 1
1898     fi
1899   fi
1900   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1901
1902   # 'f95' is the old name for the 'fortran' language. We issue a warning
1903   # and make the substitution.
1904   case ,${enable_languages}, in
1905     *,f95,*)
1906       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1907       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1908       ;;
1909   esac
1910
1911   # If bootstrapping, C++ must be enabled.
1912   case ",$enable_languages,:$enable_bootstrap" in
1913     *,c++,*:*) ;;
1914     *:yes)
1915       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1916         enable_languages="${enable_languages},c++"
1917       else
1918         AC_MSG_ERROR([bootstrapping requires c++ sources])
1919       fi
1920       ;;
1921   esac
1922
1923   # First scan to see if an enabled language requires some other language.
1924   # We assume that a given config-lang.in will list all the language
1925   # front ends it requires, even if some are required indirectly.
1926   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1927     case ${lang_frag} in
1928       ..) ;;
1929       # The odd quoting in the next line works around
1930       # an apparent bug in bash 1.12 on linux.
1931       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1932       *)
1933         # From the config-lang.in, get $language, $lang_requires, and
1934         # $lang_requires_boot_languages.
1935         language=
1936         lang_requires=
1937         lang_requires_boot_languages=
1938         # set srcdir during sourcing lang_frag to the gcc dir.
1939         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1940         # polutes this shell
1941         saved_srcdir=${srcdir}
1942         srcdir=${srcdir}/gcc . ${lang_frag}
1943         srcdir=${saved_srcdir}
1944         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1945           case ,${enable_languages}, in
1946             *,$other,*) ;;
1947             *,default,*) ;;
1948             *,all,*) ;;
1949             *,$language,*)
1950               echo " \`$other' language required by \`$language'; enabling" 1>&2
1951               enable_languages="${enable_languages},${other}"
1952               ;;
1953           esac
1954         done
1955         for other in ${lang_requires_boot_languages} ; do
1956           if test "$other" != "c"; then
1957             case ,${enable_stage1_languages}, in
1958               *,$other,*) ;;
1959               *,default,*) ;;
1960               *,all,*) ;;
1961               *)
1962                 case ,${enable_languages}, in
1963                   *,$language,*)
1964                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1965                     enable_stage1_languages="$enable_stage1_languages,${other}"
1966                     ;;
1967                 esac
1968                 ;;
1969             esac
1970           fi
1971         done
1972         ;;
1973     esac
1974   done
1975
1976   new_enable_languages=,c,
1977
1978   # If LTO is enabled, add the LTO front end.
1979   if test "$enable_lto" = "yes" ; then
1980     case ,${enable_languages}, in
1981       *,lto,*) ;;
1982       *) enable_languages="${enable_languages},lto" ;;
1983     esac
1984     if test "${build_lto_plugin}" = "yes" ; then
1985       configdirs="$configdirs lto-plugin"
1986     fi
1987   fi
1988
1989   # If we're building an offloading compiler, add the LTO front end.
1990   if test x"$enable_as_accelerator_for" != x ; then
1991     case ,${enable_languages}, in
1992       *,lto,*) ;;
1993       *) enable_languages="${enable_languages},lto" ;;
1994     esac
1995   fi
1996
1997   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1998   potential_languages=,c,
1999
2000   enabled_target_libs=
2001   disabled_target_libs=
2002
2003   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2004     case ${lang_frag} in
2005       ..) ;;
2006       # The odd quoting in the next line works around
2007       # an apparent bug in bash 1.12 on linux.
2008       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2009       *)
2010         # From the config-lang.in, get $language, $target_libs,
2011         # $lang_dirs, $boot_language, and $build_by_default
2012         language=
2013         target_libs=
2014         lang_dirs=
2015         subdir_requires=
2016         boot_language=no
2017         build_by_default=yes
2018         # set srcdir during sourcing.  See above about save & restore
2019         saved_srcdir=${srcdir}
2020         srcdir=${srcdir}/gcc . ${lang_frag}
2021         srcdir=${saved_srcdir}
2022         if test x${language} = x; then
2023           echo "${lang_frag} doesn't set \$language." 1>&2
2024           exit 1
2025         fi
2026
2027         if test "$language" = "c++"; then
2028           boot_language=yes
2029         fi
2030
2031         add_this_lang=no
2032         # C is always enabled, so no need to add it again
2033         if test "$language" != "c"; then
2034           case ,${enable_languages}, in
2035             *,${language},*)
2036               # Language was explicitly selected; include it
2037               add_this_lang=yes
2038               ;;
2039             *,all,*)
2040               # All languages are enabled
2041               add_this_lang=all
2042               ;;
2043             *,default,*)
2044               # 'default' was selected, select it if it is a default language
2045               add_this_lang=${build_by_default}
2046               ;;
2047           esac
2048         fi
2049
2050         # Disable languages that need other directories if these aren't available.
2051         for i in $subdir_requires; do
2052           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2053           case ${add_this_lang} in
2054             yes)
2055               # Specifically requested language; tell them.
2056               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2057               ;;
2058             all)
2059               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2060               add_this_lang=unsupported
2061               ;;
2062             *)
2063               # Silently disable.
2064               add_this_lang=unsupported
2065               ;;
2066           esac
2067         done
2068
2069         # Disable Ada if no preexisting GNAT is available.
2070         case ${add_this_lang}:${language}:${have_gnat} in
2071           yes:ada:no)
2072             # Specifically requested language; tell them.
2073             AC_MSG_ERROR([GNAT is required to build $language])
2074             ;;
2075           all:ada:no)
2076             AC_MSG_WARN([GNAT is required to build $language])
2077             add_this_lang=unsupported
2078             ;;
2079           *:ada:no)
2080             # Silently disable.
2081             add_this_lang=unsupported
2082             ;;
2083         esac
2084
2085         # Disable jit if -enable-host-shared not specified
2086         # but not if building for Mingw. All code in Windows
2087         # is position independent code (PIC).
2088         case $target in
2089           *mingw*) ;;
2090           *)
2091           case ${add_this_lang}:${language}:${host_shared} in
2092             yes:jit:no)
2093                    # PR jit/64780: explicitly specify --enable-host-shared
2094             AC_MSG_ERROR([
2095 Enabling language "jit" requires --enable-host-shared.
2096
2097 --enable-host-shared typically slows the rest of the compiler down by
2098 a few %, so you must explicitly enable it.
2099
2100 If you want to build both the jit and the regular compiler, it is often
2101 best to do this via two separate configure/builds, in separate
2102 directories, to avoid imposing the performance cost of
2103 --enable-host-shared on the regular compiler.])
2104                     ;;
2105             all:jit:no)
2106               AC_MSG_WARN([--enable-host-shared required to build $language])
2107               add_this_lang=unsupported
2108               ;;
2109             *:jit:no)
2110               # Silently disable.
2111               add_this_lang=unsupported
2112               ;;
2113                 esac
2114           ;;
2115         esac
2116
2117         # Disable a language that is unsupported by the target.
2118         case "${add_this_lang}: $unsupported_languages " in
2119           no:*) ;;
2120           unsupported:*) ;;
2121           *:*" $language "*)
2122             AC_MSG_WARN([${language} not supported for this target])
2123             add_this_lang=unsupported
2124             ;;
2125         esac
2126
2127         case $add_this_lang in
2128           unsupported)
2129             # Remove language-dependent dirs.
2130             disabled_target_libs="$disabled_target_libs $target_libs"
2131             noconfigdirs="$noconfigdirs $lang_dirs"
2132             ;;
2133           no)
2134             # Remove language-dependent dirs; still show language as supported.
2135             disabled_target_libs="$disabled_target_libs $target_libs"
2136             noconfigdirs="$noconfigdirs $lang_dirs"
2137             potential_languages="${potential_languages}${language},"
2138             ;;
2139           all|yes)
2140             new_enable_languages="${new_enable_languages}${language},"
2141             potential_languages="${potential_languages}${language},"
2142             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2143             enabled_target_libs="$enabled_target_libs $target_libs"
2144             case "${boot_language}:,$enable_stage1_languages," in
2145               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2146                 # Add to (comma-separated) list of stage 1 languages.
2147                 case ",$stage1_languages," in
2148                   *,$language,* | ,yes, | ,all,) ;;
2149                   *) stage1_languages="${stage1_languages}${language}," ;;
2150                 esac
2151                 # We need to bootstrap any supporting libraries.
2152                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2153                 ;;
2154             esac
2155             ;;
2156         esac
2157         ;;
2158     esac
2159   done
2160
2161   # Add target libraries which are only needed for disabled languages
2162   # to noconfigdirs.
2163   if test -n "$disabled_target_libs"; then
2164     for dir in $disabled_target_libs; do
2165       case " $enabled_target_libs " in
2166       *" ${dir} "*) ;;
2167       *) noconfigdirs="$noconfigdirs $dir" ;;
2168       esac
2169     done
2170   fi
2171
2172   AC_ARG_ENABLE(stage1-languages,
2173   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2174                   [choose additional languages to build during
2175                   stage1.  Mostly useful for compiler development])],
2176   [case ,${enable_stage1_languages}, in
2177     ,no,|,,)
2178       # Set it to something that will have no effect in the loop below
2179       enable_stage1_languages=c ;;
2180     ,yes,)
2181       enable_stage1_languages=`echo $new_enable_languages | \
2182         sed -e "s/^,//" -e "s/,$//" ` ;;
2183     *,all,*)
2184       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2185         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2186   esac
2187
2188   # Add "good" languages from enable_stage1_languages to stage1_languages,
2189   # while "bad" languages go in missing_languages.  Leave no duplicates.
2190   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2191     case $potential_languages in
2192       *,$i,*)
2193         case $stage1_languages in
2194           *,$i,*) ;;
2195           *) stage1_languages="$stage1_languages$i," ;;
2196         esac ;;
2197       *)
2198         case $missing_languages in
2199           *,$i,*) ;;
2200           *) missing_languages="$missing_languages$i," ;;
2201         esac ;;
2202      esac
2203   done])
2204
2205   # Remove leading/trailing commas that were added for simplicity
2206   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2207   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2208   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2209   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2210
2211   if test "x$missing_languages" != x; then
2212     AC_MSG_ERROR([
2213 The following requested languages could not be built: ${missing_languages}
2214 Supported languages are: ${potential_languages}])
2215   fi
2216   if test "x$new_enable_languages" != "x$enable_languages"; then
2217     echo The following languages will be built: ${new_enable_languages}
2218     enable_languages="$new_enable_languages"
2219   fi
2220
2221   AC_SUBST(stage1_languages)
2222   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2223 fi
2224
2225 # Handle --disable-<component> generically.
2226 for dir in $configdirs $build_configdirs $target_configdirs ; do
2227   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2228   varname=`echo $dirname | sed -e s/+/_/g`
2229   if eval test x\${enable_${varname}} "=" xno ; then
2230     noconfigdirs="$noconfigdirs $dir"
2231   fi
2232 done
2233
2234 # Check for Boehm's garbage collector
2235 AC_ARG_ENABLE(objc-gc,
2236 [AS_HELP_STRING([--enable-objc-gc],
2237                 [enable use of Boehm's garbage collector with the
2238                  GNU Objective-C runtime])])
2239 AC_ARG_WITH([target-bdw-gc],
2240 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2241                 [specify prefix directory for installed bdw-gc package.
2242                  Equivalent to --with-target-bdw-gc-include=PATH/include
2243                  plus --with-target-bdw-gc-lib=PATH/lib])])
2244 AC_ARG_WITH([target-bdw-gc-include],
2245 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2246                 [specify directories for installed bdw-gc include files])])
2247 AC_ARG_WITH([target-bdw-gc-lib],
2248 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2249                 [specify directories for installed bdw-gc library])])
2250
2251 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2252   AC_MSG_CHECKING([for bdw garbage collector])
2253   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2254     dnl no bdw-gw options, assume default locations
2255     AC_MSG_RESULT([using bdw-gc in default locations])
2256   else
2257     dnl bdw-gw options, first error checking, complete checking in libobjc
2258     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2259       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2260     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2261       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2262     else
2263       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2264     fi
2265   fi
2266 esac
2267
2268 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2269 case ,${enable_languages}, in
2270   *,c++,*)
2271     # Disable libitm, libsanitizer if we're not building libstdc++
2272     case "${noconfigdirs}" in
2273       *target-libstdc++-v3*)
2274         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2275         ;;
2276       *) ;;
2277     esac
2278     ;;
2279   *)
2280     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2281     ;;
2282 esac
2283
2284 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2285 # $build_configdirs and $target_configdirs.
2286 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2287
2288 notsupp=""
2289 for dir in . $skipdirs $noconfigdirs ; do
2290   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2291   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2292     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2293     if test -r $srcdir/$dirname/configure ; then
2294       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2295         true
2296       else
2297         notsupp="$notsupp $dir"
2298       fi
2299     fi
2300   fi
2301   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2302     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2303     if test -r $srcdir/$dirname/configure ; then
2304       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2305         true
2306       else
2307         notsupp="$notsupp $dir"
2308       fi
2309     fi
2310   fi
2311   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2312     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2313     if test -r $srcdir/$dirname/configure ; then
2314       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2315         true
2316       else
2317         notsupp="$notsupp $dir"
2318       fi
2319     fi
2320   fi
2321 done
2322
2323 # Quietly strip out all directories which aren't configurable in this tree.
2324 # This relies on all configurable subdirectories being autoconfiscated, which
2325 # is now the case.
2326 build_configdirs_all="$build_configdirs"
2327 build_configdirs=
2328 for i in ${build_configdirs_all} ; do
2329   j=`echo $i | sed -e s/build-//g`
2330   if test -f ${srcdir}/$j/configure ; then
2331     build_configdirs="${build_configdirs} $i"
2332   fi
2333 done
2334
2335 configdirs_all="$configdirs"
2336 configdirs=
2337 for i in ${configdirs_all} ; do
2338   if test -f ${srcdir}/$i/configure ; then
2339     configdirs="${configdirs} $i"
2340   fi
2341 done
2342
2343 target_configdirs_all="$target_configdirs"
2344 target_configdirs=
2345 for i in ${target_configdirs_all} ; do
2346   j=`echo $i | sed -e s/target-//g`
2347   if test -f ${srcdir}/$j/configure ; then
2348     target_configdirs="${target_configdirs} $i"
2349   fi
2350 done
2351
2352 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2353 # so we have to add it after the preceding checks.
2354 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2355 then
2356   case " $configdirs " in
2357     *" libiberty "*)
2358       # If we can build libiberty, we can also build libiberty-linker-plugin.
2359       configdirs="$configdirs libiberty-linker-plugin"
2360       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2361         --with-libiberty=../libiberty-linker-plugin";;
2362     *)
2363       AC_MSG_ERROR([libiberty missing]);;
2364   esac
2365 fi
2366
2367 # Sometimes we have special requirements for the host libiberty.
2368 extra_host_libiberty_configure_flags=
2369 extra_host_zlib_configure_flags=
2370 case " $configdirs " in
2371   *" lto-plugin "* | *" libcc1 "*)
2372     # When these are to be built as shared libraries, the same applies to
2373     # libiberty.
2374     extra_host_libiberty_configure_flags=--enable-shared
2375     ;;
2376   *" bfd "*)
2377     # When bfd is to be built as a shared library, the same applies to
2378     # zlib.
2379     if test "$enable_shared" = "yes"; then
2380       extra_host_zlib_configure_flags=--enable-host-shared
2381     fi
2382     ;;
2383 esac
2384 AC_SUBST(extra_host_libiberty_configure_flags)
2385 AC_SUBST(extra_host_zlib_configure_flags)
2386
2387 # Produce a warning message for the subdirs we can't configure.
2388 # This isn't especially interesting in the Cygnus tree, but in the individual
2389 # FSF releases, it's important to let people know when their machine isn't
2390 # supported by the one or two programs in a package.
2391
2392 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2393   # If $appdirs is non-empty, at least one of those directories must still
2394   # be configured, or we error out.  (E.g., if the gas release supports a
2395   # specified target in some subdirs but not the gas subdir, we shouldn't
2396   # pretend that all is well.)
2397   if test -n "$appdirs" ; then
2398     for dir in $appdirs ; do
2399       if test -r $dir/Makefile.in ; then
2400         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2401           appdirs=""
2402           break
2403         fi
2404         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2405           appdirs=""
2406           break
2407         fi
2408       fi
2409     done
2410     if test -n "$appdirs" ; then
2411       echo "*** This configuration is not supported by this package." 1>&2
2412       exit 1
2413     fi
2414   fi
2415   # Okay, some application will build, or we don't care to check.  Still
2416   # notify of subdirs not getting built.
2417   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2418   echo "    ${notsupp}" 1>&2
2419   echo "    (Any other directories should still work fine.)" 1>&2
2420 fi
2421
2422 case "$host" in
2423   *msdosdjgpp*)
2424     enable_gdbtk=no ;;
2425 esac
2426
2427 # To find our prefix, in gcc_cv_tool_prefix.
2428 ACX_TOOL_DIRS
2429
2430 copy_dirs=
2431
2432 AC_ARG_WITH([build-sysroot],
2433   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2434                   [use sysroot as the system root during the build])],
2435   [if test x"$withval" != x ; then
2436      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2437    fi],
2438   [SYSROOT_CFLAGS_FOR_TARGET=])
2439 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2440
2441 AC_ARG_WITH([debug-prefix-map],
2442   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2443                   [map A to B, C to D ... in debug information])],
2444   [if test x"$withval" != x; then
2445      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2446      for debug_map in $withval; do
2447        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2448      done
2449    fi],
2450   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2451 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2452
2453 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2454 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2455 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2456 # We want to ensure that TARGET libraries (which we know are built with
2457 # gcc) are built with "-O2 -g", so include those options when setting
2458 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2459 if test "x$CFLAGS_FOR_TARGET" = x; then
2460   if test "x${is_cross_compiler}" = xyes; then
2461     CFLAGS_FOR_TARGET="-g -O2"
2462   else
2463     CFLAGS_FOR_TARGET=$CFLAGS
2464     case " $CFLAGS " in
2465       *" -O2 "*) ;;
2466       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2467     esac
2468     case " $CFLAGS " in
2469       *" -g "* | *" -g3 "*) ;;
2470       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2471     esac
2472   fi
2473 fi
2474 AC_SUBST(CFLAGS_FOR_TARGET)
2475
2476 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2477   if test "x${is_cross_compiler}" = xyes; then
2478     CXXFLAGS_FOR_TARGET="-g -O2"
2479   else
2480     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2481     case " $CXXFLAGS " in
2482       *" -O2 "*) ;;
2483       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2484     esac
2485     case " $CXXFLAGS " in
2486       *" -g "* | *" -g3 "*) ;;
2487       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2488     esac
2489   fi
2490 fi
2491 AC_SUBST(CXXFLAGS_FOR_TARGET)
2492
2493 AC_SUBST(LDFLAGS_FOR_TARGET)
2494
2495 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2496 # the named directory are copied to $(tooldir)/sys-include.
2497 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2498   if test x${is_cross_compiler} = xno ; then
2499     echo 1>&2 '***' --with-headers is only supported when cross compiling
2500     exit 1
2501   fi
2502   if test x"${with_headers}" != xyes ; then
2503     x=${gcc_cv_tool_prefix}
2504     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2505   fi
2506 fi
2507
2508 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2509 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2510 # are permitted.
2511 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2512   if test x${is_cross_compiler} = xno ; then
2513     echo 1>&2 '***' --with-libs is only supported when cross compiling
2514     exit 1
2515   fi
2516   if test x"${with_libs}" != xyes ; then
2517     # Copy the libraries in reverse order, so that files in the first named
2518     # library override files in subsequent libraries.
2519     x=${gcc_cv_tool_prefix}
2520     for l in ${with_libs}; do
2521       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2522     done
2523   fi
2524 fi
2525
2526 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2527 #
2528 # This is done by determining whether or not the appropriate directory
2529 # is available, and by checking whether or not specific configurations
2530 # have requested that this magic not happen.
2531 #
2532 # The command line options always override the explicit settings in
2533 # configure.ac, and the settings in configure.ac override this magic.
2534 #
2535 # If the default for a toolchain is to use GNU as and ld, and you don't
2536 # want to do that, then you should use the --without-gnu-as and
2537 # --without-gnu-ld options for the configure script.  Similarly, if
2538 # the default is to use the included zlib and you don't want to do that,
2539 # you should use the --with-system-zlib option for the configure script.
2540
2541 if test x${use_gnu_as} = x &&
2542    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2543   with_gnu_as=yes
2544   extra_host_args="$extra_host_args --with-gnu-as"
2545 fi
2546
2547 if test x${use_gnu_ld} = x &&
2548    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2549   with_gnu_ld=yes
2550   extra_host_args="$extra_host_args --with-gnu-ld"
2551 fi
2552
2553 if test x${use_included_zlib} = x &&
2554    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2555   :
2556 else
2557   with_system_zlib=yes
2558   extra_host_args="$extra_host_args --with-system-zlib"
2559 fi
2560
2561 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2562 # can detect this case.
2563
2564 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2565   with_newlib=yes
2566   extra_host_args="$extra_host_args --with-newlib"
2567 fi
2568
2569 # Handle ${copy_dirs}
2570 set fnord ${copy_dirs}
2571 shift
2572 while test $# != 0 ; do
2573   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2574     :
2575   else
2576     echo Copying $1 to $2
2577
2578     # Use the install script to create the directory and all required
2579     # parent directories.
2580     if test -d $2 ; then
2581       :
2582     else
2583       echo >config.temp
2584       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2585     fi
2586
2587     # Copy the directory, assuming we have tar.
2588     # FIXME: Should we use B in the second tar?  Not all systems support it.
2589     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2590
2591     # It is the responsibility of the user to correctly adjust all
2592     # symlinks.  If somebody can figure out how to handle them correctly
2593     # here, feel free to add the code.
2594
2595     echo $1 > $2/COPIED
2596   fi
2597   shift; shift
2598 done
2599
2600 # Determine a target-dependent exec_prefix that the installed
2601 # gcc will search in.  Keep this list sorted by triplet, with
2602 # the *-*-osname triplets last.
2603 md_exec_prefix=
2604 case "${target}" in
2605   i[[34567]]86-pc-msdosdjgpp*)
2606     md_exec_prefix=/dev/env/DJDIR/bin
2607     ;;
2608   *-*-hpux* | \
2609   *-*-nto-qnx* | \
2610   *-*-solaris2*)
2611     md_exec_prefix=/usr/ccs/bin
2612     ;;
2613 esac
2614
2615 extra_arflags_for_target=
2616 extra_nmflags_for_target=
2617 extra_ranlibflags_for_target=
2618 target_makefile_frag=/dev/null
2619 case "${target}" in
2620   spu-*-*)
2621     target_makefile_frag="config/mt-spu"
2622     ;;
2623   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2624     target_makefile_frag="config/mt-sde"
2625     ;;
2626   mipsisa*-*-elfoabi*)
2627     target_makefile_frag="config/mt-mips-elfoabi"
2628     ;;
2629   mips*-*-*linux* | mips*-*-gnu*)
2630     target_makefile_frag="config/mt-mips-gnu"
2631     ;;
2632   nios2-*-elf*)
2633     target_makefile_frag="config/mt-nios2-elf"
2634     ;;
2635   *-*-linux-android*)
2636     target_makefile_frag="config/mt-android"
2637     ;;
2638   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2639     target_makefile_frag="config/mt-gnu"
2640     ;;
2641   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2642     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2643     # commands to handle both 32-bit and 64-bit objects.  These flags are
2644     # harmless if we're using GNU nm or ar.
2645     extra_arflags_for_target=" -X32_64"
2646     extra_nmflags_for_target=" -B -X32_64"
2647     ;;
2648 esac
2649
2650 alphaieee_frag=/dev/null
2651 case $target in
2652   alpha*-*-*)
2653     # This just makes sure to use the -mieee option to build target libs.
2654     # This should probably be set individually by each library.
2655     alphaieee_frag="config/mt-alphaieee"
2656     ;;
2657 esac
2658
2659 # If --enable-target-optspace always use -Os instead of -O2 to build
2660 # the target libraries, similarly if it is not specified, use -Os
2661 # on selected platforms.
2662 ospace_frag=/dev/null
2663 case "${enable_target_optspace}:${target}" in
2664   yes:*)
2665     ospace_frag="config/mt-ospace"
2666     ;;
2667   :d30v-*)
2668     ospace_frag="config/mt-d30v"
2669     ;;
2670   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2671     ospace_frag="config/mt-ospace"
2672     ;;
2673   no:* | :*)
2674     ;;
2675   *)
2676     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2677     ;;
2678 esac
2679
2680 # Some systems (e.g., one of the i386-aix systems the gas testers are
2681 # using) don't handle "\$" correctly, so don't use it here.
2682 tooldir='${exec_prefix}'/${target_noncanonical}
2683 build_tooldir=${tooldir}
2684
2685 # Create a .gdbinit file which runs the one in srcdir
2686 # and tells GDB to look there for source files.
2687
2688 if test -r ${srcdir}/.gdbinit ; then
2689   case ${srcdir} in
2690     .) ;;
2691     *) cat > ./.gdbinit <<EOF
2692 # ${NO_EDIT}
2693 dir ${srcdir}
2694 dir .
2695 source ${srcdir}/.gdbinit
2696 EOF
2697     ;;
2698   esac
2699 fi
2700
2701 # Make sure that the compiler is able to generate an executable.  If it
2702 # can't, we are probably in trouble.  We don't care whether we can run the
2703 # executable--we might be using a cross compiler--we only care whether it
2704 # can be created.  At this point the main configure script has set CC.
2705 we_are_ok=no
2706 echo "int main () { return 0; }" > conftest.c
2707 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2708 if test $? = 0 ; then
2709   if test -s conftest || test -s conftest.exe ; then
2710     we_are_ok=yes
2711   fi
2712 fi
2713 case $we_are_ok in
2714   no)
2715     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2716     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2717     rm -f conftest*
2718     exit 1
2719     ;;
2720 esac
2721 rm -f conftest*
2722
2723 # Decide which environment variable is used to find dynamic libraries.
2724 case "${host}" in
2725   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2726   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2727   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2728   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2729 esac
2730
2731 # On systems where the dynamic library environment variable is PATH,
2732 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2733 # built executables to PATH.
2734 if test "$RPATH_ENVVAR" = PATH; then
2735   GCC_SHLIB_SUBDIR=/shlib
2736 else
2737   GCC_SHLIB_SUBDIR=
2738 fi
2739
2740 # Adjust the toplevel makefile according to whether bootstrap was selected.
2741 case $enable_bootstrap in
2742   yes)
2743     bootstrap_suffix=bootstrap
2744     BUILD_CONFIG=bootstrap-debug
2745     ;;
2746   no)
2747     bootstrap_suffix=no-bootstrap
2748     BUILD_CONFIG=
2749     ;;
2750 esac
2751
2752 AC_MSG_CHECKING(for default BUILD_CONFIG)
2753
2754 AC_ARG_WITH([build-config],
2755   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2756                   [use config/NAME.mk build configuration])],
2757   [case $with_build_config in
2758    yes) with_build_config= ;;
2759    no) with_build_config= BUILD_CONFIG= ;;
2760    esac])
2761
2762 if test "x${with_build_config}" != x; then
2763   BUILD_CONFIG=$with_build_config
2764 else
2765   case $BUILD_CONFIG in
2766   bootstrap-debug)
2767     if echo "int f (void) { return 0; }" > conftest.c &&
2768        ${CC} -c conftest.c &&
2769        mv conftest.o conftest.o.g0 &&
2770        ${CC} -c -g conftest.c &&
2771        mv conftest.o conftest.o.g &&
2772        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2773       :
2774     else
2775       BUILD_CONFIG=
2776     fi
2777     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2778     ;;
2779   esac
2780 fi
2781 AC_MSG_RESULT($BUILD_CONFIG)
2782 AC_SUBST(BUILD_CONFIG)
2783
2784 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2785 AC_MSG_CHECKING([for --enable-vtable-verify])
2786 AC_ARG_ENABLE(vtable-verify,
2787 [AS_HELP_STRING([--enable-vtable-verify],
2788                 [Enable vtable verification feature])],
2789 [case "$enableval" in
2790  yes) enable_vtable_verify=yes ;;
2791  no)  enable_vtable_verify=no ;;
2792  *)   enable_vtable_verify=no;;
2793  esac],
2794 [enable_vtable_verify=no])
2795 AC_MSG_RESULT($enable_vtable_verify)
2796
2797 # Record target_configdirs and the configure arguments for target and
2798 # build configuration in Makefile.
2799 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2800 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2801 bootstrap_fixincludes=no
2802
2803 # If we are building libgomp, bootstrap it.
2804 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2805   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2806 fi
2807
2808 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2809 # or bootstrap-ubsan, bootstrap it.
2810 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2811   case "$BUILD_CONFIG" in
2812     *bootstrap-asan* | *bootstrap-ubsan* )
2813       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2814       bootstrap_fixincludes=yes
2815       ;;
2816   esac
2817 fi
2818
2819 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2820 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2821    test "$enable_vtable_verify" != no; then
2822   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2823 fi
2824
2825 # Determine whether gdb needs tk/tcl or not.
2826 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2827 # and in that case we want gdb to be built without tk.  Ugh!
2828 # In fact I believe gdb is the *only* package directly dependent on tk,
2829 # so we should be able to put the 'maybe's in unconditionally and
2830 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2831 # 100% sure that that's safe though.
2832
2833 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2834 case "$enable_gdbtk" in
2835   no)
2836     GDB_TK="" ;;
2837   yes)
2838     GDB_TK="${gdb_tk}" ;;
2839   *)
2840     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2841     # distro.  Eventually someone will fix this and move Insight, nee
2842     # gdbtk to a separate directory.
2843     if test -d ${srcdir}/gdb/gdbtk ; then
2844       GDB_TK="${gdb_tk}"
2845     else
2846       GDB_TK=""
2847     fi
2848     ;;
2849 esac
2850 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2851 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2852
2853 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2854 # else does, only include them if one of these is built.  The Makefile
2855 # provides the ordering, so it's enough here to add to the list.
2856 case " ${configdirs} " in
2857   *\ gdb\ *)
2858     configdirs="${configdirs} gnulib gdbsupport"
2859     ;;
2860   *\ gdbserver\ *)
2861     configdirs="${configdirs} gnulib gdbsupport"
2862     ;;
2863 esac
2864
2865 # Strip out unwanted targets.
2866
2867 # While at that, we remove Makefiles if we were started for recursive
2868 # configuration, so that the top-level Makefile reconfigures them,
2869 # like we used to do when configure itself was recursive.
2870
2871 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2872 # but now we're fixing up the Makefile ourselves with the additional
2873 # commands passed to AC_CONFIG_FILES.  Use separate variables
2874 # extrasub-{build,host,target} not because there is any reason to split
2875 # the substitutions up that way, but only to remain below the limit of
2876 # 99 commands in a script, for HP-UX sed.
2877
2878 # Do not nest @if/@endif or @unless/@endunless pairs, because
2879 # configure will not warn you at all.
2880
2881 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2882   yes:yes:*\ gold\ *:*,c++,*) ;;
2883   yes:yes:*\ gold\ *:*)
2884     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2885     ;;
2886 esac
2887
2888 extrasub_build=
2889 for module in ${build_configdirs} ; do
2890   if test -z "${no_recursion}" \
2891      && test -f ${build_subdir}/${module}/Makefile; then
2892     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2893     rm -f ${build_subdir}/${module}/Makefile
2894   fi
2895   extrasub_build="$extrasub_build
2896 /^@if build-$module\$/d
2897 /^@endif build-$module\$/d
2898 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2899 /^@if build-$module-$bootstrap_suffix\$/d
2900 /^@endif build-$module-$bootstrap_suffix\$/d
2901 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2902 done
2903 extrasub_host=
2904 for module in ${configdirs} ; do
2905   if test -z "${no_recursion}"; then
2906     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2907       if test -f ${file}; then
2908         echo 1>&2 "*** removing ${file} to force reconfigure"
2909         rm -f ${file}
2910       fi
2911     done
2912   fi
2913   case ${module},${bootstrap_fixincludes} in
2914     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2915     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2916   esac
2917   extrasub_host="$extrasub_host
2918 /^@if $module\$/d
2919 /^@endif $module\$/d
2920 /^@unless $module\$/,/^@endunless $module\$/d
2921 /^@if $module-$host_bootstrap_suffix\$/d
2922 /^@endif $module-$host_bootstrap_suffix\$/d
2923 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2924 done
2925 extrasub_target=
2926 for module in ${target_configdirs} ; do
2927   if test -z "${no_recursion}" \
2928      && test -f ${target_subdir}/${module}/Makefile; then
2929     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2930     rm -f ${target_subdir}/${module}/Makefile
2931   fi
2932
2933   # We only bootstrap target libraries listed in bootstrap_target_libs.
2934   case $bootstrap_target_libs in
2935     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2936     *) target_bootstrap_suffix=no-bootstrap ;;
2937   esac
2938
2939   extrasub_target="$extrasub_target
2940 /^@if target-$module\$/d
2941 /^@endif target-$module\$/d
2942 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2943 /^@if target-$module-$target_bootstrap_suffix\$/d
2944 /^@endif target-$module-$target_bootstrap_suffix\$/d
2945 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2946 done
2947
2948 # Do the final fixup along with target modules.
2949 extrasub_target="$extrasub_target
2950 /^@if /,/^@endif /d
2951 /^@unless /d
2952 /^@endunless /d"
2953
2954 # Create the serialization dependencies.  This uses a temporary file.
2955
2956 AC_ARG_ENABLE([serial-configure],
2957 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2958                 [force sequential configuration of
2959                  sub-packages for the host, target or build
2960                  machine, or all sub-packages])])
2961
2962 case ${enable_serial_configure} in
2963   yes)
2964     enable_serial_build_configure=yes
2965     enable_serial_host_configure=yes
2966     enable_serial_target_configure=yes
2967     ;;
2968 esac
2969
2970 # These force 'configure's to be done one at a time, to avoid problems
2971 # with contention over a shared config.cache.
2972 rm -f serdep.tmp
2973 echo '# serdep.tmp' > serdep.tmp
2974 olditem=
2975 test "x${enable_serial_build_configure}" = xyes &&
2976 for item in ${build_configdirs} ; do
2977   case ${olditem} in
2978     "") ;;
2979     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2980   esac
2981   olditem=${item}
2982 done
2983 olditem=
2984 test "x${enable_serial_host_configure}" = xyes &&
2985 for item in ${configdirs} ; do
2986   case ${olditem} in
2987     "") ;;
2988     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2989   esac
2990   olditem=${item}
2991 done
2992 olditem=
2993 test "x${enable_serial_target_configure}" = xyes &&
2994 for item in ${target_configdirs} ; do
2995   case ${olditem} in
2996     "") ;;
2997     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2998   esac
2999   olditem=${item}
3000 done
3001 serialization_dependencies=serdep.tmp
3002 AC_SUBST_FILE(serialization_dependencies)
3003
3004 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3005 # target, nonopt, and variable assignments.  These are the ones we
3006 # might not want to pass down to subconfigures.  The exception being
3007 # --cache-file=/dev/null, which is used to turn off the use of cache
3008 # files altogether, and which should be passed on to subconfigures.
3009 # Also strip program-prefix, program-suffix, and program-transform-name,
3010 # so that we can pass down a consistent program-transform-name.
3011 baseargs=
3012 tbaseargs=
3013 keep_next=no
3014 skip_next=no
3015 eval "set -- $ac_configure_args"
3016 for ac_arg
3017 do
3018   if test X"$skip_next" = X"yes"; then
3019     skip_next=no
3020     continue
3021   fi
3022   if test X"$keep_next" = X"yes"; then
3023     case $ac_arg in
3024       *\'*)
3025         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3026     esac
3027     baseargs="$baseargs '$ac_arg'"
3028     tbaseargs="$tbaseargs '$ac_arg'"
3029     keep_next=no
3030     continue
3031   fi
3032
3033   # Handle separated arguments.  Based on the logic generated by
3034   # autoconf 2.59.
3035   case $ac_arg in
3036     *=* | --config-cache | -C | -disable-* | --disable-* \
3037       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3038       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3039       | -with-* | --with-* | -without-* | --without-* | --x)
3040       separate_arg=no
3041       ;;
3042     -*)
3043       separate_arg=yes
3044       ;;
3045     *)
3046       separate_arg=no
3047       ;;
3048   esac
3049
3050   skip_targ=no
3051   case $ac_arg in
3052 changequote(,)
3053   --with-* | --without-*)
3054     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3055
3056     case $libopt in
3057     *[-_]include)
3058       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3059       ;;
3060     *[-_]lib)
3061       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3062       ;;
3063     *)
3064       lib=$libopt
3065       ;;
3066     esac
3067 changequote([,])
3068
3069     case $lib in
3070     mpc | mpfr | gmp | isl)
3071       # If we're processing --with-$lib, --with-$lib-include or
3072       # --with-$lib-lib, for one of the libs above, and target is
3073       # different from host, don't pass the current argument to any
3074       # target library's configure.
3075       if test x$is_cross_compiler = xyes; then
3076         skip_targ=yes
3077       fi
3078       ;;
3079     esac
3080     ;;
3081   esac
3082
3083   case "$ac_arg" in
3084     --cache-file=/dev/null | \
3085     -cache-file=/dev/null )
3086       # Handled here to avoid the test to skip args below.
3087       baseargs="$baseargs '$ac_arg'"
3088       tbaseargs="$tbaseargs '$ac_arg'"
3089       # Assert: $separate_arg should always be no.
3090       keep_next=$separate_arg
3091       ;;
3092     --no*)
3093       continue
3094       ;;
3095     --c* | \
3096     --sr* | \
3097     --ho* | \
3098     --bu* | \
3099     --t* | \
3100     --program-* | \
3101     -cache_file* | \
3102     -srcdir* | \
3103     -host* | \
3104     -build* | \
3105     -target* | \
3106     -program-prefix* | \
3107     -program-suffix* | \
3108     -program-transform-name* )
3109       skip_next=$separate_arg
3110       continue
3111       ;;
3112     -*)
3113       # An option.  Add it.
3114       case $ac_arg in
3115         *\'*)
3116           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3117       esac
3118       baseargs="$baseargs '$ac_arg'"
3119       if test X"$skip_targ" = Xno; then
3120         tbaseargs="$tbaseargs '$ac_arg'"
3121       fi
3122       keep_next=$separate_arg
3123       ;;
3124     *)
3125       # Either a variable assignment, or a nonopt (triplet).  Don't
3126       # pass it down; let the Makefile handle this.
3127       continue
3128       ;;
3129   esac
3130 done
3131 # Remove the initial space we just introduced and, as these will be
3132 # expanded by make, quote '$'.
3133 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3134
3135 # Add in --program-transform-name, after --program-prefix and
3136 # --program-suffix have been applied to it.  Autoconf has already
3137 # doubled dollar signs and backslashes in program_transform_name; we want
3138 # the backslashes un-doubled, and then the entire thing wrapped in single
3139 # quotes, because this will be expanded first by make and then by the shell.
3140 # Also, because we want to override the logic in subdir configure scripts to
3141 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3142 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3143 ${program_transform_name}
3144 EOF_SED
3145 gcc_transform_name=`cat conftestsed.out`
3146 rm -f conftestsed.out
3147 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3148 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3149 if test "$silent" = yes; then
3150   baseargs="$baseargs --silent"
3151   tbaseargs="$tbaseargs --silent"
3152 fi
3153 baseargs="$baseargs --disable-option-checking"
3154 tbaseargs="$tbaseargs --disable-option-checking"
3155
3156 # Record and document user additions to sub configure arguments.
3157 AC_ARG_VAR([build_configargs],
3158            [additional configure arguments for build directories])
3159 AC_ARG_VAR([host_configargs],
3160            [additional configure arguments for host directories])
3161 AC_ARG_VAR([target_configargs],
3162            [additional configure arguments for target directories])
3163
3164 # For the build-side libraries, we just need to pretend we're native,
3165 # and not use the same cache file.  Multilibs are neither needed nor
3166 # desired.  We can't even use the same cache file for all build-side
3167 # libraries, as they're compiled differently; some with C, some with
3168 # C++ or with different feature-enabling options.
3169 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3170
3171 # For host modules, accept cache file option, or specification as blank.
3172 case "${cache_file}" in
3173 "") # empty
3174   cache_file_option="" ;;
3175 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3176   cache_file_option="--cache-file=${cache_file}" ;;
3177 *) # relative path
3178   cache_file_option="--cache-file=../${cache_file}" ;;
3179 esac
3180
3181 # Host dirs don't like to share a cache file either, horribly enough.
3182 # This seems to be due to autoconf 2.5x stupidity.
3183 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3184
3185 target_configargs="$target_configargs ${tbaseargs}"
3186
3187 # Passing a --with-cross-host argument lets the target libraries know
3188 # whether they are being built with a cross-compiler or being built
3189 # native.  However, it would be better to use other mechanisms to make the
3190 # sorts of decisions they want to make on this basis.  Please consider
3191 # this option to be deprecated.  FIXME.
3192 if test x${is_cross_compiler} = xyes ; then
3193   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3194 fi
3195
3196 # Special user-friendly check for native x86_64-linux build, if
3197 # multilib is not explicitly enabled.
3198 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3199   x86_64-*linux*:yes:$build:$build:)
3200     # Make sure we have a development environment that handles 32-bit
3201     dev64=no
3202     echo "int main () { return 0; }" > conftest.c
3203     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3204     if test $? = 0 ; then
3205       if test -s conftest || test -s conftest.exe ; then
3206         dev64=yes
3207       fi
3208     fi
3209     rm -f conftest*
3210     if test x${dev64} != xyes ; then
3211       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3212     fi
3213     ;;
3214 esac
3215
3216 # Default to --enable-multilib.
3217 if test x${enable_multilib} = x ; then
3218   target_configargs="--enable-multilib ${target_configargs}"
3219 fi
3220
3221 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3222 # changed from the earlier setting of with_newlib.
3223 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3224   target_configargs="--with-newlib ${target_configargs}"
3225 fi
3226
3227 # Different target subdirs use different values of certain variables
3228 # (notably CXX).  Worse, multilibs use *lots* of different values.
3229 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3230 # it doesn't automatically accept command-line overrides of them.
3231 # This means it's not safe for target subdirs to share a cache file,
3232 # which is disgusting, but there you have it.  Hopefully this can be
3233 # fixed in future.  It's still worthwhile to use a cache file for each
3234 # directory.  I think.
3235
3236 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3237 # We need to pass --target, as newer autoconf's requires consistency
3238 # for target_alias and gcc doesn't manage it consistently.
3239 target_configargs="--cache-file=./config.cache ${target_configargs}"
3240
3241 FLAGS_FOR_TARGET=
3242 case " $target_configdirs " in
3243  *" newlib "*)
3244   case " $target_configargs " in
3245   *" --with-newlib "*)
3246    case "$target" in
3247     *-cygwin*)
3248       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3249       ;;
3250    esac
3251
3252    # If we're not building GCC, don't discard standard headers.
3253    if test -d ${srcdir}/gcc; then
3254      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3255
3256      if test "${build}" != "${host}"; then
3257        # On Canadian crosses, CC_FOR_TARGET will have already been set
3258        # by `configure', so we won't have an opportunity to add -Bgcc/
3259        # to it.  This is right: we don't want to search that directory
3260        # for binaries, but we want the header files in there, so add
3261        # them explicitly.
3262        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3263
3264        # Someone might think of using the pre-installed headers on
3265        # Canadian crosses, in case the installed compiler is not fully
3266        # compatible with the compiler being built.  In this case, it
3267        # would be better to flag an error than risking having
3268        # incompatible object files being constructed.  We can't
3269        # guarantee that an error will be flagged, but let's hope the
3270        # compiler will do it, when presented with incompatible header
3271        # files.
3272      fi
3273    fi
3274
3275    case "${target}-${is_cross_compiler}" in
3276    i[[3456789]]86-*-linux*-no)
3277       # Here host == target, so we don't need to build gcc,
3278       # so we don't want to discard standard headers.
3279       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3280       ;;
3281    *)
3282       # If we're building newlib, use its generic headers last, but search
3283       # for any libc-related directories first (so make it the last -B
3284       # switch).
3285       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3286
3287       # If we're building libgloss, find the startup file, simulator library
3288       # and linker script.
3289       case " $target_configdirs " in
3290         *" libgloss "*)
3291         # Look for startup file, simulator library and maybe linker script.
3292         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3293         # Look for libnosys.a in case the target needs it.
3294         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3295         # Most targets have the linker script in the source directory.
3296         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3297         ;;
3298       esac
3299       ;;
3300    esac
3301    ;;
3302   esac
3303   ;;
3304 esac
3305
3306 case "$target" in
3307   x86_64-*mingw* | *-w64-mingw*)
3308   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3309   # however, use a symlink named 'mingw' in ${prefix} .
3310     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3311     ;;
3312   *-mingw*)
3313   # MinGW can't be handled as Cygwin above since it does not use newlib.
3314     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3315     ;;
3316 esac
3317
3318 # Allow the user to override the flags for
3319 # our build compiler if desired.
3320 if test x"${build}" = x"${host}" ; then
3321   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3322   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3323   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3324 fi
3325
3326 # On Canadian crosses, we'll be searching the right directories for
3327 # the previously-installed cross compiler, so don't bother to add
3328 # flags for directories within the install tree of the compiler
3329 # being built; programs in there won't even run.
3330 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3331   # Search for pre-installed headers if nothing else fits.
3332   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3333 fi
3334
3335 if test "x${use_gnu_ld}" = x &&
3336    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3337   # Arrange for us to find uninstalled linker scripts.
3338   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3339 fi
3340
3341 # Search for other target-specific linker scripts and such.
3342 case "${target}" in
3343   mep*)
3344     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3345     ;;
3346 esac
3347
3348 # Makefile fragments.
3349 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3350 do
3351   eval fragval=\$$frag
3352   if test $fragval != /dev/null; then
3353     eval $frag=${srcdir}/$fragval
3354   fi
3355 done
3356 AC_SUBST_FILE(host_makefile_frag)
3357 AC_SUBST_FILE(target_makefile_frag)
3358 AC_SUBST_FILE(alphaieee_frag)
3359 AC_SUBST_FILE(ospace_frag)
3360
3361 # Miscellanea: directories, flags, etc.
3362 AC_SUBST(RPATH_ENVVAR)
3363 AC_SUBST(GCC_SHLIB_SUBDIR)
3364 AC_SUBST(tooldir)
3365 AC_SUBST(build_tooldir)
3366 AC_SUBST(CONFIGURE_GDB_TK)
3367 AC_SUBST(GDB_TK)
3368 AC_SUBST(INSTALL_GDB_TK)
3369
3370 # Build module lists & subconfigure args.
3371 AC_SUBST(build_configargs)
3372 AC_SUBST(build_configdirs)
3373
3374 # Host module lists & subconfigure args.
3375 AC_SUBST(host_configargs)
3376 AC_SUBST(configdirs)
3377 AC_SUBST(target_configdirs)
3378
3379 # Target module lists & subconfigure args.
3380 AC_SUBST(target_configargs)
3381
3382
3383 # Build tools.
3384 AC_SUBST(AR_FOR_BUILD)
3385 AC_SUBST(AS_FOR_BUILD)
3386 AC_SUBST(CC_FOR_BUILD)
3387 AC_SUBST(CFLAGS_FOR_BUILD)
3388 AC_SUBST(CXXFLAGS_FOR_BUILD)
3389 AC_SUBST(CXX_FOR_BUILD)
3390 AC_SUBST(DLLTOOL_FOR_BUILD)
3391 AC_SUBST(GFORTRAN_FOR_BUILD)
3392 AC_SUBST(GOC_FOR_BUILD)
3393 AC_SUBST(GDC_FOR_BUILD)
3394 AC_SUBST(LDFLAGS_FOR_BUILD)
3395 AC_SUBST(LD_FOR_BUILD)
3396 AC_SUBST(NM_FOR_BUILD)
3397 AC_SUBST(RANLIB_FOR_BUILD)
3398 AC_SUBST(WINDMC_FOR_BUILD)
3399 AC_SUBST(WINDRES_FOR_BUILD)
3400
3401 # Generate default definitions for YACC, M4, LEX and other programs that run
3402 # on the build machine.  These are used if the Makefile can't locate these
3403 # programs in objdir.
3404 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3405
3406 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3407 case " $build_configdirs " in
3408   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3409 esac
3410
3411 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3412 case " $build_configdirs " in
3413   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3414 esac
3415
3416 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3417 case " $build_configdirs " in
3418   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3419 esac
3420
3421 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3422 case " $build_configdirs " in
3423   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3424   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3425 esac
3426
3427 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3428 case " $build_configdirs " in
3429   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3430 esac
3431
3432 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3433 case " $build_configdirs " in
3434   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3435   *)
3436 changequote(,)
3437     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3438     # higher, else we use the "missing" dummy.
3439     if ${MAKEINFO} --version \
3440        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3441       :
3442     else
3443       MAKEINFO="$MISSING makeinfo"
3444     fi
3445     ;;
3446 changequote([,])
3447 esac
3448
3449 # FIXME: expect and dejagnu may become build tools?
3450
3451 AC_CHECK_PROGS(EXPECT, expect, expect)
3452 case " $configdirs " in
3453   *" expect "*)
3454     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3455     ;;
3456 esac
3457
3458 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3459 case " $configdirs " in
3460   *" dejagnu "*)
3461     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3462     ;;
3463 esac
3464
3465
3466 # Host tools.
3467 NCN_STRICT_CHECK_TOOLS(AR, ar)
3468 NCN_STRICT_CHECK_TOOLS(AS, as)
3469 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3470 NCN_STRICT_CHECK_TOOLS(LD, ld)
3471 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3472 NCN_STRICT_CHECK_TOOLS(NM, nm)
3473 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3474 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3475 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3476 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3477 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3478 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3479 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3480 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3481 AC_SUBST(CC)
3482 AC_SUBST(CXX)
3483 AC_SUBST(CFLAGS)
3484 AC_SUBST(CXXFLAGS)
3485
3486 # Target tools.
3487 AC_ARG_WITH([build-time-tools],
3488   [AS_HELP_STRING([--with-build-time-tools=PATH],
3489                   [use given path to find target tools during the build])],
3490   [case x"$withval" in
3491      x/*) ;;
3492      *)
3493        with_build_time_tools=
3494        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3495        ;;
3496    esac],
3497   [with_build_time_tools=])
3498
3499 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3500 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3501 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3502 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3503 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3504 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3505
3506 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3507 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3508 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3509 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3510 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3512 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3513 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3514 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3515 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3520
3521 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3522
3523 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3524 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3525 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3526 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3527 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3528                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3529                 c++)
3530 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3531                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3532                 c++)
3533 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3534 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3535 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3536                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3537 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3538                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3539 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3540                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3541 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3542 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3543 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3544 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3545 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3546 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3547 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3548 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3549 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3550 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3551 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3552
3553 AC_SUBST(FLAGS_FOR_TARGET)
3554 AC_SUBST(RAW_CXX_FOR_TARGET)
3555
3556 # Certain tools may need extra flags.
3557 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3558 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3559 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3560
3561 # When building target libraries, except in a Canadian cross, we use
3562 # the same toolchain as the compiler we just built.
3563 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3564 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3565 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3566 if test $host = $build; then
3567   case " $configdirs " in
3568     *" gcc "*)
3569       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3570       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3571       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3572       ;;
3573   esac
3574 fi
3575
3576 AC_SUBST(COMPILER_AS_FOR_TARGET)
3577 AC_SUBST(COMPILER_LD_FOR_TARGET)
3578 AC_SUBST(COMPILER_NM_FOR_TARGET)
3579
3580 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3581 AC_ARG_ENABLE(maintainer-mode,
3582 [AS_HELP_STRING([--enable-maintainer-mode],
3583                 [enable make rules and dependencies not useful
3584                  (and sometimes confusing) to the casual installer])],
3585       USE_MAINTAINER_MODE=$enableval,
3586       USE_MAINTAINER_MODE=no)
3587 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3588 AC_SUBST(MAINTAINER_MODE_TRUE)
3589 AC_SUBST(MAINTAINER_MODE_FALSE)
3590 if test "$USE_MAINTAINER_MODE" = yes; then
3591   MAINTAINER_MODE_TRUE=
3592   MAINTAINER_MODE_FALSE='#'
3593 else
3594   MAINTAINER_MODE_TRUE='#'
3595   MAINTAINER_MODE_FALSE=
3596 fi
3597 MAINT=$MAINTAINER_MODE_TRUE
3598 AC_SUBST(MAINT)dnl
3599
3600 # ---------------------
3601 # GCC bootstrap support
3602 # ---------------------
3603
3604 # Stage specific cflags for build.
3605 stage1_cflags="-g"
3606 case $build in
3607   vax-*-*)
3608     case ${GCC} in
3609       yes) stage1_cflags="-g -Wa,-J" ;;
3610       *) stage1_cflags="-g -J" ;;
3611     esac ;;
3612 esac
3613
3614 AC_SUBST(stage1_cflags)
3615
3616 # Enable --enable-checking in stage1 of the compiler.
3617 AC_ARG_ENABLE(stage1-checking,
3618 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3619                 [choose additional checking for stage1 of the compiler])],
3620 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3621 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3622   # For --disable-checking or implicit --enable-checking=release, avoid
3623   # setting --enable-checking=gc in the default stage1 checking for LTO
3624   # bootstraps.  See PR62077.
3625   case $BUILD_CONFIG in
3626     *lto*)
3627       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3628     *)
3629       stage1_checking=--enable-checking=yes,types;;
3630   esac
3631   if test "x$enable_checking" = x && \
3632      test -d ${srcdir}/gcc && \
3633      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3634     stage1_checking=--enable-checking=yes,types,extra
3635   fi
3636 else
3637   stage1_checking=--enable-checking=$enable_checking,types
3638 fi])
3639 AC_SUBST(stage1_checking)
3640
3641 # Enable -Werror in bootstrap stage2 and later.
3642 AC_ARG_ENABLE(werror,
3643 [AS_HELP_STRING([--enable-werror],
3644                 [enable -Werror in bootstrap stage2 and later])],
3645 [
3646 case ${enable_werror} in
3647   yes) stage2_werror_flag="--enable-werror-always" ;;
3648   *) stage2_werror_flag="" ;;
3649 esac
3650 ],
3651 [
3652 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3653   case $BUILD_CONFIG in
3654   bootstrap-debug)
3655       stage2_werror_flag="--enable-werror-always" ;;
3656   "")
3657       stage2_werror_flag="--enable-werror-always" ;;
3658   esac
3659 fi
3660 ])
3661
3662 AC_SUBST(stage2_werror_flag)
3663
3664 # Specify what files to not compare during bootstrap.
3665
3666 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3667 case "$target" in
3668   hppa*64*-*-hpux*) ;;
3669   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3670   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3671 esac
3672 AC_SUBST(compare_exclusions)
3673
3674 AC_CONFIG_FILES([Makefile],
3675   [sed "$extrasub_build" Makefile |
3676    sed "$extrasub_host" |
3677    sed "$extrasub_target" > mf$$
3678    mv -f mf$$ Makefile],
3679   [extrasub_build="$extrasub_build"
3680    extrasub_host="$extrasub_host"
3681    extrasub_target="$extrasub_target"])
3682 AC_OUTPUT