configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ(2.64)
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 dnl This should be checked before toolchain macros, otherwise they will remember
  40 dnl that ar cannot be found and linking via libtool will fail at a later stage
  41 AC_CHECK_TOOLS([AR], [ar gar])
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_C_O
  45
  46 mc_CHECK_CFLAGS
  47
  48 CFLAGS_OPTS=""
  49 if test "x$CFLAGS" = "x"; then
  50     CFLAGS_OPTS=" -O2 "
  51 fi
  52 if test x$USE_MAINTAINER_MODE = xyes; then
  53     CFLAGS_OPTS="-g3 -O -ggdb"
  54     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  55 fi
  56
  57 AC_ARG_ENABLE([werror],
  58     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  59 if test "x$enable_werror" = xyes; then
  60     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  61 fi
  62
  63 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  64 dnl which causes attribute checks to fail
  65 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  66 _AC_LANG_PREFIX[]FLAGS=
  67 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  68 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  69 unset ax_gcc_func_attribute_save_flags
  70
  71 LT_INIT
  72
  73
  74 dnl ############################################################################
  75 dnl Check for programs
  76 dnl ############################################################################
  77
  78 AC_PROG_SED
  79 PKG_PROG_PKG_CONFIG
  80 AC_PROG_INSTALL
  81 AC_PROG_LN_S
  82 dnl See also the "OS specific stuff" section below.
  83
  84 dnl Check nroff and the options it supports
  85 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  86 dnl Default values
  87 MANDOC=-man
  88 MAN_FLAGS=
  89 if $HAVE_nroff; then
  90     AC_MSG_CHECKING([for manual formatting macros])
  91     AC_CACHE_VAL(mc_cv_mandoc, [
  92     nroff -mandoc < /dev/null > /dev/null 2>&1
  93     if test $? = 0; then
  94         mc_cv_mandoc=-mandoc
  95     else
  96         mc_cv_mandoc=-man
  97     fi
  98     ])
  99     MANDOC=$mc_cv_mandoc
 100     AC_MSG_RESULT([$MANDOC])
 101
 102     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 103     AC_CACHE_VAL(mc_cv_man_nocolor, [
 104     nroff -c < /dev/null > /dev/null 2>&1
 105     if test $? = 0; then
 106         mc_cv_man_nocolor=-c
 107     else
 108         mc_cv_man_nocolor=
 109     fi
 110     ])
 111     MAN_FLAGS=$mc_cv_man_nocolor
 112     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 113
 114     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 115     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 116     mc_cv_nroff_tascii=
 117     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 118     if test $? = 0; then
 119         mc_cv_nroff_tascii=-Tlatin1
 120     else
 121         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 122         if test $? = 0; then
 123             mc_cv_nroff_tascii=-Tascii
 124         fi
 125     fi
 126     ])
 127     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 128     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 129 fi
 130
 131 AC_SUBST(MANDOC)
 132 AC_SUBST(MAN_FLAGS)
 133
 134 dnl Check for -z, -b, -L, and -S options to file
 135 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 136 if $HAVE_FILECMD; then
 137     dnl Don't use the file command if it doesn't accept the -z option
 138     AC_MSG_CHECKING([for -z option to file command])
 139     AC_CACHE_VAL(mc_cv_file_z, [
 140         file -z . > /dev/null 2>&1
 141         if test $? = 0; then
 142             mc_cv_file_z=yes
 143         else
 144             mc_cv_file_z=no
 145         fi
 146     ])
 147     AC_MSG_RESULT([$mc_cv_file_z])
 148
 149     if test x$mc_cv_file_z = xyes; then
 150         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 151     else
 152         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 153     fi
 154
 155     if test x$mc_cv_file_z = xyes; then
 156         dnl file is used; check -b, -L and -S options
 157
 158         AC_MSG_CHECKING([for -b option to file command])
 159         AC_CACHE_VAL(mc_cv_file_b, [
 160             file -b . > /dev/null 2>&1
 161             if test $? = 0; then
 162                 mc_cv_file_b=yes
 163             else
 164                 mc_cv_file_b=no
 165             fi
 166         ])
 167         AC_MSG_RESULT([$mc_cv_file_b])
 168
 169         if test x$mc_cv_file_b = xyes; then
 170             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 171         fi
 172
 173         AC_MSG_CHECKING([for -L option to file command])
 174         AC_CACHE_VAL(mc_cv_file_L, [
 175             file -L . > /dev/null 2>&1
 176             if test $? = 0; then
 177                 mc_cv_file_L=yes
 178             else
 179                 mc_cv_file_L=no
 180             fi
 181         ])
 182         AC_MSG_RESULT([$mc_cv_file_L])
 183
 184         if test x$mc_cv_file_L = xyes; then
 185             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 186         else
 187             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 188         fi
 189
 190         dnl The file command accepts the -S option since 5.33
 191         AC_MSG_CHECKING([for -S option to file command])
 192         AC_CACHE_VAL(mc_cv_file_S, [
 193             file -S . > /dev/null 2>&1
 194             if test $? = 0; then
 195                 mc_cv_file_S=yes
 196             else
 197                 mc_cv_file_S=no
 198             fi
 199         ])
 200         AC_MSG_RESULT([$mc_cv_file_S])
 201
 202         if test x$mc_cv_file_S = xyes; then
 203             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 204         else
 205             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 206         fi
 207     fi
 208 fi
 209
 210 dnl Only list browsers here that can be run in background (i.e. with `&')
 211 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 212
 213
 214 dnl ############################################################################
 215 dnl Check for other tools
 216 dnl ############################################################################
 217
 218 AC_CHECK_TOOLS([INDENT], [gindent indent])
 219 mc_UNIT_TESTS
 220
 221
 222 dnl ############################################################################
 223 dnl Check for main libraries
 224 dnl ############################################################################
 225
 226 mc_CHECK_GLIB
 227 mc_G_MODULE_SUPPORTED
 228 mc_WITH_SCREEN
 229 mc_CHECK_SEARCH_TYPE
 230 dnl X11 support. Used to read keyboard modifiers when running under X11.
 231 mc_WITH_X
 232
 233
 234 dnl ############################################################################
 235 dnl Check for header files
 236 dnl ############################################################################
 237
 238 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 239         utime.h sys/statfs.h sys/vfs.h \
 240         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 241         sys/socket.h])
 242 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 243 dnl   to work around a buggy version in autoconf <= 2.69.
 244 AC_HEADER_MAJOR
 245
 246
 247 dnl ############################################################################
 248 dnl Check for types
 249 dnl ############################################################################
 250
 251 dnl Check largefile before type sizeof checks
 252 AC_SYS_LARGEFILE
 253
 254 AC_CHECK_SIZEOF(long)
 255 AC_TYPE_UINTMAX_T
 256 AC_CHECK_SIZEOF(uintmax_t)
 257 AC_TYPE_OFF_T
 258 AC_CHECK_SIZEOF(off_t)
 259 AC_TYPE_MODE_T
 260 gl_PROMOTED_TYPE_MODE_T
 261 AC_TYPE_PID_T
 262 AC_TYPE_UID_T
 263 AC_CHECK_TYPE([major_t], [], [AC_DEFINE([major_t], [int], [Type of major device numbers.])])
 264 AC_CHECK_TYPE([minor_t], [], [AC_DEFINE([minor_t], [int], [Type of minor device numbers.])])
 265
 266 AC_STRUCT_ST_BLOCKS
 267 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim, struct stat.st_mtimespec, struct stat.st_mtimensec])
 268 gl_STAT_SIZE
 269
 270 AH_TEMPLATE([sig_atomic_t],
 271             [/* Define to `int' if <signal.h> doesn't define.])
 272 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 273             [Some systems declare sig_atomic_t as volatile, some others -- no.
 274              This define will have value `sig_atomic_t' or
 275              `volatile sig_atomic_t' accordingly.])
 276
 277 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 278 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 279   [
 280     ac_cv_type_sig_atomic_t=yes;
 281     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 282                     signal.h,
 283                     [
 284                         is_sig_atomic_t_volatile=yes;
 285                         AC_MSG_RESULT([yes, volatile])
 286                     ],
 287                     [
 288                         is_sig_atomic_t_volatile=no;
 289                         AC_MSG_RESULT([yes, non volatile])
 290                     ])
 291   ],
 292   [
 293     AC_MSG_RESULT(no)
 294     AC_CHECK_TYPE(sig_atomic_t, int)
 295     is_sig_atomic_t_volatile=no
 296   ])
 297 if test $is_sig_atomic_t_volatile = 'yes'
 298 then
 299     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 300 else
 301     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 302 fi
 303
 304
 305 dnl ############################################################################
 306 dnl Check for functions
 307 dnl ############################################################################
 308
 309 AC_CHECK_FUNCS([\
 310         strverscmp \
 311         strncasecmp \
 312         realpath
 313 ])
 314
 315 dnl getpt is a GNU Extension (glibc 2.1.x)
 316 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 317 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 318
 319 dnl replacing lstat with statlstat on sco makes it more portable between
 320 dnl sco clones
 321 AC_CHECK_FUNCS(statlstat)
 322
 323 mc_GET_FS_INFO
 324
 325
 326 dnl ############################################################################
 327 dnl Internationalization
 328 dnl ############################################################################
 329
 330 AC_CHECK_FUNCS([setlocale])
 331
 332 AM_GNU_GETTEXT([external], [need-ngettext])
 333 AM_GNU_GETTEXT_VERSION([0.18.2])
 334
 335 mc_I18N
 336
 337 dnl ############################################################################
 338 dnl OS specific stuff
 339 dnl ############################################################################
 340
 341 case $host_os in
 342 *os400)
 343     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 344     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/QOpenSys/pkgs/bin/perl])
 345     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 346     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 347     ;;
 348 *)
 349     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 350     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/usr/bin/perl])
 351     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 352     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 353 esac
 354
 355 case $host_os in
 356 aux*)
 357     # A/UX
 358     LIBS="$LIBS -lposix"
 359     AC_DEFINE(_POSIX_SOURCE)
 360     ;;
 361 esac
 362
 363 dnl If running under AIX, AC_AIX does not tell us that
 364 AC_MSG_CHECKING([for AIX defines])
 365 AC_EGREP_CPP([yes],
 366     [
 367         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 368         yes
 369         #endif
 370     ],
 371     [
 372         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 373         AC_MSG_RESULT(yes)
 374     ],
 375     [
 376         AC_MSG_RESULT(no)
 377     ])
 378
 379 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 380 AC_CHECK_FUNCS([utimensat])
 381
 382 case $host_os in
 383 *os400)
 384     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 385 esac
 386
 387 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 388 case $host_os in
 389 linux*)
 390     AC_CHECK_HEADERS([linux/fs.h])
 391 esac
 392
 393 dnl Check if the OS is supported by the console saver.
 394 cons_saver=""
 395 case $host_os in
 396 linux*)
 397     cons_saver=yes
 398 esac
 399
 400 dnl Check for gpm mouse support (Linux only)
 401 mouse_lib="xterm only"
 402 AC_ARG_WITH([gpm-mouse],
 403     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 404
 405 case $host_os in
 406 linux*)
 407     if test x$with_gpm_mouse != xno; then
 408         AC_CHECK_LIB(gpm, Gpm_Repeat,
 409             [AC_DEFINE(HAVE_LIBGPM, 1,
 410                        [Define to enable gpm mouse support on Linux])
 411             mouse_lib="gpm and xterm"
 412             MCLIBS="$MCLIBS -lgpm"],
 413             if test "x$with_gpm_mouse" = "xyes"; then
 414                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 415             else
 416                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 417             fi
 418         )
 419     fi
 420     ;;
 421 esac
 422
 423
 424 dnl ############################################################################
 425 dnl libmc
 426 dnl ############################################################################
 427
 428 LIBMC_VERSION="0.0.1"
 429 LIBMC_RELEASE="1"
 430 AC_SUBST(LIBMC_VERSION)
 431 AC_SUBST(LIBMC_RELEASE)
 432
 433 AC_ARG_ENABLE([mclib],
 434         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 435         [
 436             if test "x$enableval" = "xno" ; then
 437                 enable_mclib=no
 438             else
 439                 if test "x$enable_shared" = "xno" ; then
 440                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 441                     enable_mclib=no
 442                 else
 443                     enable_mclib=yes
 444                 fi
 445             fi
 446         ],
 447         [enable_mclib=no])
 448
 449 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 450
 451
 452 dnl ############################################################################
 453 dnl MC options
 454 dnl ############################################################################
 455
 456 mc_ASSERT
 457
 458 mc_WITH_INTERNAL_EDIT
 459
 460 dnl Diff viewer support.
 461 AC_ARG_WITH([diff_viewer],
 462     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 463
 464 if test x$with_diff_viewer != xno; then
 465         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 466         use_diff=yes
 467         diff_msg="yes"
 468         AC_MSG_NOTICE([using diff viewer])
 469 else
 470         diff_msg="no"
 471 fi
 472
 473 mc_SUBSHELL
 474 mc_BACKGROUND
 475 mc_EXT2FS_ATTR
 476 mc_VFS_CHECKS
 477
 478 dnl ############################################################################
 479 dnl Directories
 480 dnl ############################################################################
 481
 482 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 483 dnl Let define ${prefix} and ${exec_prefix}
 484 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 485 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 486
 487 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 488     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 489 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 490     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 491 else
 492     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 493 fi
 494 AC_SUBST(EXTHELPERSDIR)
 495
 496
 497 dnl ############################################################################
 498 dnl Documentation
 499 dnl ############################################################################
 500
 501 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 502 AC_SUBST(MAN_DATE)
 503
 504 dnl Determine which help translations we want to install.
 505 ALL_DOC_LINGUAS="es hu it pl ru sr"
 506
 507 DOC_LINGUAS=
 508 if test "x$USE_NLS" = xyes; then
 509     if test -z "$LINGUAS"; then
 510         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 511     else
 512         langs="$LINGUAS"
 513     fi
 514 else
 515     langs=
 516 fi
 517
 518 for h_lang in $ALL_DOC_LINGUAS; do
 519     for lang in $langs; do
 520         if test "$lang" = "$h_lang"; then
 521             DOC_LINGUAS="$DOC_LINGUAS $lang"
 522             break
 523         fi
 524     done
 525 done
 526 AC_SUBST(DOC_LINGUAS)
 527
 528 DX_HTML_FEATURE(ON)
 529 DX_CHM_FEATURE(OFF)
 530 DX_CHI_FEATURE(OFF)
 531 DX_MAN_FEATURE(OFF)
 532 DX_RTF_FEATURE(OFF)
 533 DX_XML_FEATURE(OFF)
 534 DX_PDF_FEATURE(OFF)
 535 DX_PS_FEATURE(OFF)
 536 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 537
 538
 539 dnl ############################################################################
 540 dnl Configure results
 541 dnl ############################################################################
 542
 543 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 544
 545 AC_SUBST(MCLIBS)
 546 AC_SUBST(CFLAGS)
 547 AC_SUBST(CPPFLAGS)
 548 AC_SUBST(LDFLAGS)
 549 AC_SUBST(LIBS)
 550
 551 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 552 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 553 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 554 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 555 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 556 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 557 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 558 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 559 dnl Clarify do we really need GModule
 560 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 561                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 562
 563 AC_ARG_ENABLE([configure-args],
 564     AS_HELP_STRING([--enable-configure-args], [Embed ./configure arguments into binaries]))
 565 if test "x$enable_configure_args" != xno; then
 566     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 567     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 568 fi
 569
 570
 571 AC_CONFIG_FILES(
 572 [
 573 src/man2hlp/man2hlp
 574 ],
 575 [
 576 chmod +x src/man2hlp/man2hlp
 577 ])
 578
 579 AC_CONFIG_FILES([
 580 Makefile
 581
 582 contrib/Makefile
 583
 584 misc/Makefile
 585 misc/mc.charsets
 586 misc/mc.menu
 587 misc/mcedit.menu
 588 misc/skins/Makefile
 589 misc/ext.d/Makefile
 590 misc/ext.d/doc.sh
 591 misc/ext.d/misc.sh
 592 misc/ext.d/text.sh
 593 misc/ext.d/web.sh
 594 misc/macros.d/Makefile
 595 misc/mc.ext.ini
 596
 597 src/Makefile
 598 src/consaver/Makefile
 599 src/editor/Makefile
 600 src/man2hlp/Makefile
 601 src/subshell/Makefile
 602 src/viewer/Makefile
 603 src/diffviewer/Makefile
 604 src/filemanager/Makefile
 605
 606 src/vfs/Makefile
 607
 608 src/vfs/cpio/Makefile
 609
 610 src/vfs/extfs/Makefile
 611 src/vfs/extfs/helpers/Makefile
 612 src/vfs/extfs/helpers/a+
 613 src/vfs/extfs/helpers/apt+
 614 src/vfs/extfs/helpers/audio
 615 src/vfs/extfs/helpers/deb
 616 src/vfs/extfs/helpers/deba
 617 src/vfs/extfs/helpers/debd
 618 src/vfs/extfs/helpers/dpkg+
 619 src/vfs/extfs/helpers/iso9660
 620 src/vfs/extfs/helpers/hp48+
 621 src/vfs/extfs/helpers/lslR
 622 src/vfs/extfs/helpers/mailfs
 623 src/vfs/extfs/helpers/patchfs
 624 src/vfs/extfs/helpers/rpms+
 625 src/vfs/extfs/helpers/s3+
 626 src/vfs/extfs/helpers/uace
 627 src/vfs/extfs/helpers/ualz
 628 src/vfs/extfs/helpers/uar
 629 src/vfs/extfs/helpers/uarc
 630 src/vfs/extfs/helpers/uarj
 631 src/vfs/extfs/helpers/ucab
 632 src/vfs/extfs/helpers/uha
 633 src/vfs/extfs/helpers/ulha
 634 src/vfs/extfs/helpers/ulib
 635 src/vfs/extfs/helpers/unar
 636 src/vfs/extfs/helpers/urar
 637 src/vfs/extfs/helpers/uwim
 638 src/vfs/extfs/helpers/uzip
 639 src/vfs/extfs/helpers/uzoo
 640
 641 src/vfs/shell/Makefile
 642 src/vfs/shell/helpers/Makefile
 643
 644 src/vfs/ftpfs/Makefile
 645
 646 src/vfs/sftpfs/Makefile
 647
 648 src/vfs/local/Makefile
 649
 650 src/vfs/sfs/Makefile
 651
 652 src/vfs/tar/Makefile
 653
 654 src/vfs/undelfs/Makefile
 655
 656 lib/Makefile
 657 lib/event/Makefile
 658 lib/filehighlight/Makefile
 659 lib/mcconfig/Makefile
 660 lib/search/Makefile
 661 lib/skin/Makefile
 662 lib/strutil/Makefile
 663 lib/tty/Makefile
 664
 665 lib/vfs/Makefile
 666
 667 lib/widget/Makefile
 668
 669 misc/syntax/Makefile
 670
 671 doc/Makefile
 672
 673 doc/hints/Makefile
 674 doc/hints/l10n/Makefile
 675
 676 doc/man/Makefile
 677 doc/man/es/Makefile
 678 doc/man/hu/Makefile
 679 doc/man/it/Makefile
 680 doc/man/pl/Makefile
 681 doc/man/ru/Makefile
 682 doc/man/sr/Makefile
 683
 684 doc/hlp/Makefile
 685 doc/hlp/es/Makefile
 686 doc/hlp/hu/Makefile
 687 doc/hlp/it/Makefile
 688 doc/hlp/pl/Makefile
 689 doc/hlp/ru/Makefile
 690 doc/hlp/sr/Makefile
 691
 692 po/Makefile.in
 693 ])
 694
 695 dnl https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable/30932102#30932102
 696 AC_CONFIG_FILES(
 697 [misc/syntax/Syntax], [${SED-sed} -e "s%\${prefix}%$PREFIX%" misc/syntax/Syntax > misc/syntax/Syntax.tmp && \
 698   mv -f misc/syntax/Syntax.tmp misc/syntax/Syntax], [export PREFIX=$prefix]
 699 )
 700
 701 AC_CONFIG_FILES([
 702 tests/Makefile
 703 tests/lib/Makefile
 704 tests/lib/mcconfig/Makefile
 705 tests/lib/search/Makefile
 706 tests/lib/strutil/Makefile
 707 tests/lib/vfs/Makefile
 708 tests/lib/widget/Makefile
 709 tests/src/Makefile
 710 tests/src/filemanager/Makefile
 711 tests/src/editor/Makefile
 712 tests/src/editor/test-data.txt
 713 tests/src/vfs/Makefile
 714 tests/src/vfs/extfs/Makefile
 715 tests/src/vfs/extfs/helpers-list/Makefile
 716 tests/src/vfs/extfs/helpers-list/data/config.sh
 717 tests/src/vfs/extfs/helpers-list/misc/Makefile
 718 tests/src/vfs/ftpfs/Makefile
 719 ])
 720
 721 AC_OUTPUT
 722
 723 AC_MSG_NOTICE([
 724
 725 Configuration:
 726
 727   Source code location:           ${srcdir}
 728   Compiler:                       ${CC}
 729   Compiler flags:                 ${CFLAGS}
 730   Assertions:                     ${enable_assert}
 731   Unit tests:                     ${tests_msg}
 732   File system:                    ${vfs_type}
 733                                   ${vfs_flags}
 734   Screen library:                 ${screen_msg}
 735   Mouse support:                  ${mouse_lib}
 736   X11 events support:             ${textmode_x11_support}
 737   With subshell support:          ${subshell}
 738   With background operations:     ${enable_background}
 739   With ext2fs attributes support: ${ext2fs_attr_msg}
 740   Internal editor:                ${edit_msg}
 741   Diff viewer:                    ${diff_msg}
 742   Support for charset:            ${charset_msg}
 743   Search type:                    ${SEARCH_TYPE}
 744 ])
 745
 746 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 747 dnl we enable it back for top-level ./configure
 748 if test -n "$ac_unrecognized_opts"; then
 749   case $enable_option_checking in
 750     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 751     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 752   esac
 753 fi