gcc/ada/a-ciormu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --         I N D E F I N I T E _ O R D E R E D _ M U L T I S E T S          --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2006, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Element_Type (<>) is private;
  43
  44    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  45    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  46
  47 package Ada.Containers.Indefinite_Ordered_Multisets is
  48    pragma Preelaborate;
  49
  50    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  51
  52    type Set is tagged private;
  53    pragma Preelaborable_Initialization (Set);
  54
  55    type Cursor is private;
  56    pragma Preelaborable_Initialization (Cursor);
  57
  58    Empty_Set : constant Set;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Set) return Boolean;
  63
  64    function Equivalent_Sets (Left, Right : Set) return Boolean;
  65
  66    function To_Set (New_Item : Element_Type) return Set;
  67
  68    function Length (Container : Set) return Count_Type;
  69
  70    function Is_Empty (Container : Set) return Boolean;
  71
  72    procedure Clear (Container : in out Set);
  73
  74    function Element (Position : Cursor) return Element_Type;
  75
  76    procedure Replace_Element
  77      (Container : in out Set;
  78       Position  : Cursor;
  79       New_Item  : Element_Type);
  80
  81    procedure Query_Element
  82      (Position : Cursor;
  83       Process  : not null access procedure (Element : Element_Type));
  84
  85    procedure Move (Target : in out Set; Source : in out Set);
  86
  87    procedure Insert
  88      (Container : in out Set;
  89       New_Item  : Element_Type;
  90       Position  : out Cursor);
  91
  92    procedure Insert (Container : in out Set; New_Item : Element_Type);
  93
  94 --  TODO: include Replace too???
  95 --
  96 --     procedure Replace
  97 --       (Container : in out Set;
  98 --        New_Item  : Element_Type);
  99
 100    procedure Exclude (Container : in out Set; Item : Element_Type);
 101
 102    procedure Delete (Container : in out Set; Item : Element_Type);
 103
 104    procedure Delete (Container : in out Set; Position : in out Cursor);
 105
 106    procedure Delete_First (Container : in out Set);
 107
 108    procedure Delete_Last (Container : in out Set);
 109
 110    procedure Union (Target : in out Set; Source : Set);
 111
 112    function Union (Left, Right : Set) return Set;
 113
 114    function "or" (Left, Right : Set) return Set renames Union;
 115
 116    procedure Intersection (Target : in out Set; Source : Set);
 117
 118    function Intersection (Left, Right : Set) return Set;
 119
 120    function "and" (Left, Right : Set) return Set renames Intersection;
 121
 122    procedure Difference (Target : in out Set; Source : Set);
 123
 124    function Difference (Left, Right : Set) return Set;
 125
 126    function "-" (Left, Right : Set) return Set renames Difference;
 127
 128    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 129
 130    function Symmetric_Difference (Left, Right : Set) return Set;
 131
 132    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 133
 134    function Overlap (Left, Right : Set) return Boolean;
 135
 136    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 137
 138    function First (Container : Set) return Cursor;
 139
 140    function First_Element (Container : Set) return Element_Type;
 141
 142    function Last (Container : Set) return Cursor;
 143
 144    function Last_Element (Container : Set) return Element_Type;
 145
 146    function Next (Position : Cursor) return Cursor;
 147
 148    procedure Next (Position : in out Cursor);
 149
 150    function Previous (Position : Cursor) return Cursor;
 151
 152    procedure Previous (Position : in out Cursor);
 153
 154    function Find (Container : Set; Item : Element_Type) return Cursor;
 155
 156    function Floor (Container : Set; Item : Element_Type) return Cursor;
 157
 158    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 159
 160    function Contains (Container : Set; Item : Element_Type) return Boolean;
 161
 162    function Has_Element (Position : Cursor) return Boolean;
 163
 164    function "<" (Left, Right : Cursor) return Boolean;
 165
 166    function ">" (Left, Right : Cursor) return Boolean;
 167
 168    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 169
 170    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 171
 172    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 173
 174    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 175
 176    procedure Iterate
 177      (Container : Set;
 178       Process   : not null access procedure (Position : Cursor));
 179
 180    procedure Reverse_Iterate
 181      (Container : Set;
 182       Process   : not null access procedure (Position : Cursor));
 183
 184    procedure Iterate
 185      (Container : Set;
 186       Item      : Element_Type;
 187       Process   : not null access procedure (Position : Cursor));
 188
 189    procedure Reverse_Iterate
 190      (Container : Set;
 191       Item      : Element_Type;
 192       Process   : not null access procedure (Position : Cursor));
 193
 194    generic
 195       type Key_Type (<>) is private;
 196
 197       with function Key (Element : Element_Type) return Key_Type;
 198
 199       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 200
 201    package Generic_Keys is
 202
 203       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 204
 205       function Key (Position : Cursor) return Key_Type;
 206
 207       function Element (Container : Set; Key : Key_Type) return Element_Type;
 208
 209       procedure Exclude (Container : in out Set; Key : Key_Type);
 210
 211       procedure Delete (Container : in out Set; Key : Key_Type);
 212
 213       function Find (Container : Set; Key : Key_Type) return Cursor;
 214
 215       function Floor (Container : Set; Key : Key_Type) return Cursor;
 216
 217       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 218
 219       function Contains (Container : Set; Key : Key_Type) return Boolean;
 220
 221       procedure Update_Element
 222         (Container : in out Set;
 223          Position  : Cursor;
 224          Process   : not null access
 225                        procedure (Element : in out Element_Type));
 226
 227       procedure Iterate
 228         (Container : Set;
 229          Key       : Key_Type;
 230          Process   : not null access procedure (Position : Cursor));
 231
 232       procedure Reverse_Iterate
 233         (Container : Set;
 234          Key       : Key_Type;
 235          Process   : not null access procedure (Position : Cursor));
 236
 237    end Generic_Keys;
 238
 239 private
 240
 241    type Node_Type;
 242    type Node_Access is access Node_Type;
 243
 244    type Element_Access is access Element_Type;
 245
 246    type Node_Type is limited record
 247       Parent  : Node_Access;
 248       Left    : Node_Access;
 249       Right   : Node_Access;
 250       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 251       Element : Element_Access;
 252    end record;
 253
 254    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 255      (Node_Type,
 256       Node_Access);
 257
 258    type Set is new Ada.Finalization.Controlled with record
 259       Tree : Tree_Types.Tree_Type;
 260    end record;
 261
 262    procedure Adjust (Container : in out Set);
 263
 264    procedure Finalize (Container : in out Set) renames Clear;
 265
 266    use Red_Black_Trees;
 267    use Tree_Types;
 268    use Ada.Finalization;
 269    use Ada.Streams;
 270
 271    type Set_Access is access all Set;
 272    for Set_Access'Storage_Size use 0;
 273
 274    type Cursor is record
 275       Container : Set_Access;
 276       Node      : Node_Access;
 277    end record;
 278
 279    procedure Write
 280      (Stream : access Root_Stream_Type'Class;
 281       Item   : Cursor);
 282
 283    for Cursor'Write use Write;
 284
 285    procedure Read
 286      (Stream : access Root_Stream_Type'Class;
 287       Item   : out Cursor);
 288
 289    for Cursor'Read use Read;
 290
 291    No_Element : constant Cursor := Cursor'(null, null);
 292
 293    procedure Write (Stream : access Root_Stream_Type'Class; Container : Set);
 294
 295    for Set'Write use Write;
 296
 297    procedure Read
 298      (Stream    : access Root_Stream_Type'Class;
 299       Container : out Set);
 300
 301    for Set'Read use Read;
 302
 303    Empty_Set : constant Set :=
 304                  (Controlled with Tree => (First  => null,
 305                                            Last   => null,
 306                                            Root   => null,
 307                                            Length => 0,
 308                                            Busy   => 0,
 309                                            Lock   => 0));
 310
 311 end Ada.Containers.Indefinite_Ordered_Multisets;