gcc/ada/sem_warn.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains the routines used to deal with issuing warnings
  27 --  about uses of uninitialized variables and unused with's. It also has
  28 --  some unrelated routines related to the generation of warnings.
  29
  30 with Alloc; use Alloc;
  31 with Table;
  32 with Types; use Types;
  33
  34 package Sem_Warn is
  35
  36    ------------------------
  37    -- Warnings Off Table --
  38    ------------------------
  39
  40    type Warnings_Off_Entry is record
  41       N : Node_Id;
  42       --  A pragma Warnings (Off, ent) node
  43
  44       E : Entity_Id;
  45       --  The entity involved
  46    end record;
  47
  48    --  An entry is made in the following table for any valid Pragma Warnings
  49    --  (Off, entity) encountered while Opt.Warn_On_Warnings_Off is True. It
  50    --  is used to generate warnings on any of these pragmas that turn out not
  51    --  to be needed, or that could be replaced by Unmodified/Unreferenced.
  52
  53    package Warnings_Off_Pragmas is new Table.Table (
  54      Table_Component_Type => Warnings_Off_Entry,
  55      Table_Index_Type     => Int,
  56      Table_Low_Bound      => 0,
  57      Table_Initial        => Alloc.Warnings_Off_Pragmas_Initial,
  58      Table_Increment      => Alloc.Warnings_Off_Pragmas_Increment,
  59      Table_Name           => "Name_Warnings_Off_Pragmas");
  60
  61    --------------------
  62    -- Initialization --
  63    --------------------
  64
  65    procedure Initialize;
  66    --  Initialize this package for new compilation
  67
  68    function Set_Warning_Switch (C : Character) return Boolean;
  69    --  This function sets the warning switch or switches corresponding to the
  70    --  given character. It is used to process a -gnatw switch on the command
  71    --  line, or a character in a string literal in pragma Warnings. Returns
  72    --  True for valid warning character C, False for invalid character.
  73
  74    function Set_Dot_Warning_Switch (C : Character) return Boolean;
  75    --  This function sets the warning switch or switches corresponding to the
  76    --  given character preceded by a dot. Used to process a -gnatw. switch on
  77    --  the command line or .C in a string literal in pragma Warnings. Returns
  78    --  True for valid warning character C, False for invalid character.
  79
  80    ------------------------------------------
  81    -- Routines to Handle Unused References --
  82    ------------------------------------------
  83
  84    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty);
  85    --  Called at the end of processing a declarative region. The entity E
  86    --  is the entity for the scope. All entities declared in the region,
  87    --  as indicated by First_Entity and the entity chain, are checked to
  88    --  see if they are variables for which warnings need to be posted for
  89    --  either no assignments, or a use before an assignment or no references
  90    --  at all. The Anod node is present for the case of an accept statement,
  91    --  and references the accept statement. This is used to place the warning
  92    --  messages in the right place.
  93
  94    procedure Check_Unset_Reference (N : Node_Id);
  95    --  N is the node for an expression which occurs in a reference position,
  96    --  e.g. as the right side of an assignment. This procedure checks to see
  97    --  if the node is a reference to a variable entity where the entity has
  98    --  Not_Assigned set. If so, the Unset_Reference field is set if it is not
  99    --  the first occurrence. No warning is posted, instead warnings will be
 100    --  posted later by Check_References. The reason we do things that
 101    --  way is that if there are no assignments anywhere, we prefer to flag
 102    --  the entity, rather than a reference to it. Note that for the purposes
 103    --  of this routine, a type conversion or qualified expression whose
 104    --  expression is an entity is also processed. The reason that we do not
 105    --  process these at the point of occurrence is that both these constructs
 106    --  can occur in non-reference positions (e.g. as out parameters).
 107
 108    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit);
 109    --  This routine performs two kinds of checks. It checks that all with'ed
 110    --  units are referenced, and that at least one entity of each with'ed
 111    --  unit is referenced (the latter check catches units that are only
 112    --  referenced in a use or package renaming statement). Appropriate
 113    --  warning messages are generated if either of these situations is
 114    --  detected.
 115    --
 116    --  A special case arises when a package body or a subprogram body with
 117    --  a separate spec is being compiled. In this case, a with may appear
 118    --  on the spec, but be needed only by the body. This still generates
 119    --  a warning, but the text is different (the with is not redundant,
 120    --  it is misplaced).
 121    --
 122    --  This special case is implemented by making an initial call to this
 123    --  procedure with Spec_Unit set to the unit number of the separate spec.
 124    --  This call does not generate any warning messages, but instead may
 125    --  result in flags being set in the N_With_Clause node that record that
 126    --  there was no use in the spec.
 127    --
 128    --  The main call (made after all units have been analyzed, with Spec_Unit
 129    --  set to the default value of No_Unit) generates the required warnings
 130    --  using the flags set by the initial call where appropriate to specialize
 131    --  the text of the warning messages.
 132
 133    ---------------------
 134    -- Output Routines --
 135    ---------------------
 136
 137    procedure Output_Non_Modifed_In_Out_Warnings;
 138    --  Warnings about IN OUT parameters that could be IN are collected till
 139    --  the end of the compilation process (see body of this routine for a
 140    --  discussion of why this is done). This procedure outputs the warnings.
 141    --  Note: this should be called before Output_Unreferenced_Messages, since
 142    --  if we have an IN OUT warning, that's the one we want to see!
 143
 144    procedure Output_Obsolescent_Entity_Warnings (N : Node_Id; E : Entity_Id);
 145    --  N is a reference to obsolescent entity E, for which appropriate warning
 146    --  messages are to be generated (caller has already checked that warnings
 147    --  are active and appropriate for this entity).
 148
 149    procedure Output_Unreferenced_Messages;
 150    --  Warnings about unreferenced entities are collected till the end of
 151    --  the compilation process (see Check_Unset_Reference for further
 152    --  details). This procedure outputs waiting warnings, if any.
 153
 154    procedure Output_Unused_Warnings_Off_Warnings;
 155    --  Warnings about pragma Warnings (Off, ent) statements that are unused,
 156    --  or could be replaced by Unmodified/Unreferenced pragmas, are collected
 157    --  till the end of the compilation process. This procedure outputs waiting
 158    --  warnings if any.
 159
 160    ----------------------------
 161    -- Other Warning Routines --
 162    ----------------------------
 163
 164    procedure Check_Code_Statement (N : Node_Id);
 165    --  Perform warning checks on a code statement node
 166
 167    procedure Check_Infinite_Loop_Warning (Loop_Statement : Node_Id);
 168    --  N is the node for a loop statement. This procedure checks if a warning
 169    --  should be given for a possible infinite loop, and if so issues it.
 170
 171    procedure Warn_On_Known_Condition (C : Node_Id);
 172    --  C is a node for a boolean expression resulting from a relational
 173    --  or membership operation. If the expression has a compile time known
 174    --  value, then a warning is output if all the following conditions hold:
 175    --
 176    --    1. Original expression comes from source. We don't want to generate
 177    --       warnings for internally generated conditionals.
 178    --
 179    --    2. As noted above, the expression is a relational or membership
 180    --       test, we don't want to generate warnings for boolean variables
 181    --       since this is typical of conditional compilation in Ada.
 182    --
 183    --    3. The expression appears in a statement, rather than a declaration.
 184    --       In practice, most occurrences in declarations are legitimate
 185    --       conditionalizations, but occurrences in statements are often
 186    --       errors for which the warning is useful.
 187    --
 188    --    4. The expression does not occur within an instantiation. A non-
 189    --       static expression in a generic may become constant because of
 190    --       the attributes of the actuals, and we do not want to warn on
 191    --       these legitimate constant foldings.
 192    --
 193    --  If all these conditions are met, the warning is issued noting that
 194    --  the result of the test is always false or always true as appropriate.
 195
 196    function Warn_On_Modified_As_Out_Parameter (E : Entity_Id) return Boolean;
 197    --  Returns True if we should activate warnings for entity E being modified
 198    --  as an out parameter. True if either Warn_On_Modified_Unread is set for
 199    --  an only OUT parameter, or if Warn_On_All_Unread_Out_Parameters is set.
 200
 201    procedure Warn_On_Suspicious_Index (Name : Entity_Id; X : Node_Id);
 202    --  This is called after resolving an indexed component or a slice. Name
 203    --  is the entity for the name of the indexed array, and X is the subscript
 204    --  for the indexed component case, or one of the bounds in the slice case.
 205    --  If Name is an unconstrained parameter of a standard string type, and
 206    --  the index is of the form of a literal or Name'Length [- literal], then
 207    --  a warning is generated that the subscripting operation is possibly
 208    --  incorrectly assuming a lower bound of 1.
 209
 210    procedure Warn_On_Unassigned_Out_Parameter
 211      (Return_Node : Node_Id;
 212       Scope_Id    : Entity_Id);
 213    --  Called when processing a return statement given by Return_Node. Scope_Id
 214    --  is the Entity_Id for the procedure in which the return statement lives.
 215    --  A check is made for the case of a procedure with out parameters that
 216    --  have not yet been assigned, and appropriate warnings are given.
 217
 218    procedure Warn_On_Useless_Assignment
 219      (Ent : Entity_Id;
 220       N   : Node_Id := Empty);
 221    --  Called to check if we have a case of a useless assignment to the given
 222    --  entity Ent, as indicated by a non-empty Last_Assignment field. This call
 223    --  should only be made if at least one of the flags Warn_On_Modified_Unread
 224    --  or Warn_On_All_Unread_Out_Parameters is True, and if Ent is in the
 225    --  extended main source unit. N is Empty for the end of block call
 226    --  (warning message says value unreferenced), or the it is the node for
 227    --  an overwriting assignment (warning message points to this assignment).
 228
 229    procedure Warn_On_Useless_Assignments (E : Entity_Id);
 230    pragma Inline (Warn_On_Useless_Assignments);
 231    --  Called at the end of a block or subprogram. Scans the entities of the
 232    --  block or subprogram to see if there are any variables for which useless
 233    --  assignments were made (assignments whose values were never read).
 234
 235 end Sem_Warn;