git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _githtmldir {}
 126 set _reponame {}
 127 set _iscygwin {}
 128 set _search_path {}
 129
 130 set _trace [lsearch -exact $argv --trace]
 131 if {$_trace >= 0} {
 132         set argv [lreplace $argv $_trace $_trace]
 133         set _trace 1
 134 } else {
 135         set _trace 0
 136 }
 137
 138 proc appname {} {
 139         global _appname
 140         return $_appname
 141 }
 142
 143 proc gitdir {args} {
 144         global _gitdir
 145         if {$args eq {}} {
 146                 return $_gitdir
 147         }
 148         return [eval [list file join $_gitdir] $args]
 149 }
 150
 151 proc gitexec {args} {
 152         global _gitexec
 153         if {$_gitexec eq {}} {
 154                 if {[catch {set _gitexec [git --exec-path]} err]} {
 155                         error "Git not installed?\n\n$err"
 156                 }
 157                 if {[is_Cygwin]} {
 158                         set _gitexec [exec cygpath \
 159                                 --windows \
 160                                 --absolute \
 161                                 $_gitexec]
 162                 } else {
 163                         set _gitexec [file normalize $_gitexec]
 164                 }
 165         }
 166         if {$args eq {}} {
 167                 return $_gitexec
 168         }
 169         return [eval [list file join $_gitexec] $args]
 170 }
 171
 172 proc githtmldir {args} {
 173         global _githtmldir
 174         if {$_githtmldir eq {}} {
 175                 if {[catch {set _githtmldir [git --html-path]}]} {
 176                         # Git not installed or option not yet supported
 177                         return {}
 178                 }
 179                 if {[is_Cygwin]} {
 180                         set _githtmldir [exec cygpath \
 181                                 --windows \
 182                                 --absolute \
 183                                 $_githtmldir]
 184                 } else {
 185                         set _githtmldir [file normalize $_githtmldir]
 186                 }
 187         }
 188         if {$args eq {}} {
 189                 return $_githtmldir
 190         }
 191         return [eval [list file join $_githtmldir] $args]
 192 }
 193
 194 proc reponame {} {
 195         return $::_reponame
 196 }
 197
 198 proc is_MacOSX {} {
 199         if {[tk windowingsystem] eq {aqua}} {
 200                 return 1
 201         }
 202         return 0
 203 }
 204
 205 proc is_Windows {} {
 206         if {$::tcl_platform(platform) eq {windows}} {
 207                 return 1
 208         }
 209         return 0
 210 }
 211
 212 proc is_Cygwin {} {
 213         global _iscygwin
 214         if {$_iscygwin eq {}} {
 215                 if {$::tcl_platform(platform) eq {windows}} {
 216                         if {[catch {set p [exec cygpath --windir]} err]} {
 217                                 set _iscygwin 0
 218                         } else {
 219                                 set _iscygwin 1
 220                         }
 221                 } else {
 222                         set _iscygwin 0
 223                 }
 224         }
 225         return $_iscygwin
 226 }
 227
 228 proc is_enabled {option} {
 229         global enabled_options
 230         if {[catch {set on $enabled_options($option)}]} {return 0}
 231         return $on
 232 }
 233
 234 proc enable_option {option} {
 235         global enabled_options
 236         set enabled_options($option) 1
 237 }
 238
 239 proc disable_option {option} {
 240         global enabled_options
 241         set enabled_options($option) 0
 242 }
 243
 244 ######################################################################
 245 ##
 246 ## config
 247
 248 proc is_many_config {name} {
 249         switch -glob -- $name {
 250         gui.recentrepo -
 251         remote.*.fetch -
 252         remote.*.push
 253                 {return 1}
 254         *
 255                 {return 0}
 256         }
 257 }
 258
 259 proc is_config_true {name} {
 260         global repo_config
 261         if {[catch {set v $repo_config($name)}]} {
 262                 return 0
 263         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 264                 return 1
 265         } else {
 266                 return 0
 267         }
 268 }
 269
 270 proc get_config {name} {
 271         global repo_config
 272         if {[catch {set v $repo_config($name)}]} {
 273                 return {}
 274         } else {
 275                 return $v
 276         }
 277 }
 278
 279 ######################################################################
 280 ##
 281 ## handy utils
 282
 283 proc _trace_exec {cmd} {
 284         if {!$::_trace} return
 285         set d {}
 286         foreach v $cmd {
 287                 if {$d ne {}} {
 288                         append d { }
 289                 }
 290                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 291                         set v [sq $v]
 292                 }
 293                 append d $v
 294         }
 295         puts stderr $d
 296 }
 297
 298 proc _git_cmd {name} {
 299         global _git_cmd_path
 300
 301         if {[catch {set v $_git_cmd_path($name)}]} {
 302                 switch -- $name {
 303                   version   -
 304                 --version   -
 305                 --exec-path { return [list $::_git $name] }
 306                 }
 307
 308                 set p [gitexec git-$name$::_search_exe]
 309                 if {[file exists $p]} {
 310                         set v [list $p]
 311                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 312                         # Try to determine what sort of magic will make
 313                         # git-$name go and do its thing, because native
 314                         # Tcl on Windows doesn't know it.
 315                         #
 316                         set p [gitexec git-$name]
 317                         set f [open $p r]
 318                         set s [gets $f]
 319                         close $f
 320
 321                         switch -glob -- [lindex $s 0] {
 322                         #!*sh     { set i sh     }
 323                         #!*perl   { set i perl   }
 324                         #!*python { set i python }
 325                         default   { error "git-$name is not supported: $s" }
 326                         }
 327
 328                         upvar #0 _$i interp
 329                         if {![info exists interp]} {
 330                                 set interp [_which $i]
 331                         }
 332                         if {$interp eq {}} {
 333                                 error "git-$name requires $i (not in PATH)"
 334                         }
 335                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 336                 } else {
 337                         # Assume it is builtin to git somehow and we
 338                         # aren't actually able to see a file for it.
 339                         #
 340                         set v [list $::_git $name]
 341                 }
 342                 set _git_cmd_path($name) $v
 343         }
 344         return $v
 345 }
 346
 347 proc _which {what args} {
 348         global env _search_exe _search_path
 349
 350         if {$_search_path eq {}} {
 351                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 352                         set _search_path [split [exec cygpath \
 353                                 --windows \
 354                                 --path \
 355                                 --absolute \
 356                                 $env(PATH)] {;}]
 357                         set _search_exe .exe
 358                 } elseif {[is_Windows]} {
 359                         set gitguidir [file dirname [info script]]
 360                         regsub -all ";" $gitguidir "\\;" gitguidir
 361                         set env(PATH) "$gitguidir;$env(PATH)"
 362                         set _search_path [split $env(PATH) {;}]
 363                         set _search_exe .exe
 364                 } else {
 365                         set _search_path [split $env(PATH) :]
 366                         set _search_exe {}
 367                 }
 368         }
 369
 370         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 371                 set suffix {}
 372         } else {
 373                 set suffix $_search_exe
 374         }
 375
 376         foreach p $_search_path {
 377                 set p [file join $p $what$suffix]
 378                 if {[file exists $p]} {
 379                         return [file normalize $p]
 380                 }
 381         }
 382         return {}
 383 }
 384
 385 proc _lappend_nice {cmd_var} {
 386         global _nice
 387         upvar $cmd_var cmd
 388
 389         if {![info exists _nice]} {
 390                 set _nice [_which nice]
 391         }
 392         if {$_nice ne {}} {
 393                 lappend cmd $_nice
 394         }
 395 }
 396
 397 proc git {args} {
 398         set opt [list]
 399
 400         while {1} {
 401                 switch -- [lindex $args 0] {
 402                 --nice {
 403                         _lappend_nice opt
 404                 }
 405
 406                 default {
 407                         break
 408                 }
 409
 410                 }
 411
 412                 set args [lrange $args 1 end]
 413         }
 414
 415         set cmdp [_git_cmd [lindex $args 0]]
 416         set args [lrange $args 1 end]
 417
 418         _trace_exec [concat $opt $cmdp $args]
 419         set result [eval exec $opt $cmdp $args]
 420         if {$::_trace} {
 421                 puts stderr "< $result"
 422         }
 423         return $result
 424 }
 425
 426 proc _open_stdout_stderr {cmd} {
 427         _trace_exec $cmd
 428         if {[catch {
 429                         set fd [open [concat [list | ] $cmd] r]
 430                 } err]} {
 431                 if {   [lindex $cmd end] eq {2>@1}
 432                     && $err eq {can not find channel named "1"}
 433                         } {
 434                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 435                         # redirect operator.  Fallback to |& cat for those.
 436                         # The command was not actually started, so its safe
 437                         # to try to start it a second time.
 438                         #
 439                         set fd [open [concat \
 440                                 [list | ] \
 441                                 [lrange $cmd 0 end-1] \
 442                                 [list |& cat] \
 443                                 ] r]
 444                 } else {
 445                         error $err
 446                 }
 447         }
 448         fconfigure $fd -eofchar {}
 449         return $fd
 450 }
 451
 452 proc git_read {args} {
 453         set opt [list]
 454
 455         while {1} {
 456                 switch -- [lindex $args 0] {
 457                 --nice {
 458                         _lappend_nice opt
 459                 }
 460
 461                 --stderr {
 462                         lappend args 2>@1
 463                 }
 464
 465                 default {
 466                         break
 467                 }
 468
 469                 }
 470
 471                 set args [lrange $args 1 end]
 472         }
 473
 474         set cmdp [_git_cmd [lindex $args 0]]
 475         set args [lrange $args 1 end]
 476
 477         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 478 }
 479
 480 proc git_write {args} {
 481         set opt [list]
 482
 483         while {1} {
 484                 switch -- [lindex $args 0] {
 485                 --nice {
 486                         _lappend_nice opt
 487                 }
 488
 489                 default {
 490                         break
 491                 }
 492
 493                 }
 494
 495                 set args [lrange $args 1 end]
 496         }
 497
 498         set cmdp [_git_cmd [lindex $args 0]]
 499         set args [lrange $args 1 end]
 500
 501         _trace_exec [concat $opt $cmdp $args]
 502         return [open [concat [list | ] $opt $cmdp $args] w]
 503 }
 504
 505 proc githook_read {hook_name args} {
 506         set pchook [gitdir hooks $hook_name]
 507         lappend args 2>@1
 508
 509         # On Windows [file executable] might lie so we need to ask
 510         # the shell if the hook is executable.  Yes that's annoying.
 511         #
 512         if {[is_Windows]} {
 513                 upvar #0 _sh interp
 514                 if {![info exists interp]} {
 515                         set interp [_which sh]
 516                 }
 517                 if {$interp eq {}} {
 518                         error "hook execution requires sh (not in PATH)"
 519                 }
 520
 521                 set scr {if test -x "$1";then exec "$@";fi}
 522                 set sh_c [list $interp -c $scr $interp $pchook]
 523                 return [_open_stdout_stderr [concat $sh_c $args]]
 524         }
 525
 526         if {[file executable $pchook]} {
 527                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 528         }
 529
 530         return {}
 531 }
 532
 533 proc kill_file_process {fd} {
 534         set process [pid $fd]
 535
 536         catch {
 537                 if {[is_Windows]} {
 538                         # Use a Cygwin-specific flag to allow killing
 539                         # native Windows processes
 540                         exec kill -f $process
 541                 } else {
 542                         exec kill $process
 543                 }
 544         }
 545 }
 546
 547 proc gitattr {path attr default} {
 548         if {[catch {set r [git check-attr $attr -- $path]}]} {
 549                 set r unspecified
 550         } else {
 551                 set r [join [lrange [split $r :] 2 end] :]
 552                 regsub {^ } $r {} r
 553         }
 554         if {$r eq {unspecified}} {
 555                 return $default
 556         }
 557         return $r
 558 }
 559
 560 proc sq {value} {
 561         regsub -all ' $value "'\\''" value
 562         return "'$value'"
 563 }
 564
 565 proc load_current_branch {} {
 566         global current_branch is_detached
 567
 568         set fd [open [gitdir HEAD] r]
 569         if {[gets $fd ref] < 1} {
 570                 set ref {}
 571         }
 572         close $fd
 573
 574         set pfx {ref: refs/heads/}
 575         set len [string length $pfx]
 576         if {[string equal -length $len $pfx $ref]} {
 577                 # We're on a branch.  It might not exist.  But
 578                 # HEAD looks good enough to be a branch.
 579                 #
 580                 set current_branch [string range $ref $len end]
 581                 set is_detached 0
 582         } else {
 583                 # Assume this is a detached head.
 584                 #
 585                 set current_branch HEAD
 586                 set is_detached 1
 587         }
 588 }
 589
 590 auto_load tk_optionMenu
 591 rename tk_optionMenu real__tkOptionMenu
 592 proc tk_optionMenu {w varName args} {
 593         set m [eval real__tkOptionMenu $w $varName $args]
 594         $m configure -font font_ui
 595         $w configure -font font_ui
 596         return $m
 597 }
 598
 599 proc rmsel_tag {text} {
 600         $text tag conf sel \
 601                 -background [$text cget -background] \
 602                 -foreground [$text cget -foreground] \
 603                 -borderwidth 0
 604         $text tag conf in_sel -background lightgray
 605         bind $text <Motion> break
 606         return $text
 607 }
 608
 609 set root_exists 0
 610 bind . <Visibility> {
 611         bind . <Visibility> {}
 612         set root_exists 1
 613 }
 614
 615 if {[is_Windows]} {
 616         wm iconbitmap . -default $oguilib/git-gui.ico
 617         set ::tk::AlwaysShowSelection 1
 618
 619         # Spoof an X11 display for SSH
 620         if {![info exists env(DISPLAY)]} {
 621                 set env(DISPLAY) :9999
 622         }
 623 } else {
 624         catch {
 625                 image create photo gitlogo -width 16 -height 16
 626
 627                 gitlogo put #33CC33 -to  7  0  9  2
 628                 gitlogo put #33CC33 -to  4  2 12  4
 629                 gitlogo put #33CC33 -to  7  4  9  6
 630                 gitlogo put #CC3333 -to  4  6 12  8
 631                 gitlogo put gray26  -to  4  9  6 10
 632                 gitlogo put gray26  -to  3 10  6 12
 633                 gitlogo put gray26  -to  8  9 13 11
 634                 gitlogo put gray26  -to  8 11 10 12
 635                 gitlogo put gray26  -to 11 11 13 14
 636                 gitlogo put gray26  -to  3 12  5 14
 637                 gitlogo put gray26  -to  5 13
 638                 gitlogo put gray26  -to 10 13
 639                 gitlogo put gray26  -to  4 14 12 15
 640                 gitlogo put gray26  -to  5 15 11 16
 641                 gitlogo redither
 642
 643                 wm iconphoto . -default gitlogo
 644         }
 645 }
 646
 647 ######################################################################
 648 ##
 649 ## config defaults
 650
 651 set cursor_ptr arrow
 652 font create font_diff -family Courier -size 10
 653 font create font_ui
 654 catch {
 655         label .dummy
 656         eval font configure font_ui [font actual [.dummy cget -font]]
 657         destroy .dummy
 658 }
 659
 660 font create font_uiitalic
 661 font create font_uibold
 662 font create font_diffbold
 663 font create font_diffitalic
 664
 665 foreach class {Button Checkbutton Entry Label
 666                 Labelframe Listbox Message
 667                 Radiobutton Spinbox Text} {
 668         option add *$class.font font_ui
 669 }
 670 if {![is_MacOSX]} {
 671         option add *Menu.font font_ui
 672 }
 673 unset class
 674
 675 if {[is_Windows] || [is_MacOSX]} {
 676         option add *Menu.tearOff 0
 677 }
 678
 679 if {[is_MacOSX]} {
 680         set M1B M1
 681         set M1T Cmd
 682 } else {
 683         set M1B Control
 684         set M1T Ctrl
 685 }
 686
 687 proc bind_button3 {w cmd} {
 688         bind $w <Any-Button-3> $cmd
 689         if {[is_MacOSX]} {
 690                 # Mac OS X sends Button-2 on right click through three-button mouse,
 691                 # or through trackpad right-clicking (two-finger touch + click).
 692                 bind $w <Any-Button-2> $cmd
 693                 bind $w <Control-Button-1> $cmd
 694         }
 695 }
 696
 697 proc apply_config {} {
 698         global repo_config font_descs
 699
 700         foreach option $font_descs {
 701                 set name [lindex $option 0]
 702                 set font [lindex $option 1]
 703                 if {[catch {
 704                         set need_weight 1
 705                         foreach {cn cv} $repo_config(gui.$name) {
 706                                 if {$cn eq {-weight}} {
 707                                         set need_weight 0
 708                                 }
 709                                 font configure $font $cn $cv
 710                         }
 711                         if {$need_weight} {
 712                                 font configure $font -weight normal
 713                         }
 714                         } err]} {
 715                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 716                 }
 717                 foreach {cn cv} [font configure $font] {
 718                         font configure ${font}bold $cn $cv
 719                         font configure ${font}italic $cn $cv
 720                 }
 721                 font configure ${font}bold -weight bold
 722                 font configure ${font}italic -slant italic
 723         }
 724 }
 725
 726 set default_config(branch.autosetupmerge) true
 727 set default_config(merge.tool) {}
 728 set default_config(mergetool.keepbackup) true
 729 set default_config(merge.diffstat) true
 730 set default_config(merge.summary) false
 731 set default_config(merge.verbosity) 2
 732 set default_config(user.name) {}
 733 set default_config(user.email) {}
 734
 735 set default_config(gui.encoding) [encoding system]
 736 set default_config(gui.matchtrackingbranch) false
 737 set default_config(gui.pruneduringfetch) false
 738 set default_config(gui.trustmtime) false
 739 set default_config(gui.fastcopyblame) false
 740 set default_config(gui.copyblamethreshold) 40
 741 set default_config(gui.blamehistoryctx) 7
 742 set default_config(gui.diffcontext) 5
 743 set default_config(gui.commitmsgwidth) 75
 744 set default_config(gui.newbranchtemplate) {}
 745 set default_config(gui.spellingdictionary) {}
 746 set default_config(gui.fontui) [font configure font_ui]
 747 set default_config(gui.fontdiff) [font configure font_diff]
 748 # TODO: this option should be added to the git-config documentation
 749 set default_config(gui.maxfilesdisplayed) 5000
 750 set font_descs {
 751         {fontui   font_ui   {mc "Main Font"}}
 752         {fontdiff font_diff {mc "Diff/Console Font"}}
 753 }
 754
 755 ######################################################################
 756 ##
 757 ## find git
 758
 759 set _git  [_which git]
 760 if {$_git eq {}} {
 761         catch {wm withdraw .}
 762         tk_messageBox \
 763                 -icon error \
 764                 -type ok \
 765                 -title [mc "git-gui: fatal error"] \
 766                 -message [mc "Cannot find git in PATH."]
 767         exit 1
 768 }
 769
 770 ######################################################################
 771 ##
 772 ## version check
 773
 774 if {[catch {set _git_version [git --version]} err]} {
 775         catch {wm withdraw .}
 776         tk_messageBox \
 777                 -icon error \
 778                 -type ok \
 779                 -title [mc "git-gui: fatal error"] \
 780                 -message "Cannot determine Git version:
 781
 782 $err
 783
 784 [appname] requires Git 1.5.0 or later."
 785         exit 1
 786 }
 787 if {![regsub {^git version } $_git_version {} _git_version]} {
 788         catch {wm withdraw .}
 789         tk_messageBox \
 790                 -icon error \
 791                 -type ok \
 792                 -title [mc "git-gui: fatal error"] \
 793                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 794         exit 1
 795 }
 796
 797 set _real_git_version $_git_version
 798 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 799 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 800 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 801 regsub {\.GIT$} $_git_version {} _git_version
 802 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 803
 804 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 805         catch {wm withdraw .}
 806         if {[tk_messageBox \
 807                 -icon warning \
 808                 -type yesno \
 809                 -default no \
 810                 -title "[appname]: warning" \
 811                  -message [mc "Git version cannot be determined.
 812
 813 %s claims it is version '%s'.
 814
 815 %s requires at least Git 1.5.0 or later.
 816
 817 Assume '%s' is version 1.5.0?
 818 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 819                 set _git_version 1.5.0
 820         } else {
 821                 exit 1
 822         }
 823 }
 824 unset _real_git_version
 825
 826 proc git-version {args} {
 827         global _git_version
 828
 829         switch [llength $args] {
 830         0 {
 831                 return $_git_version
 832         }
 833
 834         2 {
 835                 set op [lindex $args 0]
 836                 set vr [lindex $args 1]
 837                 set cm [package vcompare $_git_version $vr]
 838                 return [expr $cm $op 0]
 839         }
 840
 841         4 {
 842                 set type [lindex $args 0]
 843                 set name [lindex $args 1]
 844                 set parm [lindex $args 2]
 845                 set body [lindex $args 3]
 846
 847                 if {($type ne {proc} && $type ne {method})} {
 848                         error "Invalid arguments to git-version"
 849                 }
 850                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 851                         error "Last arm of $type $name must be default"
 852                 }
 853
 854                 foreach {op vr cb} [lrange $body 0 end-2] {
 855                         if {[git-version $op $vr]} {
 856                                 return [uplevel [list $type $name $parm $cb]]
 857                         }
 858                 }
 859
 860                 return [uplevel [list $type $name $parm [lindex $body end]]]
 861         }
 862
 863         default {
 864                 error "git-version >= x"
 865         }
 866
 867         }
 868 }
 869
 870 if {[git-version < 1.5]} {
 871         catch {wm withdraw .}
 872         tk_messageBox \
 873                 -icon error \
 874                 -type ok \
 875                 -title [mc "git-gui: fatal error"] \
 876                 -message "[appname] requires Git 1.5.0 or later.
 877
 878 You are using [git-version]:
 879
 880 [git --version]"
 881         exit 1
 882 }
 883
 884 ######################################################################
 885 ##
 886 ## configure our library
 887
 888 set idx [file join $oguilib tclIndex]
 889 if {[catch {set fd [open $idx r]} err]} {
 890         catch {wm withdraw .}
 891         tk_messageBox \
 892                 -icon error \
 893                 -type ok \
 894                 -title [mc "git-gui: fatal error"] \
 895                 -message $err
 896         exit 1
 897 }
 898 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 899         set idx [list]
 900         while {[gets $fd n] >= 0} {
 901                 if {$n ne {} && ![string match #* $n]} {
 902                         lappend idx $n
 903                 }
 904         }
 905 } else {
 906         set idx {}
 907 }
 908 close $fd
 909
 910 if {$idx ne {}} {
 911         set loaded [list]
 912         foreach p $idx {
 913                 if {[lsearch -exact $loaded $p] >= 0} continue
 914                 source [file join $oguilib $p]
 915                 lappend loaded $p
 916         }
 917         unset loaded p
 918 } else {
 919         set auto_path [concat [list $oguilib] $auto_path]
 920 }
 921 unset -nocomplain idx fd
 922
 923 ######################################################################
 924 ##
 925 ## config file parsing
 926
 927 git-version proc _parse_config {arr_name args} {
 928         >= 1.5.3 {
 929                 upvar $arr_name arr
 930                 array unset arr
 931                 set buf {}
 932                 catch {
 933                         set fd_rc [eval \
 934                                 [list git_read config] \
 935                                 $args \
 936                                 [list --null --list]]
 937                         fconfigure $fd_rc -translation binary
 938                         set buf [read $fd_rc]
 939                         close $fd_rc
 940                 }
 941                 foreach line [split $buf "\0"] {
 942                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 943                                 if {[is_many_config $name]} {
 944                                         lappend arr($name) $value
 945                                 } else {
 946                                         set arr($name) $value
 947                                 }
 948                         }
 949                 }
 950         }
 951         default {
 952                 upvar $arr_name arr
 953                 array unset arr
 954                 catch {
 955                         set fd_rc [eval [list git_read config --list] $args]
 956                         while {[gets $fd_rc line] >= 0} {
 957                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 958                                         if {[is_many_config $name]} {
 959                                                 lappend arr($name) $value
 960                                         } else {
 961                                                 set arr($name) $value
 962                                         }
 963                                 }
 964                         }
 965                         close $fd_rc
 966                 }
 967         }
 968 }
 969
 970 proc load_config {include_global} {
 971         global repo_config global_config system_config default_config
 972
 973         if {$include_global} {
 974                 _parse_config system_config --system
 975                 _parse_config global_config --global
 976         }
 977         _parse_config repo_config
 978
 979         foreach name [array names default_config] {
 980                 if {[catch {set v $system_config($name)}]} {
 981                         set system_config($name) $default_config($name)
 982                 }
 983         }
 984         foreach name [array names system_config] {
 985                 if {[catch {set v $global_config($name)}]} {
 986                         set global_config($name) $system_config($name)
 987                 }
 988                 if {[catch {set v $repo_config($name)}]} {
 989                         set repo_config($name) $system_config($name)
 990                 }
 991         }
 992 }
 993
 994 ######################################################################
 995 ##
 996 ## feature option selection
 997
 998 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 999         unset _junk
1000 } else {
1001         set subcommand gui
1002 }
1003 if {$subcommand eq {gui.sh}} {
1004         set subcommand gui
1005 }
1006 if {$subcommand eq {gui} && [llength $argv] > 0} {
1007         set subcommand [lindex $argv 0]
1008         set argv [lrange $argv 1 end]
1009 }
1010
1011 enable_option multicommit
1012 enable_option branch
1013 enable_option transport
1014 disable_option bare
1015
1016 switch -- $subcommand {
1017 browser -
1018 blame {
1019         enable_option bare
1020
1021         disable_option multicommit
1022         disable_option branch
1023         disable_option transport
1024 }
1025 citool {
1026         enable_option singlecommit
1027         enable_option retcode
1028
1029         disable_option multicommit
1030         disable_option branch
1031         disable_option transport
1032
1033         while {[llength $argv] > 0} {
1034                 set a [lindex $argv 0]
1035                 switch -- $a {
1036                 --amend {
1037                         enable_option initialamend
1038                 }
1039                 --nocommit {
1040                         enable_option nocommit
1041                         enable_option nocommitmsg
1042                 }
1043                 --commitmsg {
1044                         disable_option nocommitmsg
1045                 }
1046                 default {
1047                         break
1048                 }
1049                 }
1050
1051                 set argv [lrange $argv 1 end]
1052         }
1053 }
1054 }
1055
1056 ######################################################################
1057 ##
1058 ## execution environment
1059
1060 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1061
1062 # Suggest our implementation of askpass, if none is set
1063 if {![info exists env(SSH_ASKPASS)]} {
1064         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1065 }
1066
1067 ######################################################################
1068 ##
1069 ## repository setup
1070
1071 set picked 0
1072 if {[catch {
1073                 set _gitdir $env(GIT_DIR)
1074                 set _prefix {}
1075                 }]
1076         && [catch {
1077                 set _gitdir [git rev-parse --git-dir]
1078                 set _prefix [git rev-parse --show-prefix]
1079         } err]} {
1080         load_config 1
1081         apply_config
1082         choose_repository::pick
1083         set picked 1
1084 }
1085 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1086         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1087 }
1088 if {![file isdirectory $_gitdir]} {
1089         catch {wm withdraw .}
1090         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1091         exit 1
1092 }
1093 if {$_prefix ne {}} {
1094         regsub -all {[^/]+/} $_prefix ../ cdup
1095         if {[catch {cd $cdup} err]} {
1096                 catch {wm withdraw .}
1097                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1098                 exit 1
1099         }
1100         unset cdup
1101 } elseif {![is_enabled bare]} {
1102         if {[lindex [file split $_gitdir] end] ne {.git}} {
1103                 catch {wm withdraw .}
1104                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1105                 exit 1
1106         }
1107         if {[catch {cd [file dirname $_gitdir]} err]} {
1108                 catch {wm withdraw .}
1109                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1110                 exit 1
1111         }
1112 }
1113 set _reponame [file split [file normalize $_gitdir]]
1114 if {[lindex $_reponame end] eq {.git}} {
1115         set _reponame [lindex $_reponame end-1]
1116 } else {
1117         set _reponame [lindex $_reponame end]
1118 }
1119
1120 ######################################################################
1121 ##
1122 ## global init
1123
1124 set current_diff_path {}
1125 set current_diff_side {}
1126 set diff_actions [list]
1127
1128 set HEAD {}
1129 set PARENT {}
1130 set MERGE_HEAD [list]
1131 set commit_type {}
1132 set empty_tree {}
1133 set current_branch {}
1134 set is_detached 0
1135 set current_diff_path {}
1136 set is_3way_diff 0
1137 set is_submodule_diff 0
1138 set is_conflict_diff 0
1139 set selected_commit_type new
1140 set diff_empty_count 0
1141
1142 set nullid "0000000000000000000000000000000000000000"
1143 set nullid2 "0000000000000000000000000000000000000001"
1144
1145 ######################################################################
1146 ##
1147 ## task management
1148
1149 set rescan_active 0
1150 set diff_active 0
1151 set last_clicked {}
1152
1153 set disable_on_lock [list]
1154 set index_lock_type none
1155
1156 proc lock_index {type} {
1157         global index_lock_type disable_on_lock
1158
1159         if {$index_lock_type eq {none}} {
1160                 set index_lock_type $type
1161                 foreach w $disable_on_lock {
1162                         uplevel #0 $w disabled
1163                 }
1164                 return 1
1165         } elseif {$index_lock_type eq "begin-$type"} {
1166                 set index_lock_type $type
1167                 return 1
1168         }
1169         return 0
1170 }
1171
1172 proc unlock_index {} {
1173         global index_lock_type disable_on_lock
1174
1175         set index_lock_type none
1176         foreach w $disable_on_lock {
1177                 uplevel #0 $w normal
1178         }
1179 }
1180
1181 ######################################################################
1182 ##
1183 ## status
1184
1185 proc repository_state {ctvar hdvar mhvar} {
1186         global current_branch
1187         upvar $ctvar ct $hdvar hd $mhvar mh
1188
1189         set mh [list]
1190
1191         load_current_branch
1192         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1193                 set hd {}
1194                 set ct initial
1195                 return
1196         }
1197
1198         set merge_head [gitdir MERGE_HEAD]
1199         if {[file exists $merge_head]} {
1200                 set ct merge
1201                 set fd_mh [open $merge_head r]
1202                 while {[gets $fd_mh line] >= 0} {
1203                         lappend mh $line
1204                 }
1205                 close $fd_mh
1206                 return
1207         }
1208
1209         set ct normal
1210 }
1211
1212 proc PARENT {} {
1213         global PARENT empty_tree
1214
1215         set p [lindex $PARENT 0]
1216         if {$p ne {}} {
1217                 return $p
1218         }
1219         if {$empty_tree eq {}} {
1220                 set empty_tree [git mktree << {}]
1221         }
1222         return $empty_tree
1223 }
1224
1225 proc force_amend {} {
1226         global selected_commit_type
1227         global HEAD PARENT MERGE_HEAD commit_type
1228
1229         repository_state newType newHEAD newMERGE_HEAD
1230         set HEAD $newHEAD
1231         set PARENT $newHEAD
1232         set MERGE_HEAD $newMERGE_HEAD
1233         set commit_type $newType
1234
1235         set selected_commit_type amend
1236         do_select_commit_type
1237 }
1238
1239 proc rescan {after {honor_trustmtime 1}} {
1240         global HEAD PARENT MERGE_HEAD commit_type
1241         global ui_index ui_workdir ui_comm
1242         global rescan_active file_states
1243         global repo_config
1244
1245         if {$rescan_active > 0 || ![lock_index read]} return
1246
1247         repository_state newType newHEAD newMERGE_HEAD
1248         if {[string match amend* $commit_type]
1249                 && $newType eq {normal}
1250                 && $newHEAD eq $HEAD} {
1251         } else {
1252                 set HEAD $newHEAD
1253                 set PARENT $newHEAD
1254                 set MERGE_HEAD $newMERGE_HEAD
1255                 set commit_type $newType
1256         }
1257
1258         array unset file_states
1259
1260         if {!$::GITGUI_BCK_exists &&
1261                 (![$ui_comm edit modified]
1262                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1263                 if {[string match amend* $commit_type]} {
1264                 } elseif {[load_message GITGUI_MSG]} {
1265                 } elseif {[run_prepare_commit_msg_hook]} {
1266                 } elseif {[load_message MERGE_MSG]} {
1267                 } elseif {[load_message SQUASH_MSG]} {
1268                 }
1269                 $ui_comm edit reset
1270                 $ui_comm edit modified false
1271         }
1272
1273         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1274                 rescan_stage2 {} $after
1275         } else {
1276                 set rescan_active 1
1277                 ui_status [mc "Refreshing file status..."]
1278                 set fd_rf [git_read update-index \
1279                         -q \
1280                         --unmerged \
1281                         --ignore-missing \
1282                         --refresh \
1283                         ]
1284                 fconfigure $fd_rf -blocking 0 -translation binary
1285                 fileevent $fd_rf readable \
1286                         [list rescan_stage2 $fd_rf $after]
1287         }
1288 }
1289
1290 if {[is_Cygwin]} {
1291         set is_git_info_exclude {}
1292         proc have_info_exclude {} {
1293                 global is_git_info_exclude
1294
1295                 if {$is_git_info_exclude eq {}} {
1296                         if {[catch {exec test -f [gitdir info exclude]}]} {
1297                                 set is_git_info_exclude 0
1298                         } else {
1299                                 set is_git_info_exclude 1
1300                         }
1301                 }
1302                 return $is_git_info_exclude
1303         }
1304 } else {
1305         proc have_info_exclude {} {
1306                 return [file readable [gitdir info exclude]]
1307         }
1308 }
1309
1310 proc rescan_stage2 {fd after} {
1311         global rescan_active buf_rdi buf_rdf buf_rlo
1312
1313         if {$fd ne {}} {
1314                 read $fd
1315                 if {![eof $fd]} return
1316                 close $fd
1317         }
1318
1319         set ls_others [list --exclude-per-directory=.gitignore]
1320         if {[have_info_exclude]} {
1321                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1322         }
1323         set user_exclude [get_config core.excludesfile]
1324         if {$user_exclude ne {} && [file readable $user_exclude]} {
1325                 lappend ls_others "--exclude-from=$user_exclude"
1326         }
1327
1328         set buf_rdi {}
1329         set buf_rdf {}
1330         set buf_rlo {}
1331
1332         set rescan_active 3
1333         ui_status [mc "Scanning for modified files ..."]
1334         set fd_di [git_read diff-index --cached -z [PARENT]]
1335         set fd_df [git_read diff-files -z]
1336         set fd_lo [eval git_read ls-files --others -z $ls_others]
1337
1338         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1339         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1340         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1341         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1342         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1343         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1344 }
1345
1346 proc load_message {file} {
1347         global ui_comm
1348
1349         set f [gitdir $file]
1350         if {[file isfile $f]} {
1351                 if {[catch {set fd [open $f r]}]} {
1352                         return 0
1353                 }
1354                 fconfigure $fd -eofchar {}
1355                 set content [string trim [read $fd]]
1356                 close $fd
1357                 regsub -all -line {[ \r\t]+$} $content {} content
1358                 $ui_comm delete 0.0 end
1359                 $ui_comm insert end $content
1360                 return 1
1361         }
1362         return 0
1363 }
1364
1365 proc run_prepare_commit_msg_hook {} {
1366         global pch_error
1367
1368         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1369         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1370         # empty file but existant file.
1371
1372         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1373
1374         if {[file isfile [gitdir MERGE_MSG]]} {
1375                 set pcm_source "merge"
1376                 set fd_mm [open [gitdir MERGE_MSG] r]
1377                 puts -nonewline $fd_pcm [read $fd_mm]
1378                 close $fd_mm
1379         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1380                 set pcm_source "squash"
1381                 set fd_sm [open [gitdir SQUASH_MSG] r]
1382                 puts -nonewline $fd_pcm [read $fd_sm]
1383                 close $fd_sm
1384         } else {
1385                 set pcm_source ""
1386         }
1387
1388         close $fd_pcm
1389
1390         set fd_ph [githook_read prepare-commit-msg \
1391                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1392         if {$fd_ph eq {}} {
1393                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1394                 return 0;
1395         }
1396
1397         ui_status [mc "Calling prepare-commit-msg hook..."]
1398         set pch_error {}
1399
1400         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1401         fileevent $fd_ph readable \
1402                 [list prepare_commit_msg_hook_wait $fd_ph]
1403
1404         return 1;
1405 }
1406
1407 proc prepare_commit_msg_hook_wait {fd_ph} {
1408         global pch_error
1409
1410         append pch_error [read $fd_ph]
1411         fconfigure $fd_ph -blocking 1
1412         if {[eof $fd_ph]} {
1413                 if {[catch {close $fd_ph}]} {
1414                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1415                         hook_failed_popup prepare-commit-msg $pch_error
1416                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1417                         exit 1
1418                 } else {
1419                         load_message PREPARE_COMMIT_MSG
1420                 }
1421                 set pch_error {}
1422                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1423                 return
1424         }
1425         fconfigure $fd_ph -blocking 0
1426         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1427 }
1428
1429 proc read_diff_index {fd after} {
1430         global buf_rdi
1431
1432         append buf_rdi [read $fd]
1433         set c 0
1434         set n [string length $buf_rdi]
1435         while {$c < $n} {
1436                 set z1 [string first "\0" $buf_rdi $c]
1437                 if {$z1 == -1} break
1438                 incr z1
1439                 set z2 [string first "\0" $buf_rdi $z1]
1440                 if {$z2 == -1} break
1441
1442                 incr c
1443                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1444                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1445                 merge_state \
1446                         [encoding convertfrom $p] \
1447                         [lindex $i 4]? \
1448                         [list [lindex $i 0] [lindex $i 2]] \
1449                         [list]
1450                 set c $z2
1451                 incr c
1452         }
1453         if {$c < $n} {
1454                 set buf_rdi [string range $buf_rdi $c end]
1455         } else {
1456                 set buf_rdi {}
1457         }
1458
1459         rescan_done $fd buf_rdi $after
1460 }
1461
1462 proc read_diff_files {fd after} {
1463         global buf_rdf
1464
1465         append buf_rdf [read $fd]
1466         set c 0
1467         set n [string length $buf_rdf]
1468         while {$c < $n} {
1469                 set z1 [string first "\0" $buf_rdf $c]
1470                 if {$z1 == -1} break
1471                 incr z1
1472                 set z2 [string first "\0" $buf_rdf $z1]
1473                 if {$z2 == -1} break
1474
1475                 incr c
1476                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1477                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1478                 merge_state \
1479                         [encoding convertfrom $p] \
1480                         ?[lindex $i 4] \
1481                         [list] \
1482                         [list [lindex $i 0] [lindex $i 2]]
1483                 set c $z2
1484                 incr c
1485         }
1486         if {$c < $n} {
1487                 set buf_rdf [string range $buf_rdf $c end]
1488         } else {
1489                 set buf_rdf {}
1490         }
1491
1492         rescan_done $fd buf_rdf $after
1493 }
1494
1495 proc read_ls_others {fd after} {
1496         global buf_rlo
1497
1498         append buf_rlo [read $fd]
1499         set pck [split $buf_rlo "\0"]
1500         set buf_rlo [lindex $pck end]
1501         foreach p [lrange $pck 0 end-1] {
1502                 set p [encoding convertfrom $p]
1503                 if {[string index $p end] eq {/}} {
1504                         set p [string range $p 0 end-1]
1505                 }
1506                 merge_state $p ?O
1507         }
1508         rescan_done $fd buf_rlo $after
1509 }
1510
1511 proc rescan_done {fd buf after} {
1512         global rescan_active current_diff_path
1513         global file_states repo_config
1514         upvar $buf to_clear
1515
1516         if {![eof $fd]} return
1517         set to_clear {}
1518         close $fd
1519         if {[incr rescan_active -1] > 0} return
1520
1521         prune_selection
1522         unlock_index
1523         display_all_files
1524         if {$current_diff_path ne {}} { reshow_diff $after }
1525         if {$current_diff_path eq {}} { select_first_diff $after }
1526 }
1527
1528 proc prune_selection {} {
1529         global file_states selected_paths
1530
1531         foreach path [array names selected_paths] {
1532                 if {[catch {set still_here $file_states($path)}]} {
1533                         unset selected_paths($path)
1534                 }
1535         }
1536 }
1537
1538 ######################################################################
1539 ##
1540 ## ui helpers
1541
1542 proc mapicon {w state path} {
1543         global all_icons
1544
1545         if {[catch {set r $all_icons($state$w)}]} {
1546                 puts "error: no icon for $w state={$state} $path"
1547                 return file_plain
1548         }
1549         return $r
1550 }
1551
1552 proc mapdesc {state path} {
1553         global all_descs
1554
1555         if {[catch {set r $all_descs($state)}]} {
1556                 puts "error: no desc for state={$state} $path"
1557                 return $state
1558         }
1559         return $r
1560 }
1561
1562 proc ui_status {msg} {
1563         global main_status
1564         if {[info exists main_status]} {
1565                 $main_status show $msg
1566         }
1567 }
1568
1569 proc ui_ready {{test {}}} {
1570         global main_status
1571         if {[info exists main_status]} {
1572                 $main_status show [mc "Ready."] $test
1573         }
1574 }
1575
1576 proc escape_path {path} {
1577         regsub -all {\\} $path "\\\\" path
1578         regsub -all "\n" $path "\\n" path
1579         return $path
1580 }
1581
1582 proc short_path {path} {
1583         return [escape_path [lindex [file split $path] end]]
1584 }
1585
1586 set next_icon_id 0
1587 set null_sha1 [string repeat 0 40]
1588
1589 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1590         global file_states next_icon_id null_sha1
1591
1592         set s0 [string index $new_state 0]
1593         set s1 [string index $new_state 1]
1594
1595         if {[catch {set info $file_states($path)}]} {
1596                 set state __
1597                 set icon n[incr next_icon_id]
1598         } else {
1599                 set state [lindex $info 0]
1600                 set icon [lindex $info 1]
1601                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1602                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1603         }
1604
1605         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1606         elseif {$s0 eq {_}} {set s0 _}
1607
1608         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1609         elseif {$s1 eq {_}} {set s1 _}
1610
1611         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1612                 set head_info [list 0 $null_sha1]
1613         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1614                 && $head_info eq {}} {
1615                 set head_info $index_info
1616         }
1617
1618         set file_states($path) [list $s0$s1 $icon \
1619                 $head_info $index_info \
1620                 ]
1621         return $state
1622 }
1623
1624 proc display_file_helper {w path icon_name old_m new_m} {
1625         global file_lists
1626
1627         if {$new_m eq {_}} {
1628                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1629                 if {$lno >= 0} {
1630                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1631                         incr lno
1632                         $w conf -state normal
1633                         $w delete $lno.0 [expr {$lno + 1}].0
1634                         $w conf -state disabled
1635                 }
1636         } elseif {$old_m eq {_} && $new_m ne {_}} {
1637                 lappend file_lists($w) $path
1638                 set file_lists($w) [lsort -unique $file_lists($w)]
1639                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1640                 incr lno
1641                 $w conf -state normal
1642                 $w image create $lno.0 \
1643                         -align center -padx 5 -pady 1 \
1644                         -name $icon_name \
1645                         -image [mapicon $w $new_m $path]
1646                 $w insert $lno.1 "[escape_path $path]\n"
1647                 $w conf -state disabled
1648         } elseif {$old_m ne $new_m} {
1649                 $w conf -state normal
1650                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1651                 $w conf -state disabled
1652         }
1653 }
1654
1655 proc display_file {path state} {
1656         global file_states selected_paths
1657         global ui_index ui_workdir
1658
1659         set old_m [merge_state $path $state]
1660         set s $file_states($path)
1661         set new_m [lindex $s 0]
1662         set icon_name [lindex $s 1]
1663
1664         set o [string index $old_m 0]
1665         set n [string index $new_m 0]
1666         if {$o eq {U}} {
1667                 set o _
1668         }
1669         if {$n eq {U}} {
1670                 set n _
1671         }
1672         display_file_helper     $ui_index $path $icon_name $o $n
1673
1674         if {[string index $old_m 0] eq {U}} {
1675                 set o U
1676         } else {
1677                 set o [string index $old_m 1]
1678         }
1679         if {[string index $new_m 0] eq {U}} {
1680                 set n U
1681         } else {
1682                 set n [string index $new_m 1]
1683         }
1684         display_file_helper     $ui_workdir $path $icon_name $o $n
1685
1686         if {$new_m eq {__}} {
1687                 unset file_states($path)
1688                 catch {unset selected_paths($path)}
1689         }
1690 }
1691
1692 proc display_all_files_helper {w path icon_name m} {
1693         global file_lists
1694
1695         lappend file_lists($w) $path
1696         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1697         $w image create end \
1698                 -align center -padx 5 -pady 1 \
1699                 -name $icon_name \
1700                 -image [mapicon $w $m $path]
1701         $w insert end "[escape_path $path]\n"
1702 }
1703
1704 set files_warning 0
1705 proc display_all_files {} {
1706         global ui_index ui_workdir
1707         global file_states file_lists
1708         global last_clicked
1709         global files_warning
1710
1711         $ui_index conf -state normal
1712         $ui_workdir conf -state normal
1713
1714         $ui_index delete 0.0 end
1715         $ui_workdir delete 0.0 end
1716         set last_clicked {}
1717
1718         set file_lists($ui_index) [list]
1719         set file_lists($ui_workdir) [list]
1720
1721         set to_display [lsort [array names file_states]]
1722         set display_limit [get_config gui.maxfilesdisplayed]
1723         if {[llength $to_display] > $display_limit} {
1724                 if {!$files_warning} {
1725                         # do not repeatedly warn:
1726                         set files_warning 1
1727                         info_popup [mc "Displaying only %s of %s files." \
1728                                 $display_limit [llength $to_display]]
1729                 }
1730                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1731         }
1732         foreach path $to_display {
1733                 set s $file_states($path)
1734                 set m [lindex $s 0]
1735                 set icon_name [lindex $s 1]
1736
1737                 set s [string index $m 0]
1738                 if {$s ne {U} && $s ne {_}} {
1739                         display_all_files_helper $ui_index $path \
1740                                 $icon_name $s
1741                 }
1742
1743                 if {[string index $m 0] eq {U}} {
1744                         set s U
1745                 } else {
1746                         set s [string index $m 1]
1747                 }
1748                 if {$s ne {_}} {
1749                         display_all_files_helper $ui_workdir $path \
1750                                 $icon_name $s
1751                 }
1752         }
1753
1754         $ui_index conf -state disabled
1755         $ui_workdir conf -state disabled
1756 }
1757
1758 ######################################################################
1759 ##
1760 ## icons
1761
1762 set filemask {
1763 #define mask_width 14
1764 #define mask_height 15
1765 static unsigned char mask_bits[] = {
1766    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1767    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1768    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1769 }
1770
1771 image create bitmap file_plain -background white -foreground black -data {
1772 #define plain_width 14
1773 #define plain_height 15
1774 static unsigned char plain_bits[] = {
1775    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1776    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1777    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1778 } -maskdata $filemask
1779
1780 image create bitmap file_mod -background white -foreground blue -data {
1781 #define mod_width 14
1782 #define mod_height 15
1783 static unsigned char mod_bits[] = {
1784    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1785    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1786    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1787 } -maskdata $filemask
1788
1789 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1790 #define file_fulltick_width 14
1791 #define file_fulltick_height 15
1792 static unsigned char file_fulltick_bits[] = {
1793    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1794    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1795    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1796 } -maskdata $filemask
1797
1798 image create bitmap file_parttick -background white -foreground "#005050" -data {
1799 #define parttick_width 14
1800 #define parttick_height 15
1801 static unsigned char parttick_bits[] = {
1802    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1803    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1804    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1805 } -maskdata $filemask
1806
1807 image create bitmap file_question -background white -foreground black -data {
1808 #define file_question_width 14
1809 #define file_question_height 15
1810 static unsigned char file_question_bits[] = {
1811    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1812    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1813    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1814 } -maskdata $filemask
1815
1816 image create bitmap file_removed -background white -foreground red -data {
1817 #define file_removed_width 14
1818 #define file_removed_height 15
1819 static unsigned char file_removed_bits[] = {
1820    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1821    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1822    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1823 } -maskdata $filemask
1824
1825 image create bitmap file_merge -background white -foreground blue -data {
1826 #define file_merge_width 14
1827 #define file_merge_height 15
1828 static unsigned char file_merge_bits[] = {
1829    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1830    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1831    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1832 } -maskdata $filemask
1833
1834 image create bitmap file_statechange -background white -foreground green -data {
1835 #define file_merge_width 14
1836 #define file_merge_height 15
1837 static unsigned char file_statechange_bits[] = {
1838    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1839    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1840    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1841 } -maskdata $filemask
1842
1843 set ui_index .vpane.files.index.list
1844 set ui_workdir .vpane.files.workdir.list
1845
1846 set all_icons(_$ui_index)   file_plain
1847 set all_icons(A$ui_index)   file_fulltick
1848 set all_icons(M$ui_index)   file_fulltick
1849 set all_icons(D$ui_index)   file_removed
1850 set all_icons(U$ui_index)   file_merge
1851 set all_icons(T$ui_index)   file_statechange
1852
1853 set all_icons(_$ui_workdir) file_plain
1854 set all_icons(M$ui_workdir) file_mod
1855 set all_icons(D$ui_workdir) file_question
1856 set all_icons(U$ui_workdir) file_merge
1857 set all_icons(O$ui_workdir) file_plain
1858 set all_icons(T$ui_workdir) file_statechange
1859
1860 set max_status_desc 0
1861 foreach i {
1862                 {__ {mc "Unmodified"}}
1863
1864                 {_M {mc "Modified, not staged"}}
1865                 {M_ {mc "Staged for commit"}}
1866                 {MM {mc "Portions staged for commit"}}
1867                 {MD {mc "Staged for commit, missing"}}
1868
1869                 {_T {mc "File type changed, not staged"}}
1870                 {T_ {mc "File type changed, staged"}}
1871
1872                 {_O {mc "Untracked, not staged"}}
1873                 {A_ {mc "Staged for commit"}}
1874                 {AM {mc "Portions staged for commit"}}
1875                 {AD {mc "Staged for commit, missing"}}
1876
1877                 {_D {mc "Missing"}}
1878                 {D_ {mc "Staged for removal"}}
1879                 {DO {mc "Staged for removal, still present"}}
1880
1881                 {_U {mc "Requires merge resolution"}}
1882                 {U_ {mc "Requires merge resolution"}}
1883                 {UU {mc "Requires merge resolution"}}
1884                 {UM {mc "Requires merge resolution"}}
1885                 {UD {mc "Requires merge resolution"}}
1886                 {UT {mc "Requires merge resolution"}}
1887         } {
1888         set text [eval [lindex $i 1]]
1889         if {$max_status_desc < [string length $text]} {
1890                 set max_status_desc [string length $text]
1891         }
1892         set all_descs([lindex $i 0]) $text
1893 }
1894 unset i
1895
1896 ######################################################################
1897 ##
1898 ## util
1899
1900 proc scrollbar2many {list mode args} {
1901         foreach w $list {eval $w $mode $args}
1902 }
1903
1904 proc many2scrollbar {list mode sb top bottom} {
1905         $sb set $top $bottom
1906         foreach w $list {$w $mode moveto $top}
1907 }
1908
1909 proc incr_font_size {font {amt 1}} {
1910         set sz [font configure $font -size]
1911         incr sz $amt
1912         font configure $font -size $sz
1913         font configure ${font}bold -size $sz
1914         font configure ${font}italic -size $sz
1915 }
1916
1917 ######################################################################
1918 ##
1919 ## ui commands
1920
1921 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1922
1923 proc do_gitk {revs} {
1924         # -- Always start gitk through whatever we were loaded with.  This
1925         #    lets us bypass using shell process on Windows systems.
1926         #
1927         set exe [_which gitk -script]
1928         set cmd [list [info nameofexecutable] $exe]
1929         if {$exe eq {}} {
1930                 error_popup [mc "Couldn't find gitk in PATH"]
1931         } else {
1932                 global env
1933
1934                 if {[info exists env(GIT_DIR)]} {
1935                         set old_GIT_DIR $env(GIT_DIR)
1936                 } else {
1937                         set old_GIT_DIR {}
1938                 }
1939
1940                 set pwd [pwd]
1941                 cd [file dirname [gitdir]]
1942                 set env(GIT_DIR) [file tail [gitdir]]
1943
1944                 eval exec $cmd $revs "--" "--" &
1945
1946                 if {$old_GIT_DIR eq {}} {
1947                         unset env(GIT_DIR)
1948                 } else {
1949                         set env(GIT_DIR) $old_GIT_DIR
1950                 }
1951                 cd $pwd
1952
1953                 ui_status $::starting_gitk_msg
1954                 after 10000 {
1955                         ui_ready $starting_gitk_msg
1956                 }
1957         }
1958 }
1959
1960 proc do_explore {} {
1961         set explorer {}
1962         if {[is_Cygwin] || [is_Windows]} {
1963                 set explorer "explorer.exe"
1964         } elseif {[is_MacOSX]} {
1965                 set explorer "open"
1966         } else {
1967                 # freedesktop.org-conforming system is our best shot
1968                 set explorer "xdg-open"
1969         }
1970         eval exec $explorer [list [file nativename [file dirname [gitdir]]]] &
1971 }
1972
1973 set is_quitting 0
1974 set ret_code    1
1975
1976 proc terminate_me {win} {
1977         global ret_code
1978         if {$win ne {.}} return
1979         exit $ret_code
1980 }
1981
1982 proc do_quit {{rc {1}}} {
1983         global ui_comm is_quitting repo_config commit_type
1984         global GITGUI_BCK_exists GITGUI_BCK_i
1985         global ui_comm_spell
1986         global ret_code
1987
1988         if {$is_quitting} return
1989         set is_quitting 1
1990
1991         if {[winfo exists $ui_comm]} {
1992                 # -- Stash our current commit buffer.
1993                 #
1994                 set save [gitdir GITGUI_MSG]
1995                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1996                         file rename -force [gitdir GITGUI_BCK] $save
1997                         set GITGUI_BCK_exists 0
1998                 } else {
1999                         set msg [string trim [$ui_comm get 0.0 end]]
2000                         regsub -all -line {[ \r\t]+$} $msg {} msg
2001                         if {(![string match amend* $commit_type]
2002                                 || [$ui_comm edit modified])
2003                                 && $msg ne {}} {
2004                                 catch {
2005                                         set fd [open $save w]
2006                                         puts -nonewline $fd $msg
2007                                         close $fd
2008                                 }
2009                         } else {
2010                                 catch {file delete $save}
2011                         }
2012                 }
2013
2014                 # -- Cancel our spellchecker if its running.
2015                 #
2016                 if {[info exists ui_comm_spell]} {
2017                         $ui_comm_spell stop
2018                 }
2019
2020                 # -- Remove our editor backup, its not needed.
2021                 #
2022                 after cancel $GITGUI_BCK_i
2023                 if {$GITGUI_BCK_exists} {
2024                         catch {file delete [gitdir GITGUI_BCK]}
2025                 }
2026
2027                 # -- Stash our current window geometry into this repository.
2028                 #
2029                 set cfg_wmstate [wm state .]
2030                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2031                         set rc_wmstate {}
2032                 }
2033                 if {$cfg_wmstate ne $rc_wmstate} {
2034                         catch {git config gui.wmstate $cfg_wmstate}
2035                 }
2036                 if {$cfg_wmstate eq {zoomed}} {
2037                         # on Windows wm geometry will lie about window
2038                         # position (but not size) when window is zoomed
2039                         # restore the window before querying wm geometry
2040                         wm state . normal
2041                 }
2042                 set cfg_geometry [list]
2043                 lappend cfg_geometry [wm geometry .]
2044                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2045                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2046                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2047                         set rc_geometry {}
2048                 }
2049                 if {$cfg_geometry ne $rc_geometry} {
2050                         catch {git config gui.geometry $cfg_geometry}
2051                 }
2052         }
2053
2054         set ret_code $rc
2055
2056         # Briefly enable send again, working around Tk bug
2057         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2058         tk appname [appname]
2059
2060         destroy .
2061 }
2062
2063 proc do_rescan {} {
2064         rescan ui_ready
2065 }
2066
2067 proc ui_do_rescan {} {
2068         rescan {force_first_diff ui_ready}
2069 }
2070
2071 proc do_commit {} {
2072         commit_tree
2073 }
2074
2075 proc next_diff {{after {}}} {
2076         global next_diff_p next_diff_w next_diff_i
2077         show_diff $next_diff_p $next_diff_w {} {} $after
2078 }
2079
2080 proc find_anchor_pos {lst name} {
2081         set lid [lsearch -sorted -exact $lst $name]
2082
2083         if {$lid == -1} {
2084                 set lid 0
2085                 foreach lname $lst {
2086                         if {$lname >= $name} break
2087                         incr lid
2088                 }
2089         }
2090
2091         return $lid
2092 }
2093
2094 proc find_file_from {flist idx delta path mmask} {
2095         global file_states
2096
2097         set len [llength $flist]
2098         while {$idx >= 0 && $idx < $len} {
2099                 set name [lindex $flist $idx]
2100
2101                 if {$name ne $path && [info exists file_states($name)]} {
2102                         set state [lindex $file_states($name) 0]
2103
2104                         if {$mmask eq {} || [regexp $mmask $state]} {
2105                                 return $idx
2106                         }
2107                 }
2108
2109                 incr idx $delta
2110         }
2111
2112         return {}
2113 }
2114
2115 proc find_next_diff {w path {lno {}} {mmask {}}} {
2116         global next_diff_p next_diff_w next_diff_i
2117         global file_lists ui_index ui_workdir
2118
2119         set flist $file_lists($w)
2120         if {$lno eq {}} {
2121                 set lno [find_anchor_pos $flist $path]
2122         } else {
2123                 incr lno -1
2124         }
2125
2126         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2127                 if {$w eq $ui_index} {
2128                         set mmask "^$mmask"
2129                 } else {
2130                         set mmask "$mmask\$"
2131                 }
2132         }
2133
2134         set idx [find_file_from $flist $lno 1 $path $mmask]
2135         if {$idx eq {}} {
2136                 incr lno -1
2137                 set idx [find_file_from $flist $lno -1 $path $mmask]
2138         }
2139
2140         if {$idx ne {}} {
2141                 set next_diff_w $w
2142                 set next_diff_p [lindex $flist $idx]
2143                 set next_diff_i [expr {$idx+1}]
2144                 return 1
2145         } else {
2146                 return 0
2147         }
2148 }
2149
2150 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2151         global current_diff_path
2152
2153         if {$path ne $current_diff_path} {
2154                 return {}
2155         } elseif {[find_next_diff $w $path $lno $mmask]} {
2156                 return {next_diff;}
2157         } else {
2158                 return {reshow_diff;}
2159         }
2160 }
2161
2162 proc select_first_diff {after} {
2163         global ui_workdir
2164
2165         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2166             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2167                 next_diff $after
2168         } else {
2169                 uplevel #0 $after
2170         }
2171 }
2172
2173 proc force_first_diff {after} {
2174         global ui_workdir current_diff_path file_states
2175
2176         if {[info exists file_states($current_diff_path)]} {
2177                 set state [lindex $file_states($current_diff_path) 0]
2178         } else {
2179                 set state {OO}
2180         }
2181
2182         set reselect 0
2183         if {[string first {U} $state] >= 0} {
2184                 # Already a conflict, do nothing
2185         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2186                 set reselect 1
2187         } elseif {[string index $state 1] ne {O}} {
2188                 # Already a diff & no conflicts, do nothing
2189         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2190                 set reselect 1
2191         }
2192
2193         if {$reselect} {
2194                 next_diff $after
2195         } else {
2196                 uplevel #0 $after
2197         }
2198 }
2199
2200 proc toggle_or_diff {w x y} {
2201         global file_states file_lists current_diff_path ui_index ui_workdir
2202         global last_clicked selected_paths
2203
2204         set pos [split [$w index @$x,$y] .]
2205         set lno [lindex $pos 0]
2206         set col [lindex $pos 1]
2207         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2208         if {$path eq {}} {
2209                 set last_clicked {}
2210                 return
2211         }
2212
2213         set last_clicked [list $w $lno]
2214         array unset selected_paths
2215         $ui_index tag remove in_sel 0.0 end
2216         $ui_workdir tag remove in_sel 0.0 end
2217
2218         # Determine the state of the file
2219         if {[info exists file_states($path)]} {
2220                 set state [lindex $file_states($path) 0]
2221         } else {
2222                 set state {__}
2223         }
2224
2225         # Restage the file, or simply show the diff
2226         if {$col == 0 && $y > 1} {
2227                 # Conflicts need special handling
2228                 if {[string first {U} $state] >= 0} {
2229                         # $w must always be $ui_workdir, but...
2230                         if {$w ne $ui_workdir} { set lno {} }
2231                         merge_stage_workdir $path $lno
2232                         return
2233                 }
2234
2235                 if {[string index $state 1] eq {O}} {
2236                         set mmask {}
2237                 } else {
2238                         set mmask {[^O]}
2239                 }
2240
2241                 set after [next_diff_after_action $w $path $lno $mmask]
2242
2243                 if {$w eq $ui_index} {
2244                         update_indexinfo \
2245                                 "Unstaging [short_path $path] from commit" \
2246                                 [list $path] \
2247                                 [concat $after [list ui_ready]]
2248                 } elseif {$w eq $ui_workdir} {
2249                         update_index \
2250                                 "Adding [short_path $path]" \
2251                                 [list $path] \
2252                                 [concat $after [list ui_ready]]
2253                 }
2254         } else {
2255                 show_diff $path $w $lno
2256         }
2257 }
2258
2259 proc add_one_to_selection {w x y} {
2260         global file_lists last_clicked selected_paths
2261
2262         set lno [lindex [split [$w index @$x,$y] .] 0]
2263         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2264         if {$path eq {}} {
2265                 set last_clicked {}
2266                 return
2267         }
2268
2269         if {$last_clicked ne {}
2270                 && [lindex $last_clicked 0] ne $w} {
2271                 array unset selected_paths
2272                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2273         }
2274
2275         set last_clicked [list $w $lno]
2276         if {[catch {set in_sel $selected_paths($path)}]} {
2277                 set in_sel 0
2278         }
2279         if {$in_sel} {
2280                 unset selected_paths($path)
2281                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2282         } else {
2283                 set selected_paths($path) 1
2284                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2285         }
2286 }
2287
2288 proc add_range_to_selection {w x y} {
2289         global file_lists last_clicked selected_paths
2290
2291         if {[lindex $last_clicked 0] ne $w} {
2292                 toggle_or_diff $w $x $y
2293                 return
2294         }
2295
2296         set lno [lindex [split [$w index @$x,$y] .] 0]
2297         set lc [lindex $last_clicked 1]
2298         if {$lc < $lno} {
2299                 set begin $lc
2300                 set end $lno
2301         } else {
2302                 set begin $lno
2303                 set end $lc
2304         }
2305
2306         foreach path [lrange $file_lists($w) \
2307                 [expr {$begin - 1}] \
2308                 [expr {$end - 1}]] {
2309                 set selected_paths($path) 1
2310         }
2311         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2312 }
2313
2314 proc show_more_context {} {
2315         global repo_config
2316         if {$repo_config(gui.diffcontext) < 99} {
2317                 incr repo_config(gui.diffcontext)
2318                 reshow_diff
2319         }
2320 }
2321
2322 proc show_less_context {} {
2323         global repo_config
2324         if {$repo_config(gui.diffcontext) > 1} {
2325                 incr repo_config(gui.diffcontext) -1
2326                 reshow_diff
2327         }
2328 }
2329
2330 ######################################################################
2331 ##
2332 ## ui construction
2333
2334 load_config 0
2335 apply_config
2336 set ui_comm {}
2337
2338 # -- Menu Bar
2339 #
2340 menu .mbar -tearoff 0
2341 if {[is_MacOSX]} {
2342         # -- Apple Menu (Mac OS X only)
2343         #
2344         .mbar add cascade -label Apple -menu .mbar.apple
2345         menu .mbar.apple
2346 }
2347 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2348 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2349 if {[is_enabled branch]} {
2350         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2351 }
2352 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2353         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2354 }
2355 if {[is_enabled transport]} {
2356         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2357         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2358 }
2359 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2360         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2361 }
2362
2363 # -- Repository Menu
2364 #
2365 menu .mbar.repository
2366
2367 .mbar.repository add command \
2368         -label [mc "Explore Working Copy"] \
2369         -command {do_explore}
2370 .mbar.repository add separator
2371
2372 .mbar.repository add command \
2373         -label [mc "Browse Current Branch's Files"] \
2374         -command {browser::new $current_branch}
2375 set ui_browse_current [.mbar.repository index last]
2376 .mbar.repository add command \
2377         -label [mc "Browse Branch Files..."] \
2378         -command browser_open::dialog
2379 .mbar.repository add separator
2380
2381 .mbar.repository add command \
2382         -label [mc "Visualize Current Branch's History"] \
2383         -command {do_gitk $current_branch}
2384 set ui_visualize_current [.mbar.repository index last]
2385 .mbar.repository add command \
2386         -label [mc "Visualize All Branch History"] \
2387         -command {do_gitk --all}
2388 .mbar.repository add separator
2389
2390 proc current_branch_write {args} {
2391         global current_branch
2392         .mbar.repository entryconf $::ui_browse_current \
2393                 -label [mc "Browse %s's Files" $current_branch]
2394         .mbar.repository entryconf $::ui_visualize_current \
2395                 -label [mc "Visualize %s's History" $current_branch]
2396 }
2397 trace add variable current_branch write current_branch_write
2398
2399 if {[is_enabled multicommit]} {
2400         .mbar.repository add command -label [mc "Database Statistics"] \
2401                 -command do_stats
2402
2403         .mbar.repository add command -label [mc "Compress Database"] \
2404                 -command do_gc
2405
2406         .mbar.repository add command -label [mc "Verify Database"] \
2407                 -command do_fsck_objects
2408
2409         .mbar.repository add separator
2410
2411         if {[is_Cygwin]} {
2412                 .mbar.repository add command \
2413                         -label [mc "Create Desktop Icon"] \
2414                         -command do_cygwin_shortcut
2415         } elseif {[is_Windows]} {
2416                 .mbar.repository add command \
2417                         -label [mc "Create Desktop Icon"] \
2418                         -command do_windows_shortcut
2419         } elseif {[is_MacOSX]} {
2420                 .mbar.repository add command \
2421                         -label [mc "Create Desktop Icon"] \
2422                         -command do_macosx_app
2423         }
2424 }
2425
2426 if {[is_MacOSX]} {
2427         proc ::tk::mac::Quit {args} { do_quit }
2428 } else {
2429         .mbar.repository add command -label [mc Quit] \
2430                 -command do_quit \
2431                 -accelerator $M1T-Q
2432 }
2433
2434 # -- Edit Menu
2435 #
2436 menu .mbar.edit
2437 .mbar.edit add command -label [mc Undo] \
2438         -command {catch {[focus] edit undo}} \
2439         -accelerator $M1T-Z
2440 .mbar.edit add command -label [mc Redo] \
2441         -command {catch {[focus] edit redo}} \
2442         -accelerator $M1T-Y
2443 .mbar.edit add separator
2444 .mbar.edit add command -label [mc Cut] \
2445         -command {catch {tk_textCut [focus]}} \
2446         -accelerator $M1T-X
2447 .mbar.edit add command -label [mc Copy] \
2448         -command {catch {tk_textCopy [focus]}} \
2449         -accelerator $M1T-C
2450 .mbar.edit add command -label [mc Paste] \
2451         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2452         -accelerator $M1T-V
2453 .mbar.edit add command -label [mc Delete] \
2454         -command {catch {[focus] delete sel.first sel.last}} \
2455         -accelerator Del
2456 .mbar.edit add separator
2457 .mbar.edit add command -label [mc "Select All"] \
2458         -command {catch {[focus] tag add sel 0.0 end}} \
2459         -accelerator $M1T-A
2460
2461 # -- Branch Menu
2462 #
2463 if {[is_enabled branch]} {
2464         menu .mbar.branch
2465
2466         .mbar.branch add command -label [mc "Create..."] \
2467                 -command branch_create::dialog \
2468                 -accelerator $M1T-N
2469         lappend disable_on_lock [list .mbar.branch entryconf \
2470                 [.mbar.branch index last] -state]
2471
2472         .mbar.branch add command -label [mc "Checkout..."] \
2473                 -command branch_checkout::dialog \
2474                 -accelerator $M1T-O
2475         lappend disable_on_lock [list .mbar.branch entryconf \
2476                 [.mbar.branch index last] -state]
2477
2478         .mbar.branch add command -label [mc "Rename..."] \
2479                 -command branch_rename::dialog
2480         lappend disable_on_lock [list .mbar.branch entryconf \
2481                 [.mbar.branch index last] -state]
2482
2483         .mbar.branch add command -label [mc "Delete..."] \
2484                 -command branch_delete::dialog
2485         lappend disable_on_lock [list .mbar.branch entryconf \
2486                 [.mbar.branch index last] -state]
2487
2488         .mbar.branch add command -label [mc "Reset..."] \
2489                 -command merge::reset_hard
2490         lappend disable_on_lock [list .mbar.branch entryconf \
2491                 [.mbar.branch index last] -state]
2492 }
2493
2494 # -- Commit Menu
2495 #
2496 proc commit_btn_caption {} {
2497         if {[is_enabled nocommit]} {
2498                 return [mc "Done"]
2499         } else {
2500                 return [mc Commit@@verb]
2501         }
2502 }
2503
2504 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2505         menu .mbar.commit
2506
2507         if {![is_enabled nocommit]} {
2508                 .mbar.commit add radiobutton \
2509                         -label [mc "New Commit"] \
2510                         -command do_select_commit_type \
2511                         -variable selected_commit_type \
2512                         -value new
2513                 lappend disable_on_lock \
2514                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2515
2516                 .mbar.commit add radiobutton \
2517                         -label [mc "Amend Last Commit"] \
2518                         -command do_select_commit_type \
2519                         -variable selected_commit_type \
2520                         -value amend
2521                 lappend disable_on_lock \
2522                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2523
2524                 .mbar.commit add separator
2525         }
2526
2527         .mbar.commit add command -label [mc Rescan] \
2528                 -command ui_do_rescan \
2529                 -accelerator F5
2530         lappend disable_on_lock \
2531                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2532
2533         .mbar.commit add command -label [mc "Stage To Commit"] \
2534                 -command do_add_selection \
2535                 -accelerator $M1T-T
2536         lappend disable_on_lock \
2537                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2538
2539         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2540                 -command do_add_all \
2541                 -accelerator $M1T-I
2542         lappend disable_on_lock \
2543                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2544
2545         .mbar.commit add command -label [mc "Unstage From Commit"] \
2546                 -command do_unstage_selection \
2547                 -accelerator $M1T-U
2548         lappend disable_on_lock \
2549                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2550
2551         .mbar.commit add command -label [mc "Revert Changes"] \
2552                 -command do_revert_selection \
2553                 -accelerator $M1T-J
2554         lappend disable_on_lock \
2555                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2556
2557         .mbar.commit add separator
2558
2559         .mbar.commit add command -label [mc "Show Less Context"] \
2560                 -command show_less_context \
2561                 -accelerator $M1T-\-
2562
2563         .mbar.commit add command -label [mc "Show More Context"] \
2564                 -command show_more_context \
2565                 -accelerator $M1T-=
2566
2567         .mbar.commit add separator
2568
2569         if {![is_enabled nocommitmsg]} {
2570                 .mbar.commit add command -label [mc "Sign Off"] \
2571                         -command do_signoff \
2572                         -accelerator $M1T-S
2573         }
2574
2575         .mbar.commit add command -label [commit_btn_caption] \
2576                 -command do_commit \
2577                 -accelerator $M1T-Return
2578         lappend disable_on_lock \
2579                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2580 }
2581
2582 # -- Merge Menu
2583 #
2584 if {[is_enabled branch]} {
2585         menu .mbar.merge
2586         .mbar.merge add command -label [mc "Local Merge..."] \
2587                 -command merge::dialog \
2588                 -accelerator $M1T-M
2589         lappend disable_on_lock \
2590                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2591         .mbar.merge add command -label [mc "Abort Merge..."] \
2592                 -command merge::reset_hard
2593         lappend disable_on_lock \
2594                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2595 }
2596
2597 # -- Transport Menu
2598 #
2599 if {[is_enabled transport]} {
2600         menu .mbar.remote
2601
2602         .mbar.remote add command \
2603                 -label [mc "Add..."] \
2604                 -command remote_add::dialog \
2605                 -accelerator $M1T-A
2606         .mbar.remote add command \
2607                 -label [mc "Push..."] \
2608                 -command do_push_anywhere \
2609                 -accelerator $M1T-P
2610         .mbar.remote add command \
2611                 -label [mc "Delete Branch..."] \
2612                 -command remote_branch_delete::dialog
2613 }
2614
2615 if {[is_MacOSX]} {
2616         proc ::tk::mac::ShowPreferences {} {do_options}
2617 } else {
2618         # -- Edit Menu
2619         #
2620         .mbar.edit add separator
2621         .mbar.edit add command -label [mc "Options..."] \
2622                 -command do_options
2623 }
2624
2625 # -- Tools Menu
2626 #
2627 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2628         set tools_menubar .mbar.tools
2629         menu $tools_menubar
2630         $tools_menubar add separator
2631         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2632         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2633         set tools_tailcnt 3
2634         if {[array names repo_config guitool.*.cmd] ne {}} {
2635                 tools_populate_all
2636         }
2637 }
2638
2639 # -- Help Menu
2640 #
2641 .mbar add cascade -label [mc Help] -menu .mbar.help
2642 menu .mbar.help
2643
2644 if {[is_MacOSX]} {
2645         .mbar.apple add command -label [mc "About %s" [appname]] \
2646                 -command do_about
2647         .mbar.apple add separator
2648 } else {
2649         .mbar.help add command -label [mc "About %s" [appname]] \
2650                 -command do_about
2651 }
2652 . configure -menu .mbar
2653
2654 set doc_path [githtmldir]
2655 if {$doc_path ne {}} {
2656         set doc_path [file join $doc_path index.html]
2657
2658         if {[is_Cygwin]} {
2659                 set doc_path [exec cygpath --mixed $doc_path]
2660         }
2661 }
2662
2663 if {[file isfile $doc_path]} {
2664         set doc_url "file:$doc_path"
2665 } else {
2666         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2667 }
2668
2669 proc start_browser {url} {
2670         git "web--browse" $url
2671 }
2672
2673 .mbar.help add command -label [mc "Online Documentation"] \
2674         -command [list start_browser $doc_url]
2675
2676 .mbar.help add command -label [mc "Show SSH Key"] \
2677         -command do_ssh_key
2678
2679 unset doc_path doc_url
2680
2681 # -- Standard bindings
2682 #
2683 wm protocol . WM_DELETE_WINDOW do_quit
2684 bind all <$M1B-Key-q> do_quit
2685 bind all <$M1B-Key-Q> do_quit
2686 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2687 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2688
2689 set subcommand_args {}
2690 proc usage {} {
2691         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2692         exit 1
2693 }
2694
2695 proc normalize_relpath {path} {
2696         set elements {}
2697         foreach item [file split $path] {
2698                 if {$item eq {.}} continue
2699                 if {$item eq {..} && [llength $elements] > 0
2700                     && [lindex $elements end] ne {..}} {
2701                         set elements [lrange $elements 0 end-1]
2702                         continue
2703                 }
2704                 lappend elements $item
2705         }
2706         return [eval file join $elements]
2707 }
2708
2709 # -- Not a normal commit type invocation?  Do that instead!
2710 #
2711 switch -- $subcommand {
2712 browser -
2713 blame {
2714         if {$subcommand eq "blame"} {
2715                 set subcommand_args {[--line=<num>] rev? path}
2716         } else {
2717                 set subcommand_args {rev? path}
2718         }
2719         if {$argv eq {}} usage
2720         set head {}
2721         set path {}
2722         set jump_spec {}
2723         set is_path 0
2724         foreach a $argv {
2725                 if {$is_path || [file exists $_prefix$a]} {
2726                         if {$path ne {}} usage
2727                         set path [normalize_relpath $_prefix$a]
2728                         break
2729                 } elseif {$a eq {--}} {
2730                         if {$path ne {}} {
2731                                 if {$head ne {}} usage
2732                                 set head $path
2733                                 set path {}
2734                         }
2735                         set is_path 1
2736                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2737                         if {$jump_spec ne {} || $head ne {}} usage
2738                         set jump_spec [list $lnum]
2739                 } elseif {$head eq {}} {
2740                         if {$head ne {}} usage
2741                         set head $a
2742                         set is_path 1
2743                 } else {
2744                         usage
2745                 }
2746         }
2747         unset is_path
2748
2749         if {$head ne {} && $path eq {}} {
2750                 set path [normalize_relpath $_prefix$head]
2751                 set head {}
2752         }
2753
2754         if {$head eq {}} {
2755                 load_current_branch
2756         } else {
2757                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2758                         if {[catch {
2759                                         set head [git rev-parse --verify $head]
2760                                 } err]} {
2761                                 puts stderr $err
2762                                 exit 1
2763                         }
2764                 }
2765                 set current_branch $head
2766         }
2767
2768         switch -- $subcommand {
2769         browser {
2770                 if {$jump_spec ne {}} usage
2771                 if {$head eq {}} {
2772                         if {$path ne {} && [file isdirectory $path]} {
2773                                 set head $current_branch
2774                         } else {
2775                                 set head $path
2776                                 set path {}
2777                         }
2778                 }
2779                 browser::new $head $path
2780         }
2781         blame   {
2782                 if {$head eq {} && ![file exists $path]} {
2783                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2784                         exit 1
2785                 }
2786                 blame::new $head $path $jump_spec
2787         }
2788         }
2789         return
2790 }
2791 citool -
2792 gui {
2793         if {[llength $argv] != 0} {
2794                 puts -nonewline stderr "usage: $argv0"
2795                 if {$subcommand ne {gui}
2796                         && [file tail $argv0] ne "git-$subcommand"} {
2797                         puts -nonewline stderr " $subcommand"
2798                 }
2799                 puts stderr {}
2800                 exit 1
2801         }
2802         # fall through to setup UI for commits
2803 }
2804 default {
2805         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2806         exit 1
2807 }
2808 }
2809
2810 # -- Branch Control
2811 #
2812 frame .branch \
2813         -borderwidth 1 \
2814         -relief sunken
2815 label .branch.l1 \
2816         -text [mc "Current Branch:"] \
2817         -anchor w \
2818         -justify left
2819 label .branch.cb \
2820         -textvariable current_branch \
2821         -anchor w \
2822         -justify left
2823 pack .branch.l1 -side left
2824 pack .branch.cb -side left -fill x
2825 pack .branch -side top -fill x
2826
2827 # -- Main Window Layout
2828 #
2829 panedwindow .vpane -orient horizontal
2830 panedwindow .vpane.files -orient vertical
2831 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2832 pack .vpane -anchor n -side top -fill both -expand 1
2833
2834 # -- Index File List
2835 #
2836 frame .vpane.files.index -height 100 -width 200
2837 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2838         -background lightgreen -foreground black
2839 text $ui_index -background white -foreground black \
2840         -borderwidth 0 \
2841         -width 20 -height 10 \
2842         -wrap none \
2843         -cursor $cursor_ptr \
2844         -xscrollcommand {.vpane.files.index.sx set} \
2845         -yscrollcommand {.vpane.files.index.sy set} \
2846         -state disabled
2847 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2848 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2849 pack .vpane.files.index.title -side top -fill x
2850 pack .vpane.files.index.sx -side bottom -fill x
2851 pack .vpane.files.index.sy -side right -fill y
2852 pack $ui_index -side left -fill both -expand 1
2853
2854 # -- Working Directory File List
2855 #
2856 frame .vpane.files.workdir -height 100 -width 200
2857 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2858         -background lightsalmon -foreground black
2859 text $ui_workdir -background white -foreground black \
2860         -borderwidth 0 \
2861         -width 20 -height 10 \
2862         -wrap none \
2863         -cursor $cursor_ptr \
2864         -xscrollcommand {.vpane.files.workdir.sx set} \
2865         -yscrollcommand {.vpane.files.workdir.sy set} \
2866         -state disabled
2867 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2868 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2869 pack .vpane.files.workdir.title -side top -fill x
2870 pack .vpane.files.workdir.sx -side bottom -fill x
2871 pack .vpane.files.workdir.sy -side right -fill y
2872 pack $ui_workdir -side left -fill both -expand 1
2873
2874 .vpane.files add .vpane.files.workdir -sticky nsew
2875 .vpane.files add .vpane.files.index -sticky nsew
2876
2877 foreach i [list $ui_index $ui_workdir] {
2878         rmsel_tag $i
2879         $i tag conf in_diff -background [$i tag cget in_sel -background]
2880 }
2881 unset i
2882
2883 # -- Diff and Commit Area
2884 #
2885 frame .vpane.lower -height 300 -width 400
2886 frame .vpane.lower.commarea
2887 frame .vpane.lower.diff -relief sunken -borderwidth 1
2888 pack .vpane.lower.diff -fill both -expand 1
2889 pack .vpane.lower.commarea -side bottom -fill x
2890 .vpane add .vpane.lower -sticky nsew
2891
2892 # -- Commit Area Buttons
2893 #
2894 frame .vpane.lower.commarea.buttons
2895 label .vpane.lower.commarea.buttons.l -text {} \
2896         -anchor w \
2897         -justify left
2898 pack .vpane.lower.commarea.buttons.l -side top -fill x
2899 pack .vpane.lower.commarea.buttons -side left -fill y
2900
2901 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2902         -command ui_do_rescan
2903 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2904 lappend disable_on_lock \
2905         {.vpane.lower.commarea.buttons.rescan conf -state}
2906
2907 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2908         -command do_add_all
2909 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2910 lappend disable_on_lock \
2911         {.vpane.lower.commarea.buttons.incall conf -state}
2912
2913 if {![is_enabled nocommitmsg]} {
2914         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2915                 -command do_signoff
2916         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2917 }
2918
2919 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2920         -command do_commit
2921 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2922 lappend disable_on_lock \
2923         {.vpane.lower.commarea.buttons.commit conf -state}
2924
2925 if {![is_enabled nocommit]} {
2926         button .vpane.lower.commarea.buttons.push -text [mc Push] \
2927                 -command do_push_anywhere
2928         pack .vpane.lower.commarea.buttons.push -side top -fill x
2929 }
2930
2931 # -- Commit Message Buffer
2932 #
2933 frame .vpane.lower.commarea.buffer
2934 frame .vpane.lower.commarea.buffer.header
2935 set ui_comm .vpane.lower.commarea.buffer.t
2936 set ui_coml .vpane.lower.commarea.buffer.header.l
2937
2938 if {![is_enabled nocommit]} {
2939         radiobutton .vpane.lower.commarea.buffer.header.new \
2940                 -text [mc "New Commit"] \
2941                 -command do_select_commit_type \
2942                 -variable selected_commit_type \
2943                 -value new
2944         lappend disable_on_lock \
2945                 [list .vpane.lower.commarea.buffer.header.new conf -state]
2946         radiobutton .vpane.lower.commarea.buffer.header.amend \
2947                 -text [mc "Amend Last Commit"] \
2948                 -command do_select_commit_type \
2949                 -variable selected_commit_type \
2950                 -value amend
2951         lappend disable_on_lock \
2952                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
2953 }
2954
2955 label $ui_coml \
2956         -anchor w \
2957         -justify left
2958 proc trace_commit_type {varname args} {
2959         global ui_coml commit_type
2960         switch -glob -- $commit_type {
2961         initial       {set txt [mc "Initial Commit Message:"]}
2962         amend         {set txt [mc "Amended Commit Message:"]}
2963         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2964         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2965         merge         {set txt [mc "Merge Commit Message:"]}
2966         *             {set txt [mc "Commit Message:"]}
2967         }
2968         $ui_coml conf -text $txt
2969 }
2970 trace add variable commit_type write trace_commit_type
2971 pack $ui_coml -side left -fill x
2972
2973 if {![is_enabled nocommit]} {
2974         pack .vpane.lower.commarea.buffer.header.amend -side right
2975         pack .vpane.lower.commarea.buffer.header.new -side right
2976 }
2977
2978 text $ui_comm -background white -foreground black \
2979         -borderwidth 1 \
2980         -undo true \
2981         -maxundo 20 \
2982         -autoseparators true \
2983         -relief sunken \
2984         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2985         -font font_diff \
2986         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2987 scrollbar .vpane.lower.commarea.buffer.sby \
2988         -command [list $ui_comm yview]
2989 pack .vpane.lower.commarea.buffer.header -side top -fill x
2990 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2991 pack $ui_comm -side left -fill y
2992 pack .vpane.lower.commarea.buffer -side left -fill y
2993
2994 # -- Commit Message Buffer Context Menu
2995 #
2996 set ctxm .vpane.lower.commarea.buffer.ctxm
2997 menu $ctxm -tearoff 0
2998 $ctxm add command \
2999         -label [mc Cut] \
3000         -command {tk_textCut $ui_comm}
3001 $ctxm add command \
3002         -label [mc Copy] \
3003         -command {tk_textCopy $ui_comm}
3004 $ctxm add command \
3005         -label [mc Paste] \
3006         -command {tk_textPaste $ui_comm}
3007 $ctxm add command \
3008         -label [mc Delete] \
3009         -command {catch {$ui_comm delete sel.first sel.last}}
3010 $ctxm add separator
3011 $ctxm add command \
3012         -label [mc "Select All"] \
3013         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3014 $ctxm add command \
3015         -label [mc "Copy All"] \
3016         -command {
3017                 $ui_comm tag add sel 0.0 end
3018                 tk_textCopy $ui_comm
3019                 $ui_comm tag remove sel 0.0 end
3020         }
3021 $ctxm add separator
3022 $ctxm add command \
3023         -label [mc "Sign Off"] \
3024         -command do_signoff
3025 set ui_comm_ctxm $ctxm
3026
3027 # -- Diff Header
3028 #
3029 proc trace_current_diff_path {varname args} {
3030         global current_diff_path diff_actions file_states
3031         if {$current_diff_path eq {}} {
3032                 set s {}
3033                 set f {}
3034                 set p {}
3035                 set o disabled
3036         } else {
3037                 set p $current_diff_path
3038                 set s [mapdesc [lindex $file_states($p) 0] $p]
3039                 set f [mc "File:"]
3040                 set p [escape_path $p]
3041                 set o normal
3042         }
3043
3044         .vpane.lower.diff.header.status configure -text $s
3045         .vpane.lower.diff.header.file configure -text $f
3046         .vpane.lower.diff.header.path configure -text $p
3047         foreach w $diff_actions {
3048                 uplevel #0 $w $o
3049         }
3050 }
3051 trace add variable current_diff_path write trace_current_diff_path
3052
3053 frame .vpane.lower.diff.header -background gold
3054 label .vpane.lower.diff.header.status \
3055         -background gold \
3056         -foreground black \
3057         -width $max_status_desc \
3058         -anchor w \
3059         -justify left
3060 label .vpane.lower.diff.header.file \
3061         -background gold \
3062         -foreground black \
3063         -anchor w \
3064         -justify left
3065 label .vpane.lower.diff.header.path \
3066         -background gold \
3067         -foreground black \
3068         -anchor w \
3069         -justify left
3070 pack .vpane.lower.diff.header.status -side left
3071 pack .vpane.lower.diff.header.file -side left
3072 pack .vpane.lower.diff.header.path -fill x
3073 set ctxm .vpane.lower.diff.header.ctxm
3074 menu $ctxm -tearoff 0
3075 $ctxm add command \
3076         -label [mc Copy] \
3077         -command {
3078                 clipboard clear
3079                 clipboard append \
3080                         -format STRING \
3081                         -type STRING \
3082                         -- $current_diff_path
3083         }
3084 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3085 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3086
3087 # -- Diff Body
3088 #
3089 frame .vpane.lower.diff.body
3090 set ui_diff .vpane.lower.diff.body.t
3091 text $ui_diff -background white -foreground black \
3092         -borderwidth 0 \
3093         -width 80 -height 5 -wrap none \
3094         -font font_diff \
3095         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3096         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3097         -state disabled
3098 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3099         -command [list $ui_diff xview]
3100 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3101         -command [list $ui_diff yview]
3102 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3103 pack .vpane.lower.diff.body.sby -side right -fill y
3104 pack $ui_diff -side left -fill both -expand 1
3105 pack .vpane.lower.diff.header -side top -fill x
3106 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3107
3108 $ui_diff tag conf d_cr -elide true
3109 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
3110 $ui_diff tag conf d_+ -foreground {#00a000}
3111 $ui_diff tag conf d_- -foreground red
3112
3113 $ui_diff tag conf d_++ -foreground {#00a000}
3114 $ui_diff tag conf d_-- -foreground red
3115 $ui_diff tag conf d_+s \
3116         -foreground {#00a000} \
3117         -background {#e2effa}
3118 $ui_diff tag conf d_-s \
3119         -foreground red \
3120         -background {#e2effa}
3121 $ui_diff tag conf d_s+ \
3122         -foreground {#00a000} \
3123         -background ivory1
3124 $ui_diff tag conf d_s- \
3125         -foreground red \
3126         -background ivory1
3127
3128 $ui_diff tag conf d<<<<<<< \
3129         -foreground orange \
3130         -font font_diffbold
3131 $ui_diff tag conf d======= \
3132         -foreground orange \
3133         -font font_diffbold
3134 $ui_diff tag conf d>>>>>>> \
3135         -foreground orange \
3136         -font font_diffbold
3137
3138 $ui_diff tag raise sel
3139
3140 # -- Diff Body Context Menu
3141 #
3142
3143 proc create_common_diff_popup {ctxm} {
3144         $ctxm add command \
3145                 -label [mc "Show Less Context"] \
3146                 -command show_less_context
3147         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3148         $ctxm add command \
3149                 -label [mc "Show More Context"] \
3150                 -command show_more_context
3151         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3152         $ctxm add separator
3153         $ctxm add command \
3154                 -label [mc Refresh] \
3155                 -command reshow_diff
3156         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3157         $ctxm add command \
3158                 -label [mc Copy] \
3159                 -command {tk_textCopy $ui_diff}
3160         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3161         $ctxm add command \
3162                 -label [mc "Select All"] \
3163                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3164         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3165         $ctxm add command \
3166                 -label [mc "Copy All"] \
3167                 -command {
3168                         $ui_diff tag add sel 0.0 end
3169                         tk_textCopy $ui_diff
3170                         $ui_diff tag remove sel 0.0 end
3171                 }
3172         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3173         $ctxm add separator
3174         $ctxm add command \
3175                 -label [mc "Decrease Font Size"] \
3176                 -command {incr_font_size font_diff -1}
3177         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3178         $ctxm add command \
3179                 -label [mc "Increase Font Size"] \
3180                 -command {incr_font_size font_diff 1}
3181         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3182         $ctxm add separator
3183         set emenu $ctxm.enc
3184         menu $emenu
3185         build_encoding_menu $emenu [list force_diff_encoding]
3186         $ctxm add cascade \
3187                 -label [mc "Encoding"] \
3188                 -menu $emenu
3189         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3190         $ctxm add separator
3191         $ctxm add command -label [mc "Options..."] \
3192                 -command do_options
3193 }
3194
3195 set ctxm .vpane.lower.diff.body.ctxm
3196 menu $ctxm -tearoff 0
3197 $ctxm add command \
3198         -label [mc "Apply/Reverse Hunk"] \
3199         -command {apply_hunk $cursorX $cursorY}
3200 set ui_diff_applyhunk [$ctxm index last]
3201 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3202 $ctxm add command \
3203         -label [mc "Apply/Reverse Line"] \
3204         -command {apply_line $cursorX $cursorY; do_rescan}
3205 set ui_diff_applyline [$ctxm index last]
3206 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3207 $ctxm add separator
3208 create_common_diff_popup $ctxm
3209
3210 set ctxmmg .vpane.lower.diff.body.ctxmmg
3211 menu $ctxmmg -tearoff 0
3212 $ctxmmg add command \
3213         -label [mc "Run Merge Tool"] \
3214         -command {merge_resolve_tool}
3215 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3216 $ctxmmg add separator
3217 $ctxmmg add command \
3218         -label [mc "Use Remote Version"] \
3219         -command {merge_resolve_one 3}
3220 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3221 $ctxmmg add command \
3222         -label [mc "Use Local Version"] \
3223         -command {merge_resolve_one 2}
3224 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3225 $ctxmmg add command \
3226         -label [mc "Revert To Base"] \
3227         -command {merge_resolve_one 1}
3228 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3229 $ctxmmg add separator
3230 create_common_diff_popup $ctxmmg
3231
3232 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
3233         global current_diff_path file_states
3234         set ::cursorX $x
3235         set ::cursorY $y
3236         if {[info exists file_states($current_diff_path)]} {
3237                 set state [lindex $file_states($current_diff_path) 0]
3238         } else {
3239                 set state {__}
3240         }
3241         if {[string first {U} $state] >= 0} {
3242                 tk_popup $ctxmmg $X $Y
3243         } else {
3244                 if {$::ui_index eq $::current_diff_side} {
3245                         set l [mc "Unstage Hunk From Commit"]
3246                         set t [mc "Unstage Line From Commit"]
3247                 } else {
3248                         set l [mc "Stage Hunk For Commit"]
3249                         set t [mc "Stage Line For Commit"]
3250                 }
3251                 if {$::is_3way_diff || $::is_submodule_diff
3252                         || $current_diff_path eq {}
3253                         || {__} eq $state
3254                         || {_O} eq $state
3255                         || {_T} eq $state
3256                         || {T_} eq $state} {
3257                         set s disabled
3258                 } else {
3259                         set s normal
3260                 }
3261                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3262                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3263                 tk_popup $ctxm $X $Y
3264         }
3265 }
3266 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3267
3268 # -- Status Bar
3269 #
3270 set main_status [::status_bar::new .status]
3271 pack .status -anchor w -side bottom -fill x
3272 $main_status show [mc "Initializing..."]
3273
3274 # -- Load geometry
3275 #
3276 catch {
3277 set gm $repo_config(gui.geometry)
3278 wm geometry . [lindex $gm 0]
3279 .vpane sash place 0 \
3280         [lindex $gm 1] \
3281         [lindex [.vpane sash coord 0] 1]
3282 .vpane.files sash place 0 \
3283         [lindex [.vpane.files sash coord 0] 0] \
3284         [lindex $gm 2]
3285 unset gm
3286 }
3287
3288 # -- Load window state
3289 #
3290 catch {
3291 set gws $repo_config(gui.wmstate)
3292 wm state . $gws
3293 unset gws
3294 }
3295
3296 # -- Key Bindings
3297 #
3298 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3299 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3300 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3301 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3302 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3303 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3304 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3305 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3306 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3307 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3308 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3309 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3310 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3311 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3312 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3313 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3314 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3315 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3316 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3317 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3318 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3319 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3320
3321 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3322 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3323 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3324 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3325 bind $ui_diff <$M1B-Key-v> {break}
3326 bind $ui_diff <$M1B-Key-V> {break}
3327 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3328 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3329 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3330 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3331 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3332 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3333 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3334 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3335 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3336 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3337 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3338 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3339 bind $ui_diff <Button-1>   {focus %W}
3340
3341 if {[is_enabled branch]} {
3342         bind . <$M1B-Key-n> branch_create::dialog
3343         bind . <$M1B-Key-N> branch_create::dialog
3344         bind . <$M1B-Key-o> branch_checkout::dialog
3345         bind . <$M1B-Key-O> branch_checkout::dialog
3346         bind . <$M1B-Key-m> merge::dialog
3347         bind . <$M1B-Key-M> merge::dialog
3348 }
3349 if {[is_enabled transport]} {
3350         bind . <$M1B-Key-p> do_push_anywhere
3351         bind . <$M1B-Key-P> do_push_anywhere
3352 }
3353
3354 bind .   <Key-F5>     ui_do_rescan
3355 bind .   <$M1B-Key-r> ui_do_rescan
3356 bind .   <$M1B-Key-R> ui_do_rescan
3357 bind .   <$M1B-Key-s> do_signoff
3358 bind .   <$M1B-Key-S> do_signoff
3359 bind .   <$M1B-Key-t> do_add_selection
3360 bind .   <$M1B-Key-T> do_add_selection
3361 bind .   <$M1B-Key-i> do_add_all
3362 bind .   <$M1B-Key-I> do_add_all
3363 bind .   <$M1B-Key-minus> {show_less_context;break}
3364 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3365 bind .   <$M1B-Key-equal> {show_more_context;break}
3366 bind .   <$M1B-Key-plus> {show_more_context;break}
3367 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3368 bind .   <$M1B-Key-Return> do_commit
3369 foreach i [list $ui_index $ui_workdir] {
3370         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3371         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3372         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3373 }
3374 unset i
3375
3376 set file_lists($ui_index) [list]
3377 set file_lists($ui_workdir) [list]
3378
3379 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3380 focus -force $ui_comm
3381
3382 # -- Warn the user about environmental problems.  Cygwin's Tcl
3383 #    does *not* pass its env array onto any processes it spawns.
3384 #    This means that git processes get none of our environment.
3385 #
3386 if {[is_Cygwin]} {
3387         set ignored_env 0
3388         set suggest_user {}
3389         set msg [mc "Possible environment issues exist.
3390
3391 The following environment variables are probably
3392 going to be ignored by any Git subprocess run
3393 by %s:
3394
3395 " [appname]]
3396         foreach name [array names env] {
3397                 switch -regexp -- $name {
3398                 {^GIT_INDEX_FILE$} -
3399                 {^GIT_OBJECT_DIRECTORY$} -
3400                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3401                 {^GIT_DIFF_OPTS$} -
3402                 {^GIT_EXTERNAL_DIFF$} -
3403                 {^GIT_PAGER$} -
3404                 {^GIT_TRACE$} -
3405                 {^GIT_CONFIG$} -
3406                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3407                         append msg " - $name\n"
3408                         incr ignored_env
3409                 }
3410                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3411                         append msg " - $name\n"
3412                         incr ignored_env
3413                         set suggest_user $name
3414                 }
3415                 }
3416         }
3417         if {$ignored_env > 0} {
3418                 append msg [mc "
3419 This is due to a known issue with the
3420 Tcl binary distributed by Cygwin."]
3421
3422                 if {$suggest_user ne {}} {
3423                         append msg [mc "
3424
3425 A good replacement for %s
3426 is placing values for the user.name and
3427 user.email settings into your personal
3428 ~/.gitconfig file.
3429 " $suggest_user]
3430                 }
3431                 warn_popup $msg
3432         }
3433         unset ignored_env msg suggest_user name
3434 }
3435
3436 # -- Only initialize complex UI if we are going to stay running.
3437 #
3438 if {[is_enabled transport]} {
3439         load_all_remotes
3440
3441         set n [.mbar.remote index end]
3442         populate_remotes_menu
3443         set n [expr {[.mbar.remote index end] - $n}]
3444         if {$n > 0} {
3445                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3446                 .mbar.remote insert $n separator
3447         }
3448         unset n
3449 }
3450
3451 if {[winfo exists $ui_comm]} {
3452         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3453
3454         # -- If both our backup and message files exist use the
3455         #    newer of the two files to initialize the buffer.
3456         #
3457         if {$GITGUI_BCK_exists} {
3458                 set m [gitdir GITGUI_MSG]
3459                 if {[file isfile $m]} {
3460                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3461                                 catch {file delete [gitdir GITGUI_MSG]}
3462                         } else {
3463                                 $ui_comm delete 0.0 end
3464                                 $ui_comm edit reset
3465                                 $ui_comm edit modified false
3466                                 catch {file delete [gitdir GITGUI_BCK]}
3467                                 set GITGUI_BCK_exists 0
3468                         }
3469                 }
3470                 unset m
3471         }
3472
3473         proc backup_commit_buffer {} {
3474                 global ui_comm GITGUI_BCK_exists
3475
3476                 set m [$ui_comm edit modified]
3477                 if {$m || $GITGUI_BCK_exists} {
3478                         set msg [string trim [$ui_comm get 0.0 end]]
3479                         regsub -all -line {[ \r\t]+$} $msg {} msg
3480
3481                         if {$msg eq {}} {
3482                                 if {$GITGUI_BCK_exists} {
3483                                         catch {file delete [gitdir GITGUI_BCK]}
3484                                         set GITGUI_BCK_exists 0
3485                                 }
3486                         } elseif {$m} {
3487                                 catch {
3488                                         set fd [open [gitdir GITGUI_BCK] w]
3489                                         puts -nonewline $fd $msg
3490                                         close $fd
3491                                         set GITGUI_BCK_exists 1
3492                                 }
3493                         }
3494
3495                         $ui_comm edit modified false
3496                 }
3497
3498                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3499         }
3500
3501         backup_commit_buffer
3502
3503         # -- If the user has aspell available we can drive it
3504         #    in pipe mode to spellcheck the commit message.
3505         #
3506         set spell_cmd [list |]
3507         set spell_dict [get_config gui.spellingdictionary]
3508         lappend spell_cmd aspell
3509         if {$spell_dict ne {}} {
3510                 lappend spell_cmd --master=$spell_dict
3511         }
3512         lappend spell_cmd --mode=none
3513         lappend spell_cmd --encoding=utf-8
3514         lappend spell_cmd pipe
3515         if {$spell_dict eq {none}
3516          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3517                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3518         } else {
3519                 set ui_comm_spell [spellcheck::init \
3520                         $spell_fd \
3521                         $ui_comm \
3522                         $ui_comm_ctxm \
3523                 ]
3524         }
3525         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3526 }
3527
3528 lock_index begin-read
3529 if {![winfo ismapped .]} {
3530         wm deiconify .
3531 }
3532 after 1 {
3533         if {[is_enabled initialamend]} {
3534                 force_amend
3535         } else {
3536                 do_rescan
3537         }
3538
3539         if {[is_enabled nocommitmsg]} {
3540                 $ui_comm configure -state disabled -background gray
3541         }
3542 }
3543 if {[is_enabled multicommit]} {
3544         after 1000 hint_gc
3545 }
3546 if {[is_enabled retcode]} {
3547         bind . <Destroy> {+terminate_me %W}
3548 }
3549 if {$picked && [is_config_true gui.autoexplore]} {
3550         do_explore
3551 }