sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-1997,2000-2002,2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <jmpbuf-offsets.h>
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27
  28 #define PARMS   LINKAGE         /* no space for saved regs */
  29 #define JMPBUF  PARMS
  30 #define SIGMSK  JMPBUF+PTR_SIZE
  31
  32 ENTRY (BP_SYM (_setjmp))
  33         ENTER
  34
  35         xorl %eax, %eax
  36         movl JMPBUF(%esp), %edx
  37         CHECK_BOUNDS_BOTH_WIDE (%edx, JMPBUF(%esp), $(JB_SIZE+4))
  38
  39         /* Save registers.  */
  40         movl %ebx, (JB_BX*4)(%edx)
  41         movl %esi, (JB_SI*4)(%edx)
  42         movl %edi, (JB_DI*4)(%edx)
  43         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  44 #ifdef PTR_MANGLE
  45         PTR_MANGLE (%ecx)
  46 #endif
  47         movl %ecx, (JB_SP*4)(%edx)
  48         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  49 #ifdef PTR_MANGLE
  50         PTR_MANGLE (%ecx)
  51 #endif
  52         movl %ecx, (JB_PC*4)(%edx)
  53         LEAVE
  54         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  55
  56         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  57         ret
  58 END (BP_SYM (_setjmp))
  59 libc_hidden_def (_setjmp)