gcc/testsuite/lib/profopt.exp

   1 #   Copyright (C) 2001, 2004, 2005, 2007 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16 #
  17 # This script was submitted by Janis Johnson <janis187@us.ibm.com>.
  18
  19 # Test the functionality and optionally, performance improvement, of
  20 # programs compiled with profile-directed optimizations.  Compile and
  21 # run a test with profile options, compile it with options using the
  22 # profile feedback, and then run the test again.  Optionally compile
  23 # and run a third time without the profile-directed optimization and
  24 # compare timing results of the program with normal optimization and
  25 # with the profile-directed optimization. Each test is run using
  26 # multiple sets of optimization and/or code generation options in
  27 # addition to the profiling and feedback options.
  28
  29 # If perf_ext is defined and the performance value for the
  30 # profile-directed test run is nonzero then the performance check will
  31 # be done.
  32
  33 load_lib dg.exp
  34 load_lib gcc-dg.exp
  35
  36 global PROFOPT_OPTIONS perf_delta
  37
  38 # The including .exp file must define these.
  39 global tool profile_option feedback_option prof_ext
  40 if ![info exists tool] {
  41     error "Tools is not specified."
  42 }
  43 if ![info exists prof_ext] {
  44     error "No profile data file extensions specified."
  45 }
  46
  47 # The maximum perforance degradation can be defined in the including file.
  48 if ![info exists perf_delta] {
  49     set perf_delta 4
  50 }
  51
  52 # The default option list can be overridden by
  53 # PROFOPT_OPTIONS="{ { list1 } ... { list2 } }"
  54
  55 if ![info exists PROFOPT_OPTIONS] {
  56     set PROFOPT_OPTIONS [list \
  57         { -g } \
  58         { -O0 } \
  59         { -O1 } \
  60         { -O2 } \
  61         { -O3 } \
  62         { -O3 -g } \
  63         { -Os } ]
  64 }
  65
  66 set prof_option_list $PROFOPT_OPTIONS
  67
  68 #
  69 # profopt-cleanup -- remove profiling or performance results files.
  70 #
  71 # TESTCASE is the name of the test
  72 # EXT is the extensions of files to remove
  73 #
  74 proc profopt-cleanup { testcase extlist } {
  75     set basename [file tail $testcase]
  76     set base [file rootname $basename]
  77     foreach ext $extlist {
  78         set files [glob -nocomplain $base.$ext]
  79         if { $files != "" } {
  80             eval "remote_file build delete $files"
  81         }
  82     }
  83 }
  84
  85 #
  86 # profopt-perf-value -- get performance value for a test
  87 #
  88 # TESTCASE is the name of the test
  89 # PERF_EXT is the extension of the performance result file
  90 # OPTSTR is the string of compiler options
  91 #
  92 proc profopt-perf-value { testcase perf_ext optstr } {
  93     set basename [file tail $testcase]
  94     set base [file rootname $basename]
  95     set files [glob -nocomplain $base.$perf_ext]
  96     # The file doesn't exist; let the caller decide if that's a problem.
  97     if { $files == "" } {
  98         return -2
  99     }
 100     remote_upload host $base.$perf_ext $base.$perf_ext
 101     set fd [open $base.$perf_ext r]
 102     gets $fd line
 103     set val -2
 104     if [regexp "TIME" $line] {
 105         if [regexp "TIME -1" $line] {
 106             fail "$testcase perf check: no consistent time available, $optstr"
 107             set val -1
 108         } elseif ![regexp "(\[0-9\]+)" "$line" val] {
 109             set val -2
 110         }
 111     }
 112     # Report problems with an existing file.
 113     if { $val == -2 } {
 114         fail "$testcase perf check: file $base.$perf_ext has wrong format, $optstr"
 115     }
 116     close $fd
 117     profopt-cleanup $testcase $perf_ext
 118     return $val
 119 }
 120
 121 #
 122 # dg-final-generate -- process code to run after the profile-generate step
 123 #
 124 # ARGS is the line number of the directive followed by the commands.
 125 #
 126 proc dg-final-generate { args } {
 127     global generate_final_code
 128
 129     if { [llength $args] > 2 } {
 130         error "[lindex $args 0]: too many arguments"
 131         return
 132     }
 133     append generate_final_code "[lindex $args 1]\n"
 134 }
 135
 136 #
 137 # dg-final-use -- process code to run after the profile-use step
 138 #
 139 # ARGS is the line number of the directive followed by the commands.
 140 #
 141 proc dg-final-use { args } {
 142     global use_final_code
 143
 144     if { [llength $args] > 2 } {
 145         error "[lindex $args 0]: too many arguments"
 146         return
 147     }
 148     append use_final_code "[lindex $args 1]\n"
 149 }
 150
 151 #
 152 # profopt-final-code -- run final code
 153 #
 154 # WHICH is "generate" or "use".
 155 # FINAL_CODE is the TCL code to run.
 156 # TESTCASE is the name of the test, for error messages.
 157 #
 158 proc profopt-final-code { which final_code name } {
 159     # This is copied from dg-test in dg.exp of DejaGnu.
 160     regsub -all "\\\\(\[{}\])" $final_code "\\1" final_code
 161     proc profopt-final-proc { args } $final_code
 162     if [catch "profopt-final-proc $name" errmsg] {
 163         perror "$name: error executing dg-final-${which}: $errmsg"
 164         unresolved "$name: Error executing dg-final-${which}: $errmsg"
 165     }
 166 }
 167
 168 #
 169 # profopt-get-options -- process test directives
 170 #
 171 # SRC is the full pathname of the testcase.
 172 #
 173 proc profopt-get-options { src } {
 174     # dg-options sets a variable called dg-extra-tool-flags.
 175     set dg-extra-tool-flags ""
 176
 177     # dg-require-* sets dg-do-what.
 178     upvar dg-do-what dg-do-what
 179
 180     set tmp [dg-get-options $src]
 181     foreach op $tmp {
 182         set cmd [lindex $op 0]
 183         if { ![string compare "dg-options" $cmd] \
 184              || ![string compare "dg-skip-if" $cmd] \
 185              || ![string compare "dg-final-generate" $cmd] \
 186              || ![string compare "dg-final-use" $cmd] \
 187              || ![string compare "dg-additional-sources" $cmd] \
 188              || [string match "dg-require-*" $cmd]  } {
 189             set status [catch "$op" errmsg]
 190             if { $status != 0 } {
 191                 perror "src: $errmsg for \"$op\"\n"
 192                 unresolved "$src: $errmsg for \"$op\""
 193                 return
 194             }
 195         } else {
 196             # Ignore unrecognized dg- commands, but warn about them.
 197             warning "compat.exp does not support $cmd"
 198         }
 199     }
 200
 201     # Return flags to use for compiling the primary source file and for
 202     # linking.
 203     return ${dg-extra-tool-flags}
 204 }
 205
 206 #
 207 # c-prof-execute -- compile for profiling and then feedback, then normal
 208 #
 209 # SRC is the full pathname of the testcase.
 210 #
 211 proc profopt-execute { src } {
 212     global srcdir tmpdir
 213     global prof_option_list
 214     global tool profile_option feedback_option prof_ext perf_ext perf_delta
 215     global generate_final_code use_final_code
 216     global verbose
 217
 218     if ![info exists profile_option] {
 219         error "No profile option specified for first compile."
 220     }
 221     if ![info exists feedback_option] {
 222         error "No feedback option specified for second compile."
 223     }
 224
 225     regsub "(?q)$srcdir/" $src "" testcase
 226     # If we couldn't rip $srcdir out of `src' then just do the best we can.
 227     # The point is to reduce the unnecessary noise in the logs.  Don't strip
 228     # out too much because different testcases with the same name can confuse
 229     # `test-tool'.
 230     if [string match "/*" $testcase] {
 231         set testcase "[file tail [file dirname $src]]/[file tail $src]"
 232     }
 233
 234     set executable $tmpdir/[file tail [file rootname $src].x]
 235     set basename [file tail $testcase]
 236     set base [file rootname $basename]
 237
 238     set count 0
 239     foreach option $prof_option_list {
 240         set execname1 "${executable}${count}1"
 241         set execname2 "${executable}${count}2"
 242         set execname3 "${executable}${count}3"
 243         incr count
 244
 245         remote_file build delete $execname1
 246         remote_file build delete $execname2
 247         remote_file build delete $execname3
 248         verbose "Testing $testcase, $option" 1
 249
 250         # Remove old profiling and performance data files.
 251         foreach ext $prof_ext {
 252             remote_file target delete $tmpdir/$base.$ext
 253         }
 254         if [info exists perf_ext] {
 255             profopt-cleanup $testcase $perf_ext
 256         }
 257
 258         # Process test directives.
 259
 260         set generate_final_code ""
 261         set use_final_code ""
 262         set dg-do-what [list "run" "" P]
 263         set extra_flags [profopt-get-options $src]
 264         if { [lindex ${dg-do-what} 1 ] == "N" } {
 265             unsupported "$src"
 266             verbose "$src not supported on this target, skipping it" 3
 267             return
 268         }
 269
 270         set extra_options [dg-additional-files-options "" "$src"]
 271
 272         # Compile for profiling.
 273
 274         set options "$extra_options"
 275         lappend options "additional_flags=$option $extra_flags $profile_option"
 276         set optstr "$option $profile_option"
 277         set comp_output [${tool}_target_compile "$src" "$execname1" executable $options]
 278         if ![${tool}_check_compile "$testcase compilation" $optstr $execname1 $comp_output] {
 279             unresolved "$testcase execution,   $optstr"
 280             unresolved "$testcase compilation, $option $feedback_option"
 281             unresolved "$testcase execution,   $option $feedback_option"
 282             continue
 283         }
 284
 285         # Run the profiled test.
 286
 287         set result [${tool}_load $execname1 "" ""]
 288         set status [lindex $result 0]
 289         set missing_file 0
 290         # Make sure the profile data was generated, and fail if not.
 291         if { $status == "pass" } {
 292             foreach ext $prof_ext {
 293                 remote_upload target $tmpdir/$base.$ext
 294                 set files [glob -nocomplain $base.$ext]
 295                 if { $files == "" } {
 296                     set status "fail"
 297                     set missing_file 1
 298                     fail "$testcase execution: file $base.$ext does not exist, $option $profile_option"
 299                 }
 300             }
 301         }
 302         if { $missing_file == 0 } {
 303             $status "$testcase execution,   $optstr"
 304         }
 305
 306         # If there is dg-final code to execute for the generate step, do it
 307         # even if it failed; it might clean up temporary files.
 308         if ![string match $generate_final_code ""] {
 309             profopt-final-code "generate" $generate_final_code $testcase
 310         }
 311
 312         remote_file build delete $execname1
 313
 314         # Quit for this round if it failed
 315         if { $status != "pass" } {
 316             unresolved "$testcase compilation, $option $feedback_option"
 317             unresolved "$testcase execution,   $option $feedback_option"
 318             continue
 319         }
 320
 321         # Compile with feedback-directed optimizations.
 322
 323         set options "$extra_options"
 324         lappend options "additional_flags=$option $extra_flags $feedback_option"
 325         set optstr "$option $feedback_option"
 326         set comp_output [${tool}_target_compile "$src" "$execname2" "executable" $options]
 327         if ![${tool}_check_compile "$testcase compilation" $optstr $execname2 $comp_output] {
 328             unresolved "$testcase execution,   $optstr"
 329             continue
 330         }
 331
 332         # Run the profile-directed optimized test.
 333
 334         set result [${tool}_load "$execname2" "" ""]
 335         set status [lindex $result 0]
 336         $status "$testcase execution,   $optstr"
 337
 338         # If there is dg-final code to execute for the use step, do it.
 339         if ![string match $use_final_code ""] {
 340             profopt-final-code "use" $use_final_code $testcase
 341         }
 342
 343         # Remove the profiling data files.
 344         foreach ext $prof_ext {
 345             remote_file target delete $tmpdir/$base.$ext
 346         }
 347
 348         if { $status != "pass" } {
 349             continue
 350         }
 351
 352         # If the test is not expected to produce performance data then
 353         # we're done now.
 354         if ![info exists perf_ext] {
 355             remote_file build delete $execname2
 356             continue
 357         }
 358
 359         # Get the performance data from the test built with
 360         # profile-directed optimization.  If the file doesn't exist or if
 361         # the value is zero, skip the performance comparison.
 362         set val2 [profopt-perf-value $testcase $perf_ext $optstr]
 363         if { $val2 <= 0 } {
 364             remote_file build delete $execname2
 365             continue
 366         }
 367
 368         # Compile with normal optimizations.
 369
 370         set options "$extra_options"
 371         lappend options "additional_flags=$option"
 372         set optstr "$option"
 373         set comp_output [${tool}_target_compile "$src" "$execname3" "executable" $options]
 374         if ![${tool}_check_compile "$testcase compilation" $optstr $execname3 $comp_output] {
 375             unresolved "$testcase execution,   $optstr"
 376             unresolved "$testcase perf check,  $optstr"
 377             continue
 378         }
 379
 380         # Run the test with normal optimizations.
 381
 382         set result [${tool}_load "$execname3" "" ""]
 383         set status [lindex $result 0]
 384         $status "$testcase execution,   $optstr"
 385         if { $status != "pass" } {
 386             unresolved "$testcase perf check, $optstr"
 387             continue
 388         }
 389
 390         # Get the performance data from the test built with normal
 391         # optimization.
 392         set val1 [profopt-perf-value $testcase $perf_ext $optstr]
 393         if { $val1 < 0 } {
 394             if { $val1 == -2 } {
 395                 # The data file existed with the profile-directed
 396                 # optimization so this one should, too.
 397                 fail "$testcase perf check: file $base.$perf_ext does not exist, $optstr"
 398             }
 399             continue
 400         }
 401
 402         # Compare results of the two runs and fail if the time with the
 403         # profile-directed optimization is significantly more than the time
 404         # without it.
 405         set status "pass"
 406         if { $val2 > $val1 } {
 407             # Check for a performance degration outside of allowable limits.
 408             if { [expr $val2 - $val1] > [expr [expr $val1 * $perf_delta] / 100] } {
 409                 set status "fail"
 410             }
 411         }
 412         if { $status == "fail" } {
 413             fail "$testcase perf check: orig: $val1  new: $val2, $optstr"
 414         } else {
 415             $status "$testcase perf check,  $optstr"
 416             verbose "$testcase orig: $val1  new: $val2, $optstr" 2
 417             remote_file build delete $execname2
 418             remote_file build delete $execname3
 419         }
 420     }
 421 }