gcc/ada/s-carsi8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --         S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 8        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Ada.Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Signed_8 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Big_Words is array (Natural) of Word;
  44    type Big_Words_Ptr is access Big_Words;
  45    for Big_Words_Ptr'Storage_Size use 0;
  46    --  Array type used to access by words
  47
  48    type Byte is range -128 .. +127;
  49    for Byte'Size use 8;
  50    --  Used to process operands by bytes
  51
  52    type Big_Bytes is array (Natural) of Byte;
  53    type Big_Bytes_Ptr is access Big_Bytes;
  54    for Big_Bytes_Ptr'Storage_Size use 0;
  55    --  Array type used to access by bytes
  56
  57    function To_Big_Words is new
  58      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  59
  60    function To_Big_Bytes is new
  61      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  62
  63    ----------------------
  64    -- Compare_Array_S8 --
  65    ----------------------
  66
  67    function Compare_Array_S8
  68      (Left      : System.Address;
  69       Right     : System.Address;
  70       Left_Len  : Natural;
  71       Right_Len : Natural) return Integer
  72    is
  73       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  74
  75    begin
  76       --  If operands are non-aligned, or length is too short, go by bytes
  77
  78       if ModA (OrA (Left, Right), 4) /= 0 or else Compare_Len < 4 then
  79          return Compare_Array_S8_Unaligned (Left, Right, Left_Len, Right_Len);
  80       end if;
  81
  82       --  Here we can go by words
  83
  84       declare
  85          LeftP                   : constant Big_Words_Ptr :=
  86                                      To_Big_Words (Left);
  87          RightP                  : constant Big_Words_Ptr :=
  88                                      To_Big_Words (Right);
  89          Words_To_Compare        : constant Natural := Compare_Len / 4;
  90          Bytes_Compared_As_Words : constant Natural := Words_To_Compare * 4;
  91
  92       begin
  93          for J in 0 .. Words_To_Compare - 1 loop
  94             if LeftP (J) /= RightP (J) then
  95                return Compare_Array_S8_Unaligned
  96                         (AddA (Left,  Address (4 * J)),
  97                          AddA (Right, Address (4 * J)),
  98                          4, 4);
  99             end if;
 100          end loop;
 101
 102          return Compare_Array_S8_Unaligned
 103                   (AddA (Left,  Address (Bytes_Compared_As_Words)),
 104                    AddA (Right, Address (Bytes_Compared_As_Words)),
 105                    Left_Len  - Bytes_Compared_As_Words,
 106                    Right_Len - Bytes_Compared_As_Words);
 107       end;
 108    end Compare_Array_S8;
 109
 110    --------------------------------
 111    -- Compare_Array_S8_Unaligned --
 112    --------------------------------
 113
 114    function Compare_Array_S8_Unaligned
 115      (Left      : System.Address;
 116       Right     : System.Address;
 117       Left_Len  : Natural;
 118       Right_Len : Natural) return Integer
 119    is
 120       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 121
 122       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 123       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 124
 125    begin
 126       for J in 0 .. Compare_Len - 1 loop
 127          if LeftP (J) /= RightP (J) then
 128             if LeftP (J) > RightP (J) then
 129                return +1;
 130             else
 131                return -1;
 132             end if;
 133          end if;
 134       end loop;
 135
 136       if Left_Len = Right_Len then
 137          return 0;
 138       elsif Left_Len > Right_Len then
 139          return +1;
 140       else
 141          return -1;
 142       end if;
 143    end Compare_Array_S8_Unaligned;
 144
 145 end System.Compare_Array_Signed_8;