gcc/ada/s-osinte-aix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1997-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is a AIX (Native) version of this package
  35
  36 pragma Polling (Off);
  37 --  Turn off polling, we do not want ATC polling to take place during tasking
  38 --  operations. It causes infinite loops and other problems.
  39
  40 package body System.OS_Interface is
  41
  42    use Interfaces.C;
  43
  44    -----------------
  45    -- To_Duration --
  46    -----------------
  47
  48    function To_Duration (TS : timespec) return Duration is
  49    begin
  50       return Duration (TS.tv_sec) + Duration (TS.tv_nsec) / 10#1#E9;
  51    end To_Duration;
  52
  53    function To_Duration (TV : struct_timeval) return Duration is
  54    begin
  55       return Duration (TV.tv_sec) + Duration (TV.tv_usec) / 10#1#E6;
  56    end To_Duration;
  57
  58    ------------------------
  59    -- To_Target_Priority --
  60    ------------------------
  61
  62    function To_Target_Priority
  63      (Prio : System.Any_Priority) return Interfaces.C.int
  64    is
  65       Dispatching_Policy : Character;
  66       pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
  67
  68       Time_Slice_Val : Integer;
  69       pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
  70
  71    begin
  72       --  For the case SCHED_OTHER the only valid priority across all supported
  73       --  versions of AIX is 1 (note that the scheduling policy can be set
  74       --  with the pragma Task_Dispatching_Policy or setting the time slice
  75       --  value). Otherwise, for SCHED_RR and SCHED_FIFO, the system defines
  76       --  priorities in the range 1 .. 127. This means that we must map
  77       --  System.Any_Priority in the range 0 .. 126 to 1 .. 127.
  78
  79       if Dispatching_Policy = ' ' and then Time_Slice_Val < 0 then
  80          return 1;
  81       else
  82          return Interfaces.C.int (Prio) + 1;
  83       end if;
  84    end To_Target_Priority;
  85
  86    -----------------
  87    -- To_Timespec --
  88    -----------------
  89
  90    function To_Timespec (D : Duration) return timespec is
  91       S : time_t;
  92       F : Duration;
  93
  94    begin
  95       S := time_t (Long_Long_Integer (D));
  96       F := D - Duration (S);
  97
  98       --  If F is negative due to a round-up, adjust for positive F value
  99
 100       if F < 0.0 then
 101          S := S - 1;
 102          F := F + 1.0;
 103       end if;
 104
 105       return timespec'(tv_sec => S,
 106                        tv_nsec => long (Long_Long_Integer (F * 10#1#E9)));
 107    end To_Timespec;
 108
 109    ----------------
 110    -- To_Timeval --
 111    ----------------
 112
 113    function To_Timeval (D : Duration) return struct_timeval is
 114       S : long;
 115       F : Duration;
 116
 117    begin
 118       S := long (Long_Long_Integer (D));
 119       F := D - Duration (S);
 120
 121       --  If F is negative due to a round-up, adjust for positive F value
 122
 123       if F < 0.0 then
 124          S := S - 1;
 125          F := F + 1.0;
 126       end if;
 127
 128       return
 129         struct_timeval'
 130           (tv_sec => S,
 131            tv_usec => long (Long_Long_Integer (F * 10#1#E6)));
 132    end To_Timeval;
 133
 134    -------------------
 135    -- clock_gettime --
 136    -------------------
 137
 138    function clock_gettime
 139      (clock_id : clockid_t;
 140       tp       : access timespec)
 141       return     int
 142    is
 143       pragma Warnings (Off, clock_id);
 144
 145       Result : int;
 146       tv     : aliased struct_timeval;
 147
 148       function gettimeofday
 149         (tv   : access struct_timeval;
 150          tz   : System.Address := System.Null_Address)
 151          return int;
 152       pragma Import (C, gettimeofday, "gettimeofday");
 153
 154    begin
 155       Result := gettimeofday (tv'Unchecked_Access);
 156       tp.all := To_Timespec (To_Duration (tv));
 157       return Result;
 158    end clock_gettime;
 159
 160    -----------------
 161    -- sched_yield --
 162    -----------------
 163
 164    --  AIX Thread does not have sched_yield;
 165
 166    function sched_yield return int is
 167       procedure pthread_yield;
 168       pragma Import (C, pthread_yield, "sched_yield");
 169    begin
 170       pthread_yield;
 171       return 0;
 172    end sched_yield;
 173
 174    --------------------
 175    -- Get_Stack_Base --
 176    --------------------
 177
 178    function Get_Stack_Base (thread : pthread_t) return Address is
 179       pragma Warnings (Off, thread);
 180    begin
 181       return Null_Address;
 182    end Get_Stack_Base;
 183
 184    --------------------------
 185    -- PTHREAD_PRIO_INHERIT --
 186    --------------------------
 187
 188    AIX_Version : Integer := 0;
 189    --  AIX version in the form xy for AIX version x.y (0 means not set)
 190
 191    SYS_NMLN : constant := 32;
 192    --  AIX system constant used to define utsname, see sys/utsname.h
 193
 194    subtype String_NMLN is String (1 .. SYS_NMLN);
 195
 196    type utsname is record
 197       sysname    : String_NMLN;
 198       nodename   : String_NMLN;
 199       release    : String_NMLN;
 200       version    : String_NMLN;
 201       machine    : String_NMLN;
 202       procserial : String_NMLN;
 203    end record;
 204    pragma Convention (C, utsname);
 205
 206    procedure uname (name : out utsname);
 207    pragma Import (C, uname);
 208
 209    function PTHREAD_PRIO_INHERIT return int is
 210       name : utsname;
 211
 212       function Val (C : Character) return Integer;
 213       --  Transform a numeric character ('0' .. '9') to an integer
 214
 215       ---------
 216       -- Val --
 217       ---------
 218
 219       function Val (C : Character) return Integer is
 220       begin
 221          return Character'Pos (C) - Character'Pos ('0');
 222       end Val;
 223
 224    --  Start of processing for PTHREAD_PRIO_INHERIT
 225
 226    begin
 227       if AIX_Version = 0 then
 228
 229          --  Set AIX_Version
 230
 231          uname (name);
 232          AIX_Version := Val (name.version (1)) * 10 + Val (name.release (1));
 233       end if;
 234
 235       if AIX_Version < 53 then
 236
 237          --  Under AIX < 5.3, PTHREAD_PRIO_INHERIT is defined as 0 in pthread.h
 238
 239          return 0;
 240
 241       else
 242          --  Under AIX >= 5.3, PTHREAD_PRIO_INHERIT is defined as 3
 243
 244          return 3;
 245       end if;
 246    end PTHREAD_PRIO_INHERIT;
 247
 248 end System.OS_Interface;