libffi/src/sparc/v8.S

   1 /* -----------------------------------------------------------------------
   2    v8.S - Copyright (c) 1996, 1997, 2003 Cygnus Solutions
   3
   4    Sparc Foreign Function Interface
   5
   6    Permission is hereby granted, free of charge, to any person obtaining
   7    a copy of this software and associated documentation files (the
   8    ``Software''), to deal in the Software without restriction, including
   9    without limitation the rights to use, copy, modify, merge, publish,
  10    distribute, sublicense, and/or sell copies of the Software, and to
  11    permit persons to whom the Software is furnished to do so, subject to
  12    the following conditions:
  13
  14    The above copyright notice and this permission notice shall be included
  15    in all copies or substantial portions of the Software.
  16
  17    THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, EXPRESS
  18    OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19    MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  20    IN NO EVENT SHALL CYGNUS SOLUTIONS BE LIABLE FOR ANY CLAIM, DAMAGES OR
  21    OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
  22    ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  23    OTHER DEALINGS IN THE SOFTWARE.
  24    ----------------------------------------------------------------------- */
  25
  26 #define LIBFFI_ASM
  27 #include <ffi.h>
  28
  29 #define STACKFRAME 96           /* Minimum stack framesize for SPARC */
  30 #define ARGS (64+4)             /* Offset of register area in frame */
  31
  32 .text
  33         .align 8
  34 .globl ffi_call_V8
  35 .globl _ffi_call_V8
  36
  37 ffi_call_V8:
  38 _ffi_call_V8:
  39 .LLFB1:
  40         save    %sp, -STACKFRAME, %sp
  41 .LLCFI0:
  42
  43         sub     %sp, %i2, %sp   ! alloca() space in stack for frame to set up
  44         add     %sp, STACKFRAME, %l0    ! %l0 has start of
  45                                         ! frame to set up
  46
  47         mov     %l0, %o0        ! call routine to set up frame
  48         call    %i0
  49         mov     %i1, %o1        ! (delay)
  50
  51         ld      [%l0+ARGS], %o0 ! call foreign function
  52         ld      [%l0+ARGS+4], %o1
  53         ld      [%l0+ARGS+8], %o2
  54         ld      [%l0+ARGS+12], %o3
  55         ld      [%l0+ARGS+16], %o4
  56         ld      [%l0+ARGS+20], %o5
  57         call    %i5
  58         mov     %l0, %sp        ! (delay) switch to frame
  59         nop                     ! STRUCT returning functions skip 12 instead of 8 bytes
  60
  61         ! If the return value pointer is NULL, assume no return value.
  62         tst     %i4
  63         bz      done
  64         nop
  65
  66         cmp     %i3, FFI_TYPE_INT
  67         be,a    done
  68         st      %o0, [%i4]      ! (delay)
  69
  70         cmp     %i3, FFI_TYPE_FLOAT
  71         be,a    done
  72         st      %f0, [%i4+0]    ! (delay)
  73
  74         cmp     %i3, FFI_TYPE_SINT64
  75         be      longlong
  76
  77         cmp     %i3, FFI_TYPE_DOUBLE
  78         bne     done
  79         nop
  80         st      %f0, [%i4+0]
  81         st      %f1, [%i4+4]
  82
  83 done:
  84         ret
  85         restore
  86
  87 longlong:
  88         st      %o0, [%i4+0]
  89         st      %o1, [%i4+4]
  90         ret
  91         restore
  92 .LLFE1:
  93
  94 .ffi_call_V8_end:
  95         .size   ffi_call_V8,.ffi_call_V8_end-ffi_call_V8
  96
  97
  98 #define STACKFRAME      104     /* 16*4 register window +
  99                                    1*4 struct return +
 100                                    6*4 args backing store +
 101                                    3*4 locals */
 102
 103 /* ffi_closure_v8(...)
 104
 105    Receives the closure argument in %g2.   */
 106
 107         .text
 108         .align 8
 109         .globl ffi_closure_v8
 110
 111 ffi_closure_v8:
 112         .register       %g2, #scratch
 113 .LLFB2:
 114         save    %sp, -STACKFRAME, %sp
 115 .LLCFI1:
 116
 117         ! Store all of the potential argument registers in va_list format.
 118         st      %i0, [%fp+68+0]
 119         st      %i1, [%fp+68+4]
 120         st      %i2, [%fp+68+8]
 121         st      %i3, [%fp+68+12]
 122         st      %i4, [%fp+68+16]
 123         st      %i5, [%fp+68+20]
 124
 125         ! Call ffi_closure_sparc_inner to do the bulk of the work.
 126         mov     %g2, %o0
 127         add     %fp, -8, %o1
 128         add     %fp,  68, %o2
 129         call    ffi_closure_sparc_inner
 130          mov    0, %o3
 131
 132         ! Load up the return value in the proper type.
 133         cmp     %o0, FFI_TYPE_VOID
 134         be      done1
 135
 136         cmp     %o0, FFI_TYPE_FLOAT
 137         be,a    done1
 138          ld     [%fp-8], %f0
 139
 140         cmp     %o0, FFI_TYPE_DOUBLE
 141         be,a    done1
 142          ldd    [%fp-8], %f0
 143
 144         cmp     %o0, FFI_TYPE_SINT64
 145         be,a    integer
 146          ld     [%fp-4], %i1
 147
 148         cmp     %o0, FFI_TYPE_UINT64
 149         be,a    integer
 150          ld     [%fp-4], %i1
 151
 152 integer:
 153         ld      [%fp-8], %i0
 154
 155 done1:
 156         ret
 157          restore
 158 .LLFE2:
 159
 160 .ffi_closure_v8_end:
 161         .size   ffi_closure_v8,.ffi_closure_v8_end-ffi_closure_v8
 162
 163 #ifdef SPARC64
 164 #define WS 8
 165 #define nword   xword
 166 #define uanword uaxword
 167 #else
 168 #define WS 4
 169 #define nword   long
 170 #define uanword uaword
 171 #endif
 172
 173         .section        ".eh_frame",#alloc,#write
 174 .LLframe1:
 175         .uaword .LLECIE1-.LLSCIE1       ! Length of Common Information Entry
 176 .LLSCIE1:
 177         .uaword 0x0     ! CIE Identifier Tag
 178         .byte   0x1     ! CIE Version
 179         .ascii "zR\0"   ! CIE Augmentation
 180         .byte   0x1     ! uleb128 0x1; CIE Code Alignment Factor
 181         .byte   0x80-WS ! sleb128 -WS; CIE Data Alignment Factor
 182         .byte   0xf     ! CIE RA Column
 183         .byte   0x1     ! uleb128 0x1; Augmentation size
 184 #ifdef HAVE_AS_SPARC_UA_PCREL
 185         .byte   0x1b    ! FDE Encoding (pcrel sdata4)
 186 #else
 187         .byte   0x50    ! FDE Encoding (aligned absolute)
 188 #endif
 189         .byte   0xc     ! DW_CFA_def_cfa
 190         .byte   0xe     ! uleb128 0xe
 191         .byte   0x0     ! uleb128 0x0
 192         .align  WS
 193 .LLECIE1:
 194 .LLSFDE1:
 195         .uaword .LLEFDE1-.LLASFDE1      ! FDE Length
 196 .LLASFDE1:
 197         .uaword .LLASFDE1-.LLframe1     ! FDE CIE offset
 198 #ifdef HAVE_AS_SPARC_UA_PCREL
 199         .uaword %r_disp32(.LLFB1)
 200         .uaword .LLFE1-.LLFB1   ! FDE address range
 201 #else
 202         .align  WS
 203         .nword  .LLFB1
 204         .uanword .LLFE1-.LLFB1  ! FDE address range
 205 #endif
 206         .byte   0x0     ! uleb128 0x0; Augmentation size
 207         .byte   0x4     ! DW_CFA_advance_loc4
 208         .uaword .LLCFI0-.LLFB1
 209         .byte   0xd     ! DW_CFA_def_cfa_register
 210         .byte   0x1e    ! uleb128 0x1e
 211         .byte   0x2d    ! DW_CFA_GNU_window_save
 212         .byte   0x9     ! DW_CFA_register
 213         .byte   0xf     ! uleb128 0xf
 214         .byte   0x1f    ! uleb128 0x1f
 215         .align  WS
 216 .LLEFDE1:
 217 .LLSFDE2:
 218         .uaword .LLEFDE2-.LLASFDE2      ! FDE Length
 219 .LLASFDE2:
 220         .uaword .LLASFDE2-.LLframe1     ! FDE CIE offset
 221 #ifdef HAVE_AS_SPARC_UA_PCREL
 222         .uaword %r_disp32(.LLFB2)
 223         .uaword .LLFE2-.LLFB2   ! FDE address range
 224 #else
 225         .align  WS
 226         .nword  .LLFB2
 227         .uanword .LLFE2-.LLFB2  ! FDE address range
 228 #endif
 229         .byte   0x0     ! uleb128 0x0; Augmentation size
 230         .byte   0x4     ! DW_CFA_advance_loc4
 231         .uaword .LLCFI1-.LLFB2
 232         .byte   0xd     ! DW_CFA_def_cfa_register
 233         .byte   0x1e    ! uleb128 0x1e
 234         .byte   0x2d    ! DW_CFA_GNU_window_save
 235         .byte   0x9     ! DW_CFA_register
 236         .byte   0xf     ! uleb128 0xf
 237         .byte   0x1f    ! uleb128 0x1f
 238         .align  WS
 239 .LLEFDE2: