gcc/ada/s-strcom.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --                S Y S T E M . S T R I N G _ C O M P A R E                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 with Ada.Unchecked_Conversion;
  39
  40 package body System.String_Compare is
  41
  42    type Word is mod 2 ** 32;
  43    --  Used to process operands by words
  44
  45    type Big_Words is array (Natural) of Word;
  46    type Big_Words_Ptr is access Big_Words;
  47    --  Array type used to access by words
  48
  49    type Byte is mod 2 ** 8;
  50    --  Used to process operands by bytes
  51
  52    type Big_Bytes is array (Natural) of Byte;
  53    type Big_Bytes_Ptr is access Big_Bytes;
  54    --  Array type used to access by bytes
  55
  56    function To_Big_Words is new
  57      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  58
  59    function To_Big_Bytes is new
  60      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  61
  62    -----------------
  63    -- Str_Compare --
  64    -----------------
  65
  66    function Str_Compare
  67      (Left      : System.Address;
  68       Right     : System.Address;
  69       Left_Len  : Natural;
  70       Right_Len : Natural) return Integer
  71    is
  72       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  73
  74    begin
  75       --  If operands are non-aligned, or length is too short, go by bytes
  76
  77       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  78          return Str_Compare_Bytes (Left, Right, Left_Len, Right_Len);
  79       end if;
  80
  81       --  Here we can go by words
  82
  83       declare
  84          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  85          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  86          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  87          Clen4F : constant Natural       := Clen4 * 4;
  88
  89       begin
  90          for J in 0 .. Clen4 loop
  91             if LeftP (J) /= RightP (J) then
  92                return Str_Compare_Bytes
  93                         (Left  + Address (4 * J),
  94                          Right + Address (4 * J),
  95                          4, 4);
  96             end if;
  97          end loop;
  98
  99          return Str_Compare_Bytes
 100                   (Left      + Address (Clen4F),
 101                    Right     + Address (Clen4F),
 102                    Left_Len  - Clen4F,
 103                    Right_Len - Clen4F);
 104       end;
 105    end Str_Compare;
 106
 107    -----------------------
 108    -- Str_Compare_Bytes --
 109    -----------------------
 110
 111    function Str_Compare_Bytes
 112      (Left      : System.Address;
 113       Right     : System.Address;
 114       Left_Len  : Natural;
 115       Right_Len : Natural) return Integer
 116    is
 117       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 118
 119       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 120       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 121
 122    begin
 123       for J in 0 .. Compare_Len - 1 loop
 124          if LeftP (J) /= RightP (J) then
 125             if LeftP (J) > RightP (J) then
 126                return +1;
 127             else
 128                return -1;
 129             end if;
 130          end if;
 131       end loop;
 132
 133       if Left_Len = Right_Len then
 134          return 0;
 135       elsif Left_Len > Right_Len then
 136          return +1;
 137       else
 138          return -1;
 139       end if;
 140    end Str_Compare_Bytes;
 141
 142 end System.String_Compare;