gcc/ada/s-tpopsp-rtems.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --    S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S .   --
   6 --                              S P E C I F I C                             --
   7 --                                                                          --
   8 --                                  B o d y                                 --
   9 --                                                                          --
  10 --                             $Revision: 1.1 $
  11 --                                                                          --
  12 --            Copyright (C) 1991-2003, Florida State University             --
  13 --                                                                          --
  14 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  15 -- terms of the  GNU General Public License as published  by the Free Soft- --
  16 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  17 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  18 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  19 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  20 -- for  more details.  You should have  received  a copy of the GNU General --
  21 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  22 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  23 -- MA 02111-1307, USA.                                                      --
  24 --                                                                          --
  25 -- As a special exception,  if other files  instantiate  generics from this --
  26 -- unit, or you link  this unit with other files  to produce an executable, --
  27 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  28 -- covered  by the  GNU  General  Public  License.  This exception does not --
  29 -- however invalidate  any other reasons why  the executable file  might be --
  30 -- covered by the  GNU Public License.                                      --
  31 --                                                                          --
  32 -- GNARL was developed by the GNARL team at Florida State University. It is --
  33 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  34 -- State University (http://www.gnat.com).                                  --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  This is a RTEMS version of this package which uses a special
  39 --  variable for Ada self which is contexted switch implicitly by RTEMS.
  40 --
  41 --  This is the same as the POSIX version except that an RTEMS variable
  42 --  is used instead of a POSIX key.
  43
  44 separate (System.Task_Primitives.Operations)
  45 package body Specific is
  46
  47    --  The following gives the Ada run-time direct access to a variable
  48    --  context switched by RTEMS at the lowest level.
  49
  50    RTEMS_Ada_Self : System.Address;
  51    pragma Import (C, RTEMS_Ada_Self, "rtems_ada_self");
  52
  53    ----------------
  54    -- Initialize --
  55    ----------------
  56
  57    procedure Initialize (Environment_Task : Task_Id) is
  58       pragma Warnings (Off, Environment_Task);
  59
  60    begin
  61       ATCB_Key := No_Key;
  62       RTEMS_Ada_Self := To_Address (Environment_Task);
  63    end Initialize;
  64
  65    -------------------
  66    -- Is_Valid_Task --
  67    -------------------
  68
  69    function Is_Valid_Task return Boolean is
  70    begin
  71       return RTEMS_Ada_Self /= System.Null_Address;
  72    end Is_Valid_Task;
  73
  74    ---------
  75    -- Set --
  76    ---------
  77
  78    procedure Set (Self_Id : Task_Id) is
  79    begin
  80       RTEMS_Ada_Self := To_Address (Self_Id);
  81    end Set;
  82
  83    ----------
  84    -- Self --
  85    ----------
  86
  87    --  To make Ada tasks and C threads interoperate better, we have added some
  88    --  functionality to Self. Suppose a C main program (with threads) calls an
  89    --  Ada procedure and the Ada procedure calls the tasking runtime system.
  90    --  Eventually, a call will be made to self. Since the call is not coming
  91    --  from an Ada task, there will be no corresponding ATCB.
  92
  93    --  What we do in Self is to catch references that do not come from
  94    --  recognized Ada tasks, and create an ATCB for the calling thread.
  95
  96    --  The new ATCB will be "detached" from the normal Ada task master
  97    --  hierarchy, much like the existing implicitly created signal-server
  98    --  tasks.
  99
 100    function Self return Task_Id is
 101       Result : System.Address;
 102
 103    begin
 104       Result := RTEMS_Ada_Self;
 105
 106       --  If the key value is Null, then it is a non-Ada task.
 107
 108       if Result /= System.Null_Address then
 109          return To_Task_Id (Result);
 110       else
 111          return Register_Foreign_Thread;
 112       end if;
 113    end Self;
 114
 115 end Specific;