libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=13:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 GOOS=unknown
 170 case ${host} in
 171   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 172   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 173   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 174   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 175   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 176   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 177   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 178   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 179   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 180   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 181 esac
 182 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 183 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 184 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 185 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 186 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 187 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 188 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 189 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 190 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 191 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 192 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 193 AC_SUBST(GOOS)
 194 AC_SUBST(ALLGOOS)
 195
 196 dnl Test whether we need to use DejaGNU or whether we can use the
 197 dnl simpler gotest approach.  We can only use gotest for a native
 198 dnl build.
 199 USE_DEJAGNU=no
 200 case ${host} in
 201   *-*-rtems*) USE_DEJAGNU=yes ;;
 202   ${build}) ;;
 203   *) USE_DEJAGNU=yes ;;
 204 esac
 205 AC_SUBST(USE_DEJAGNU)
 206
 207 # All known GOARCH values.  This is the union of all architectures
 208 # supported by the gofrontend and all architectures supported by the
 209 # gc toolchain.
 210 # To add a new architecture:
 211 # - add it to this list
 212 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 213 # - add an entry to the case on ${host} below to set GOARCH
 214 # - update goarchList in libgo/go/go/build/syslist.go
 215 # - update goarch.sh to report the values for this architecture
 216 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 217 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 218 # - update arch lists in libgo/match.sh
 219 # - update arch lists in libgo/testsuite/gotest
 220 # - update +build lines in several places
 221 #   - libgo/go/runtime/lfstack_NNbit.go
 222 #   - libgo/go/runtime/hashNN.go
 223 #   - libgo/go/runtime/unalignedN.go
 224 #   - libgo/go/syscall/endian_XX.go
 225 #   - possibly others
 226 # - possibly update files in libgo/go/internal/syscall/unix
 227 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le ppc ppc64 ppc64le s390 s390x sh shbe sparc sparc64"
 228
 229 # All known GOARCH family values.
 230 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SH SPARC SPARC64"
 231
 232 GOARCH=unknown
 233 case ${host} in
 234   alpha*-*-*)
 235     GOARCH=alpha
 236     ;;
 237   aarch64-*-*)
 238     GOARCH=arm64
 239     ;;
 240   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 241     GOARCH=arm
 242     case ${host} in
 243       arm*b*-*-*)
 244         GOARCH=armbe
 245         ;;
 246     esac
 247     ;;
 248 changequote(,)dnl
 249   i[34567]86-*-* | x86_64-*-*)
 250 changequote([,])dnl
 251     AC_COMPILE_IFELSE([
 252 #ifdef __x86_64__
 253 #error 64-bit
 254 #endif],
 255 [GOARCH=386],
 256 [GOARCH=amd64])
 257     ;;
 258   ia64-*-*)
 259     GOARCH=ia64
 260     ;;
 261   m68k*-*-*)
 262     GOARCH=m68k
 263     ;;
 264   mips*-*-*)
 265     AC_COMPILE_IFELSE([
 266 #if _MIPS_SIM != _ABIO32
 267 #error not o32
 268 #endif],
 269 [mips_abi="o32"],
 270         [AC_COMPILE_IFELSE([
 271 #if _MIPS_SIM != _ABIN32
 272 #error not n32
 273 #endif],
 274 [mips_abi="n32"],
 275         [AC_COMPILE_IFELSE([
 276 #if _MIPS_SIM != _ABI64
 277 #error not n64
 278 #endif],
 279 [mips_abi="n64"],
 280         [AC_MSG_ERROR([unknown MIPS ABI])
 281 [mips_abi="n32"]])])])
 282     case "$mips_abi" in
 283     "o32") GOARCH=mips ;;
 284     "n32") GOARCH=mips64p32 ;;
 285     "n64") GOARCH=mips64 ;;
 286     esac
 287     case "${host}" in
 288     mips*el-*-*)
 289         GOARCH="${GOARCH}le"
 290         ;;
 291     esac
 292     ;;
 293   rs6000*-*-* | powerpc*-*-*)
 294     AC_COMPILE_IFELSE([
 295 #ifdef _ARCH_PPC64
 296 #error 64-bit
 297 #endif],
 298 [GOARCH=ppc],
 299     [
 300 AC_COMPILE_IFELSE([
 301 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 302 #error 64be
 303 #endif],
 304 [GOARCH=ppc64le],
 305 [GOARCH=ppc64])])
 306     ;;
 307   s390*-*-*)
 308     AC_COMPILE_IFELSE([
 309 #if defined(__s390x__)
 310 #error 64-bit
 311 #endif],
 312 [GOARCH=s390],
 313 [GOARCH=s390x])
 314     ;;
 315   sh3eb*-*-* | sh4eb*-*-*)
 316     GOARCH=shbe
 317     ;;
 318   sh3*-*-* | sh4*-*-*)
 319     GOARCH=sh
 320     ;;
 321   sparc*-*-*)
 322     AC_COMPILE_IFELSE([
 323 #if defined(__sparcv9) || defined(__arch64__)
 324 #error 64-bit
 325 #endif],
 326 [GOARCH=sparc],
 327 [GOARCH=sparc64])
 328     ;;
 329 esac
 330 AC_SUBST(GOARCH)
 331 AC_SUBST(ALLGOARCH)
 332 AC_SUBST(ALLGOARCHFAMILY)
 333
 334 dnl Some files are only present when needed for specific architectures.
 335 GO_LIBCALL_OS_FILE=
 336 GO_LIBCALL_OS_ARCH_FILE=
 337 GO_SYSCALL_OS_FILE=
 338 GO_SYSCALL_OS_ARCH_FILE=
 339 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 340   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 341 fi
 342 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 343   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 344 fi
 345 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 346   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 347 fi
 348 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 349   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 350 fi
 351 AC_SUBST(GO_LIBCALL_OS_FILE)
 352 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 353 AC_SUBST(GO_SYSCALL_OS_FILE)
 354 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 355
 356 dnl Special flags used to generate sysinfo.go.
 357 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 358 case "$target" in
 359     mips-sgi-irix6.5*)
 360         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 361         # msghdr in <sys/socket.h>.
 362         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 363         ;;
 364     *-*-solaris2.1[[01]])
 365         # Solaris 10+ needs this so struct msghdr gets the msg_control
 366         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 367         # above doesn't work with C99.
 368         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 369         ;;
 370 esac
 371 AC_SUBST(OSCFLAGS)
 372
 373 dnl Check if assembler supports disabling hardware capability support.
 374 GCC_CHECK_ASSEMBLER_HWCAP
 375
 376 dnl Use -fsplit-stack when compiling C code if available.
 377 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 378 [libgo_cv_c_split_stack_supported],
 379 [CFLAGS_hold=$CFLAGS
 380 CFLAGS="$CFLAGS -fsplit-stack"
 381 AC_COMPILE_IFELSE([[int i;]],
 382 [libgo_cv_c_split_stack_supported=yes],
 383 [libgo_cv_c_split_stack_supported=no])
 384 CFLAGS=$CFLAGS_hold])
 385
 386 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 387 dnl reject split-stack code calling non-split-stack code on targets
 388 dnl they don't support.
 389 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 390 [libgo_cv_c_linker_split_non_split],
 391 [cat > conftest1.c << EOF
 392 extern void f();
 393 int main() { f(); return 0; }
 394 EOF
 395 cat > conftest2.c << EOF
 396 void f() {}
 397 EOF
 398 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 399 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 400 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 401   libgo_cv_c_linker_split_non_split=yes
 402 else
 403   libgo_cv_c_linker_split_non_split=no
 404 fi
 405 rm -f conftest1.* conftest2.* conftest])
 406
 407 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 408   SPLIT_STACK=-fsplit-stack
 409   AC_DEFINE(USING_SPLIT_STACK, 1,
 410                 [Define if the compiler supports -fsplit-stack])
 411 else
 412   SPLIT_STACK=
 413 fi
 414 AC_SUBST(SPLIT_STACK)
 415 AM_CONDITIONAL(USING_SPLIT_STACK,
 416         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 417
 418 dnl If the compiler supports split-stack but the linker does not, then
 419 dnl we need to explicitly disable split-stack for Go.
 420 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 421   GO_SPLIT_STACK=-fno-split-stack
 422 else
 423   GO_SPLIT_STACK=
 424 fi
 425 AC_SUBST(GO_SPLIT_STACK)
 426
 427 dnl Check whether the linker does stack munging when calling from
 428 dnl split-stack into non-split-stack code.  We check this by looking
 429 dnl at the --help output.  FIXME: This is only half right: it's
 430 dnl possible for the linker to support this for some targets but not
 431 dnl others.
 432 dnl This is slightly different from the above check, which is whether
 433 dnl the linker permits the call at all.
 434 AC_CACHE_CHECK([whether linker supports split stack],
 435 [libgo_cv_c_linker_supports_split_stack],
 436 [libgo_cv_c_linker_supports_split_stack=no
 437 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 438   libgo_cv_c_linker_supports_split_stack=yes
 439 fi])
 440 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 441   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 442             [Define if the linker support split stack adjustments])
 443 fi
 444
 445 AC_CACHE_CHECK([whether compiler is llgo],
 446 [libgo_cv_c_goc_is_llgo],
 447 [libgo_cv_c_goc_is_llgo=no
 448 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 449   libgo_cv_c_goc_is_llgo=yes
 450 fi])
 451 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 452
 453 dnl Test for the -lm library.
 454 MATH_LIBS=
 455 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 456 AC_SUBST(MATH_LIBS)
 457
 458 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 459 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 460   [libgo_cv_lib_sockets=
 461    libgo_check_both=no
 462    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 463    if test "$libgo_check_socket" = "yes"; then
 464      unset ac_cv_func_connect
 465      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 466                   libgo_check_both=yes)
 467    fi
 468    if test "$libgo_check_both" = "yes"; then
 469      libgo_old_libs=$LIBS
 470      LIBS="$LIBS -lsocket -lnsl"
 471      unset ac_cv_func_accept
 472      AC_CHECK_FUNC(accept,
 473                    [libgo_check_nsl=no
 474                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 475      unset ac_cv_func_accept
 476      LIBS=$libgo_old_libs
 477    fi
 478    unset ac_cv_func_gethostbyname
 479    libgo_old_libs="$LIBS"
 480    AC_CHECK_FUNC(gethostbyname, ,
 481                  [AC_CHECK_LIB(nsl, main,
 482                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 483    unset ac_cv_func_gethostbyname
 484    AC_CHECK_FUNC(sendfile, ,
 485                  [AC_CHECK_LIB(sendfile, main,
 486                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 487    LIBS=$libgo_old_libs
 488 ])
 489 NET_LIBS="$libgo_cv_lib_sockets"
 490 AC_SUBST(NET_LIBS)
 491
 492 dnl Test whether the compiler supports the -pthread option.
 493 AC_CACHE_CHECK([whether -pthread is supported],
 494 [libgo_cv_lib_pthread],
 495 [CFLAGS_hold=$CFLAGS
 496 CFLAGS="$CFLAGS -pthread"
 497 AC_COMPILE_IFELSE([[int i;]],
 498 [libgo_cv_lib_pthread=yes],
 499 [libgo_cv_lib_pthread=no])
 500 CFLAGS=$CFLAGS_hold])
 501 PTHREAD_CFLAGS=
 502 if test "$libgo_cv_lib_pthread" = yes; then
 503   PTHREAD_CFLAGS=-pthread
 504 fi
 505 AC_SUBST(PTHREAD_CFLAGS)
 506
 507 dnl Test for the -lpthread library.
 508 PTHREAD_LIBS=
 509 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 510 AC_SUBST(PTHREAD_LIBS)
 511
 512 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 513 AC_SEARCH_LIBS([sched_yield], [rt])
 514 AC_SEARCH_LIBS([nanosleep], [rt])
 515 AC_SEARCH_LIBS([clock_gettime], [rt])
 516
 517 AC_C_BIGENDIAN
 518
 519 GCC_CHECK_UNWIND_GETIPINFO
 520
 521 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 522
 523 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 524 [#include <netinet/in.h>
 525 ])
 526
 527 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 528 [#ifdef HAVE_SYS_SOCKET_H
 529 #include <sys/socket.h>
 530 #endif
 531 ])
 532
 533 AC_CACHE_CHECK([whether <ustat.h> can be used],
 534 [libgo_cv_c_ustat_h],
 535 [CFLAGS_hold=$CFLAGS
 536 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 537 AC_COMPILE_IFELSE(
 538 [AC_LANG_SOURCE([
 539 #include <sys/types.h>
 540 #ifdef HAVE_LINUX_FILTER_H
 541 #include <linux/filter.h>
 542 #endif
 543 #include <ustat.h>
 544 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 545 CFLAGS=$CFLAGS_hold])
 546 if test $libgo_cv_c_ustat_h = yes; then
 547   AC_DEFINE(HAVE_USTAT_H, 1,
 548     [Define to 1 if you have the <ustat.h> header file and it works.])
 549 fi
 550
 551 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 552
 553 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 554 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 555 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 556
 557 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 558 AC_TYPE_OFF_T
 559 AC_CHECK_TYPES([loff_t])
 560
 561 LIBS_hold="$LIBS"
 562 LIBS="$LIBS -lm"
 563 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 564 LIBS="$LIBS_hold"
 565
 566 CFLAGS_hold="$CFLAGS"
 567 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 568 LIBS_hold="$LIBS"
 569 LIBS="$LIBS $PTHREAD_LIBS"
 570 AC_CHECK_FUNCS(sem_timedwait)
 571 CFLAGS="$CFLAGS_hold"
 572 LIBS="$LIBS_hold"
 573
 574 LIBS_hold="$LIBS"
 575 LIBS="$LIBS $MATH_LIBS"
 576 AC_CHECK_FUNCS(matherr)
 577 LIBS="$LIBS_hold"
 578
 579 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 580 [libgo_cv_func___sync_bool_compare_and_swap_4],
 581 [AC_LINK_IFELSE([
 582 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 583 uint32 i;
 584 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 585 ],
 586 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 587 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 588 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 589   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 590     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 591 fi
 592
 593 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 594 [libgo_cv_func___sync_bool_compare_and_swap_8],
 595 [AC_LINK_IFELSE([
 596 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 597 uint64 i;
 598 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 599 ],
 600 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 601 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 602 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 603   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 604     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 605 fi
 606
 607 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 608 [libgo_cv_func___sync_fetch_and_add_4],
 609 [AC_LINK_IFELSE([
 610 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 611 uint32 i;
 612 int main() { return __sync_fetch_and_add (&i, 1); }
 613 ],
 614 [libgo_cv_func___sync_fetch_and_add_4=yes],
 615 [libgo_cv_func___sync_fetch_and_add_4=no])])
 616 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 617   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 618     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 619 fi
 620
 621 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 622 [libgo_cv_func___sync_add_and_fetch_8],
 623 [AC_LINK_IFELSE([
 624 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 625 uint64 i;
 626 int main() { return __sync_add_and_fetch (&i, 1); }
 627 ],
 628 [libgo_cv_func___sync_add_and_fetch_8=yes],
 629 [libgo_cv_func___sync_add_and_fetch_8=no])])
 630 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 631   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 632     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 633 fi
 634
 635 dnl For x86 we want to use the -minline-all-stringops option to avoid
 636 dnl forcing a stack split when calling memcpy and friends.
 637 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 638 [libgo_cv_c_stringops],
 639 [CFLAGS_hold=$CFLAGS
 640 CFLAGS="$CFLAGS -minline-all-stringops"
 641 AC_COMPILE_IFELSE([int i;],
 642 [libgo_cv_c_stringops=yes],
 643 [libgo_cv_c_stringops=no])
 644 CFLAGS=$CFLAGS_hold])
 645 STRINGOPS_FLAG=
 646 if test "$libgo_cv_c_stringops" = yes; then
 647   STRINGOPS_FLAG=-minline-all-stringops
 648 fi
 649 AC_SUBST(STRINGOPS_FLAG)
 650
 651 dnl For x86 we want to compile the math library with -mfancy-math-387
 652 dnl so that we can use the builtin instructions directly.
 653 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 654 [libgo_cv_c_fancymath],
 655 [CFLAGS_hold=$CFLAGS
 656 CFLAGS="$CFLAGS -mfancy-math-387"
 657 AC_COMPILE_IFELSE([int i;],
 658 [libgo_cv_c_fancymath=yes],
 659 [libgo_cv_c_fancymath=no])
 660 CFLAGS=$CFLAGS_hold])
 661 MATH_FLAG=
 662 if test "$libgo_cv_c_fancymath" = yes; then
 663   MATH_FLAG="-mfancy-math-387"
 664 fi
 665 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 666 AC_SUBST(MATH_FLAG)
 667
 668 CFLAGS_hold=$CFLAGS
 669 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 670 AC_CHECK_TYPES([off64_t])
 671 CFLAGS=$CFLAGS_hold
 672
 673 dnl Work out the size of the epoll_events struct on GNU/Linux.
 674 AC_CACHE_CHECK([epoll_event size],
 675 [libgo_cv_c_epoll_event_size],
 676 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 677 [sizeof (struct epoll_event)],
 678 [#include <sys/epoll.h>],
 679 [libgo_cv_c_epoll_event_size=0])])
 680 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 681 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 682
 683 dnl Work out the offset of the fd field in the epoll_events struct on
 684 dnl GNU/Linux.
 685 AC_CACHE_CHECK([epoll_event data.fd offset],
 686 [libgo_cv_c_epoll_event_fd_offset],
 687 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 688 [offsetof (struct epoll_event, data.fd)],
 689 [#include <stddef.h>
 690 #include <sys/epoll.h>],
 691 [libgo_cv_c_epoll_event_fd_offset=0])])
 692 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 693 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 694
 695 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 696 dnl in Solaris 11.4 for XPG7 compatibility.
 697 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 698                 [have_stat_timespec=yes], [have_stat_timespec=no])
 699 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 700
 701 dnl See if struct exception is defined in <math.h>.
 702 AC_CHECK_TYPE([struct exception],
 703 [libgo_has_struct_exception=yes],
 704 [libgo_has_struct_exception=no],
 705 [#include <math.h>])
 706 if test "$libgo_has_struct_exception" = "yes"; then
 707   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 708             [Define to 1 if <math.h> defines struct exception])
 709 fi
 710
 711 dnl See whether setcontext changes the value of TLS variables.
 712 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 713 [libgo_cv_lib_setcontext_clobbers_tls],
 714 [CFLAGS_hold="$CFLAGS"
 715 CFLAGS="$PTHREAD_CFLAGS"
 716 LIBS_hold="$LIBS"
 717 LIBS="$LIBS $PTHREAD_LIBS"
 718 AC_CHECK_SIZEOF([void *])
 719 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 720 AC_RUN_IFELSE(
 721   [AC_LANG_SOURCE([
 722 #include <pthread.h>
 723 #include <stdlib.h>
 724 #include <ucontext.h>
 725 #include <unistd.h>
 726
 727 __thread int tls;
 728
 729 static char stack[[10 * 1024 * 1024]];
 730 static ucontext_t c;
 731
 732 /* Called via makecontext/setcontext.  */
 733
 734 static void
 735 cfn (void)
 736 {
 737   exit (tls);
 738 }
 739
 740 /* Called via pthread_create.  */
 741
 742 static void *
 743 tfn (void *dummy)
 744 {
 745   /* The thread should still see this value after calling
 746      setcontext.  */
 747   tls = 0;
 748
 749   setcontext (&c);
 750
 751   /* The call to setcontext should not return.  */
 752   abort ();
 753 }
 754
 755 int
 756 main ()
 757 {
 758   pthread_t tid;
 759
 760   /* The thread should not see this value.  */
 761   tls = 1;
 762
 763   if (getcontext (&c) < 0)
 764     abort ();
 765
 766   c.uc_stack.ss_sp = stack;
 767 #ifdef MAKECONTEXT_STACK_TOP
 768   c.uc_stack.ss_sp += sizeof stack;
 769 #endif
 770   c.uc_stack.ss_flags = 0;
 771   c.uc_stack.ss_size = sizeof stack;
 772   c.uc_link = NULL;
 773   makecontext (&c, cfn, 0);
 774
 775   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 776     abort ();
 777
 778   if (pthread_join (tid, NULL) != 0)
 779     abort ();
 780
 781   /* The thread should have called exit.  */
 782   abort ();
 783 }
 784 ])],
 785 [libgo_cv_lib_setcontext_clobbers_tls=no],
 786 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 787 [case "$target:$ptr_type_size" in
 788   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 789     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 790   *)
 791     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 792  esac
 793 ])
 794 CFLAGS="$CFLAGS_hold"
 795 LIBS="$LIBS_hold"
 796 ])
 797 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 798   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 799             [Define if setcontext clobbers TLS variables])
 800 fi
 801
 802 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 803 libgo_cv_ro_eh_frame, [
 804 libgo_cv_ro_eh_frame=no
 805 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 806 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 807   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 808     libgo_cv_ro_eh_frame=yes
 809   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 810        | grep -v '#write' > /dev/null; then
 811     libgo_cv_ro_eh_frame=yes
 812   fi
 813 fi
 814 rm -f conftest.*
 815 ])
 816 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 817   AC_DEFINE(EH_FRAME_FLAGS, "a",
 818             [Define to the flags needed for the .section .eh_frame directive.])
 819 else
 820   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 821             [Define to the flags needed for the .section .eh_frame directive.])
 822 fi
 823
 824 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 825 [libgo_cv_c_unused_arguments],
 826 [CFLAGS_hold=$CFLAGS
 827 CFLAGS="$CFLAGS -Qunused-arguments"
 828 AC_COMPILE_IFELSE([[int i;]],
 829 [libgo_cv_c_unused_arguments=yes],
 830 [libgo_cv_c_unused_arguments=no])
 831 CFLAGS=$CFLAGS_hold])
 832
 833 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 834 libgo_cv_as_comdat_gnu, [
 835 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 836 CFLAGS_hold=$CFLAGS
 837 if test "$libgo_cv_c_unused_arguments" = yes; then
 838   CFLAGS="$CFLAGS -Qunused-arguments"
 839 fi
 840 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 841   libgo_cv_as_comdat_gnu=yes
 842 else
 843   libgo_cv_as_comdat_gnu=no
 844 fi
 845 CFLAGS=$CFLAGS_hold
 846 ])
 847 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 848   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 849             [Define if your assembler supports GNU comdat group syntax.])
 850 fi
 851
 852 AC_CACHE_CHECK([assembler supports pc related relocs],
 853 libgo_cv_as_x86_pcrel, [
 854 libgo_cv_as_x86_pcrel=yes
 855 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 856 CFLAGS_hold=$CFLAGS
 857 if test "$libgo_cv_c_unused_arguments" = yes; then
 858   CFLAGS="$CFLAGS -Qunused-arguments"
 859 fi
 860 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 861     libgo_cv_as_x86_pcrel=no
 862 fi
 863 CFLAGS=$CFLAGS_hold
 864 ])
 865 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 866   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 867             [Define if your assembler supports PC relative relocs.])
 868 fi
 869
 870 AC_CACHE_CHECK([assembler supports unwind section type],
 871 libgo_cv_as_x86_64_unwind_section_type, [
 872 libgo_cv_as_x86_64_unwind_section_type=yes
 873 echo '.section .eh_frame,"a",@unwind' > conftest.s
 874 CFLAGS_hold=$CFLAGS
 875 if test "$libgo_cv_c_unused_arguments" = yes; then
 876   CFLAGS="$CFLAGS -Qunused-arguments"
 877 fi
 878 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 879     libgo_cv_as_x86_64_unwind_section_type=no
 880 fi
 881 CFLAGS=$CFLAGS_hold
 882 ])
 883 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 884   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 885             [Define if your assembler supports unwind section type.])
 886 fi
 887
 888 AC_CACHE_CHECK([assembler supports AES instructions],
 889 libgo_cv_as_x86_aes, [
 890 libgo_cv_as_x86_aes=yes
 891 echo 'aesenc %xmm0, %xmm1' > conftest.s
 892 CFLAGS_hold=$CFLAGS
 893 if test "$libgo_cv_c_unused_arguments" = yes; then
 894   CFLAGS="$CFLAGS -Qunused-arguments"
 895 fi
 896 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 897     libgo_cv_as_x86_aes=no
 898 fi
 899 CFLAGS=$CFLAGS_hold
 900 ])
 901 if test "x$libgo_cv_as_x86_aes" = xyes; then
 902   AC_DEFINE(HAVE_AS_X86_AES, 1,
 903             [Define if your assembler supports AES instructions.])
 904 fi
 905
 906 AC_CACHE_SAVE
 907
 908 if test ${multilib} = yes; then
 909   multilib_arg="--enable-multilib"
 910 else
 911   multilib_arg=
 912 fi
 913
 914 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 915
 916 AC_CONFIG_COMMANDS([default],
 917 [if test -n "$CONFIG_FILES"; then
 918    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 919    # that multilib installs will end up installed in the correct place.
 920    # The testsuite needs it for multilib-aware ABI baseline files.
 921    # To work around this not being passed down from config-ml.in ->
 922    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 923    # append it here.  Only modify Makefiles that have just been created.
 924    #
 925    # Also, get rid of this simulated-VPATH thing that automake does.
 926    cat > vpsed << \_EOF
 927 s!`test -f '$<' || echo '$(srcdir)/'`!!
 928 _EOF
 929    for i in $SUBDIRS; do
 930     case $CONFIG_FILES in
 931      *${i}/Makefile*)
 932        #echo "Adding MULTISUBDIR to $i/Makefile"
 933        sed -f vpsed $i/Makefile > tmp
 934        grep '^MULTISUBDIR =' Makefile >> tmp
 935        mv tmp $i/Makefile
 936        ;;
 937     esac
 938    done
 939    rm vpsed
 940  fi
 941 ],
 942 [
 943 # Variables needed in config.status (file generation) which aren't already
 944 # passed by autoconf.
 945 SUBDIRS="$SUBDIRS"
 946 ])
 947
 948 AC_OUTPUT