gcc/testsuite/gcc.target/mips/mips.exp

   1 # Copyright (C) 1997-2015 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # A MIPS version of the GCC dg.exp driver.
  18 #
  19 # There are many MIPS features that we want to test, and many of those
  20 # features are specific to certain architectures, certain ABIs and so on.
  21 # There are therefore many cases in which we want to test something that
  22 # is incompatible with the user's chosen test options.
  23 #
  24 # In most dg testsuites, the options added by dg-options have a lower
  25 # priority than the options chosen by the user.  For example, if a test
  26 # specifies:
  27 #
  28 #    { dg-options "-mips1" }
  29 #
  30 # and the user passes the following option to runtest:
  31 #
  32 #    --target_board unix/-mips3
  33 #
  34 # the test would be compiled as MIPS III rather than MIPS I.  If the
  35 # test really wouldn't work with -mips3, normal practice would be to
  36 # have something like:
  37 #
  38 #    { dg-do compile { target can_force_mips1 } }
  39 #
  40 # so that the test is skipped when an option like -mips3 is passed.
  41 #
  42 # Sticking to the same approach here would cause us to skip many tests,
  43 # even though the toolchain can generate the required code.  For example,
  44 # there are 6 MIPS ABIs, plus variants.  Some configurations support
  45 # more than one ABI, so it is natural to use something like:
  46 #
  47 #    --target_board unix{-mabi=n32,-mabi=32,-mabi=64}
  48 #
  49 # when testing them.  But these -mabi=* options would normally prevent any
  50 # EABI and o64 tests from running.
  51 #
  52 # This testsuite therefore defines a local version of dg-options that
  53 # overrides any user options that are incompatible with the test options.
  54 # It tries to keep the other user options intact.
  55 #
  56 #
  57 # Most of the tests in this testsuite are scan-assembler tests, but
  58 # sometimes we need a link test instead.  In these cases, we must not
  59 # try to link code with options that are incompatible with the current
  60 # multilib, because xgcc is passed -L and -B options that are specific
  61 # to that multilib.
  62 #
  63 # Normal GCC practice would be to skip incompatible link tests as
  64 # unsupported, but in this particular case, it seems better to downgrade
  65 # them to an assemble test instead.  At least that way we get some
  66 # test-for-ICE and code-sanity coverage.
  67 #
  68 # The same problem applies to run tests.  If a test requires runtime
  69 # support for a particular feature, and if the current target does not
  70 # provide that support, normal practice would be to skip the test.
  71 # But in this case it seems better to downgrade it to a link test instead.
  72 # (We might then have to downgrade it to an assembler test according to
  73 # the constraints just mentioned.)
  74 #
  75 # The local dg-options therefore checks whether the new options are
  76 # link-compatiable with the user's options.  If not, it automatically
  77 # downgrades link tests to assemble tests.  It does the same for run
  78 # tests, but in addition, it downgrades run tests to link tests if the
  79 # target does not provide runtime support for a required feature or ASE.
  80 #
  81 #
  82 # Another problem is that many of the options we want to test require
  83 # certain other features.  For example, -mips3d requires both 64-bit
  84 # FPRs and a MIPS32 or MIPS64 target; -mfix-r10000 requires branch-
  85 # likely instructions; and so on.  We could handle this by specifying
  86 # a set of options that are guaranteed to give us what we want, such as:
  87 #
  88 #   dg-options "-mips3d -mpaired-single -mhard-float -mgp64 -mfp64 -mabi=n32 -march=mips64 -mips64"
  89 #
  90 # With the new dg-options semantics, this would override any troublesome
  91 # user options like -mips3, -march=vr4100, -mfp32, -mgp32, -msoft-float,
  92 # -mno-paired-single and so on.  But there are three major problems with
  93 # this:
  94 #
  95 #   - It is easy to forget options.
  96 #
  97 #   - If a new option is added, all tests that are incompatible with that
  98 #     option must be updated.
  99 #
 100 #   - We want to be able to test MIPS-3D with things like -march=mips32,
 101 #     -march=mips64r2, -march=sb1, and so on.
 102 #
 103 # The local version of dg-options therefore works out the requirements
 104 # of each test option.  As with the test options themselves, the local
 105 # dg-options overrides any user options that incompatible with these
 106 # requirements, but it keeps the other user options the same.
 107 #
 108 # For example, if the user passes -mips3, a MIPS-3D test will choose
 109 # a different architecture like -mips64 instead.  But if the user
 110 # passes -march=sb1, MIPS-3D tests will be run with that option.
 111 #
 112 #
 113 # Sometimes it is useful to say "I want an environment that is compatible
 114 # with option X, but I don't want to pass option X itself".  The main example
 115 # of this is -mips16: we want to be able to test __attribute__((mips16))
 116 # without requiring the test itself to be compiled as -mips16.  The local
 117 # version of dg-options lets you do this by putting X in parentheses.
 118 # For example:
 119 #
 120 #   { dg-options "(-mips16)" }
 121 #
 122 # selects a MIPS16-compatible target without passing -mips16 itself.
 123 #
 124 # It is also useful to say "any architecture within this ISA range is fine".
 125 # This can be done using special pseudo-options of the form:
 126 #
 127 #   PROP=VALUE PROP<=VALUE PROP>=VALUE
 128 #
 129 # where PROP can be:
 130 #
 131 #   isa:
 132 #       the value of the __mips macro.
 133 #
 134 #   isa_rev:
 135 #       the value of the __mips_isa_rev macro, or 0 if it isn't defined.
 136 #
 137 # For example, "isa_rev>=1" selects a MIPS32 or MIPS64 processor,
 138 # "isa=4" selects a MIPS IV processor, and so on.
 139 #
 140 # There are also the following special pseudo-options:
 141 #
 142 #   isa=loongson
 143 #       select a Loongson processor
 144 #
 145 #   addressing=absolute
 146 #       force absolute addresses to be used
 147 #
 148 #   forbid_cpu=REGEXP
 149 #       forbid processors that match the given regexp; choose a
 150 #       generic ISA instead.
 151 #
 152 #
 153 # In summary:
 154 #
 155 #   (1) Try to avoid { target ... } requirements wherever possible.
 156 #       Specify the requirements as dg-options instead.
 157 #
 158 #   (2) Don't worry about the consequences of (1) for link and run tests.
 159 #       If the test uses { dg-do link } or { dg-do run }, and its
 160 #       dg-options are incompatible with the current target, the
 161 #       testsuite will downgrade them where necessary.
 162 #
 163 #   (3) Try to use the bare minimum of options and leave dg-options
 164 #       to work out the dependencies.  For example, if you want
 165 #       a MIPS-3D test, you should generally just specify -mips3d.
 166 #       Don't specify an architecture option like -mips64 unless
 167 #       the test really doesn't work with -mips32r2, -mips64r2,
 168 #       -march=sb1, etc.
 169 #
 170 #   (4) If you want something compatible with a particular option,
 171 #       but don't want to pass the option itself, wrap that option
 172 #       in parentheses.  In particular, pass '(-mips16)' if you
 173 #       want to use "mips16" attributes.
 174 #
 175 #   (5) When testing a feature of a generic ISA (as opposed to a
 176 #       processor-specific extension), try to use the "isa" and
 177 #       "isa_rev" pseudo-options instead of specific architecture
 178 #       options.  For example, if the feature is present on revision 2
 179 #       processors and above, try to use "isa_rev>=2" instead of
 180 #       "-mips32r2" or "-mips64r2".
 181 #
 182 #   (6) If you need to disable processor-specific extensions use
 183 #       forbid_cpu=REGEXP instead of forcing a generic ISA.
 184 #
 185 #
 186 # Terminology
 187 #
 188 #   Option group or just group:
 189 #      See comment before mips_option_groups.
 190 #
 191 #   Test options:
 192 #      The options specified in dg-options.
 193 #
 194 #   Explicit options:
 195 #      The options that were either passed to runtest as "multilib" options
 196 #      (e.g. -mips4 in --target_board=mips-sim-idt/-mips4) or specified as
 197 #      test options.  Note that options in parenthesis (i.e. (-mips16)) are
 198 #      not explicit and can be omitted depending on the base options.
 199 #
 200 #   Base options:
 201 #      Options that are on by default without being specified in dg-options,
 202 #      e.g. -march=mips64r2 for mipsisa64r2-elf or because they've been
 203 #      passed to runtest as "multilib" options.
 204 #
 205 #   Option array:
 206 #      Many functions in this file work with option arrays.  These are
 207 #      two-dimensional Tcl arrays where the first dimension can have three
 208 #      values: option, explicit_p or test_option_p.  The second dimension is
 209 #      the name of the option group.  "option" contains the name of the
 210 #      option that is in effect from this group.  If no option is active it
 211 #      contains the empty string.  The flags "explicit_p" and "test_option_p"
 212 #      are set for explicit and test options.
 213
 214 # Exit immediately if this isn't a MIPS target.
 215 if ![istarget mips*-*-*] {
 216     return
 217 }
 218
 219 # Load support procs.
 220 load_lib gcc-dg.exp
 221
 222 # A list of GROUP REGEXP pairs.  Each GROUP represents a logical group of
 223 # options from which only one option should be chosen.  REGEXP matches all
 224 # the options in that group; it is implicitly wrapped in "^(...)$".
 225 #
 226 # Note that -O* is deliberately omitted from this list.  Tests in this
 227 # directory are run at various optimisation levels and should use
 228 # dg-skip-if to skip any incompatible levels.
 229 set mips_option_groups {
 230     abi "-mabi=.*"
 231     addressing "addressing=.*"
 232     arch "-mips([1-5]|32.*|64.*)|-march=.*|isa(|_rev)(=|<=|>=).*"
 233     debug "-g.*"
 234     dump_pattern "-dp"
 235     endianness "-E(L|B)|-me(l|b)"
 236     float "-m(hard|soft)-float"
 237     fpu "-m(double|single)-float"
 238     forbid_cpu "forbid_cpu=.*"
 239     fp "-mfp(32|xx|64)"
 240     gp "-mgp(32|64)"
 241     long "-mlong(32|64)"
 242     micromips "-mmicromips|-mno-micromips"
 243     mips16 "-mips16|-mno-mips16|-mflip-mips16"
 244     mips3d "-mips3d|-mno-mips3d"
 245     pic "-f(no-|)(pic|PIC)"
 246     cb "-mcompact-branches=.*"
 247     profiling "-pg"
 248     small-data "-G[0-9]+"
 249     warnings "-w"
 250     dump "-fdump-.*"
 251     ins "HAS_INS"
 252     dmul "NOT_HAS_DMUL"
 253     ldc "HAS_LDC"
 254     movn "HAS_MOVN"
 255     madd "HAS_MADD"
 256     maddps "HAS_MADDPS"
 257     lsa "(|!)HAS_LSA"
 258     section_start "-Wl,--section-start=.*"
 259 }
 260
 261 for { set option 0 } { $option < 32 } { incr option } {
 262     lappend mips_option_groups "fixed-f$option" "-ffixed-f$option"
 263 }
 264
 265 # Add -mfoo/-mno-foo options to mips_option_groups.
 266 foreach option {
 267     abicalls
 268     branch-likely
 269     dsp
 270     dspr2
 271     explicit-relocs
 272     extern-sdata
 273     fix-r4000
 274     fix-r10000
 275     fix-vr4130
 276     gpopt
 277     local-sdata
 278     long-calls
 279     paired-single
 280     plt
 281     shared
 282     smartmips
 283     sym32
 284     synci
 285     relax-pic-calls
 286     mcount-ra-address
 287     odd-spreg
 288 } {
 289     lappend mips_option_groups $option "-m(no-|)$option"
 290 }
 291
 292 # Add -mfoo= options to mips_option_groups.
 293 foreach option {
 294     abs
 295     branch-cost
 296     code-readable
 297     nan
 298     r10k-cache-barrier
 299     tune
 300 } {
 301     lappend mips_option_groups $option "-m$option=.*"
 302 }
 303
 304 # Add -ffoo/-fno-foo options to mips_option_groups.
 305 foreach option {
 306     common
 307     delayed-branch
 308     expensive-optimizations
 309     fast-math
 310     fat-lto-objects
 311     finite-math-only
 312     fixed-hi
 313     fixed-lo
 314     lax-vector-conversions
 315     omit-frame-pointer
 316     optimize-sibling-calls
 317     peephole2
 318     schedule-insns2
 319     split-wide-types
 320     tree-vectorize
 321     unroll-all-loops
 322     unroll-loops
 323     ipa-ra
 324 } {
 325     lappend mips_option_groups $option "-f(no-|)$option"
 326 }
 327
 328 # A list of option groups that have an impact on the ABI.
 329 set mips_abi_groups {
 330     abi
 331     abicalls
 332     arch
 333     endianness
 334     float
 335     fp
 336     gp
 337     gpopt
 338     long
 339     pic
 340     small-data
 341 }
 342
 343 # mips_option_tests(OPTION) is some assembly code that will run to completion
 344 # on a target that supports OPTION.
 345 set mips_option_tests(-mips16) {
 346     move $2,$31
 347     bal 1f
 348     .set mips16
 349     jr $31
 350     .set nomips16
 351     .align 2
 352 1:
 353     ori $3,$31,1
 354     jalr $3
 355     move $31,$2
 356 }
 357 set mips_option_tests(-mpaired-single) {
 358     .set mips64
 359     lui $2,0x3f80
 360     mtc1 $2,$f0
 361     cvt.ps.s $f2,$f0,$f0
 362 }
 363 set mips_option_tests(-mips3d) {
 364     .set mips64
 365     .set mips3d
 366     lui $2,0x3f80
 367     mtc1 $2,$f0
 368     cvt.ps.s $f2,$f0,$f0
 369     mulr.ps $f2,$f2,$f2
 370     rsqrt1.s $f2,$f0
 371     mul.s $f4,$f2,$f0
 372     rsqrt2.s $f4,$f4,$f2
 373     madd.s $f4,$f2,$f2,$f4
 374 }
 375 set mips_option_tests(-mdsp) {
 376     .set mips64r2
 377     .set dsp
 378     addsc $2,$2,$2
 379 }
 380 set mips_option_tests(-mdspr2) {
 381     .set mips64r2
 382     .set dspr2
 383     prepend $2,$3,11
 384 }
 385
 386 # Canonicalize command-line option OPTION.
 387 proc mips_canonicalize_option { option } {
 388     regsub {^-mips([1-5]|32*|64*)$} $option {-march=mips\1} option
 389
 390     regsub {^-mel$} $option {-EL} option
 391     regsub {^-meb$} $option {-EB} option
 392
 393     regsub {^-O$} $option {-O1} option
 394
 395     # MIPS doesn't use -fpic and -fPIC to distinguish between code models.
 396     regsub {^-f(no-|)PIC} $option {-f\1pic} option
 397
 398     return $option
 399 }
 400
 401 # Return true if OPTION1 and OPTION2 represent the same command-line option.
 402 proc mips_same_option_p { option1 option2 } {
 403     return [string equal \
 404                 [mips_canonicalize_option $option1] \
 405                 [mips_canonicalize_option $option2]]
 406 }
 407
 408 # Preprocess CODE using target_compile options OPTIONS.  Return the
 409 # compiler output.
 410 proc mips_preprocess { options code } {
 411     global tool
 412
 413     set src dummy[pid].c
 414     set f [open $src "w"]
 415     puts $f $code
 416     close $f
 417     set output [${tool}_target_compile $src "" preprocess $options]
 418     file delete $src
 419
 420     return $output
 421 }
 422
 423 # Set the target board's command-line options to NEW_OPTIONS, storing the
 424 # old values in UPVAR.
 425 proc mips_push_test_options { upvar new_options } {
 426     upvar $upvar var
 427     global board_info
 428
 429     array unset var
 430     set var(name) board_info([target_info name],multilib_flags)
 431     if { [info exists $var(name)] } {
 432         set var(old_options) [set $var(name)]
 433         set $var(name) [join $new_options " "]
 434     }
 435 }
 436
 437 # Undo the effects of [mips_push_test_options UPVAR ...]
 438 proc mips_pop_test_options { upvar } {
 439     upvar $upvar var
 440     global board_info
 441
 442     if { [info exists var(old_options)] } {
 443         set $var(name) $var(old_options)
 444     }
 445 }
 446
 447 # Return property PROP for architecture option ARCH (which belongs to
 448 # the "arch" group in mips_option_groups).  See the comment at the
 449 # top of the file for the valid property names.
 450 #
 451 # Cache the results in mips_arch_info (which can be reused between test
 452 # variants).
 453 proc mips_arch_info { arch prop } {
 454     global mips_arch_info
 455     global board_info
 456
 457     set arch [mips_canonicalize_option $arch]
 458     if { ![info exists mips_arch_info($arch,$prop)] } {
 459         mips_push_test_options saved_options {}
 460         set output [mips_preprocess [list "additional_flags=$arch -mabi=32"] {
 461             int isa = __mips;
 462             #ifdef __mips_isa_rev
 463             int isa_rev = __mips_isa_rev;
 464             #else
 465             int isa_rev = 0;
 466             #endif
 467         }]
 468         foreach lhs { isa isa_rev } {
 469             regsub ".*$lhs = (\[^;\]*).*" $output {\1} rhs
 470             verbose -log "Architecture $arch has $lhs $rhs"
 471             set mips_arch_info($arch,$lhs) $rhs
 472         }
 473         mips_pop_test_options saved_options
 474     }
 475     return $mips_arch_info($arch,$prop)
 476 }
 477
 478 # Return the option group associated with OPTION, or "" if none.
 479 proc mips_option_maybe_group { option } {
 480     global mips_option_groups
 481
 482     foreach { group regexp } $mips_option_groups {
 483         if { [regexp -- "^($regexp)\$" $option] } {
 484             return $group
 485         }
 486     }
 487     return ""
 488 }
 489
 490 # Return the option group associated with OPTION.  Raise an error if
 491 # there is none.
 492 proc mips_option_group { option } {
 493     set group [mips_option_maybe_group $option]
 494     if { [string equal $group ""] } {
 495         error "Unrecognised option: $option"
 496     }
 497     return $group
 498 }
 499
 500 # Return the option for option group GROUP, or "" if no option in that
 501 # group has been chosen.  UPSTATUS describes the option status.
 502 proc mips_option { upstatus group } {
 503     upvar $upstatus status
 504
 505     return $status(option,$group)
 506 }
 507
 508 # If the base options for this test run include an option in group GROUP,
 509 # return that option, otherwise return "".
 510 proc mips_original_option { group } {
 511     global mips_base_options
 512
 513     return [mips_option mips_base_options $group]
 514 }
 515
 516 # Return true if the test described by UPSTATUS requires a specific
 517 # option in group GROUP.  UPSTATUS describes the option status.
 518 proc mips_test_option_p { upstatus group } {
 519     upvar $upstatus status
 520
 521     return $status(test_option_p,$group)
 522 }
 523
 524 # If the test described by UPSTATUS requires a particular option in group
 525 # GROUP, return that option, otherwise return "".
 526 proc mips_test_option { upstatus group } {
 527     upvar $upstatus status
 528
 529     if { [mips_test_option_p status $group] } {
 530         return [mips_option status $group]
 531     } else {
 532         return ""
 533     }
 534 }
 535
 536 # Return true if the options described by UPSTATUS include OPTION.
 537 proc mips_have_option_p { upstatus option } {
 538     upvar $upstatus status
 539
 540     return [mips_same_option_p \
 541                 [mips_option status [mips_option_group $option]] \
 542                 $option]
 543 }
 544
 545 # Return true if the options described by UPSTATUS require MIPS16 support.
 546 proc mips_using_mips16_p { upstatus } {
 547     upvar $upstatus status
 548
 549     return [expr { [mips_have_option_p status "-mips16"]
 550                    || [mips_have_option_p status "-mflip-mips16"] }]
 551 }
 552
 553 # Return true if the test described by UPSTATUS requires option OPTION.
 554 proc mips_have_test_option_p { upstatus option } {
 555     upvar $upstatus status
 556
 557     set group [mips_option_group $option]
 558     return [mips_same_option_p [mips_test_option status $group] $option]
 559 }
 560
 561 # If the test described by UPSTATUS does not specify an option in
 562 # OPTION's group, act as though it had specified OPTION.
 563 #
 564 # The first optional argument indicates whether the option should be
 565 # treated as though it were wrapped in parentheses; see the comment at
 566 # the top of the file for details about this convention.  The default is 0.
 567 proc mips_make_test_option { upstatus option args } {
 568     upvar $upstatus status
 569
 570     set group [mips_option_group $option]
 571     if { ![mips_test_option_p status $group] } {
 572         set status(option,$group) $option
 573         set status(test_option_p,$group) 1
 574         if { [llength $args] == 0 || ![lindex $args 0] } {
 575             set status(explicit_p,$group) 1
 576         }
 577     }
 578 }
 579
 580 # If the test described by UPSTATUS requires option FROM, assume that
 581 # it implicitly requires option TO.
 582 proc mips_option_dependency { upstatus from to } {
 583     upvar $upstatus status
 584
 585     if { [mips_have_test_option_p status $from] } {
 586         mips_make_test_option status $to
 587     }
 588 }
 589
 590 # Return true if the given arch-group option specifies a 32-bit ISA.
 591 proc mips_32bit_arch_p { option } {
 592     set isa [mips_arch_info $option isa]
 593     return [expr { $isa < 3 || $isa == 32 }]
 594 }
 595
 596 # Return true if the given arch-group option specifies a 64-bit ISA.
 597 proc mips_64bit_arch_p { option } {
 598     return [expr { ![mips_32bit_arch_p $option] }]
 599 }
 600
 601 # Return true if the given abi-group option implicitly requires -mgp32.
 602 proc mips_32bit_abi_p { option } {
 603     switch -glob -- $option {
 604         -mabi=32 {
 605             return 1
 606         }
 607     }
 608     return 0
 609 }
 610
 611 # Return true if the given abi-group option implicitly requires -mgp64.
 612 proc mips_64bit_abi_p { option } {
 613     switch -glob -- $option {
 614         -mabi=o64 -
 615         -mabi=n32 -
 616         -mabi=64 {
 617             return 1
 618         }
 619     }
 620     return 0
 621 }
 622
 623 # Return true if the given abi-group option implicitly requires -mlong32.
 624 # o64 requires this for -mabicalls, but not otherwise; pick the conservative
 625 # case for simplicity.
 626 proc mips_long32_abi_p { option } {
 627     switch -glob -- $option {
 628         -mabi=o64 -
 629         -mabi=n32 -
 630         -mabi=32 {
 631             return 1
 632         }
 633     }
 634     return 0
 635 }
 636
 637 # Return true if the given abi-group option implicitly requires -mlong64.
 638 proc mips_long64_abi_p { option } {
 639     switch -glob -- $option {
 640         -mabi=64 {
 641             return 1
 642         }
 643     }
 644     return 0
 645 }
 646
 647 # Check whether the current target supports all the options that the
 648 # current test requires.  Return "" if so, otherwise return one of
 649 # the incompatible options.  UPSTATUS describes the option status.
 650 proc mips_first_unsupported_option { upstatus } {
 651     global mips_option_tests
 652     upvar $upstatus status
 653
 654     foreach { option code } [array get mips_option_tests] {
 655         if { [mips_have_test_option_p status $option] } {
 656             regsub -all "\n" $code "\\n\\\n" asm
 657             # Use check_runtime from target-supports.exp, which caches
 658             # the result for us.
 659             if { ![check_runtime mips_option_$option [subst {
 660                 __attribute__((nomips16)) int
 661                 main (void)
 662                 {
 663                     asm (".set push\
 664                     $asm\
 665                     .set pop");
 666                     return 0;
 667                 }
 668             }]] } {
 669                 return $option
 670             }
 671         }
 672     }
 673     return ""
 674 }
 675
 676 # Initialize this testsuite for a new test variant.
 677 proc mips-dg-init {} {
 678     # Invariant information.
 679     global mips_option_groups
 680
 681     # Internally-generated information about this run.
 682     global mips_base_options
 683     global mips_extra_options
 684
 685     # Override dg-options with our mips-dg-options routine.
 686     rename dg-options mips-old-dg-options
 687     rename mips-dg-options dg-options
 688
 689     # Start with a fresh option status.
 690     array unset mips_base_options
 691     foreach { group regexp } $mips_option_groups {
 692         set mips_base_options(option,$group) ""
 693         set mips_base_options(explicit_p,$group) 0
 694         set mips_base_options(test_option_p,$group) 0
 695     }
 696
 697     # Use preprocessor macros to work out as many implicit options as we can.
 698     set output [mips_preprocess "" {
 699         const char *options[] = {
 700             #if !defined _MIPS_SIM
 701             "-mabi=eabi",
 702             #elif _MIPS_SIM==_ABIO32
 703             "-mabi=32",
 704             #elif _MIPS_SIM==_ABIO64
 705             "-mabi=o64",
 706             #elif _MIPS_SIM==_ABIN32
 707             "-mabi=n32",
 708             #else
 709             "-mabi=64",
 710             #endif
 711
 712             "-march=" _MIPS_ARCH,
 713
 714             #ifdef _MIPSEB
 715             "-EB",
 716             #else
 717             "-EL",
 718             #endif
 719
 720             #ifdef __mips_hard_float
 721             "-mhard-float",
 722             #else
 723             "-msoft-float",
 724             #endif
 725
 726             #ifdef __mips_abs2008
 727             "-mabs=2008",
 728             #else
 729             "-mabs=legacy",
 730             #endif
 731
 732             #ifdef __mips_nan2008
 733             "-mnan=2008",
 734             #else
 735             "-mnan=legacy",
 736             #endif
 737
 738             #if __mips_fpr == 64
 739             "-mfp64",
 740             #else
 741             #if __mips_fpr == 0
 742             "-mfpxx",
 743             #else
 744             "-mfp32",
 745             #endif
 746             #endif
 747
 748             #ifdef __mips64
 749             "-mgp64",
 750             #else
 751             "-mgp32",
 752             #endif
 753
 754             #if _MIPS_SZLONG == 64
 755             "-mlong64",
 756             #else
 757             "-mlong32",
 758             #endif
 759
 760             #ifdef __mips16
 761             "-mips16",
 762             #else
 763             "-mno-mips16",
 764             #endif
 765
 766             #ifdef __mips3d
 767             "-mips3d",
 768             #else
 769             "-mno-mips3d",
 770             #endif
 771
 772             #ifdef __mips_paired_single_float
 773             "-mpaired-single",
 774             #else
 775             "-mno-paired-single",
 776             #endif
 777
 778             #if _MIPS_SPFPSET == 32
 779             "-modd-spreg",
 780             #else
 781             "-mno-odd-spreg",
 782             #endif
 783
 784             #if __mips_abicalls
 785             "-mabicalls",
 786             #else
 787             "-mno-abicalls",
 788             #endif
 789
 790             #if __mips_dsp_rev >= 2
 791             "-mdspr2",
 792             #else
 793             "-mno-dspr2",
 794             #endif
 795
 796             #if __mips_dsp_rev >= 1
 797             "-mdsp",
 798             #else
 799             "-mno-dsp",
 800             #endif
 801
 802             #ifndef __PIC__
 803             "addressing=absolute",
 804             #endif
 805
 806             #ifdef __mips_smartmips
 807             "-msmartmips",
 808             #else
 809             "-mno-smartmips",
 810             #endif
 811
 812             #ifdef __mips_synci
 813             "-msynci",
 814             #else
 815             "-mno-synci",
 816             #endif
 817
 818             0
 819         };
 820     }]
 821     foreach line [split $output "\r\n"] {
 822         # Poor man's string concatenation.
 823         regsub -all {" "} $line "" line
 824         if { [regexp {"(.*)",} $line dummy option] } {
 825             set group [mips_option_group $option]
 826             set mips_base_options(option,$group) $option
 827         }
 828     }
 829
 830     # Process the target's multilib options, saving any unrecognized
 831     # ones in mips_extra_options.
 832     set mips_extra_options {}
 833     foreach option [split [board_info target multilib_flags]] {
 834         set group [mips_option_maybe_group $option]
 835         if { ![string equal $group ""] } {
 836             set mips_base_options(option,$group) $option
 837             set mips_base_options(explicit_p,$group) 1
 838         } else {
 839             lappend mips_extra_options $option
 840         }
 841     }
 842 }
 843
 844 # Finish a test run started by mips-dg-init.
 845 proc mips-dg-finish {} {
 846     rename dg-options mips-dg-options
 847     rename mips-old-dg-options dg-options
 848 }
 849
 850 # Override dg-options so that we can do some MIPS-specific processing.
 851 # All options used in this testsuite must appear in mips_option_groups.
 852 #
 853 # Test options override multilib options.  Certain test options can
 854 # also imply other test options, which also override multilib options.
 855 # These dependencies are ordered as follows:
 856 #
 857 #          START                        END
 858 #            |                           |
 859 #         -mips16/-mflip-mips16       -mno-mips16
 860 #            |                           |
 861 #         -micromips                  -mno-micromips
 862 #            |                           |
 863 #         -mips3d                     -mno-mips3d
 864 #            |                           |
 865 #         -mpaired-single             -mno-paired-single
 866 #            |                           |
 867 #         -mfp64                      -mfp32
 868 #            |                           |
 869 #         -modd-spreg                 -mno-odd-spreg
 870 #            |                           |
 871 #         -mdouble-float              -msingle-float
 872 #            |                           |
 873 #         -mabs=2008/-mabs=legacy     <no option>
 874 #            |                           |
 875 #         -mhard-float                -msoft-float
 876 #            |                           |
 877 #         -mno-sym32                  -msym32
 878 #            |                           |
 879 #         -mrelax-pic-calls           -mno-relax-pic-calls
 880 #            |                           |
 881 #         -fpic                       -fno-pic
 882 #            |                           |
 883 #         -mshared                    -mno-shared
 884 #            |                           |
 885 #         -mno-plt                    -mplt
 886 #            |                           |
 887 #         addressing=unknown          addressing=absolute
 888 #            |                           |
 889 #         -mabicalls                  -mno-abicalls
 890 #            |                           |
 891 #         -G0                         <other value>
 892 #            |                           |
 893 #         <other value>               -mr10k-cache-barrier=none
 894 #            |                           |
 895 #         -mfix-r10000                -mno-fix-r10000
 896 #            |                           |
 897 #         -mbranch-likely             -mno-branch-likely
 898 #            |                           |
 899 #         -msmartmips                 -mno-smartmips
 900 #            |                           |
 901 #         -mno-gpopt                  -mgpopt
 902 #            |                           |
 903 #         -mexplicit-relocs           -mno-explicit-relocs
 904 #            |                           |
 905 #         -mdspr2                     -mno-dspr2
 906 #            |                           |
 907 #         -mdsp                       -mno-dsp
 908 #            |                           |
 909 #         -msynci                     -mno-synci
 910 #            |                           |
 911 #            +-- gp, abi & arch ---------+
 912 #
 913 # For these purposes, the "gp", "abi" & "arch" option groups are treated
 914 # as a single node.
 915 proc mips-dg-options { args } {
 916     # dg.exp variables.
 917     upvar dg-extra-tool-flags extra_tool_flags
 918     upvar dg-do-what do_what
 919
 920     # Invariant information.
 921     global mips_option_groups
 922     global mips_abi_groups
 923
 924     # Information about this run.
 925     global mips_base_options
 926
 927     if { [llength $args] >= 3 } {
 928         switch { [dg-process-target [lindex $args 2]] } {
 929             "S" { }
 930             "N" { return }
 931             "F" { error "[lindex $args 0]: `xfail' not allowed here" }
 932             "P" { error "[lindex $args 0]: `xfail' not allowed here" }
 933         }
 934     }
 935
 936     # Start out with the default option state.
 937     array set options [array get mips_base_options]
 938
 939     # Record the options that this test explicitly needs.
 940     foreach option [lindex $args 1] {
 941         set all_but_p [regexp {^\((.*)\)$} $option dummy option]
 942         set group [mips_option_group $option]
 943         if { [mips_test_option_p options $group] } {
 944             set old [mips_option options $group]
 945             error "Inconsistent $group option: $old vs. $option"
 946         } else {
 947             mips_make_test_option options $option $all_but_p
 948         }
 949     }
 950
 951     # Handle dependencies between the test options and the optimization ones.
 952     mips_option_dependency options "-fno-unroll-loops" "-fno-unroll-all-loops"
 953     mips_option_dependency options "-pg" "-fno-omit-frame-pointer"
 954
 955     # Handle dependencies between options on the left of the
 956     # dependency diagram.
 957     mips_option_dependency options "-mips16" "-mno-micromips"
 958     mips_option_dependency options "-mmicromips" "-mno-mips16"
 959     mips_option_dependency options "-mips3d" "-mpaired-single"
 960     mips_option_dependency options "-mips3d" "-mno-micromips"
 961     mips_option_dependency options "-mpaired-single" "-mfp64"
 962     mips_option_dependency options "-mfp64" "-mhard-float"
 963     mips_option_dependency options "-mfp32" "-mhard-float"
 964     mips_option_dependency options "-mfpxx" "-mhard-float"
 965     mips_option_dependency options "-mfp64" "-modd-spreg"
 966     mips_option_dependency options "-mfp64" "-mdouble-float"
 967     mips_option_dependency options "-mfp32" "-mdouble-float"
 968     mips_option_dependency options "-mfpxx" "-mdouble-float"
 969     mips_option_dependency options "-mabs=2008" "-mhard-float"
 970     mips_option_dependency options "-mabs=legacy" "-mhard-float"
 971     mips_option_dependency options "-mrelax-pic-calls" "-mno-plt"
 972     mips_option_dependency options "-mrelax-pic-calls" "-mabicalls"
 973     mips_option_dependency options "-mrelax-pic-calls" "-mexplicit-relocs"
 974     mips_option_dependency options "-fpic" "-mshared"
 975     mips_option_dependency options "-mshared" "-mno-plt"
 976     mips_option_dependency options "-mshared" "-mabicalls"
 977     mips_option_dependency options "-mno-plt" "addressing=unknown"
 978     mips_option_dependency options "-mabicalls" "-G0"
 979     mips_option_dependency options "-mno-gpopt" "-mexplicit-relocs"
 980
 981     # Work out information about the current ABI.
 982     set abi_test_option_p [mips_test_option_p options abi]
 983     set abi [mips_option options abi]
 984     set eabi_p [mips_same_option_p $abi "-mabi=eabi"]
 985
 986     # If the test forces a particular ABI, set the register size
 987     # accordingly.
 988     if { $abi_test_option_p } {
 989         if { [mips_32bit_abi_p $abi] } {
 990             mips_make_test_option options "-mgp32"
 991         } elseif { [mips_64bit_abi_p $abi] } {
 992             mips_make_test_option options "-mgp64"
 993         }
 994     }
 995
 996     # See whether forbid_cpu forces us to choose a new architecture.
 997     set arch [mips_option mips_base_options arch]
 998     set force_generic_isa_p [expr {
 999         [regexp "forbid_cpu=(.*)" [mips_option options forbid_cpu] dummy spec]
1000         && [regexp -- "^-march=$spec\$" $arch]
1001     }]
1002
1003     # Interpret the special "isa" and "isa_rev" options.  If we have
1004     # a choice of a 32-bit or a 64-bit architecture, prefer to keep
1005     # the -mgp setting the same.
1006     set spec [mips_option options arch]
1007     if { [regexp {^[^-]} $spec] } {
1008         if { [string equal $spec "isa=loongson"] } {
1009             if { ![regexp {^-march=loongson} $arch] } {
1010                 set arch "-march=loongson2f"
1011             }
1012         } else {
1013             if { ![regexp {^(isa(?:|_rev))(=|<=|>=)([0-9]*)$} \
1014                        $spec dummy prop relation value nocpus] } {
1015                 error "Unrecognized isa specification: $spec"
1016             }
1017             set current [mips_arch_info $arch $prop]
1018             if { $force_generic_isa_p
1019                  || ($current < $value && ![string equal $relation "<="])
1020                  || ($current > $value && ![string equal $relation ">="])
1021                  || ([mips_have_test_option_p options "-mgp64"]
1022                      && [mips_32bit_arch_p $arch]) } {
1023                 # The current setting is out of range; it cannot
1024                 # possibly be used.  Find a replacement that can.
1025                 if { [string equal $prop "isa"] } {
1026                     set arch "-mips$value"
1027                 } elseif { $value == 0 } {
1028                     set arch "-mips4"
1029                 } else {
1030                     if { [mips_have_option_p options "-mgp32"] } {
1031                         set arch "-mips32"
1032                     } else {
1033                         set arch "-mips64"
1034                     }
1035                     if { $value > 1 } {
1036                         append arch "r$value"
1037                     }
1038                 }
1039             }
1040         }
1041         set options(option,arch) $arch
1042     }
1043
1044     # Work out information about the current architecture.
1045     set arch_test_option_p [mips_test_option_p options arch]
1046     set arch [mips_option options arch]
1047     set isa [mips_arch_info $arch isa]
1048     set isa_rev [mips_arch_info $arch isa_rev]
1049     set orig_isa_rev $isa_rev
1050
1051     # If the test forces a 32-bit architecture, force -mgp32.
1052     # Force the current -mgp setting otherwise; if we don't,
1053     # some configurations would make a 64-bit architecture
1054     # imply -mgp64.
1055     if { $arch_test_option_p } {
1056         if { [mips_32bit_arch_p $arch] } {
1057             mips_make_test_option options "-mgp32"
1058         } else {
1059             mips_make_test_option options [mips_option options gp]
1060         }
1061     }
1062
1063     # We've now fixed the GP register size.  Make it easily available.
1064     set gp_size [expr { [mips_have_option_p options "-mgp32"] ? 32 : 64 }]
1065
1066     # Handle dependencies between the pre-arch options and the arch option.
1067     # This should mirror the arch and post-arch code below.
1068     if { !$arch_test_option_p } {
1069         # We need a revision 6 or better ISA for:
1070         #
1071         #   - When the LSA instruction is required
1072         #   - When only using compact branches
1073         if { $isa_rev < 6
1074              && ([mips_have_test_option_p options "HAS_LSA"]
1075                  || [mips_have_test_option_p options "-mcompact-branches=always"]) } {
1076             if { $gp_size == 32 } {
1077                 mips_make_test_option options "-mips32r6"
1078             } else {
1079                 mips_make_test_option options "-mips64r6"
1080             }
1081         # We need a revision 2 or better ISA for:
1082         #
1083         #   - the combination of -mgp32 -mfp64
1084         #   - the DSP ASE
1085         } elseif { $isa_rev < 2
1086              && (($gp_size == 32 && [mips_have_test_option_p options "-mfp64"])
1087                  || [mips_have_test_option_p options "-msynci"]
1088                  || [mips_have_test_option_p options "-mdsp"]
1089                  || [mips_have_test_option_p options "HAS_INS"]
1090                  || [mips_have_test_option_p options "HAS_MADD"]
1091                  || [mips_have_test_option_p options "HAS_MADDPS"]
1092                  || [mips_have_test_option_p options "-mdspr2"]) } {
1093             if { $gp_size == 32 } {
1094                 mips_make_test_option options "-mips32r2"
1095             } else {
1096                 mips_make_test_option options "-mips64r2"
1097             }
1098         # We need a MIPS32 or MIPS64 ISA for:
1099         #
1100         #   - paired-single instructions(*)
1101         #   - odd numbered single precision registers
1102         #
1103         # (*) Note that we don't support MIPS V at the moment.
1104         } elseif { $isa_rev < 1
1105                    && ([mips_have_test_option_p options "-mpaired-single"]
1106                        || ([mips_have_test_option_p options "-modd-spreg"]
1107                            && ![mips_have_test_option_p options "-mfp64"]))} {
1108             if { $gp_size == 32 } {
1109                 mips_make_test_option options "-mips32"
1110             } else {
1111                 mips_make_test_option options "-mips64"
1112             }
1113         # We need MIPS IV or higher for:
1114         #
1115         #
1116         } elseif { $isa < 3
1117                    && [mips_have_test_option_p options "HAS_MOVN"] } {
1118             mips_make_test_option options "-mips4"
1119         # We need MIPS III or higher for:
1120         #
1121         #   - the "cache" instruction
1122         } elseif { $isa < 3
1123                    && ([mips_have_test_option_p options \
1124                             "-mr10k-cache-barrier=load-store"]
1125                        || [mips_have_test_option_p options \
1126                                "-mr10k-cache-barrier=store"]) } {
1127             mips_make_test_option options "-mips3"
1128         # We need MIPS II or higher for:
1129         #
1130         #   - branch-likely instructions(*)
1131         #
1132         # (*) needed by both -mbranch-likely and -mfix-r10000
1133         } elseif { $isa < 2
1134                    && ([mips_have_test_option_p options "-mbranch-likely"]
1135                        || [mips_have_test_option_p options "-mfix-r10000"]
1136                        || ($gp_size == 32
1137                            && ([mips_have_test_option_p options "-mfpxx"]
1138                                || [mips_have_test_option_p options "HAS_LDC"]))) } {
1139             mips_make_test_option options "-mips2"
1140         # We need to use octeon's base ISA if a test must not run with an
1141         # architecture that supports dmul.
1142         } elseif { [regexp -- "^-march=octeon.*\$" $arch]
1143                    && [mips_have_test_option_p options "NOT_HAS_DMUL"] } {
1144             mips_make_test_option options "-mips${isa}r${isa_rev}"
1145         # Check whether we need to switch from mips*r6 down to mips*r5 due
1146         # to options that are incompatible with mips*r6.  If we do, use
1147         # -mnan=2008 because r6 is nan2008 by default and without this flag
1148         # tests that include stdlib.h will fail due to not finding
1149         # stubs-o32_hard.h  (r6 compilers only have stubs-o32_hard_2008.h)
1150         } elseif { $isa_rev > 5
1151                    && ([mips_have_test_option_p options "-mdsp"]
1152                        || [mips_have_test_option_p options "-mdspr2"]
1153                        || [mips_have_test_option_p options "-mips16"]
1154                        || [mips_have_test_option_p options "-mmicromips"]
1155                        || [mips_have_test_option_p options "-mfp32"]
1156                        || [mips_have_test_option_p options "-mfix-r10000"]
1157                        || [mips_have_test_option_p options "NOT_HAS_DMUL"]
1158                        || [mips_have_test_option_p options "HAS_MOVN"]
1159                        || [mips_have_test_option_p options "HAS_MADD"]
1160                        || [mips_have_test_option_p options "-mpaired-single"]
1161                        || [mips_have_test_option_p options "-mnan=legacy"]
1162                        || [mips_have_test_option_p options "-mabs=legacy"]
1163                        || [mips_have_test_option_p options "!HAS_LSA"]) } {
1164             if { $gp_size == 32 } {
1165                 mips_make_test_option options "-mips32r5"
1166             } else {
1167                 mips_make_test_option options "-mips64r5"
1168             }
1169             mips_make_test_option options "-mnan=2008"
1170             if { [mips_have_option_p options "-mcompact-branches=always"] } {
1171                 mips_make_test_option options "-mcompact-branches=optimal"
1172             }
1173         # Check whether we need to switch from a 32-bit processor to the
1174         # "nearest" 64-bit processor.
1175         } elseif { $gp_size == 64 && [mips_32bit_arch_p $arch] } {
1176             if { $isa_rev == 0 } {
1177                 mips_make_test_option options "-mips3"
1178             } elseif { $isa_rev == 1 } {
1179                 mips_make_test_option options "-mips64"
1180             } else {
1181                 mips_make_test_option options "-mips64r$isa_rev"
1182             }
1183         # Otherwise, if the current choice of architecture is unacceptable,
1184         # choose the equivalent generic architecture.
1185         } elseif { $force_generic_isa_p } {
1186             set arch "-mips[mips_arch_info $arch isa]"
1187             if { $isa_rev > 1 } {
1188                 append arch "r$isa_rev"
1189             }
1190             mips_make_test_option options $arch
1191         }
1192         unset arch
1193         unset isa
1194         unset isa_rev
1195     }
1196
1197     # Re-calculate the isa_rev for use in the abi handling code below
1198     set arch [mips_option options arch]
1199     set isa [mips_arch_info $arch isa]
1200     set isa_rev [mips_arch_info $arch isa_rev]
1201
1202     # Set an appropriate ABI, handling dependencies between the pre-abi
1203     # options and the abi options.  This should mirror the abi and post-abi
1204     # code below.
1205     if { !$abi_test_option_p } {
1206         if { ($eabi_p
1207               && ([mips_have_option_p options "-mabicalls"]
1208                   || ($gp_size == 32
1209                       && [mips_have_option_p options "-mfp64"]))) } {
1210             # EABI doesn't support -mabicalls.
1211             # EABI doesn't support the combination -mgp32 -mfp64.
1212             set force_abi 1
1213         } elseif { [mips_using_mips16_p options]
1214                    && ![mips_same_option_p $abi "-mabi=32"]
1215                    && ![mips_same_option_p $abi "-mabi=o64"]
1216                    && (![mips_have_option_p options "addressing=absolute"]
1217                        || [mips_have_option_p options "-mhard-float"]) } {
1218             # -mips16 -mhard-float requires o32 or o64.
1219             # -mips16 PIC requires o32 or o64.
1220             set force_abi 1
1221         } elseif { [mips_have_test_option_p options "-mlong32"]
1222                    && [mips_long64_abi_p $abi] } {
1223             set force_abi 1
1224         } elseif { [mips_have_test_option_p options "-mlong64"]
1225                    && [mips_long32_abi_p $abi] } {
1226             set force_abi 1
1227         } elseif { [mips_have_test_option_p options "-mfpxx"]
1228                    && ![mips_same_option_p $abi "-mabi=32"] } {
1229             set force_abi 1
1230         } else {
1231             set force_abi 0
1232         }
1233         if { $gp_size == 32 } {
1234             if { $force_abi || [mips_64bit_abi_p $abi] } {
1235                 if { [mips_have_test_option_p options "-mlong64"] } {
1236                     mips_make_test_option options "-mabi=eabi"
1237                     mips_make_test_option options "-mgp32"
1238                 } else {
1239                     mips_make_test_option options "-mabi=32"
1240                 }
1241             }
1242         } else {
1243             if { $force_abi || [mips_32bit_abi_p $abi] } {
1244                 if { [mips_have_test_option_p options "-mlong64"] } {
1245                     mips_make_test_option options "-mabi=eabi"
1246                     mips_make_test_option options "-mgp64"
1247                 } else {
1248                     # All configurations should have an assembler that
1249                     # supports o64, since it requires the same BFD target
1250                     # vector as o32.  In contrast, many assembler
1251                     # configurations do not have n32 or n64 support.
1252                     mips_make_test_option options "-mabi=o64"
1253                 }
1254             }
1255         }
1256         set abi_test_option_p [mips_test_option_p options abi]
1257         set abi [mips_option options abi]
1258         set eabi_p [mips_same_option_p $abi "-mabi=eabi"]
1259     }
1260
1261     # Handle dependencies between the abi options and the post-abi options.
1262     # This should mirror the abi and pre-abi code above.
1263     if { $abi_test_option_p } {
1264         if { $eabi_p } {
1265             mips_make_test_option options "-mno-abicalls"
1266             if { $isa_rev < 6 && $gp_size == 32 } {
1267                     mips_make_test_option options "-mfp32"
1268             }
1269         }
1270         if { [mips_using_mips16_p options]
1271              && ![mips_same_option_p $abi "-mabi=32"]
1272              && ![mips_same_option_p $abi "-mabi=o64"]
1273              && ([mips_have_option_p options "-mabicalls"]
1274                  || [mips_have_option_p options "-mhard-float"]) } {
1275             if { [mips_test_option_p options mips16] } {
1276                 mips_make_test_option options "addressing=absolute"
1277                 mips_make_test_option options "-msoft-float"
1278             } else {
1279                 mips_make_test_option options "-mno-mips16"
1280             }
1281         }
1282         if { [mips_long32_abi_p $abi] } {
1283             mips_make_test_option options "-mlong32"
1284         } elseif { [mips_long64_abi_p $abi] } {
1285             mips_make_test_option options "-mlong64"
1286         }
1287     }
1288
1289     # Handle dependencies between the arch option and the post-arch options.
1290     # This should mirror the arch and pre-arch code above.  For pre-r6
1291     # architectures this only needs to be done when we've moved down
1292     # to a lower architecture and might need to turn features off,
1293     # but moving up from pre-r6 to r6 can remove features too.
1294     if { $arch_test_option_p || ($orig_isa_rev < 6 && $isa_rev >= 6) } {
1295         if { $isa < 2 } {
1296             mips_make_test_option options "-mno-branch-likely"
1297             mips_make_test_option options "-mno-fix-r10000"
1298         }
1299         if { $isa < 3 } {
1300             mips_make_test_option options "-mr10k-cache-barrier=none"
1301         }
1302         if { $isa_rev < 1 } {
1303             mips_make_test_option options "-mno-paired-single"
1304             if { ![mips_have_test_option_p options "-mgp64"] } {
1305                 mips_make_test_option options "-mno-odd-spreg"
1306             }
1307         }
1308         if { $isa_rev < 2 } {
1309             if { $gp_size == 32 } {
1310                 mips_make_test_option options "-mfp32"
1311             }
1312             mips_make_test_option options "-mno-dsp"
1313             mips_make_test_option options "-mno-synci"
1314             mips_make_test_option options "-mno-micromips"
1315             mips_make_test_option options "-mnan=legacy"
1316         }
1317         if { $isa_rev < 6 } {
1318             if { [mips_have_option_p options "-mcompact-branches=always"] } {
1319                 mips_make_test_option options "-mcompact-branches=optimal"
1320             }
1321         }
1322         if { $isa_rev > 5 } {
1323             mips_make_test_option options "-mno-dsp"
1324             mips_make_test_option options "-mno-mips16"
1325             if { [mips_have_test_option_p options "-mdsp"] } {
1326                 mips_make_test_option options "-mfp64"
1327             }
1328             mips_make_test_option options "-mno-fix-r10000"
1329             mips_make_test_option options "-mno-paired-single"
1330             mips_make_test_option options "-mnan=2008"
1331             mips_make_test_option options "-mabs=2008"
1332         }
1333         if { [regexp {^-march=(octeon|loongson)} $arch] } {
1334             mips_make_test_option options "-mno-micromips"
1335         }
1336
1337         unset arch
1338         unset isa
1339         unset isa_rev
1340     }
1341
1342     # Handle dependencies between options on the right of the diagram.
1343     mips_option_dependency options "-mno-dsp" "-mno-dspr2"
1344     mips_option_dependency options "-mno-explicit-relocs" "-mgpopt"
1345     switch -- [mips_test_option options small-data] {
1346         "" -
1347         -G0 {}
1348         default {
1349             mips_make_test_option options "-mno-abicalls"
1350         }
1351     }
1352     if { [mips_have_option_p options "-mabicalls"] } {
1353         mips_option_dependency options "addressing=absolute" "-mplt"
1354     }
1355     mips_option_dependency options "-mplt" "-msym32"
1356     mips_option_dependency options "-mplt" "-mno-shared"
1357     mips_option_dependency options "-mno-shared" "-fno-pic"
1358     mips_option_dependency options "-mfp32" "-mno-paired-single"
1359     mips_option_dependency options "-mfpxx" "-mno-paired-single"
1360     mips_option_dependency options "-msoft-float" "-mno-paired-single"
1361     mips_option_dependency options "-mno-paired-single" "-mno-mips3d"
1362
1363     # If the test requires an unsupported option, change run tests
1364     # to link tests.
1365
1366     switch -- [lindex $do_what 0] {
1367         run {
1368             set option [mips_first_unsupported_option options]
1369             if { ![string equal $option ""] } {
1370                 set do_what [lreplace $do_what 0 0 link]
1371                 verbose -log "Downgraded to a 'link' test due to unsupported option '$option'"
1372             }
1373         }
1374     }
1375
1376     # If the test has overridden a option that changes the ABI,
1377     # downgrade a link or execution test to an assembler test.
1378     foreach group $mips_abi_groups {
1379         set old_option [mips_original_option $group]
1380         set new_option [mips_option options $group]
1381         if { ![mips_same_option_p $old_option $new_option]
1382              && ![mips_same_option_p $old_option "-mfpxx"]
1383              && ![mips_same_option_p $new_option "-mfpxx"] } {
1384             switch -- [lindex $do_what 0] {
1385                 link -
1386                 run {
1387                     set do_what [lreplace $do_what 0 0 assemble]
1388                     verbose -log "Downgraded to an 'assemble' test due to incompatible $group option ($old_option changed to $new_option)"
1389                 }
1390             }
1391             break
1392         }
1393     }
1394
1395     # Add all options to the dg variable.
1396     set options(explicit_p,addressing) 0
1397     set options(explicit_p,forbid_cpu) 0
1398     foreach { group regexp } $mips_option_groups {
1399         if { $options(explicit_p,$group) } {
1400             append extra_tool_flags " " $options(option,$group)
1401         }
1402     }
1403
1404     # If the test is MIPS16-compatible, provide a counterpart to the
1405     # NOMIPS16 convenience macro.
1406     if { [mips_have_test_option_p options "-mips16"] } {
1407         append extra_tool_flags " -DMIPS16=__attribute__((mips16))"
1408     }
1409
1410     if { [mips_have_test_option_p options "-mmicromips"] } {
1411         append extra_tool_flags " -DMICROMIPS=__attribute__((micromips))"
1412     }
1413
1414     # Use our version of gcc-dg-test for this test.
1415     if { ![string equal [info procs "mips-gcc-dg-test"] ""] } {
1416         rename gcc-dg-test mips-old-gcc-dg-test
1417         rename mips-gcc-dg-test gcc-dg-test
1418     }
1419 }
1420
1421 # A version of gcc-dg-test that is used by dg-options tests.
1422 proc mips-gcc-dg-test { prog do_what extra_tool_flags } {
1423     global board_info
1424     global mips_extra_options
1425
1426     # Override the user's chosen test options with the combined test/user
1427     # version.
1428     mips_push_test_options saved_options $mips_extra_options
1429     set result [gcc-dg-test-1 gcc_target_compile $prog \
1430                     $do_what $extra_tool_flags]
1431     mips_pop_test_options saved_options
1432
1433     # Restore the usual gcc-dg-test.
1434     rename gcc-dg-test mips-gcc-dg-test
1435     rename mips-old-gcc-dg-test gcc-dg-test
1436
1437     return $result
1438 }
1439
1440 dg-init
1441 mips-dg-init
1442 gcc-dg-runtest [lsort [glob -nocomplain $srcdir/$subdir/*.c]] \
1443     "" "-DNOMIPS16=__attribute__((nomips16)) -DNOMICROMIPS=__attribute__((nomicromips)) -DNOCOMPRESSION=__attribute__((nocompression))"
1444 mips-dg-finish
1445 dg-finish