gcc/ada/g-table.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                            G N A T . T A B L E                           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --            Copyright (C) 1998-2001 Ada Core Technologies, Inc.           --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Resizable one dimensional array support
  35
  36 --  This package provides an implementation of dynamically resizable one
  37 --  dimensional arrays. The idea is to mimic the normal Ada semantics for
  38 --  arrays as closely as possible with the one additional capability of
  39 --  dynamically modifying the value of the Last attribute.
  40
  41 --  This package provides a facility similar to that of GNAT.Dynamic_Tables,
  42 --  except that this package declares a single instance of the table type,
  43 --  while an instantiation of GNAT.Dynamic_Tables creates a type that can be
  44 --  used to define dynamic instances of the table.
  45
  46 --  Note that this interface should remain synchronized with those in
  47 --  GNAT.Dynamic_Tables and the GNAT compiler source unit Table to keep
  48 --  as much coherency as possible between these three related units.
  49
  50 generic
  51    type Table_Component_Type is private;
  52    type Table_Index_Type     is range <>;
  53
  54    Table_Low_Bound : Table_Index_Type;
  55    Table_Initial   : Positive;
  56    Table_Increment : Natural;
  57
  58 package GNAT.Table is
  59 pragma Elaborate_Body (Table);
  60
  61    --  Table_Component_Type and Table_Index_Type specify the type of the
  62    --  array, Table_Low_Bound is the lower bound. Index_type must be an
  63    --  integer type. The effect is roughly to declare:
  64
  65    --    Table : array (Table_Index_Type range Table_Low_Bound .. <>)
  66    --                       of Table_Component_Type;
  67
  68    --    Note: since the upper bound can be one less than the lower
  69    --    bound for an empty array, the table index type must be able
  70    --    to cover this range, e.g. if the lower bound is 1, then the
  71    --    Table_Index_Type should be Natural rather than Positive.
  72
  73    --  Table_Component_Type may be any Ada type, except that controlled
  74    --  types are not supported. Note however that default initialization
  75    --  will NOT occur for array components.
  76
  77    --  The Table_Initial values controls the allocation of the table when
  78    --  it is first allocated, either by default, or by an explicit Init call.
  79
  80    --  The Table_Increment value controls the amount of increase, if the
  81    --  table has to be increased in size. The value given is a percentage
  82    --  value (e.g. 100 = increase table size by 100%, i.e. double it).
  83
  84    --  The Last and Set_Last subprograms provide control over the current
  85    --  logical allocation. They are quite efficient, so they can be used
  86    --  freely (expensive reallocation occurs only at major granularity
  87    --  chunks controlled by the allocation parameters).
  88
  89    --  Note: we do not make the table components aliased, since this would
  90    --  restrict the use of table for discriminated types. If it is necessary
  91    --  to take the access of a table element, use Unrestricted_Access.
  92
  93    type Table_Type is
  94      array (Table_Index_Type range <>) of Table_Component_Type;
  95
  96    subtype Big_Table_Type is
  97      Table_Type (Table_Low_Bound .. Table_Index_Type'Last);
  98    --  We work with pointers to a bogus array type that is constrained
  99    --  with the maximum possible range bound. This means that the pointer
 100    --  is a thin pointer, which is more efficient. Since subscript checks
 101    --  in any case must be on the logical, rather than physical bounds,
 102    --  safety is not compromised by this approach.
 103
 104    type Table_Ptr is access all Big_Table_Type;
 105    --  The table is actually represented as a pointer to allow reallocation
 106
 107    Table : aliased Table_Ptr := null;
 108    --  The table itself. The lower bound is the value of Low_Bound.
 109    --  Logically the upper bound is the current value of Last (although
 110    --  the actual size of the allocated table may be larger than this).
 111    --  The program may only access and modify Table entries in the range
 112    --  First .. Last.
 113
 114    Locked : Boolean := False;
 115    --  Table expansion is permitted only if this switch is set to False. A
 116    --  client may set Locked to True, in which case any attempt to expand
 117    --  the table will cause an assertion failure. Note that while a table
 118    --  is locked, its address in memory remains fixed and unchanging.
 119
 120    procedure Init;
 121    --  This procedure allocates a new table of size Initial (freeing any
 122    --  previously allocated larger table). It is not necessary to call
 123    --  Init when a table is first instantiated (since the instantiation does
 124    --  the same initialization steps). However, it is harmless to do so, and
 125    --  Init is convenient in reestablishing a table for new use.
 126
 127    function Last return Table_Index_Type;
 128    pragma Inline (Last);
 129    --  Returns the current value of the last used entry in the table, which
 130    --  can then be used as a subscript for Table. Note that the only way to
 131    --  modify Last is to call the Set_Last procedure. Last must always be
 132    --  used to determine the logically last entry.
 133
 134    procedure Release;
 135    --  Storage is allocated in chunks according to the values given in the
 136    --  Initial and Increment parameters. A call to Release releases all
 137    --  storage that is allocated, but is not logically part of the current
 138    --  array value. Current array values are not affected by this call.
 139
 140    procedure Free;
 141    --  Free all allocated memory for the table. A call to init is required
 142    --  before any use of this table after calling Free.
 143
 144    First : constant Table_Index_Type := Table_Low_Bound;
 145    --  Export First as synonym for Low_Bound (parallel with use of Last)
 146
 147    procedure Set_Last (New_Val : Table_Index_Type);
 148    pragma Inline (Set_Last);
 149    --  This procedure sets Last to the indicated value. If necessary the
 150    --  table is reallocated to accommodate the new value (i.e. on return
 151    --  the allocated table has an upper bound of at least Last). If Set_Last
 152    --  reduces the size of the table, then logically entries are removed
 153    --  from the table. If Set_Last increases the size of the table, then
 154    --  new entries are logically added to the table.
 155
 156    procedure Increment_Last;
 157    pragma Inline (Increment_Last);
 158    --  Adds 1 to Last (same as Set_Last (Last + 1).
 159
 160    procedure Decrement_Last;
 161    pragma Inline (Decrement_Last);
 162    --  Subtracts 1 from Last (same as Set_Last (Last - 1).
 163
 164    procedure Append (New_Val : Table_Component_Type);
 165    pragma Inline (Append);
 166    --  Equivalent to:
 167    --    x.Increment_Last;
 168    --    x.Table (x.Last) := New_Val;
 169    --  i.e. the table size is increased by one, and the given new item
 170    --  stored in the newly created table element.
 171
 172    procedure Set_Item
 173      (Index : Table_Index_Type;
 174       Item  : Table_Component_Type);
 175    pragma Inline (Set_Item);
 176    --  Put Item in the table at position Index. The table is expanded if the
 177    --  current table length is less than Index and in that case Last is set to
 178    --  Index. Item will replace any value already present in the table at this
 179    --  position.
 180
 181    function Allocate (Num : Integer := 1) return Table_Index_Type;
 182    pragma Inline (Allocate);
 183    --  Adds Num to Last, and returns the old value of Last + 1. Note that
 184    --  this function has the possible side effect of reallocating the table.
 185    --  This means that a reference X.Table (X.Allocate) is incorrect, since
 186    --  the call to X.Allocate may modify the results of calling X.Table.
 187
 188 end GNAT.Table;