gcc/ada/a-wtinio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . W I D E _ T E X T _ I O . I N T E G E R _ I O          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-2000 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with Ada.Wide_Text_IO.Integer_Aux;
  36 with System.WCh_Con; use System.WCh_Con;
  37 with System.WCh_WtS; use System.WCh_WtS;
  38
  39 package body Ada.Wide_Text_IO.Integer_IO is
  40
  41    Need_LLI : constant Boolean := Num'Base'Size > Integer'Size;
  42    --  Throughout this generic body, we distinguish between the case
  43    --  where type Integer is acceptable, and where a Long_Long_Integer
  44    --  is needed. This constant Boolean is used to test for these cases
  45    --  and since it is a constant, only the code for the relevant case
  46    --  will be included in the instance.
  47
  48    subtype TFT is Ada.Wide_Text_IO.File_Type;
  49    --  File type required for calls to routines in Aux
  50
  51    package Aux renames Ada.Wide_Text_IO.Integer_Aux;
  52
  53    ---------
  54    -- Get --
  55    ---------
  56
  57    procedure Get
  58      (File  : in File_Type;
  59       Item  : out Num;
  60       Width : in Field := 0)
  61    is
  62    begin
  63       if Need_LLI then
  64          Aux.Get_LLI (TFT (File), Long_Long_Integer (Item), Width);
  65       else
  66          Aux.Get_Int (TFT (File), Integer (Item), Width);
  67       end if;
  68
  69    exception
  70       when Constraint_Error => raise Data_Error;
  71    end Get;
  72
  73    procedure Get
  74      (Item  : out Num;
  75       Width : in Field := 0)
  76    is
  77    begin
  78       Get (Current_Input, Item, Width);
  79    end Get;
  80
  81    procedure Get
  82      (From : in Wide_String;
  83       Item : out Num;
  84       Last : out Positive)
  85    is
  86       S : constant String := Wide_String_To_String (From, WCEM_Upper);
  87       --  String on which we do the actual conversion. Note that the method
  88       --  used for wide character encoding is irrelevant, since if there is
  89       --  a character outside the Standard.Character range then the call to
  90       --  Aux.Gets will raise Data_Error in any case.
  91
  92    begin
  93       if Need_LLI then
  94          Aux.Gets_LLI (S, Long_Long_Integer (Item), Last);
  95       else
  96          Aux.Gets_Int (S, Integer (Item), Last);
  97       end if;
  98
  99    exception
 100       when Constraint_Error => raise Data_Error;
 101    end Get;
 102
 103    ---------
 104    -- Put --
 105    ---------
 106
 107    procedure Put
 108      (File  : in File_Type;
 109       Item  : in Num;
 110       Width : in Field := Default_Width;
 111       Base  : in Number_Base := Default_Base)
 112    is
 113    begin
 114       if Need_LLI then
 115          Aux.Put_LLI (TFT (File), Long_Long_Integer (Item), Width, Base);
 116       else
 117          Aux.Put_Int (TFT (File), Integer (Item), Width, Base);
 118       end if;
 119    end Put;
 120
 121    procedure Put
 122      (Item  : in Num;
 123       Width : in Field := Default_Width;
 124       Base  : in Number_Base := Default_Base)
 125    is
 126    begin
 127       Put (Current_Output, Item, Width, Base);
 128    end Put;
 129
 130    procedure Put
 131      (To   : out Wide_String;
 132       Item : in Num;
 133       Base : in Number_Base := Default_Base)
 134    is
 135       S : String (To'First .. To'Last);
 136
 137    begin
 138       if Need_LLI then
 139          Aux.Puts_LLI (S, Long_Long_Integer (Item), Base);
 140       else
 141          Aux.Puts_Int (S, Integer (Item), Base);
 142       end if;
 143
 144       for J in S'Range loop
 145          To (J) := Wide_Character'Val (Character'Pos (S (J)));
 146       end loop;
 147    end Put;
 148
 149 end Ada.Wide_Text_IO.Integer_IO;