gcc/config/arm/libunwind.S

   1 /* Support functions for the unwinder.
   2    Copyright (C) 2003, 2004, 2005  Free Software Foundation, Inc.
   3    Contributed by Paul Brook
   4
   5    This file is free software; you can redistribute it and/or modify it
   6    under the terms of the GNU General Public License as published by the
   7    Free Software Foundation; either version 2, or (at your option) any
   8    later version.
   9
  10    In addition to the permissions in the GNU General Public License, the
  11    Free Software Foundation gives you unlimited permission to link the
  12    compiled version of this file into combinations with other programs,
  13    and to distribute those combinations without any restriction coming
  14    from the use of this file.  (The General Public License restrictions
  15    do apply in other respects; for example, they cover modification of
  16    the file, and distribution when not linked into a combine
  17    executable.)
  18
  19    This file is distributed in the hope that it will be useful, but
  20    WITHOUT ANY WARRANTY; without even the implied warranty of
  21    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22    General Public License for more details.
  23
  24    You should have received a copy of the GNU General Public License
  25    along with this program; see the file COPYING.  If not, write to
  26    the Free Software Foundation, 51 Franklin Street, Fifth Floor,
  27    Boston, MA 02110-1301, USA.  */
  28
  29 /* An executable stack is *not* required for these functions.  */
  30 #if defined(__ELF__) && defined(__linux__)
  31 .section .note.GNU-stack,"",%progbits
  32 .previous
  33 #endif
  34
  35 #ifndef __symbian__
  36
  37 #include "lib1funcs.asm"
  38
  39 .macro UNPREFIX name
  40         .global SYM (\name)
  41         EQUIV SYM (\name), SYM (__\name)
  42 .endm
  43
  44 /* r0 points to a 16-word block.  Upload these values to the actual core
  45    state.  */
  46 ARM_FUNC_START restore_core_regs
  47         /* We must use sp as the base register when restoring sp.  Push the
  48            last 3 registers onto the top of the current stack to achieve
  49            this.  */
  50         add r1, r0, #52
  51         ldmia r1, {r3, r4, r5}  /* {sp, lr, pc}.  */
  52 #ifdef __INTERWORKING__
  53         /* Restore pc into ip.  */
  54         mov r2, r5
  55         stmfd sp!, {r2, r3, r4}
  56 #else
  57         stmfd sp!, {r3, r4, r5}
  58 #endif
  59         /* Don't bother restoring ip.  */
  60         ldmia r0, {r0, r1, r2, r3, r4, r5, r6, r7, r8, r9, sl, fp}
  61         /* Pop the three registers we pushed earlier.  */
  62 #ifdef __INTERWORKING__
  63         ldmfd sp, {ip, sp, lr}
  64         bx ip
  65 #else
  66         ldmfd sp, {sp, lr, pc}
  67 #endif
  68         FUNC_END restore_core_regs
  69         UNPREFIX restore_core_regs
  70
  71 /* Load VFP registers d0-d15 from the address in r0.
  72    Use this to load from FSTMX format.  */
  73 ARM_FUNC_START gnu_Unwind_Restore_VFP
  74         /* Use the generic coprocessor form so that gas doesn't complain
  75            on soft-float targets.  */
  76         ldc   p11,cr0,[r0],{0x21} /* fldmiax r0, {d0-d15} */
  77         RET
  78
  79 /* Store VFP registers d0-d15 to the address in r0.
  80    Use this to store in FSTMX format.  */
  81 ARM_FUNC_START gnu_Unwind_Save_VFP
  82         /* Use the generic coprocessor form so that gas doesn't complain
  83            on soft-float targets.  */
  84         stc   p11,cr0,[r0],{0x21} /* fstmiax r0, {d0-d15} */
  85         RET
  86
  87 /* Load VFP registers d0-d15 from the address in r0.
  88    Use this to load from FSTMD format.  */
  89 ARM_FUNC_START gnu_Unwind_Restore_VFP_D
  90         ldc   p11,cr0,[r0],{0x20} /* fldmiad r0, {d0-d15} */
  91         RET
  92
  93 /* Store VFP registers d0-d15 to the address in r0.
  94    Use this to store in FLDMD format.  */
  95 ARM_FUNC_START gnu_Unwind_Save_VFP_D
  96         stc   p11,cr0,[r0],{0x20} /* fstmiad r0, {d0-d15} */
  97         RET
  98
  99 /* Load VFP registers d16-d31 from the address in r0.
 100    Use this to load from FSTMD (=VSTM) format.  Needs VFPv3.  */
 101 ARM_FUNC_START gnu_Unwind_Restore_VFP_D_16_to_31
 102         ldcl  p11,cr0,[r0],{0x20} /* vldm r0, {d16-d31} */
 103         RET
 104
 105 /* Store VFP registers d16-d31 to the address in r0.
 106    Use this to store in FLDMD (=VLDM) format.  Needs VFPv3.  */
 107 ARM_FUNC_START gnu_Unwind_Save_VFP_D_16_to_31
 108         stcl  p11,cr0,[r0],{0x20} /* vstm r0, {d16-d31} */
 109         RET
 110
 111 /* Wrappers to save core registers, then call the real routine.   */
 112
 113 .macro  UNWIND_WRAPPER name nargs
 114         ARM_FUNC_START \name
 115         /* Create a phase2_vrs structure.  */
 116         /* Split reg push in two to ensure the correct value for sp.  */
 117         stmfd sp!, {sp, lr, pc}
 118         stmfd sp!, {r0, r1, r2, r3, r4, r5, r6, r7, r8, r9, sl, fp, ip}
 119
 120         /* Demand-save flags, plus an extra word for alignment.  */
 121         mov r3, #0
 122         stmfd sp!, {r2, r3}
 123
 124         /* Point r1 at the block.  Pass r[0..nargs) unchanged.  */
 125         add r\nargs, sp, #4
 126 #if defined(__thumb__)
 127         /* Switch back to thumb mode to avoid interworking hassle.  */
 128         adr ip, .L1_\name
 129         orr ip, ip, #1
 130         bx ip
 131         .thumb
 132 .L1_\name:
 133         bl SYM (__gnu\name) __PLT__
 134         ldr r3, [sp, #64]
 135         add sp, #72
 136         bx r3
 137 #else
 138         bl SYM (__gnu\name) __PLT__
 139         ldr lr, [sp, #64]
 140         add sp, sp, #72
 141         RET
 142 #endif
 143         FUNC_END \name
 144         UNPREFIX \name
 145 .endm
 146
 147 UNWIND_WRAPPER _Unwind_RaiseException 1
 148 UNWIND_WRAPPER _Unwind_Resume 1
 149 UNWIND_WRAPPER _Unwind_Resume_or_Rethrow 1
 150 UNWIND_WRAPPER _Unwind_ForcedUnwind 3
 151
 152 #endif  /* __symbian__ */