gcc/ada/s-imgwiu.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ W I U                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System.Unsigned_Types; use System.Unsigned_Types;
  36
  37 package body System.Img_WIU is
  38
  39    -----------------------------
  40    -- Set_Image_Width_Integer --
  41    -----------------------------
  42
  43    procedure Set_Image_Width_Integer
  44      (V : Integer;
  45       W : Integer;
  46       S : out String;
  47       P : in out Natural)
  48    is
  49       Start : Natural;
  50
  51    begin
  52       --  Positive case can just use the unsigned circuit directly
  53
  54       if V >= 0 then
  55          Set_Image_Width_Unsigned (Unsigned (V), W, S, P);
  56
  57       --  Negative case has to set a minus sign. Note also that we have to be
  58       --  careful not to generate overflow with the largest negative number.
  59
  60       else
  61          P := P + 1;
  62          S (P) := ' ';
  63          Start := P;
  64
  65          declare
  66             pragma Suppress (Overflow_Check);
  67             pragma Suppress (Range_Check);
  68          begin
  69             Set_Image_Width_Unsigned (Unsigned (-V), W - 1, S, P);
  70          end;
  71
  72          --  Set minus sign in last leading blank location. Because of the
  73          --  code above, there must be at least one such location.
  74
  75          while S (Start + 1) = ' ' loop
  76             Start := Start + 1;
  77          end loop;
  78
  79          S (Start) := '-';
  80       end if;
  81
  82    end Set_Image_Width_Integer;
  83
  84    ------------------------------
  85    -- Set_Image_Width_Unsigned --
  86    ------------------------------
  87
  88    procedure Set_Image_Width_Unsigned
  89      (V : Unsigned;
  90       W : Integer;
  91       S : out String;
  92       P : in out Natural)
  93    is
  94       Start : constant Natural := P;
  95       F, T  : Natural;
  96
  97       procedure Set_Digits (T : Unsigned);
  98       --  Set digits of absolute value of T
  99
 100       procedure Set_Digits (T : Unsigned) is
 101       begin
 102          if T >= 10 then
 103             Set_Digits (T / 10);
 104             P := P + 1;
 105             S (P) := Character'Val (T mod 10 + Character'Pos ('0'));
 106          else
 107             P := P + 1;
 108             S (P) := Character'Val (T + Character'Pos ('0'));
 109          end if;
 110       end Set_Digits;
 111
 112    --  Start of processing for Set_Image_Width_Unsigned
 113
 114    begin
 115       Set_Digits (V);
 116
 117       --  Add leading spaces if required by width parameter
 118
 119       if P - Start < W then
 120          F := P;
 121          P := P + (W - (P - Start));
 122          T := P;
 123
 124          while F > Start loop
 125             S (T) := S (F);
 126             T := T - 1;
 127             F := F - 1;
 128          end loop;
 129
 130          for J in Start + 1 .. T loop
 131             S (J) := ' ';
 132          end loop;
 133       end if;
 134
 135    end Set_Image_Width_Unsigned;
 136
 137 end System.Img_WIU;