sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-2024 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <pointer_guard.h>
  25 #include <jmpbuf-offsets.h>
  26 #include <stap-probe.h>
  27
  28 #define PARMS   4               /* no space for saved regs */
  29 #define JMPBUF  PARMS
  30 #define SIGMSK  JMPBUF+4
  31
  32 ENTRY (_setjmp)
  33
  34         xorl %eax, %eax
  35         movl JMPBUF(%esp), %edx
  36
  37         /* Save registers.  */
  38         movl %ebx, (JB_BX*4)(%edx)
  39         movl %esi, (JB_SI*4)(%edx)
  40         movl %edi, (JB_DI*4)(%edx)
  41         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  42 #ifdef PTR_MANGLE
  43         PTR_MANGLE (%ecx)
  44 #endif
  45         movl %ecx, (JB_SP*4)(%edx)
  46         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  47         LIBC_PROBE (setjmp, 3, 4@%edx, -4@$0, 4@%ecx)
  48 #ifdef PTR_MANGLE
  49         PTR_MANGLE (%ecx)
  50 #endif
  51         movl %ecx, (JB_PC*4)(%edx)
  52         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  53
  54         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  55         ret
  56 END (_setjmp)
  57 libc_hidden_def (_setjmp)