gcc/ada/sem_attr.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ A T T R                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Attribute handling is isolated in a separate package to ease the addition
  28 --  of implementation defined attributes. Logically this processing belongs
  29 --  in chapter 4. See Sem_Ch4 for a description of the relation of the
  30 --  Analyze and Resolve routines for expression components.
  31
  32 --  This spec also documents all GNAT implementation defined pragmas
  33
  34 with Exp_Tss; use Exp_Tss;
  35 with Namet;   use Namet;
  36 with Snames;  use Snames;
  37 with Types;   use Types;
  38
  39 package Sem_Attr is
  40
  41    -----------------------------------------
  42    -- Implementation Dependent Attributes --
  43    -----------------------------------------
  44
  45    --  This section describes the implementation dependent attributes
  46    --  provided in GNAT, as well as constructing an array of flags
  47    --  indicating which attributes these are.
  48
  49    Attribute_Impl_Def : Attribute_Class_Array := Attribute_Class_Array'(
  50
  51       ------------------
  52       -- Abort_Signal --
  53       ------------------
  54
  55       Attribute_Abort_Signal => True,
  56       --  Standard'Abort_Signal (Standard is the only allowed prefix) provides
  57       --  the entity for the special exception used to signal task abort or
  58       --  asynchronous transfer of control. Normally this attribute should only
  59       --  be used in the tasking runtime (it is highly peculiar, and completely
  60       --  outside the normal semantics of Ada, for a user program to intercept
  61       --  the abort exception).
  62
  63       ------------------
  64       -- Address_Size --
  65       ------------------
  66
  67       Attribute_Address_Size => True,
  68       --  Standard'Address_Size (Standard is the only allowed prefix) is
  69       --  a static constant giving the number of bits in an Address. It
  70       --  is used primarily for constructing the definition of Memory_Size
  71       --  in package Standard, but may be freely used in user programs.
  72       --  This is a static attribute.
  73
  74       ---------------
  75       -- Asm_Input --
  76       ---------------
  77
  78       Attribute_Asm_Input => True,
  79       --  Used only in conjunction with the Asm subprograms in package
  80       --  Machine_Code to construct machine instructions. See documentation
  81       --  in package Machine_Code in file s-maccod.ads.
  82
  83       ----------------
  84       -- Asm_Output --
  85       ----------------
  86
  87       Attribute_Asm_Output => True,
  88       --  Used only in conjunction with the Asm subprograms in package
  89       --  Machine_Code to construct machine instructions. See documentation
  90       --  in package Machine_Code in file s-maccod.ads.
  91
  92       ---------------
  93       -- AST_Entry --
  94       ---------------
  95
  96       Attribute_AST_Entry => True,
  97       --  E'Ast_Entry, where E is a task entry, yields a value of the
  98       --  predefined type System.DEC.AST_Handler, that enables the given
  99       --  entry to be called when an AST occurs. If the name to which the
 100       --  attribute applies has not been specified with the pragma AST_Entry,
 101       --  the attribute returns the value No_Ast_Handler, and no AST occurs.
 102       --  If the entry is for a task that is not callable (T'Callable False),
 103       --  the exception program error is raised. If an AST occurs for an
 104       --  entry of a task that is terminated, the program is erroneous.
 105       --
 106       --  The attribute AST_Entry is supported only in OpenVMS versions
 107       --  of GNAT. It will be rejected as illegal in other GNAT versions.
 108
 109       ---------
 110       -- Bit --
 111       ---------
 112
 113       Attribute_Bit => True,
 114       --  Obj'Bit, where Obj is any object, yields the bit offset within the
 115       --  storage unit (byte) that contains the first bit of storage allocated
 116       --  for the object. The attribute value is of type Universal_Integer,
 117       --  and is always a non-negative number not exceeding the value of
 118       --  System.Storage_Unit.
 119       --
 120       --  For an object that is a variable or a constant allocated in a
 121       --  register, the value is zero. (The use of this attribute does not
 122       --  force the allocation of a variable to memory).
 123       --
 124       --  For an object that is a formal parameter, this attribute applies to
 125       --  either the matching actual parameter or to a copy of the matching
 126       --  actual parameter.
 127       --
 128       --  For an access object the value is zero. Note that Obj.all'Bit is
 129       --  subject to an Access_Check for the designated object. Similarly
 130       --  for a record component X.C'Bit is subject to a discriminant check
 131       --  and X(I).Bit and X(I1..I2)'Bit are subject to index checks.
 132       --
 133       --  This attribute is designed to be compatible with the DEC Ada
 134       --  definition and implementation of the Bit attribute.
 135
 136       ------------------
 137       -- Code_Address --
 138       ------------------
 139
 140       Attribute_Code_Address => True,
 141       --  The reference subp'Code_Address, where subp is a subprogram entity,
 142       --  gives the address of the first generated instruction for the sub-
 143       --  program. This is often, but not always the same as the 'Address
 144       --  value, which is the address to be used in a call. The differences
 145       --  occur in the case of a nested procedure (where Address yields the
 146       --  address of the trampoline code used to load the static link), and on
 147       --  some systems which use procedure descriptors (in which case Address
 148       --  yields the address of the descriptor).
 149
 150       -----------------------
 151       -- Default_Bit_Order --
 152       -----------------------
 153
 154       Attribute_Default_Bit_Order => True,
 155       --  Standard'Default_Bit_Order (Standard is the only permissible prefix),
 156       --  provides the value System.Default_Bit_Order as a Pos value (0 for
 157       --  High_Order_First, 1 for Low_Order_First). This is used to construct
 158       --  the definition of Default_Bit_Order in package System. This is a
 159       --  static attribute.
 160
 161       ---------------
 162       -- Elab_Body --
 163       ---------------
 164
 165       Attribute_Elab_Body => True,
 166       --  This attribute can only be applied to a program unit name. It returns
 167       --  the entity for the corresponding elaboration procedure for elabor-
 168       --  ating the body of the referenced unit. This is used in the main
 169       --  generated elaboration procedure by the binder, and is not normally
 170       --  used in any other context, but there may be specialized situations in
 171       --  which it is useful to be able to call this elaboration procedure from
 172       --  Ada code, e.g. if it is necessary to do selective reelaboration to
 173       --  fix some error.
 174
 175       ---------------
 176       -- Elab_Spec --
 177       ---------------
 178
 179       Attribute_Elab_Spec => True,
 180       --  This attribute can only be applied to a program unit name. It
 181       --  returns the entity for the corresponding elaboration procedure
 182       --  for elaborating the spec of the referenced unit. This is used
 183       --  in the main generated elaboration procedure by the binder, and
 184       --  is not normally used in any other context, but there may be
 185       --  specialized situations in which it is useful to be able to
 186       --  call this elaboration procedure from Ada code, e.g. if it
 187       --  is necessary to do selective reelaboration to fix some error.
 188
 189       ----------------
 190       -- Elaborated --
 191       ----------------
 192
 193       Attribute_Elaborated => True,
 194       --  Lunit'Elaborated, where Lunit is a library unit, yields a boolean
 195       --  value indicating whether or not the body of the designated library
 196       --  unit has been elaborated yet.
 197
 198       --------------
 199       -- Enum_Rep --
 200       --------------
 201
 202       Attribute_Enum_Rep => True,
 203       --  For every enumeration subtype S, S'Enum_Rep denotes a function
 204       --  with the following specification:
 205       --
 206       --    function S'Enum_Rep (Arg : S'Base) return universal_integer;
 207       --
 208       --  The function returns the representation value for the given
 209       --  enumeration value. This will be equal to the 'Pos value in the
 210       --  absence of an enumeration representation clause. This is a static
 211       --  attribute (i.e. the result is static if the argument is static).
 212
 213       -----------------
 214       -- Fixed_Value --
 215       -----------------
 216
 217       Attribute_Fixed_Value => True,
 218       --  For every fixed-point type S, S'Fixed_Value denotes a function
 219       --  with the following specification:
 220       --
 221       --    function S'Fixed_Value (Arg : universal_integer) return S;
 222       --
 223       --  The value returned is the fixed-point value V such that
 224       --
 225       --    V = Arg * S'Small
 226       --
 227       --  The effect is thus equivalent to first converting the argument to
 228       --  the integer type used to represent S, and then doing an unchecked
 229       --  conversion to the fixed-point type. This attribute is primarily
 230       --  intended for use in implementation of the input-output functions for
 231       --  fixed-point values.
 232
 233       -----------------------
 234       -- Has_Discriminants --
 235       -----------------------
 236
 237       Attribute_Has_Discriminants => True,
 238       --  Gtyp'Has_Discriminants, where Gtyp is a generic formal type, yields
 239       --  a Boolean value indicating whether or not the actual instantiation
 240       --  type has discriminants.
 241
 242       ---------
 243       -- Img --
 244       ---------
 245
 246       Attribute_Img => True,
 247       --  The 'Img function is defined for any prefix, P, that denotes an
 248       --  object of scalar type T. P'Img is equivalent to T'Image (P). This
 249       --  is convenient for debugging. For example:
 250       --
 251       --     Put_Line ("X = " & X'Img);
 252       --
 253       --  has the same meaning as the more verbose:
 254       --
 255       --     Put_Line ("X = " & Temperature_Type'Image (X));
 256       --
 257       --  where Temperature_Type is the subtype of the object X.
 258
 259       -------------------
 260       -- Integer_Value --
 261       -------------------
 262
 263       Attribute_Integer_Value => True,
 264       --  For every integer type S, S'Integer_Value denotes a function
 265       --  with the following specification:
 266       --
 267       --    function S'Integer_Value (Arg : universal_fixed) return S;
 268       --
 269       --  The value returned is the integer value V, such that
 270       --
 271       --    Arg = V * fixed-type'Small
 272       --
 273       --  The effect is thus equivalent to first doing an unchecked convert
 274       --  from the fixed-point type to its corresponding implementation type,
 275       --  and then converting the result to the target integer type. This
 276       --  attribute is primarily intended for use in implementation of the
 277       --  standard input-output functions for fixed-point values.
 278
 279       ------------------
 280       -- Machine_Size --
 281       ------------------
 282
 283       Attribute_Machine_Size => True,
 284       --  This attribute is identical to the Object_Size attribute. It is
 285       --  provided for compatibility with the DEC attribute of this name.
 286
 287       -----------------------
 288       -- Maximum_Alignment --
 289       -----------------------
 290
 291       Attribute_Maximum_Alignment => True,
 292       --  Standard'Maximum_Alignment (Standard is the only permissible prefix)
 293       --  provides the maximum useful alignment value for the target. This
 294       --  is a static value that can be used to specify the alignment for an
 295       --  object, guaranteeing that it is properly aligned in all cases. The
 296       --  time this is useful is when an external object is imported and its
 297       --  alignment requirements are unknown. This is a static attribute.
 298
 299       --------------------
 300       -- Mechanism_Code --
 301       --------------------
 302
 303       Attribute_Mechanism_Code => True,
 304       --  function'Mechanism_Code yeilds an integer code for the mechanism
 305       --  used for the result of function, and subprogram'Mechanism_Code (n)
 306       --  yields the mechanism used for formal parameter number n (a static
 307       --  integer value, 1 = first parameter). The code returned is:
 308       --
 309       --     1 = by copy (value)
 310       --     2 = by reference
 311       --     3 = by descriptor (default descriptor type)
 312       --     4 = by descriptor (UBS  unaligned bit string)
 313       --     5 = by descriptor (UBSB aligned bit string with arbitrary bounds)
 314       --     6 = by descriptor (UBA  unaligned bit array)
 315       --     7 = by descriptor (S    string, also scalar access type parameter)
 316       --     8 = by descriptor (SB   string with arbitrary bounds)
 317       --     9 = by descriptor (A    contiguous array)
 318       --    10 = by descriptor (NCA  non-contiguous array)
 319
 320       --------------------
 321       -- Null_Parameter --
 322       --------------------
 323
 324       Attribute_Null_Parameter => True,
 325       --  A reference T'Null_Parameter denotes an (imaginary) object of type or
 326       --  subtype T allocated at (machine) address zero. The attribute is
 327       --  allowed only as the default expression of a formal parameter, or as
 328       --  an actual expression of a subporgram call. In either case, the
 329       --  subprogram must be imported.
 330       --
 331       --  The identity of the object is represented by the address zero in the
 332       --  argument list, independent of the passing mechanism (explicit or
 333       --  default).
 334       --
 335       --  The reason that this capability is needed is that for a record or
 336       --  other composite object passed by reference, there is no other way of
 337       --  specifying that a zero address should be passed.
 338
 339       -----------------
 340       -- Object_Size --
 341       -----------------
 342
 343       Attribute_Object_Size => True,
 344       --  Type'Object_Size is the same as Type'Size for all types except
 345       --  fixed-point types and discrete types. For fixed-point types and
 346       --  discrete types, this attribute gives the size used for default
 347       --  allocation of objects and components of the size. See section in
 348       --  Einfo ("Handling of type'Size values") for further details.
 349
 350       -------------------------
 351       -- Passed_By_Reference --
 352       -------------------------
 353
 354       Attribute_Passed_By_Reference => True,
 355       --  T'Passed_By_Reference for any subtype T returns a boolean value that
 356       --  is true if the type is normally passed by reference and false if the
 357       --  type is normally passed by copy in calls. For scalar types, the
 358       --  result is always False and is static. For non-scalar types, the
 359       --  result is non-static (since it is computed by Gigi).
 360
 361       ------------------
 362       -- Range_Length --
 363       ------------------
 364
 365       Attribute_Range_Length => True,
 366       --  T'Range_Length for any discrete type T yields the number of values
 367       --  represented by the subtype (zero for a null range). The result is
 368       --  static for static subtypes. Note that Range_Length applied to the
 369       --  index subtype of a one dimensional array always gives the same result
 370       --  as Range applied to the array itself. The result is of type universal
 371       --  integer.
 372
 373       ------------------
 374       -- Storage_Unit --
 375       ------------------
 376
 377       Attribute_Storage_Unit => True,
 378       --  Standard'Storage_Unit (Standard is the only permissible prefix)
 379       --  provides the value System.Storage_Unit, and is intended primarily
 380       --  for constructing this definition in package System (see note above
 381       --  in Default_Bit_Order description). The is a static attribute.
 382
 383       ---------------
 384       -- Stub_Type --
 385       ---------------
 386
 387       Attribute_Stub_Type => True,
 388       --  The GNAT implementation of remote access-to-classwide types is
 389       --  organised as described in AARM E.4(20.t): a value of an RACW type
 390       --  (designating a remote object) is represented as a normal access
 391       --  value, pointing to a "stub" object which in turn contains the
 392       --  necessary information to contact the designated remote object. A
 393       --  call on any dispatching operation of such a stub object does the
 394       --  remote call, if necessary, using the information in the stub object
 395       --  to locate the target partition, etc.
 396       --
 397       --  For a prefix T that denotes a remote access-to-classwide type,
 398       --  T'Stub_Type denotes the type of the corresponding stub objects.
 399       --
 400       --  By construction, the layout of T'Stub_Type is identical to that of
 401       --  System.Partition_Interface.RACW_Stub_Type (see implementation notes
 402       --  in body of Exp_Dist).
 403
 404       -----------------
 405       -- Target_Name --
 406       -----------------
 407
 408       Attribute_Target_Name => True,
 409       --  Standard'Target_Name yields the string identifying the target for the
 410       --  compilation, taken from Sdefault.Target_Name.
 411
 412       ----------------
 413       -- To_Address --
 414       ----------------
 415
 416       Attribute_To_Address => True,
 417       --  System'To_Address (Address is the only permissible prefix) is a
 418       --  function that takes any integer value, and converts it into an
 419       --  address value. The semantics is to first convert the integer value to
 420       --  type Integer_Address according to normal conversion rules, and then
 421       --  to convert this to an address using the same semantics as the
 422       --  System.Storage_Elements.To_Address function. The important difference
 423       --  is that this is a static attribute so it can be used in
 424       --  initializations in preealborate packages.
 425
 426       ----------------
 427       -- Type_Class --
 428       ----------------
 429
 430       Attribute_Type_Class => True,
 431       --  T'Type_Class for any type or subtype T yields the value of the type
 432       --  class for the full type of T. If T is a generic formal type, then the
 433       --  value is the value for the corresponding actual subtype. The value of
 434       --  this attribute is of type System.Aux_DEC.Type_Class, which has the
 435       --  following definition:
 436       --
 437       --    type Type_Class is
 438       --      (Type_Class_Enumeration,
 439       --       Type_Class_Integer,
 440       --       Type_Class_Fixed_Point,
 441       --       Type_Class_Floating_Point,
 442       --       Type_Class_Array,
 443       --       Type_Class_Record,
 444       --       Type_Class_Access,
 445       --       Type_Class_Task,
 446       --       Type_Class_Address);
 447       --
 448       --  Protected types yield the value Type_Class_Task, which thus applies
 449       --  to all concurrent types. This attribute is designed to be compatible
 450       --  with the DEC Ada attribute of the same name.
 451       --
 452       --  Note: if pragma Extend_System is used to merge the definitions of
 453       --  Aux_DEC into System, then the type Type_Class can be referenced
 454       --  as an entity within System, as can its enumeration literals.
 455
 456       -----------------
 457       -- UET_Address --
 458       -----------------
 459
 460       Attribute_UET_Address => True,
 461       --  Unit'UET_Address, where Unit is a program unit, yields the address
 462       --  of the unit exception table for the specified unit. This is only
 463       --  used in the internal implementation of exception handling. See the
 464       --  implementation of unit Ada.Exceptions for details on its use.
 465
 466       ------------------------------
 467       -- Universal_Literal_String --
 468       ------------------------------
 469
 470       Attribute_Universal_Literal_String => True,
 471       --  The prefix of 'Universal_Literal_String must be a named number. The
 472       --  static result is the string consisting of the characters of the
 473       --  number as defined in the original source. This allows the user
 474       --  program to access the actual text of named numbers without
 475       --  intermediate conversions and without the need to enclose the strings
 476       --  in quotes (which would preclude their use as numbers). This is used
 477       --  internally for the construction of values of the floating-point
 478       --  attributes from the file ttypef.ads, but may also be used by user
 479       --  programs.
 480
 481       -------------------------
 482       -- Unrestricted_Access --
 483       -------------------------
 484
 485       Attribute_Unrestricted_Access => True,
 486       --  The Unrestricted_Access attribute is similar to Access except that
 487       --  all accessibility and aliased view checks are omitted. This is very
 488       --  much a user-beware attribute. Basically its status is very similar
 489       --  to Address, for which it is a desirable replacement where the value
 490       --  desired is an access type. In other words, its effect is identical
 491       --  to first taking 'Address and then doing an unchecked conversion to
 492       --  a desired access type. Note that in GNAT, but not necessarily in
 493       --  other implementations, the use of static chains for inner level
 494       --  subprograms means that Unrestricted_Access applied to a subprogram
 495       --  yields a value that can be called as long as the subprogram is in
 496       --  scope (normal Ada 95 accessibility rules restrict this usage).
 497
 498       ---------------
 499       -- VADS_Size --
 500       ---------------
 501
 502       Attribute_VADS_Size => True,
 503       --  Typ'VADS_Size yields the Size value typically yielded by some Ada 83
 504       --  compilers. The differences between VADS_Size and Size is that for
 505       --  scalar types for which no Size has been specified, VADS_Size yields
 506       --  the Object_Size rather than the Value_Size. For example, while
 507       --  Natural'Size is typically 31, the value of Natural'VADS_Size is 32.
 508       --  For all other types, Size and VADS_Size yield the same value.
 509
 510       ----------------
 511       -- Value_Size --
 512       ----------------
 513
 514       Attribute_Value_Size => True,
 515       --  Type'Value_Size is the number of bits required to represent value of
 516       --  the given subtype. It is the same as Type'Size, but, unlike Size, may
 517       --  be set for non-first subtypes. See section in Einfo ("Handling of
 518       --  type'Size values") for further details.
 519
 520       ---------------
 521       -- Word_Size --
 522       ---------------
 523
 524       Attribute_Word_Size => True,
 525       --  Standard'Word_Size (Standard is the only permissible prefix)
 526       --  provides the value System.Word_Size, and is intended primarily
 527       --  for constructing this definition in package System (see note above
 528       --  in Default_Bit_Order description). This is a static attribute.
 529
 530       others => False);
 531
 532    -----------------
 533    -- Subprograms --
 534    -----------------
 535
 536    procedure Analyze_Attribute (N : Node_Id);
 537    --  Performs bottom up semantic analysis of an attribute. Note that the
 538    --  parser has already checked that type returning attributes appear only
 539    --  in appropriate contexts (i.e. in subtype marks, or as prefixes for
 540    --  other attributes).
 541
 542    function Name_Implies_Lvalue_Prefix (Nam : Name_Id) return Boolean;
 543    --  Determine whether the name of an attribute reference categorizes its
 544    --  prefix as an lvalue. The following attributes fall under this bracket
 545    --  by directly or indirectly modifying their prefixes.
 546    --     Access
 547    --     Address
 548    --     Input
 549    --     Read
 550    --     Unchecked_Access
 551    --     Unrestricted_Access
 552
 553    procedure Resolve_Attribute (N : Node_Id; Typ : Entity_Id);
 554    --  Performs type resolution of attribute. If the attribute yields a
 555    --  universal value, mark its type as that of the context. On the other
 556    --  hand, if the context itself is universal (as in T'Val (T'Pos (X)), mark
 557    --  the type as being the largest type of that class that can be used at
 558    --  run-time. This is correct since either the value gets folded (in which
 559    --  case it doesn't matter what type of the class we give if, since the
 560    --  folding uses universal arithmetic anyway) or it doesn't get folded (in
 561    --  which case it is going to be dealt with at runtime, and the largest type
 562    --  is right).
 563
 564    function Stream_Attribute_Available
 565      (Typ          : Entity_Id;
 566       Nam          : TSS_Name_Type;
 567       Partial_View : Entity_Id := Empty) return Boolean;
 568    --  For a limited type Typ, return True iff the given attribute is
 569    --  available. For Ada 05, availability is defined by 13.13.2(36/1). For Ada
 570    --  95, an attribute is considered to be available if it has been specified
 571    --  using an attribute definition clause for the type, or for its full view,
 572    --  or for an ancestor of either. Parameter Partial_View is used only
 573    --  internally, when checking for an attribute definition clause that is not
 574    --  visible (Ada 95 only).
 575
 576 end Sem_Attr;