configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_AUX_DIR(config)
  10 AC_CONFIG_SRCDIR(src/main.c)
  11 AC_CONFIG_HEADERS(config.h)
  12 mc_VERSION
  13 AM_INIT_AUTOMAKE(mc, ${VERSION} )
  14 dnl Enable silent rules by default (if yes)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23
  24 dnl ############################################################################
  25 dnl Check for compiler
  26 dnl ############################################################################
  27
  28 AC_PROG_CC_STDC
  29 AM_PROG_CC_C_O
  30
  31 mc_CHECK_CFLAGS
  32
  33 CFLAGS_OPTS=""
  34 if test "x$CFLAGS" = "x"; then
  35     CFLAGS_OPTS=" -O2 "
  36 fi
  37 if test x$USE_MAINTAINER_MODE = xyes; then
  38     CFLAGS_OPTS="-g3 -O -ggdb"
  39     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  40 fi
  41
  42 AC_ARG_ENABLE([werror],
  43     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  44 if test "x$enable_werror" = xyes; then
  45     mc_CHECK_ONE_CFLAG([-Werror])
  46 fi
  47
  48 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  49
  50 AC_PROG_LIBTOOL
  51
  52
  53 dnl ############################################################################
  54 dnl Check for programs
  55 dnl ############################################################################
  56
  57 PKG_PROG_PKG_CONFIG
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
  61 AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
  62 AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
  63
  64 dnl Check nroff and the options it supports
  65 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  66 dnl Default values
  67 MANDOC=-man
  68 MAN_FLAGS=
  69 if $HAVE_nroff; then
  70     AC_MSG_CHECKING([for manual formatting macros])
  71     AC_CACHE_VAL(mc_cv_mandoc, [
  72     nroff -mandoc < /dev/null > /dev/null 2>&1
  73     if test $? = 0; then
  74         mc_cv_mandoc=-mandoc
  75     else
  76         mc_cv_mandoc=-man
  77     fi
  78     ])
  79     MANDOC=$mc_cv_mandoc
  80     AC_MSG_RESULT([$MANDOC])
  81
  82     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
  83     AC_CACHE_VAL(mc_cv_man_nocolor, [
  84     nroff -c < /dev/null > /dev/null 2>&1
  85     if test $? = 0; then
  86         mc_cv_man_nocolor=-c
  87     else
  88         mc_cv_man_nocolor=
  89     fi
  90     ])
  91     MAN_FLAGS=$mc_cv_man_nocolor
  92     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
  93
  94     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
  95     AC_CACHE_VAL(mc_cv_nroff_tascii, [
  96     mc_cv_nroff_tascii=
  97     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
  98     if test $? = 0; then
  99         mc_cv_nroff_tascii=-Tlatin1
 100     else
 101         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 102         if test $? = 0; then
 103             mc_cv_nroff_tascii=-Tascii
 104         fi
 105     fi
 106     ])
 107     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 108     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 109 fi
 110
 111 AC_SUBST(MANDOC)
 112 AC_SUBST(MAN_FLAGS)
 113
 114 dnl Check for -L option to file
 115 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 116 if $HAVE_FILECMD; then
 117     AC_MSG_CHECKING([for -L option to file command])
 118     AC_CACHE_VAL(mc_cv_filel, [
 119     file -L . > /dev/null 2>&1
 120     if test $? = 0; then
 121         mc_cv_filel=yes
 122     else
 123         mc_cv_filel=no
 124     fi
 125     ])
 126     if test x$mc_cv_filel = xyes; then
 127         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 128     fi
 129     filel=$mc_cv_filel
 130     AC_MSG_RESULT([$filel])
 131 fi
 132
 133 dnl Only list browsers here that can be run in background (i.e. with `&')
 134 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 135
 136
 137 dnl ############################################################################
 138 dnl Check for other tools
 139 dnl ############################################################################
 140
 141 AC_CHECK_TOOL(AR, ar, ar)
 142 mc_UNIT_TESTS
 143
 144
 145 dnl ############################################################################
 146 dnl Check for main libraies
 147 dnl ############################################################################
 148
 149 mc_CHECK_GLIB
 150 mc_G_MODULE_SUPPORTED
 151 mc_WITH_SCREEN
 152 mc_CHECK_SEARCH_TYPE
 153 dnl X11 support. Used to read keyboard modifiers when running under X11.
 154 mc_WITH_X
 155
 156
 157 dnl ############################################################################
 158 dnl Check for header files
 159 dnl ############################################################################
 160
 161 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 162         utime.h sys/statfs.h sys/vfs.h \
 163         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 164         sys/socket.h])
 165 dnl This macro is redefined in m4.include/sys_types_h.m4
 166 dnl   to work around a buggy version in autoconf <= 2.69.
 167 AC_HEADER_MAJOR
 168
 169
 170 dnl ############################################################################
 171 dnl Check for types
 172 dnl ############################################################################
 173
 174 dnl Check largefile before type sizeof checks
 175 AC_SYS_LARGEFILE
 176
 177 AC_CHECK_SIZEOF(long)
 178 AC_TYPE_UINTMAX_T
 179 AC_CHECK_SIZEOF(uintmax_t)
 180 AC_TYPE_OFF_T
 181 AC_CHECK_SIZEOF(off_t)
 182 AC_TYPE_MODE_T
 183 gl_PROMOTED_TYPE_MODE_T
 184 AC_TYPE_PID_T
 185 AC_TYPE_UID_T
 186
 187 AC_STRUCT_ST_BLOCKS
 188 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim])
 189 gl_STAT_SIZE
 190
 191 AH_TEMPLATE([sig_atomic_t],
 192             [/* Define to `int' if <signal.h> doesn't define.])
 193 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 194             [Some systems declare sig_atomic_t as volatile, some others -- no.
 195              This define will have value `sig_atomic_t' or
 196              `volatile sig_atomic_t' accordingly.])
 197
 198 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 199 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 200   [
 201     ac_cv_type_sig_atomic_t=yes;
 202     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 203                     signal.h,
 204                     [
 205                         is_sig_atomic_t_volatile=yes;
 206                         AC_MSG_RESULT([yes, volatile])
 207                     ],
 208                     [
 209                         is_sig_atomic_t_volatile=no;
 210                         AC_MSG_RESULT([yes, non volatile])
 211                     ])
 212   ],
 213   [
 214     AC_MSG_RESULT(no)
 215     AC_CHECK_TYPE(sig_atomic_t, int)
 216     is_sig_atomic_t_volatile=no
 217   ])
 218 if test $is_sig_atomic_t_volatile = 'yes'
 219 then
 220     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 221 else
 222     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 223 fi
 224
 225
 226 dnl ############################################################################
 227 dnl Check for functions
 228 dnl ############################################################################
 229
 230 AC_CHECK_FUNCS([\
 231         strverscmp \
 232         strncasecmp \
 233         realpath
 234 ])
 235
 236 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 237 AC_CHECK_FUNCS([utimensat])
 238
 239 dnl getpt is a GNU Extension (glibc 2.1.x)
 240 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 241 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 242
 243 dnl replacing lstat with statlstat on sco makes it more portable between
 244 dnl sco clones
 245 AC_CHECK_FUNCS(statlstat)
 246
 247 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
 248 dnl We use only part of the functionality of mmap, so on AIX,
 249 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 250 AC_ARG_WITH([mmap],
 251         AS_HELP_STRING([--with-mmap], [Use the mmap call @<:@yes if found@:>@]))
 252 if test x$with_mmap != xno; then
 253     if test x$with_mmap = x; then
 254         AC_FUNC_MMAP
 255     else
 256         AC_DEFINE(HAVE_MMAP, 1)
 257     fi
 258 fi
 259
 260 dnl Sequent wants getprocessstats
 261 AC_CHECK_LIB(seq, get_process_stats, [
 262         LIBS="$LIBS -lseq"
 263         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 264                   [Define if you have function `get_process_stats' and
 265 have to use that instead of gettimeofday])])
 266
 267 mc_AC_GET_FS_INFO
 268
 269
 270 dnl ############################################################################
 271 dnl Internationalization
 272 dnl ############################################################################
 273
 274 AM_GNU_GETTEXT([no-libtool], [need-ngettext])
 275 AM_GNU_GETTEXT_VERSION([0.18.1])
 276
 277 mc_I18N
 278
 279 dnl ############################################################################
 280 dnl OS specific flags
 281 dnl ############################################################################
 282
 283 case $host_os in
 284 aux*)
 285     # A/UX
 286     LIBS="$LIBS -lposix"
 287     AC_DEFINE(_POSIX_SOURCE)
 288     ;;
 289 esac
 290
 291 dnl If running under AIX, AC_AIX does not tell us that
 292 AC_MSG_CHECKING([for AIX defines])
 293 AC_EGREP_CPP([yes],
 294     [
 295         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 296         yes
 297         #endif
 298     ],
 299     [
 300         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 301         AC_MSG_RESULT(yes)
 302     ],
 303     [
 304         AC_MSG_RESULT(no)
 305     ])
 306
 307 dnl Check if the OS is supported by the console saver.
 308 cons_saver=""
 309 case $host_os in
 310 linux*)
 311     cons_saver=yes
 312 esac
 313
 314 dnl Check for gpm mouse support (Linux only)
 315 mouse_lib="xterm only"
 316 AC_ARG_WITH([gpm-mouse],
 317     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 318
 319 case $host_os in
 320 linux*)
 321     if test x$with_gpm_mouse != xno; then
 322         AC_CHECK_LIB(gpm, Gpm_Repeat,
 323             [AC_DEFINE(HAVE_LIBGPM, 1,
 324                        [Define to enable gpm mouse support on Linux])
 325             mouse_lib="gpm and xterm"
 326             MCLIBS="$MCLIBS -lgpm"],
 327             if test "x$with_gpm_mouse" = "xyes"; then
 328                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 329             else
 330                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 331             fi
 332         )
 333     fi
 334     ;;
 335 esac
 336
 337
 338 dnl ############################################################################
 339 dnl libmc
 340 dnl ############################################################################
 341
 342 LIBMC_VERSION="0.0.1"
 343 LIBMC_RELEASE="1"
 344 AC_SUBST(LIBMC_VERSION)
 345 AC_SUBST(LIBMC_RELEASE)
 346
 347 AC_ARG_ENABLE([mclib],
 348         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 349         [
 350             if test "x$enableval" = "xno" ; then
 351                 enable_mclib=no
 352             else
 353                 if test "x$enable_shared" = "xno" ; then
 354                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 355                     enable_mclib=no
 356                 else
 357                     enable_mclib=yes
 358                 fi
 359             fi
 360         ],
 361         [enable_mclib=no])
 362
 363 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 364
 365
 366 dnl ############################################################################
 367 dnl Where config files should be placed
 368 dnl ############################################################################
 369
 370 AC_ARG_WITH([homedir],
 371     AS_HELP_STRING([--with-homedir],
 372                    [Choose any place of user settings relative to home dir, or XDG for respect XDG standards @<:@XDG@:>@]),
 373     [
 374         dnl Unfortunately, there is no way to tell AC_ARG_WITH that the
 375         dnl argument value is required, so we can't differentiate
 376         dnl between `--with-homedir` and `--with-homedir=yes`, because
 377         dnl `with_homedir` is set to `yes` in both cases.
 378         dnl
 379         dnl We opt to set `with_homedir` to `.mc` if the value is `yes`
 380         dnl in order to avoid the surprise for users using
 381         dnl `--with-homedir` w/o any value and then getting mc to store
 382         dnl settings in the `yes` directory.
 383
 384         if test "x$withval" = "xXDG"; then
 385             with_homedir=XDG
 386         elif test "x$withval" = "xyes"; then
 387             with_homedir=.mc
 388         else
 389             with_homedir=$withval
 390         fi
 391     ],
 392     [with_homedir=XDG])
 393
 394
 395 if test x$with_homedir = xXDG; then
 396     AC_DEFINE(MC_HOMEDIR_XDG, 1, [Define to enable XDG standard support])
 397 else
 398     AC_DEFINE(MC_HOMEDIR_XDG, 0, [Define to disable XDG standard support])
 399     AC_DEFINE_UNQUOTED([MC_USERCONF_DIR], ["$with_homedir"], [Where configs will be placed relative to $HOME])
 400 fi
 401
 402
 403 dnl ############################################################################
 404 dnl MC options
 405 dnl ############################################################################
 406
 407 mc_ASSERT
 408
 409 mc_WITH_INTERNAL_EDIT
 410
 411 dnl Diff viewer support.
 412 AC_ARG_WITH([diff_viewer],
 413     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 414
 415 if test x$with_diff_viewer != xno; then
 416         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 417         use_diff=yes
 418         diff_msg="yes"
 419         AC_MSG_NOTICE([using diff viewer])
 420 else
 421         diff_msg="no"
 422 fi
 423
 424 mc_SUBSHELL
 425 mc_BACKGROUND
 426 mc_VFS_CHECKS
 427
 428 dnl ############################################################################
 429 dnl Directories
 430 dnl ############################################################################
 431
 432 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 433 dnl Let define ${prefix} and ${exec_prefix}
 434 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 435 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 436
 437 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 438     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 439 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 440     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 441 else
 442     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 443 fi
 444 AC_SUBST(EXTHELPERSDIR)
 445
 446
 447 dnl ############################################################################
 448 dnl Documentation
 449 dnl ############################################################################
 450
 451 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 452 AC_SUBST(MAN_DATE)
 453
 454 dnl Determine which help translations we want to install.
 455 ALL_DOC_LINGUAS="es hu it pl ru sr"
 456
 457 DOC_LINGUAS=
 458 if test "x$USE_NLS" = xyes; then
 459     if test -z "$LINGUAS"; then
 460         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 461     else
 462         langs="$LINGUAS"
 463     fi
 464 else
 465     langs=
 466 fi
 467
 468 for h_lang in $ALL_DOC_LINGUAS; do
 469     for lang in $langs; do
 470         if test "$lang" = "$h_lang"; then
 471             DOC_LINGUAS="$DOC_LINGUAS $lang"
 472             break
 473         fi
 474     done
 475 done
 476 AC_SUBST(DOC_LINGUAS)
 477
 478 DX_HTML_FEATURE(ON)
 479 DX_CHM_FEATURE(OFF)
 480 DX_CHI_FEATURE(OFF)
 481 DX_MAN_FEATURE(OFF)
 482 DX_RTF_FEATURE(OFF)
 483 DX_XML_FEATURE(OFF)
 484 DX_PDF_FEATURE(OFF)
 485 DX_PS_FEATURE(OFF)
 486 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 487
 488
 489 dnl ############################################################################
 490 dnl Configure results
 491 dnl ############################################################################
 492
 493 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 494
 495 AC_SUBST(MCLIBS)
 496 AC_SUBST(CFLAGS)
 497 AC_SUBST(CPPFLAGS)
 498 AC_SUBST(LDFLAGS)
 499 AC_SUBST(LIBS)
 500
 501 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 502 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 503 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 504 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 505 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 506 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 507 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 508 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 509 dnl Clarify do we really need GModule
 510 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 511                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 512
 513 AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 514
 515 AC_CONFIG_FILES(
 516 [
 517 src/man2hlp/man2hlp
 518 ],
 519 [
 520 chmod +x src/man2hlp/man2hlp
 521 ])
 522
 523 AC_CONFIG_FILES([
 524 Makefile
 525
 526 contrib/Makefile
 527 contrib/dist/Makefile
 528 contrib/dist/gentoo/Makefile
 529 contrib/dist/redhat/Makefile
 530 contrib/dist/redhat/mc.spec
 531 contrib/dist/pkginfo
 532 contrib/dist/prototype
 533
 534 misc/Makefile
 535 misc/mc.menu
 536 misc/mcedit.menu
 537 misc/skins/Makefile
 538 misc/ext.d/Makefile
 539 misc/ext.d/doc.sh
 540 misc/ext.d/misc.sh
 541 misc/ext.d/text.sh
 542 misc/ext.d/web.sh
 543 misc/macros.d/Makefile
 544 misc/mc.ext
 545
 546 src/Makefile
 547 src/consaver/Makefile
 548 src/editor/Makefile
 549 src/man2hlp/Makefile
 550 src/subshell/Makefile
 551 src/viewer/Makefile
 552 src/diffviewer/Makefile
 553 src/filemanager/Makefile
 554
 555 src/vfs/Makefile
 556
 557 src/vfs/cpio/Makefile
 558
 559 src/vfs/extfs/Makefile
 560 src/vfs/extfs/helpers/Makefile
 561 src/vfs/extfs/helpers/a+
 562 src/vfs/extfs/helpers/apt+
 563 src/vfs/extfs/helpers/audio
 564 src/vfs/extfs/helpers/deb
 565 src/vfs/extfs/helpers/deba
 566 src/vfs/extfs/helpers/debd
 567 src/vfs/extfs/helpers/dpkg+
 568 src/vfs/extfs/helpers/iso9660
 569 src/vfs/extfs/helpers/hp48+
 570 src/vfs/extfs/helpers/lslR
 571 src/vfs/extfs/helpers/mailfs
 572 src/vfs/extfs/helpers/patchfs
 573 src/vfs/extfs/helpers/rpms+
 574 src/vfs/extfs/helpers/s3+
 575 src/vfs/extfs/helpers/uace
 576 src/vfs/extfs/helpers/ualz
 577 src/vfs/extfs/helpers/uar
 578 src/vfs/extfs/helpers/uarc
 579 src/vfs/extfs/helpers/uarj
 580 src/vfs/extfs/helpers/uc1541
 581 src/vfs/extfs/helpers/ucab
 582 src/vfs/extfs/helpers/uha
 583 src/vfs/extfs/helpers/ulha
 584 src/vfs/extfs/helpers/ulib
 585 src/vfs/extfs/helpers/urar
 586 src/vfs/extfs/helpers/uzip
 587 src/vfs/extfs/helpers/uzoo
 588
 589 src/vfs/fish/Makefile
 590 src/vfs/fish/helpers/Makefile
 591
 592 src/vfs/ftpfs/Makefile
 593
 594 src/vfs/sftpfs/Makefile
 595
 596 src/vfs/local/Makefile
 597
 598 src/vfs/sfs/Makefile
 599
 600 src/vfs/smbfs/Makefile
 601
 602 src/vfs/tar/Makefile
 603
 604 src/vfs/undelfs/Makefile
 605
 606 lib/Makefile
 607 lib/event/Makefile
 608 lib/filehighlight/Makefile
 609 lib/mcconfig/Makefile
 610 lib/search/Makefile
 611 lib/skin/Makefile
 612 lib/strutil/Makefile
 613 lib/tty/Makefile
 614
 615 lib/vfs/Makefile
 616
 617 lib/widget/Makefile
 618
 619 misc/syntax/Makefile
 620 misc/syntax/Syntax
 621
 622 doc/Makefile
 623
 624 doc/hints/Makefile
 625 doc/hints/l10n/Makefile
 626
 627 doc/man/Makefile
 628 doc/man/es/Makefile
 629 doc/man/hu/Makefile
 630 doc/man/it/Makefile
 631 doc/man/pl/Makefile
 632 doc/man/ru/Makefile
 633 doc/man/sr/Makefile
 634
 635 doc/hlp/Makefile
 636 doc/hlp/es/Makefile
 637 doc/hlp/hu/Makefile
 638 doc/hlp/it/Makefile
 639 doc/hlp/pl/Makefile
 640 doc/hlp/ru/Makefile
 641 doc/hlp/sr/Makefile
 642
 643 intl/Makefile
 644 po/Makefile.in
 645 ])
 646
 647 AC_CONFIG_FILES([
 648 tests/Makefile
 649 tests/lib/Makefile
 650 tests/lib/mcconfig/Makefile
 651 tests/lib/search/Makefile
 652 tests/lib/strutil/Makefile
 653 tests/lib/vfs/Makefile
 654 tests/lib/widget/Makefile
 655 tests/src/Makefile
 656 tests/src/filemanager/Makefile
 657 tests/src/editor/Makefile
 658 tests/src/editor/test-data.txt
 659 tests/src/vfs/Makefile
 660 tests/src/vfs/extfs/Makefile
 661 tests/src/vfs/extfs/helpers-list/Makefile
 662 tests/src/vfs/extfs/helpers-list/data/config.sh
 663 tests/src/vfs/extfs/helpers-list/misc/Makefile
 664 ])
 665
 666 AC_OUTPUT
 667
 668 AC_MSG_NOTICE([
 669
 670 Configuration:
 671
 672   Source code location:       ${srcdir}
 673   Compiler:                   ${CC}
 674   Compiler flags:             ${CFLAGS}
 675   Assertions:                 ${enable_assert}
 676   Unit tests:                 ${tests_msg}
 677   File system:                ${vfs_type}
 678                               ${vfs_flags}
 679   Screen library:             ${screen_msg}
 680   Mouse support:              ${mouse_lib}
 681   X11 events support:         ${textmode_x11_support}
 682   With subshell support:      ${subshell}
 683   With background operations: ${enable_background}
 684   Internal editor:            ${edit_msg}
 685   Diff viewer:                ${diff_msg}
 686   Support for charset:        ${charset_msg}
 687   Search type:                ${SEARCH_TYPE}
 688 ])
 689
 690 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 691 dnl we enable it back for top-level ./configure
 692 if test -n "$ac_unrecognized_opts"; then
 693   case $enable_option_checking in
 694     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 695     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 696   esac
 697 fi