gcc/ada/s-osprim-vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                  S Y S T E M . O S _ P R I M I T I V E S                 --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This version is for VxWorks targets
  35
  36 with System.OS_Interface;
  37 --  Since the thread library is part of the VxWorks kernel, using OS_Interface
  38 --  is not a problem here, as long as we only use System.OS_Interface as a
  39 --  set of C imported routines: using Ada routines from this package would
  40 --  create a dependency on libgnarl in libgnat, which is not desirable.
  41
  42 with Interfaces.C;
  43 --  used for type int
  44
  45 package body System.OS_Primitives is
  46
  47    use System.OS_Interface;
  48    use type Interfaces.C.int;
  49
  50    ------------------------
  51    -- Internal functions --
  52    ------------------------
  53
  54    function To_Clock_Ticks (D : Duration) return int;
  55    --  Convert a duration value (in seconds) into clock ticks.
  56    --  Note that this routine is duplicated from System.OS_Interface since
  57    --  as explained above, we do not want to depend on libgnarl
  58
  59    function To_Clock_Ticks (D : Duration) return int is
  60       Ticks          : Long_Long_Integer;
  61       Rate_Duration  : Duration;
  62       Ticks_Duration : Duration;
  63
  64    begin
  65       if D < 0.0 then
  66          return -1;
  67       end if;
  68
  69       --  Ensure that the duration can be converted to ticks
  70       --  at the current clock tick rate without overflowing.
  71
  72       Rate_Duration := Duration (sysClkRateGet);
  73
  74       if D > (Duration'Last / Rate_Duration) then
  75          Ticks := Long_Long_Integer (int'Last);
  76       else
  77          Ticks_Duration := D * Rate_Duration;
  78          Ticks := Long_Long_Integer (Ticks_Duration);
  79
  80          if Ticks_Duration > Duration (Ticks) then
  81             Ticks := Ticks + 1;
  82          end if;
  83
  84          if Ticks > Long_Long_Integer (int'Last) then
  85             Ticks := Long_Long_Integer (int'Last);
  86          end if;
  87       end if;
  88
  89       return int (Ticks);
  90    end To_Clock_Ticks;
  91
  92    -----------
  93    -- Clock --
  94    -----------
  95
  96    function Clock return Duration is
  97       TS     : aliased timespec;
  98       Result : int;
  99    begin
 100       Result := clock_gettime (CLOCK_REALTIME, TS'Unchecked_Access);
 101       pragma Assert (Result = 0);
 102       return Duration (TS.ts_sec) + Duration (TS.ts_nsec) / 10#1#E9;
 103    end Clock;
 104
 105    ---------------------
 106    -- Monotonic_Clock --
 107    ---------------------
 108
 109    function Monotonic_Clock return Duration renames Clock;
 110
 111    -----------------
 112    -- Timed_Delay --
 113    -----------------
 114
 115    procedure Timed_Delay
 116      (Time : Duration;
 117       Mode : Integer)
 118    is
 119       Rel_Time   : Duration;
 120       Abs_Time   : Duration;
 121       Base_Time  : constant Duration := Clock;
 122       Check_Time : Duration := Base_Time;
 123       Ticks      : int;
 124
 125       Result     : int;
 126       pragma Unreferenced (Result);
 127
 128    begin
 129       if Mode = Relative then
 130          Rel_Time := Time;
 131          Abs_Time := Time + Check_Time;
 132       else
 133          Rel_Time := Time - Check_Time;
 134          Abs_Time := Time;
 135       end if;
 136
 137       if Rel_Time > 0.0 then
 138          loop
 139             Ticks := To_Clock_Ticks (Rel_Time);
 140
 141             if Mode = Relative and then Ticks < int'Last then
 142                --  The first tick will delay anytime between 0 and
 143                --  1 / sysClkRateGet seconds, so we need to add one to
 144                --  be on the safe side.
 145
 146                Ticks := Ticks + 1;
 147             end if;
 148
 149             Result := taskDelay (Ticks);
 150             Check_Time := Clock;
 151
 152             exit when Abs_Time <= Check_Time or else Check_Time < Base_Time;
 153
 154             Rel_Time := Abs_Time - Check_Time;
 155          end loop;
 156       end if;
 157    end Timed_Delay;
 158
 159    ----------------
 160    -- Initialize --
 161    ----------------
 162
 163    procedure Initialize is
 164    begin
 165       null;
 166    end Initialize;
 167
 168 end System.OS_Primitives;