gcc/ada/mlib-tgt-solaris.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                            (Solaris Version)                             --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --              Copyright (C) 2002-2004 Free Software Foundation, Inc.      --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the Solaris version of the body
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  44    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  45
  46    Wl_Init_String : constant String         := "-Wl,-zinitarray=";
  47    Wl_Fini_String : constant String         := "-Wl,-zfiniarray=";
  48
  49    Init_Fini_List :  constant Argument_List_Access :=
  50                        new Argument_List'(1 => null,
  51                                           2 => null);
  52
  53    --  Used to put switches for automatic elaboration/finalization
  54
  55    ---------------------
  56    -- Archive_Builder --
  57    ---------------------
  58
  59    function Archive_Builder return String is
  60    begin
  61       return "ar";
  62    end Archive_Builder;
  63
  64    -----------------------------
  65    -- Archive_Builder_Options --
  66    -----------------------------
  67
  68    function Archive_Builder_Options return String_List_Access is
  69    begin
  70       return new String_List'(1 => new String'("cr"));
  71    end Archive_Builder_Options;
  72
  73    -----------------
  74    -- Archive_Ext --
  75    -----------------
  76
  77    function Archive_Ext return  String is
  78    begin
  79       return "a";
  80    end Archive_Ext;
  81
  82    ---------------------
  83    -- Archive_Indexer --
  84    ---------------------
  85
  86    function Archive_Indexer return String is
  87    begin
  88       return "ranlib";
  89    end Archive_Indexer;
  90
  91    -----------------------------
  92    -- Archive_Indexer_Options --
  93    -----------------------------
  94
  95    function Archive_Indexer_Options return String_List_Access is
  96    begin
  97       return new String_List (1 .. 0);
  98    end Archive_Indexer_Options;
  99
 100    ---------------------------
 101    -- Build_Dynamic_Library --
 102    ---------------------------
 103
 104    procedure Build_Dynamic_Library
 105      (Ofiles       : Argument_List;
 106       Foreign      : Argument_List;
 107       Afiles       : Argument_List;
 108       Options      : Argument_List;
 109       Options_2    : Argument_List;
 110       Interfaces   : Argument_List;
 111       Lib_Filename : String;
 112       Lib_Dir      : String;
 113       Symbol_Data  : Symbol_Record;
 114       Driver_Name  : Name_Id := No_Name;
 115       Lib_Version  : String  := "";
 116       Auto_Init    : Boolean := False)
 117    is
 118       pragma Unreferenced (Foreign);
 119       pragma Unreferenced (Afiles);
 120       pragma Unreferenced (Interfaces);
 121       pragma Unreferenced (Symbol_Data);
 122
 123       Lib_File : constant String :=
 124                    Lib_Dir & Directory_Separator & "lib" &
 125                    Fil.Ext_To (Lib_Filename, DLL_Ext);
 126
 127       Version_Arg          : String_Access;
 128       Symbolic_Link_Needed : Boolean := False;
 129
 130       Init_Fini : Argument_List_Access := Empty_Argument_List;
 131
 132    begin
 133       if Opt.Verbose_Mode then
 134          Write_Str ("building relocatable shared library ");
 135          Write_Line (Lib_File);
 136       end if;
 137
 138       --  If specified, add automatic elaboration/finalization
 139
 140       if Auto_Init then
 141          Init_Fini := Init_Fini_List;
 142          Init_Fini (1) :=
 143            new String'(Wl_Init_String & Lib_Filename & "init");
 144          Init_Fini (2) :=
 145            new String'(Wl_Fini_String & Lib_Filename & "final");
 146       end if;
 147
 148       if Lib_Version = "" then
 149          Utl.Gcc
 150            (Output_File => Lib_File,
 151             Objects     => Ofiles,
 152             Options     => Options & Init_Fini.all,
 153             Options_2   => Options_2,
 154             Driver_Name => Driver_Name);
 155
 156       else
 157          Version_Arg := new String'("-Wl,-h," & Lib_Version);
 158
 159          if Is_Absolute_Path (Lib_Version) then
 160             Utl.Gcc
 161               (Output_File => Lib_Version,
 162                Objects     => Ofiles,
 163                Options     => Options & Version_Arg & Init_Fini.all,
 164                Options_2   => Options_2,
 165                Driver_Name => Driver_Name);
 166             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 167
 168          else
 169             Utl.Gcc
 170               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 171                Objects     => Ofiles,
 172                Options     => Options & Version_Arg & Init_Fini.all,
 173                Options_2   => Options_2,
 174                Driver_Name => Driver_Name);
 175             Symbolic_Link_Needed :=
 176               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 177          end if;
 178
 179          if Symbolic_Link_Needed then
 180             declare
 181                Success : Boolean;
 182                Oldpath : String (1 .. Lib_Version'Length + 1);
 183                Newpath : String (1 .. Lib_File'Length + 1);
 184
 185                Result : Integer;
 186                pragma Unreferenced (Result);
 187
 188                function Symlink
 189                  (Oldpath : System.Address;
 190                   Newpath : System.Address)
 191                   return    Integer;
 192                pragma Import (C, Symlink, "__gnat_symlink");
 193
 194             begin
 195                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 196                Oldpath (Oldpath'Last)            := ASCII.NUL;
 197                Newpath (1 .. Lib_File'Length)    := Lib_File;
 198                Newpath (Newpath'Last)            := ASCII.NUL;
 199
 200                Delete_File (Lib_File, Success);
 201
 202                Result := Symlink (Oldpath'Address, Newpath'Address);
 203             end;
 204          end if;
 205       end if;
 206    end Build_Dynamic_Library;
 207
 208    -------------
 209    -- DLL_Ext --
 210    -------------
 211
 212    function DLL_Ext return String is
 213    begin
 214       return "so";
 215    end DLL_Ext;
 216
 217    --------------------
 218    -- Dynamic_Option --
 219    --------------------
 220
 221    function Dynamic_Option return String is
 222    begin
 223       return "-shared";
 224    end Dynamic_Option;
 225
 226    -------------------
 227    -- Is_Object_Ext --
 228    -------------------
 229
 230    function Is_Object_Ext (Ext : String) return Boolean is
 231    begin
 232       return Ext = ".o";
 233    end Is_Object_Ext;
 234
 235    --------------
 236    -- Is_C_Ext --
 237    --------------
 238
 239    function Is_C_Ext (Ext : String) return Boolean is
 240    begin
 241       return Ext = ".c";
 242    end Is_C_Ext;
 243
 244    --------------------
 245    -- Is_Archive_Ext --
 246    --------------------
 247
 248    function Is_Archive_Ext (Ext : String) return Boolean is
 249    begin
 250       return Ext = ".a" or else Ext = ".so";
 251    end Is_Archive_Ext;
 252
 253    -------------
 254    -- Libgnat --
 255    -------------
 256
 257    function Libgnat return String is
 258    begin
 259       return "libgnat.a";
 260    end Libgnat;
 261
 262    ------------------------
 263    -- Library_Exists_For --
 264    ------------------------
 265
 266    function Library_Exists_For (Project : Project_Id) return Boolean is
 267    begin
 268       if not Projects.Table (Project).Library then
 269          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 270                        "for non library project");
 271          return False;
 272
 273       else
 274          declare
 275             Lib_Dir : constant String :=
 276               Get_Name_String (Projects.Table (Project).Library_Dir);
 277             Lib_Name : constant String :=
 278               Get_Name_String (Projects.Table (Project).Library_Name);
 279
 280          begin
 281             if Projects.Table (Project).Library_Kind = Static then
 282                return Is_Regular_File
 283                  (Lib_Dir & Directory_Separator & "lib" &
 284                   Fil.Ext_To (Lib_Name, Archive_Ext));
 285
 286             else
 287                return Is_Regular_File
 288                  (Lib_Dir & Directory_Separator & "lib" &
 289                   Fil.Ext_To (Lib_Name, DLL_Ext));
 290             end if;
 291          end;
 292       end if;
 293    end Library_Exists_For;
 294
 295    ---------------------------
 296    -- Library_File_Name_For --
 297    ---------------------------
 298
 299    function Library_File_Name_For (Project : Project_Id) return Name_Id is
 300    begin
 301       if not Projects.Table (Project).Library then
 302          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 303                        "for non library project");
 304          return No_Name;
 305
 306       else
 307          declare
 308             Lib_Name : constant String :=
 309               Get_Name_String (Projects.Table (Project).Library_Name);
 310
 311          begin
 312             Name_Len := 3;
 313             Name_Buffer (1 .. Name_Len) := "lib";
 314
 315             if Projects.Table (Project).Library_Kind = Static then
 316                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 317
 318             else
 319                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 320             end if;
 321
 322             return Name_Find;
 323          end;
 324       end if;
 325    end Library_File_Name_For;
 326
 327    ----------------
 328    -- Object_Ext --
 329    ----------------
 330
 331    function Object_Ext return String is
 332    begin
 333       return "o";
 334    end Object_Ext;
 335
 336    ----------------
 337    -- PIC_Option --
 338    ----------------
 339
 340    function PIC_Option return String is
 341    begin
 342       return "-fPIC";
 343    end PIC_Option;
 344
 345    -----------------------------------------------
 346    -- Standalone_Library_Auto_Init_Is_Supported --
 347    -----------------------------------------------
 348
 349    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 350    begin
 351       return True;
 352    end Standalone_Library_Auto_Init_Is_Supported;
 353
 354    ---------------------------
 355    -- Support_For_Libraries --
 356    ---------------------------
 357
 358    function Support_For_Libraries return Library_Support is
 359    begin
 360       return Full;
 361    end Support_For_Libraries;
 362
 363 end MLib.Tgt;