gcc/ada/exp_smem.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ S M E M                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Einfo;    use Einfo;
  28 with Exp_Util; use Exp_Util;
  29 with Nmake;    use Nmake;
  30 with Namet;    use Namet;
  31 with Nlists;   use Nlists;
  32 with Rtsfind;  use Rtsfind;
  33 with Sem;      use Sem;
  34 with Sem_Util; use Sem_Util;
  35 with Sinfo;    use Sinfo;
  36 with Snames;   use Snames;
  37 with Stand;    use Stand;
  38 with Stringt;  use Stringt;
  39 with Tbuild;   use Tbuild;
  40
  41 package body Exp_Smem is
  42
  43    Insert_Node : Node_Id;
  44    --  Node after which a write call is to be inserted
  45
  46    -----------------------
  47    -- Local Subprograms --
  48    -----------------------
  49
  50    procedure Add_Read_Before (N : Node_Id);
  51    --  Insert a Shared_Var_ROpen call for variable before node N
  52
  53    procedure Add_Write_After (N : Node_Id);
  54    --  Insert a Shared_Var_WOpen call for variable after the node
  55    --  Insert_Node, as recorded by On_Lhs_Of_Assigment (where it points
  56    --  to the assignment statement) or Is_Out_Actual (where it points to
  57    --  the procedure call statement).
  58
  59    procedure Build_Full_Name (E : Entity_Id; N : out String_Id);
  60    --  Build the fully qualified string name of a shared variable
  61
  62    function On_Lhs_Of_Assignment (N : Node_Id) return Boolean;
  63    --  Determines if N is on the left hand of the assignment. This means
  64    --  that either it is a simple variable, or it is a record or array
  65    --  variable with a corresponding selected or indexed component on
  66    --  the left side of an assignment. If the result is True, then
  67    --  Insert_Node is set to point to the assignment
  68
  69    function Is_Out_Actual (N : Node_Id) return Boolean;
  70    --  In a similar manner, this function determines if N appears as an
  71    --  OUT or IN OUT parameter to a procedure call. If the result is
  72    --  True, then Insert_Node is set to point to the call.
  73
  74    ---------------------
  75    -- Add_Read_Before --
  76    ---------------------
  77
  78    procedure Add_Read_Before (N : Node_Id) is
  79       Loc : constant Source_Ptr := Sloc (N);
  80       Ent : constant Node_Id    := Entity (N);
  81
  82    begin
  83       if Present (Shared_Var_Read_Proc (Ent)) then
  84          Insert_Action (N,
  85            Make_Procedure_Call_Statement (Loc,
  86              Name =>
  87                New_Occurrence_Of (Shared_Var_Read_Proc (Ent), Loc),
  88              Parameter_Associations => Empty_List));
  89       end if;
  90    end Add_Read_Before;
  91
  92    -------------------------------
  93    -- Add_Shared_Var_Lock_Procs --
  94    -------------------------------
  95
  96    procedure Add_Shared_Var_Lock_Procs (N : Node_Id) is
  97       Loc   : constant Source_Ptr := Sloc (N);
  98       Obj   : constant Entity_Id  := Entity (Expression (First_Actual (N)));
  99       Inode : Node_Id;
 100       Vnm   : String_Id;
 101
 102    begin
 103       --  We have to add Shared_Var_Lock and Shared_Var_Unlock calls around
 104       --  the procedure or function call node. First we locate the right
 105       --  place to do the insertion, which is the call itself in the
 106       --  procedure call case, or else the nearest non subexpression
 107       --  node that contains the function call.
 108
 109       Inode := N;
 110       while Nkind (Inode) /= N_Procedure_Call_Statement
 111         and then Nkind (Inode) in N_Subexpr
 112       loop
 113          Inode := Parent (Inode);
 114       end loop;
 115
 116       --  Now insert the Lock and Unlock calls and the read/write calls
 117
 118       --  Two concerns here. First we are not dealing with the exception
 119       --  case, really we need some kind of cleanup routine to do the
 120       --  Unlock. Second, these lock calls should be inside the protected
 121       --  object processing, not outside, otherwise they can be done at
 122       --  the wrong priority, resulting in dead lock situations ???
 123
 124       Build_Full_Name (Obj, Vnm);
 125
 126       --  First insert the Lock call before
 127
 128       Insert_Before_And_Analyze (Inode,
 129         Make_Procedure_Call_Statement (Loc,
 130           Name => New_Occurrence_Of (RTE (RE_Shared_Var_Lock), Loc),
 131           Parameter_Associations => New_List (
 132             Make_String_Literal (Loc, Vnm))));
 133
 134       --  Now, right after the Lock, insert a call to read the object
 135
 136       Insert_Before_And_Analyze (Inode,
 137         Make_Procedure_Call_Statement (Loc,
 138           Name => New_Occurrence_Of (Shared_Var_Read_Proc (Obj), Loc)));
 139
 140       --  Now insert the Unlock call after
 141
 142       Insert_After_And_Analyze (Inode,
 143         Make_Procedure_Call_Statement (Loc,
 144           Name => New_Occurrence_Of (RTE (RE_Shared_Var_Unlock), Loc),
 145           Parameter_Associations => New_List (
 146             Make_String_Literal (Loc, Vnm))));
 147
 148       --  Now for a procedure call, but not a function call, insert the
 149       --  call to write the object just before the unlock.
 150
 151       if Nkind (N) = N_Procedure_Call_Statement then
 152          Insert_After_And_Analyze (Inode,
 153            Make_Procedure_Call_Statement (Loc,
 154              Name => New_Occurrence_Of (Shared_Var_Assign_Proc (Obj), Loc)));
 155       end if;
 156
 157    end Add_Shared_Var_Lock_Procs;
 158
 159    ---------------------
 160    -- Add_Write_After --
 161    ---------------------
 162
 163    procedure Add_Write_After (N : Node_Id) is
 164       Loc : constant Source_Ptr := Sloc (N);
 165       Ent : constant Node_Id    := Entity (N);
 166
 167    begin
 168       if Present (Shared_Var_Assign_Proc (Ent)) then
 169          Insert_After_And_Analyze (Insert_Node,
 170            Make_Procedure_Call_Statement (Loc,
 171              Name =>
 172                New_Occurrence_Of (Shared_Var_Assign_Proc (Ent), Loc),
 173              Parameter_Associations => Empty_List));
 174       end if;
 175    end Add_Write_After;
 176
 177    ---------------------
 178    -- Build_Full_Name --
 179    ---------------------
 180
 181    procedure Build_Full_Name (E : Entity_Id; N : out String_Id) is
 182
 183       procedure Build_Name (E : Entity_Id);
 184       --  This is a recursive routine used to construct the fully qualified
 185       --  string name of the package corresponding to the shared variable.
 186
 187       ----------------
 188       -- Build_Name --
 189       ----------------
 190
 191       procedure Build_Name (E : Entity_Id) is
 192       begin
 193          if Scope (E) /= Standard_Standard then
 194             Build_Name (Scope (E));
 195             Store_String_Char ('.');
 196          end if;
 197
 198          Get_Decoded_Name_String (Chars (E));
 199          Store_String_Chars (Name_Buffer (1 .. Name_Len));
 200       end Build_Name;
 201
 202    --  Start of processing for Build_Full_Name
 203
 204    begin
 205       Start_String;
 206       Build_Name (E);
 207       N := End_String;
 208    end Build_Full_Name;
 209
 210    ------------------------------------
 211    -- Expand_Shared_Passive_Variable --
 212    ------------------------------------
 213
 214    procedure Expand_Shared_Passive_Variable (N : Node_Id) is
 215       Typ : constant Entity_Id := Etype (N);
 216
 217    begin
 218       --  Nothing to do for protected or limited objects
 219
 220       if Is_Limited_Type (Typ) or else Is_Concurrent_Type (Typ) then
 221          return;
 222
 223       --  If we are on the left hand side of an assignment, then we add
 224       --  the write call after the assignment.
 225
 226       elsif On_Lhs_Of_Assignment (N) then
 227          Add_Write_After (N);
 228
 229       --  If we are a parameter for an out or in out formal, then put
 230       --  the read before and the write after.
 231
 232       elsif Is_Out_Actual (N) then
 233          Add_Read_Before (N);
 234          Add_Write_After (N);
 235
 236       --  All other cases are simple reads
 237
 238       else
 239          Add_Read_Before (N);
 240       end if;
 241    end Expand_Shared_Passive_Variable;
 242
 243    -------------------
 244    -- Is_Out_Actual --
 245    -------------------
 246
 247    function Is_Out_Actual (N : Node_Id) return Boolean is
 248       Formal : Entity_Id;
 249       Call   : Node_Id;
 250
 251    begin
 252       Find_Actual (N, Formal, Call);
 253
 254       if No (Formal) then
 255          return False;
 256
 257       else
 258          if Ekind (Formal) = E_Out_Parameter
 259               or else
 260             Ekind (Formal) = E_In_Out_Parameter
 261          then
 262             Insert_Node := Call;
 263             return True;
 264          else
 265             return False;
 266          end if;
 267       end if;
 268    end Is_Out_Actual;
 269
 270    ---------------------------
 271    -- Make_Shared_Var_Procs --
 272    ---------------------------
 273
 274    function Make_Shared_Var_Procs (N : Node_Id) return Node_Id is
 275       Loc : constant Source_Ptr := Sloc (N);
 276       Ent : constant Entity_Id  := Defining_Identifier (N);
 277       Typ : constant Entity_Id  := Etype (Ent);
 278       Vnm : String_Id;
 279       Atr : Node_Id;
 280
 281       After : constant Node_Id := Next (N);
 282       --  Node located right after N originally (after insertion of the SV
 283       --  procs this node is right after the last inserted node).
 284
 285       Assign_Proc : constant Entity_Id :=
 286                       Make_Defining_Identifier (Loc,
 287                         Chars => New_External_Name (Chars (Ent), 'A'));
 288
 289       Read_Proc : constant Entity_Id :=
 290                     Make_Defining_Identifier (Loc,
 291                       Chars => New_External_Name (Chars (Ent), 'R'));
 292
 293       S : Entity_Id;
 294
 295    --  Start of processing for Make_Shared_Var_Procs
 296
 297    begin
 298       Build_Full_Name (Ent, Vnm);
 299
 300       --  We turn off Shared_Passive during construction and analysis of
 301       --  the assign and read routines, to avoid improper attempts to
 302       --  process the variable references within these procedures.
 303
 304       Set_Is_Shared_Passive (Ent, False);
 305
 306       --  Construct assignment routine
 307
 308       --    procedure VarA is
 309       --       S : Ada.Streams.Stream_IO.Stream_Access;
 310       --    begin
 311       --       S := Shared_Var_WOpen ("pkg.var");
 312       --       typ'Write (S, var);
 313       --       Shared_Var_Close (S);
 314       --    end VarA;
 315
 316       S   := Make_Defining_Identifier (Loc, Name_uS);
 317
 318       Atr :=
 319         Make_Attribute_Reference (Loc,
 320           Prefix => New_Occurrence_Of (Typ, Loc),
 321           Attribute_Name => Name_Write,
 322           Expressions => New_List (
 323             New_Reference_To (S, Loc),
 324             New_Occurrence_Of (Ent, Loc)));
 325
 326       Insert_After_And_Analyze (N,
 327         Make_Subprogram_Body (Loc,
 328           Specification =>
 329             Make_Procedure_Specification (Loc,
 330               Defining_Unit_Name => Assign_Proc),
 331
 332          --  S : Ada.Streams.Stream_IO.Stream_Access;
 333
 334           Declarations => New_List (
 335             Make_Object_Declaration (Loc,
 336               Defining_Identifier => S,
 337               Object_Definition =>
 338                 New_Occurrence_Of (RTE (RE_Stream_Access), Loc))),
 339
 340           Handled_Statement_Sequence =>
 341             Make_Handled_Sequence_Of_Statements (Loc,
 342               Statements => New_List (
 343
 344                --  S := Shared_Var_WOpen ("pkg.var");
 345
 346                 Make_Assignment_Statement (Loc,
 347                   Name => New_Reference_To (S, Loc),
 348                   Expression =>
 349                     Make_Function_Call (Loc,
 350                       Name =>
 351                         New_Occurrence_Of
 352                           (RTE (RE_Shared_Var_WOpen), Loc),
 353                       Parameter_Associations => New_List (
 354                         Make_String_Literal (Loc, Vnm)))),
 355
 356                 Atr,
 357
 358                --  Shared_Var_Close (S);
 359
 360                 Make_Procedure_Call_Statement (Loc,
 361                   Name =>
 362                     New_Occurrence_Of (RTE (RE_Shared_Var_Close), Loc),
 363                   Parameter_Associations =>
 364                     New_List (New_Reference_To (S, Loc)))))));
 365
 366       --  Construct read routine
 367
 368       --    procedure varR is
 369       --       S : Ada.Streams.Stream_IO.Stream_Access;
 370       --    begin
 371       --       S := Shared_Var_ROpen ("pkg.var");
 372       --       if S /= null then
 373       --          typ'Read (S, Var);
 374       --          Shared_Var_Close (S);
 375       --       end if;
 376       --    end varR;
 377
 378       S   := Make_Defining_Identifier (Loc, Name_uS);
 379
 380       Atr :=
 381         Make_Attribute_Reference (Loc,
 382           Prefix => New_Occurrence_Of (Typ, Loc),
 383           Attribute_Name => Name_Read,
 384           Expressions => New_List (
 385             New_Reference_To (S, Loc),
 386             New_Occurrence_Of (Ent, Loc)));
 387
 388       Insert_After_And_Analyze (N,
 389         Make_Subprogram_Body (Loc,
 390           Specification =>
 391             Make_Procedure_Specification (Loc,
 392               Defining_Unit_Name => Read_Proc),
 393
 394          --  S : Ada.Streams.Stream_IO.Stream_Access;
 395
 396           Declarations => New_List (
 397             Make_Object_Declaration (Loc,
 398               Defining_Identifier => S,
 399               Object_Definition =>
 400                 New_Occurrence_Of (RTE (RE_Stream_Access), Loc))),
 401
 402           Handled_Statement_Sequence =>
 403             Make_Handled_Sequence_Of_Statements (Loc,
 404               Statements => New_List (
 405
 406                --  S := Shared_Var_ROpen ("pkg.var");
 407
 408                 Make_Assignment_Statement (Loc,
 409                   Name => New_Reference_To (S, Loc),
 410                   Expression =>
 411                     Make_Function_Call (Loc,
 412                       Name =>
 413                         New_Occurrence_Of
 414                           (RTE (RE_Shared_Var_ROpen), Loc),
 415                       Parameter_Associations => New_List (
 416                         Make_String_Literal (Loc, Vnm)))),
 417
 418                --  if S /= null then
 419
 420                 Make_Implicit_If_Statement (N,
 421                   Condition =>
 422                     Make_Op_Ne (Loc,
 423                       Left_Opnd  => New_Reference_To (S, Loc),
 424                       Right_Opnd => Make_Null (Loc)),
 425
 426                    Then_Statements => New_List (
 427
 428                      --  typ'Read (S, Var);
 429
 430                      Atr,
 431
 432                      --  Shared_Var_Close (S);
 433
 434                      Make_Procedure_Call_Statement (Loc,
 435                        Name =>
 436                          New_Occurrence_Of
 437                            (RTE (RE_Shared_Var_Close), Loc),
 438                        Parameter_Associations =>
 439                          New_List (New_Reference_To (S, Loc)))))))));
 440
 441       Set_Is_Shared_Passive      (Ent, True);
 442       Set_Shared_Var_Assign_Proc (Ent, Assign_Proc);
 443       Set_Shared_Var_Read_Proc   (Ent, Read_Proc);
 444
 445       --  Return last node before After
 446
 447       declare
 448          Nod : Node_Id := Next (N);
 449
 450       begin
 451          while Next (Nod) /= After loop
 452             Nod := Next (Nod);
 453          end loop;
 454
 455          return Nod;
 456       end;
 457    end Make_Shared_Var_Procs;
 458
 459    --------------------------
 460    -- On_Lhs_Of_Assignment --
 461    --------------------------
 462
 463    function On_Lhs_Of_Assignment (N : Node_Id) return Boolean is
 464       P : constant Node_Id := Parent (N);
 465
 466    begin
 467       if Nkind (P) = N_Assignment_Statement then
 468          if N = Name (P) then
 469             Insert_Node := P;
 470             return True;
 471          else
 472             return False;
 473          end if;
 474
 475       elsif (Nkind (P) = N_Indexed_Component
 476                or else
 477              Nkind (P) = N_Selected_Component)
 478         and then N = Prefix (P)
 479       then
 480          return On_Lhs_Of_Assignment (P);
 481
 482       else
 483          return False;
 484       end if;
 485    end On_Lhs_Of_Assignment;
 486
 487 end Exp_Smem;