gcc/ada/mlib.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                 M L I B                                  --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1999-2005, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Ada.Characters.Handling; use Ada.Characters.Handling;
  28 with Interfaces.C.Strings;
  29
  30 with Hostparm;
  31 with Opt;
  32 with Output; use Output;
  33 with Namet;  use Namet;
  34
  35 with MLib.Utl; use MLib.Utl;
  36
  37 with Prj.Com;
  38
  39 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  40
  41 package body MLib is
  42
  43    -------------------
  44    -- Build_Library --
  45    -------------------
  46
  47    procedure Build_Library
  48      (Ofiles      : Argument_List;
  49       Afiles      : Argument_List;
  50       Output_File : String;
  51       Output_Dir  : String)
  52    is
  53       pragma Warnings (Off, Afiles);
  54
  55    begin
  56       if not Opt.Quiet_Output then
  57          Write_Line ("building a library...");
  58          Write_Str  ("   make ");
  59          Write_Line (Output_File);
  60       end if;
  61
  62       Ar (Output_Dir & "/lib" & Output_File & ".a", Objects => Ofiles);
  63    end Build_Library;
  64
  65    ------------------------
  66    -- Check_Library_Name --
  67    ------------------------
  68
  69    procedure Check_Library_Name (Name : String) is
  70    begin
  71       if Name'Length = 0 then
  72          Prj.Com.Fail ("library name cannot be empty");
  73       end if;
  74
  75       if Name'Length > Max_Characters_In_Library_Name then
  76          Prj.Com.Fail ("illegal library name """, Name, """: too long");
  77       end if;
  78
  79       if not Is_Letter (Name (Name'First)) then
  80          Prj.Com.Fail ("illegal library name """,
  81                        Name,
  82                        """: should start with a letter");
  83       end if;
  84
  85       for Index in Name'Range loop
  86          if not Is_Alphanumeric (Name (Index)) then
  87             Prj.Com.Fail ("illegal library name """,
  88                           Name,
  89                           """: should include only letters and digits");
  90          end if;
  91       end loop;
  92    end Check_Library_Name;
  93
  94    --------------------
  95    -- Copy_ALI_Files --
  96    --------------------
  97
  98    procedure Copy_ALI_Files
  99      (Files      : Argument_List;
 100       To         : Name_Id;
 101       Interfaces : String_List)
 102    is
 103       Success      : Boolean := False;
 104       To_Dir       : constant String := Get_Name_String (To);
 105       Is_Interface : Boolean := False;
 106
 107       procedure Verbose_Copy (Index : Positive);
 108       --  In verbose mode, output a message that the indexed file is copied
 109       --  to the destination directory.
 110
 111       ------------------
 112       -- Verbose_Copy --
 113       ------------------
 114
 115       procedure Verbose_Copy (Index : Positive) is
 116       begin
 117          if Opt.Verbose_Mode then
 118             Write_Str ("Copying """);
 119             Write_Str (Files (Index).all);
 120             Write_Str (""" to """);
 121             Write_Str (To_Dir);
 122             Write_Line ("""");
 123          end if;
 124       end Verbose_Copy;
 125
 126    begin
 127       if Interfaces'Length = 0 then
 128
 129          --  If there are no Interfaces, copy all the ALI files as is
 130
 131          for Index in Files'Range loop
 132             Verbose_Copy (Index);
 133             Copy_File
 134               (Files (Index).all,
 135                To_Dir,
 136                Success,
 137                Mode => Overwrite,
 138                Preserve => Preserve);
 139
 140             exit when not Success;
 141          end loop;
 142
 143       else
 144          --  Copy only the interface ALI file, and put the special indicator
 145          --  "SL" on the P line.
 146
 147          for Index in Files'Range loop
 148
 149             declare
 150                File_Name : String := Base_Name (Files (Index).all);
 151             begin
 152                Canonical_Case_File_Name (File_Name);
 153
 154                --  Check if this is one of the interface ALIs
 155
 156                Is_Interface := False;
 157
 158                for Index in Interfaces'Range loop
 159                   if File_Name = Interfaces (Index).all then
 160                      Is_Interface := True;
 161                      exit;
 162                   end if;
 163                end loop;
 164
 165                --  If it is an interface ALI, copy line by line. Insert
 166                --  the interface indication at the end of the P line.
 167                --  Do not copy ALI files that are not Interfaces.
 168
 169                if Is_Interface then
 170                   Success := False;
 171                   Verbose_Copy (Index);
 172
 173                   declare
 174                      FD         : File_Descriptor;
 175                      Len        : Integer;
 176                      Actual_Len : Integer;
 177                      S          : String_Access;
 178                      Curr       : Natural;
 179                      P_Line_Found : Boolean;
 180                      Status     : Boolean;
 181
 182                   begin
 183                      --  Open the file
 184
 185                      Name_Len := Files (Index)'Length;
 186                      Name_Buffer (1 .. Name_Len) := Files (Index).all;
 187                      Name_Len := Name_Len + 1;
 188                      Name_Buffer (Name_Len) := ASCII.NUL;
 189
 190                      FD := Open_Read (Name_Buffer'Address, Binary);
 191
 192                      if FD /= Invalid_FD then
 193                         Len := Integer (File_Length (FD));
 194
 195                         S := new String (1 .. Len + 3);
 196
 197                         --  Read the file. Note that the loop is not necessary
 198                         --  since the whole file is read at once except on VMS.
 199
 200                         Curr := 1;
 201                         Actual_Len := Len;
 202
 203                         while Actual_Len /= 0 loop
 204                            Actual_Len := Read (FD, S (Curr)'Address, Len);
 205                            Curr := Curr + Actual_Len;
 206                         end loop;
 207
 208                         --  We are done with the input file, so we close it
 209
 210                         Close (FD, Status);
 211                         --  We simply ignore any bad status
 212
 213                         P_Line_Found := False;
 214
 215                         --  Look for the P line. When found, add marker SL
 216                         --  at the beginning of the P line.
 217
 218                         for Index in 1 .. Len - 3 loop
 219                            if (S (Index) = ASCII.LF or else
 220                                  S (Index) = ASCII.CR)
 221                              and then
 222                                S (Index + 1) = 'P'
 223                            then
 224                               S (Index + 5 .. Len + 3) := S (Index + 2 .. Len);
 225                               S (Index + 2 .. Index + 4) := " SL";
 226                               P_Line_Found := True;
 227                               exit;
 228                            end if;
 229                         end loop;
 230
 231                         if P_Line_Found then
 232
 233                            --  Create new modified ALI file
 234
 235                            Name_Len := To_Dir'Length;
 236                            Name_Buffer (1 .. Name_Len) := To_Dir;
 237                            Name_Len := Name_Len + 1;
 238                            Name_Buffer (Name_Len) := Directory_Separator;
 239                            Name_Buffer
 240                              (Name_Len + 1 .. Name_Len + File_Name'Length) :=
 241                                 File_Name;
 242                            Name_Len := Name_Len + File_Name'Length + 1;
 243                            Name_Buffer (Name_Len) := ASCII.NUL;
 244
 245                            FD := Create_File (Name_Buffer'Address, Binary);
 246
 247                            --  Write the modified text and close the newly
 248                            --  created file.
 249
 250                            if FD /= Invalid_FD then
 251                               Actual_Len := Write (FD, S (1)'Address, Len + 3);
 252
 253                               Close (FD, Status);
 254
 255                               --  Set Success to True only if the newly
 256                               --  created file has been correctly written.
 257
 258                               Success := Status and Actual_Len = Len + 3;
 259
 260                               if Success then
 261                                  Set_Read_Only (
 262                                    Name_Buffer (1 .. Name_Len - 1));
 263                               end if;
 264                            end if;
 265                         end if;
 266                      end if;
 267                   end;
 268
 269                else
 270                   --  This is not an interface ALI
 271
 272                   Success := True;
 273
 274                end if;
 275             end;
 276
 277             if not Success then
 278                Prj.Com.Fail ("could not copy ALI files to library dir");
 279             end if;
 280          end loop;
 281       end if;
 282    end Copy_ALI_Files;
 283
 284    --------------------------------
 285    -- Linker_Library_Path_Option --
 286    --------------------------------
 287
 288    function Linker_Library_Path_Option return String_Access is
 289
 290       Run_Path_Option_Ptr : Interfaces.C.Strings.chars_ptr;
 291       pragma Import (C, Run_Path_Option_Ptr, "__gnat_run_path_option");
 292       --  Pointer to string representing the native linker option which
 293       --  specifies the path where the dynamic loader should find shared
 294       --  libraries. Equal to null string if this system doesn't support it.
 295
 296       S : constant String := Interfaces.C.Strings.Value (Run_Path_Option_Ptr);
 297
 298    begin
 299       if S'Length = 0 then
 300          return null;
 301       else
 302          return new String'(S);
 303       end if;
 304    end Linker_Library_Path_Option;
 305
 306 --  Package elaboration
 307
 308 begin
 309    --  Copy_Attributes always fails on VMS
 310
 311    if Hostparm.OpenVMS then
 312       Preserve := None;
 313    end if;
 314 end MLib;