gcc/ada/lib-sort.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . S O R T                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with GNAT.Heap_Sort_G;
  35
  36 separate (Lib)
  37 procedure Sort (Tbl : in out Unit_Ref_Table) is
  38
  39    T : array (0 .. Integer (Tbl'Last - Tbl'First + 1)) of Unit_Number_Type;
  40    --  Actual sort is done on this copy of the array with 0's origin
  41    --  subscripts. Location 0 is used as a temporary by the sorting algorithm.
  42    --  Also the addressing of the table is more efficient with 0's origin,
  43    --  even though we have to copy Tbl back and forth.
  44
  45    function Lt_Uname (C1, C2 : Natural) return Boolean;
  46    --  Comparison routine for comparing Unames. Needed by the sorting routine
  47
  48    procedure Move_Uname (From : Natural; To : Natural);
  49    --  Move routine needed by the sorting routine below
  50
  51    package Sorting is new GNAT.Heap_Sort_G (Move_Uname, Lt_Uname);
  52
  53    --------------
  54    -- Lt_Uname --
  55    --------------
  56
  57    function Lt_Uname (C1, C2 : Natural) return Boolean is
  58    begin
  59       --  Preprocessing data and definition files are not sorted, they are
  60       --  at the bottom of the list. They are recognized because they are
  61       --  the only ones without a Unit_Name.
  62
  63       if Units.Table (T (C1)).Unit_Name = No_Unit_Name then
  64          return False;
  65
  66       elsif Units.Table (T (C2)).Unit_Name = No_Unit_Name then
  67          return True;
  68
  69       else
  70          return
  71            Uname_Lt
  72              (Units.Table (T (C1)).Unit_Name, Units.Table (T (C2)).Unit_Name);
  73       end if;
  74    end Lt_Uname;
  75
  76    ----------------
  77    -- Move_Uname --
  78    ----------------
  79
  80    procedure Move_Uname (From : Natural; To : Natural) is
  81    begin
  82       T (To) := T (From);
  83    end Move_Uname;
  84
  85 --  Start of processing for Sort
  86
  87 begin
  88    if T'Last > 0 then
  89       for I in 1 .. T'Last loop
  90          T (I) := Tbl (Int (I) - 1 + Tbl'First);
  91       end loop;
  92
  93       Sorting.Sort (T'Last);
  94
  95    --  Sort is complete, copy result back into place
  96
  97       for I in 1 .. T'Last loop
  98          Tbl (Int (I) - 1 + Tbl'First) := T (I);
  99       end loop;
 100    end if;
 101 end Sort;