git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitworktree {}
 125 set _isbare {}
 126 set _gitexec {}
 127 set _githtmldir {}
 128 set _reponame {}
 129 set _iscygwin {}
 130 set _search_path {}
 131
 132 set _trace [lsearch -exact $argv --trace]
 133 if {$_trace >= 0} {
 134         set argv [lreplace $argv $_trace $_trace]
 135         set _trace 1
 136 } else {
 137         set _trace 0
 138 }
 139
 140 proc appname {} {
 141         global _appname
 142         return $_appname
 143 }
 144
 145 proc gitdir {args} {
 146         global _gitdir
 147         if {$args eq {}} {
 148                 return $_gitdir
 149         }
 150         return [eval [list file join $_gitdir] $args]
 151 }
 152
 153 proc gitexec {args} {
 154         global _gitexec
 155         if {$_gitexec eq {}} {
 156                 if {[catch {set _gitexec [git --exec-path]} err]} {
 157                         error "Git not installed?\n\n$err"
 158                 }
 159                 if {[is_Cygwin]} {
 160                         set _gitexec [exec cygpath \
 161                                 --windows \
 162                                 --absolute \
 163                                 $_gitexec]
 164                 } else {
 165                         set _gitexec [file normalize $_gitexec]
 166                 }
 167         }
 168         if {$args eq {}} {
 169                 return $_gitexec
 170         }
 171         return [eval [list file join $_gitexec] $args]
 172 }
 173
 174 proc githtmldir {args} {
 175         global _githtmldir
 176         if {$_githtmldir eq {}} {
 177                 if {[catch {set _githtmldir [git --html-path]}]} {
 178                         # Git not installed or option not yet supported
 179                         return {}
 180                 }
 181                 if {[is_Cygwin]} {
 182                         set _githtmldir [exec cygpath \
 183                                 --windows \
 184                                 --absolute \
 185                                 $_githtmldir]
 186                 } else {
 187                         set _githtmldir [file normalize $_githtmldir]
 188                 }
 189         }
 190         if {$args eq {}} {
 191                 return $_githtmldir
 192         }
 193         return [eval [list file join $_githtmldir] $args]
 194 }
 195
 196 proc reponame {} {
 197         return $::_reponame
 198 }
 199
 200 proc is_MacOSX {} {
 201         if {[tk windowingsystem] eq {aqua}} {
 202                 return 1
 203         }
 204         return 0
 205 }
 206
 207 proc is_Windows {} {
 208         if {$::tcl_platform(platform) eq {windows}} {
 209                 return 1
 210         }
 211         return 0
 212 }
 213
 214 proc is_Cygwin {} {
 215         global _iscygwin
 216         if {$_iscygwin eq {}} {
 217                 if {$::tcl_platform(platform) eq {windows}} {
 218                         if {[catch {set p [exec cygpath --windir]} err]} {
 219                                 set _iscygwin 0
 220                         } else {
 221                                 set _iscygwin 1
 222                         }
 223                 } else {
 224                         set _iscygwin 0
 225                 }
 226         }
 227         return $_iscygwin
 228 }
 229
 230 proc is_enabled {option} {
 231         global enabled_options
 232         if {[catch {set on $enabled_options($option)}]} {return 0}
 233         return $on
 234 }
 235
 236 proc enable_option {option} {
 237         global enabled_options
 238         set enabled_options($option) 1
 239 }
 240
 241 proc disable_option {option} {
 242         global enabled_options
 243         set enabled_options($option) 0
 244 }
 245
 246 ######################################################################
 247 ##
 248 ## config
 249
 250 proc is_many_config {name} {
 251         switch -glob -- $name {
 252         gui.recentrepo -
 253         remote.*.fetch -
 254         remote.*.push
 255                 {return 1}
 256         *
 257                 {return 0}
 258         }
 259 }
 260
 261 proc is_config_true {name} {
 262         global repo_config
 263         if {[catch {set v $repo_config($name)}]} {
 264                 return 0
 265         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 266                 return 1
 267         } else {
 268                 return 0
 269         }
 270 }
 271
 272 proc get_config {name} {
 273         global repo_config
 274         if {[catch {set v $repo_config($name)}]} {
 275                 return {}
 276         } else {
 277                 return $v
 278         }
 279 }
 280
 281 proc is_bare {} {
 282         global _isbare
 283         global _gitdir
 284         global _gitworktree
 285
 286         if {$_isbare eq {}} {
 287                 if {[catch {
 288                         set _bare [git rev-parse --is-bare-repository]
 289                         switch  -- $_bare {
 290                         true { set _isbare 1 }
 291                         false { set _isbare 0}
 292                         default { throw }
 293                         }
 294                 }]} {
 295                         if {[is_config_true core.bare]
 296                                 || ($_gitworktree eq {}
 297                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 298                                 set _isbare 1
 299                         } else {
 300                                 set _isbare 0
 301                         }
 302                 }
 303         }
 304         return $_isbare
 305 }
 306
 307 ######################################################################
 308 ##
 309 ## handy utils
 310
 311 proc _trace_exec {cmd} {
 312         if {!$::_trace} return
 313         set d {}
 314         foreach v $cmd {
 315                 if {$d ne {}} {
 316                         append d { }
 317                 }
 318                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 319                         set v [sq $v]
 320                 }
 321                 append d $v
 322         }
 323         puts stderr $d
 324 }
 325
 326 proc _git_cmd {name} {
 327         global _git_cmd_path
 328
 329         if {[catch {set v $_git_cmd_path($name)}]} {
 330                 switch -- $name {
 331                   version   -
 332                 --version   -
 333                 --exec-path { return [list $::_git $name] }
 334                 }
 335
 336                 set p [gitexec git-$name$::_search_exe]
 337                 if {[file exists $p]} {
 338                         set v [list $p]
 339                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 340                         # Try to determine what sort of magic will make
 341                         # git-$name go and do its thing, because native
 342                         # Tcl on Windows doesn't know it.
 343                         #
 344                         set p [gitexec git-$name]
 345                         set f [open $p r]
 346                         set s [gets $f]
 347                         close $f
 348
 349                         switch -glob -- [lindex $s 0] {
 350                         #!*sh     { set i sh     }
 351                         #!*perl   { set i perl   }
 352                         #!*python { set i python }
 353                         default   { error "git-$name is not supported: $s" }
 354                         }
 355
 356                         upvar #0 _$i interp
 357                         if {![info exists interp]} {
 358                                 set interp [_which $i]
 359                         }
 360                         if {$interp eq {}} {
 361                                 error "git-$name requires $i (not in PATH)"
 362                         }
 363                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 364                 } else {
 365                         # Assume it is builtin to git somehow and we
 366                         # aren't actually able to see a file for it.
 367                         #
 368                         set v [list $::_git $name]
 369                 }
 370                 set _git_cmd_path($name) $v
 371         }
 372         return $v
 373 }
 374
 375 proc _which {what args} {
 376         global env _search_exe _search_path
 377
 378         if {$_search_path eq {}} {
 379                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 380                         set _search_path [split [exec cygpath \
 381                                 --windows \
 382                                 --path \
 383                                 --absolute \
 384                                 $env(PATH)] {;}]
 385                         set _search_exe .exe
 386                 } elseif {[is_Windows]} {
 387                         set gitguidir [file dirname [info script]]
 388                         regsub -all ";" $gitguidir "\\;" gitguidir
 389                         set env(PATH) "$gitguidir;$env(PATH)"
 390                         set _search_path [split $env(PATH) {;}]
 391                         set _search_exe .exe
 392                 } else {
 393                         set _search_path [split $env(PATH) :]
 394                         set _search_exe {}
 395                 }
 396         }
 397
 398         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 399                 set suffix {}
 400         } else {
 401                 set suffix $_search_exe
 402         }
 403
 404         foreach p $_search_path {
 405                 set p [file join $p $what$suffix]
 406                 if {[file exists $p]} {
 407                         return [file normalize $p]
 408                 }
 409         }
 410         return {}
 411 }
 412
 413 proc _lappend_nice {cmd_var} {
 414         global _nice
 415         upvar $cmd_var cmd
 416
 417         if {![info exists _nice]} {
 418                 set _nice [_which nice]
 419         }
 420         if {$_nice ne {}} {
 421                 lappend cmd $_nice
 422         }
 423 }
 424
 425 proc git {args} {
 426         set opt [list]
 427
 428         while {1} {
 429                 switch -- [lindex $args 0] {
 430                 --nice {
 431                         _lappend_nice opt
 432                 }
 433
 434                 default {
 435                         break
 436                 }
 437
 438                 }
 439
 440                 set args [lrange $args 1 end]
 441         }
 442
 443         set cmdp [_git_cmd [lindex $args 0]]
 444         set args [lrange $args 1 end]
 445
 446         _trace_exec [concat $opt $cmdp $args]
 447         set result [eval exec $opt $cmdp $args]
 448         if {$::_trace} {
 449                 puts stderr "< $result"
 450         }
 451         return $result
 452 }
 453
 454 proc _open_stdout_stderr {cmd} {
 455         _trace_exec $cmd
 456         if {[catch {
 457                         set fd [open [concat [list | ] $cmd] r]
 458                 } err]} {
 459                 if {   [lindex $cmd end] eq {2>@1}
 460                     && $err eq {can not find channel named "1"}
 461                         } {
 462                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 463                         # redirect operator.  Fallback to |& cat for those.
 464                         # The command was not actually started, so its safe
 465                         # to try to start it a second time.
 466                         #
 467                         set fd [open [concat \
 468                                 [list | ] \
 469                                 [lrange $cmd 0 end-1] \
 470                                 [list |& cat] \
 471                                 ] r]
 472                 } else {
 473                         error $err
 474                 }
 475         }
 476         fconfigure $fd -eofchar {}
 477         return $fd
 478 }
 479
 480 proc git_read {args} {
 481         set opt [list]
 482
 483         while {1} {
 484                 switch -- [lindex $args 0] {
 485                 --nice {
 486                         _lappend_nice opt
 487                 }
 488
 489                 --stderr {
 490                         lappend args 2>@1
 491                 }
 492
 493                 default {
 494                         break
 495                 }
 496
 497                 }
 498
 499                 set args [lrange $args 1 end]
 500         }
 501
 502         set cmdp [_git_cmd [lindex $args 0]]
 503         set args [lrange $args 1 end]
 504
 505         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 506 }
 507
 508 proc git_write {args} {
 509         set opt [list]
 510
 511         while {1} {
 512                 switch -- [lindex $args 0] {
 513                 --nice {
 514                         _lappend_nice opt
 515                 }
 516
 517                 default {
 518                         break
 519                 }
 520
 521                 }
 522
 523                 set args [lrange $args 1 end]
 524         }
 525
 526         set cmdp [_git_cmd [lindex $args 0]]
 527         set args [lrange $args 1 end]
 528
 529         _trace_exec [concat $opt $cmdp $args]
 530         return [open [concat [list | ] $opt $cmdp $args] w]
 531 }
 532
 533 proc githook_read {hook_name args} {
 534         set pchook [gitdir hooks $hook_name]
 535         lappend args 2>@1
 536
 537         # On Windows [file executable] might lie so we need to ask
 538         # the shell if the hook is executable.  Yes that's annoying.
 539         #
 540         if {[is_Windows]} {
 541                 upvar #0 _sh interp
 542                 if {![info exists interp]} {
 543                         set interp [_which sh]
 544                 }
 545                 if {$interp eq {}} {
 546                         error "hook execution requires sh (not in PATH)"
 547                 }
 548
 549                 set scr {if test -x "$1";then exec "$@";fi}
 550                 set sh_c [list $interp -c $scr $interp $pchook]
 551                 return [_open_stdout_stderr [concat $sh_c $args]]
 552         }
 553
 554         if {[file executable $pchook]} {
 555                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 556         }
 557
 558         return {}
 559 }
 560
 561 proc kill_file_process {fd} {
 562         set process [pid $fd]
 563
 564         catch {
 565                 if {[is_Windows]} {
 566                         # Use a Cygwin-specific flag to allow killing
 567                         # native Windows processes
 568                         exec kill -f $process
 569                 } else {
 570                         exec kill $process
 571                 }
 572         }
 573 }
 574
 575 proc gitattr {path attr default} {
 576         if {[catch {set r [git check-attr $attr -- $path]}]} {
 577                 set r unspecified
 578         } else {
 579                 set r [join [lrange [split $r :] 2 end] :]
 580                 regsub {^ } $r {} r
 581         }
 582         if {$r eq {unspecified}} {
 583                 return $default
 584         }
 585         return $r
 586 }
 587
 588 proc sq {value} {
 589         regsub -all ' $value "'\\''" value
 590         return "'$value'"
 591 }
 592
 593 proc load_current_branch {} {
 594         global current_branch is_detached
 595
 596         set fd [open [gitdir HEAD] r]
 597         if {[gets $fd ref] < 1} {
 598                 set ref {}
 599         }
 600         close $fd
 601
 602         set pfx {ref: refs/heads/}
 603         set len [string length $pfx]
 604         if {[string equal -length $len $pfx $ref]} {
 605                 # We're on a branch.  It might not exist.  But
 606                 # HEAD looks good enough to be a branch.
 607                 #
 608                 set current_branch [string range $ref $len end]
 609                 set is_detached 0
 610         } else {
 611                 # Assume this is a detached head.
 612                 #
 613                 set current_branch HEAD
 614                 set is_detached 1
 615         }
 616 }
 617
 618 auto_load tk_optionMenu
 619 rename tk_optionMenu real__tkOptionMenu
 620 proc tk_optionMenu {w varName args} {
 621         set m [eval real__tkOptionMenu $w $varName $args]
 622         $m configure -font font_ui
 623         $w configure -font font_ui
 624         return $m
 625 }
 626
 627 proc rmsel_tag {text} {
 628         $text tag conf sel \
 629                 -background [$text cget -background] \
 630                 -foreground [$text cget -foreground] \
 631                 -borderwidth 0
 632         $text tag conf in_sel -background lightgray
 633         bind $text <Motion> break
 634         return $text
 635 }
 636
 637 set root_exists 0
 638 bind . <Visibility> {
 639         bind . <Visibility> {}
 640         set root_exists 1
 641 }
 642
 643 if {[is_Windows]} {
 644         wm iconbitmap . -default $oguilib/git-gui.ico
 645         set ::tk::AlwaysShowSelection 1
 646
 647         # Spoof an X11 display for SSH
 648         if {![info exists env(DISPLAY)]} {
 649                 set env(DISPLAY) :9999
 650         }
 651 } else {
 652         catch {
 653                 image create photo gitlogo -width 16 -height 16
 654
 655                 gitlogo put #33CC33 -to  7  0  9  2
 656                 gitlogo put #33CC33 -to  4  2 12  4
 657                 gitlogo put #33CC33 -to  7  4  9  6
 658                 gitlogo put #CC3333 -to  4  6 12  8
 659                 gitlogo put gray26  -to  4  9  6 10
 660                 gitlogo put gray26  -to  3 10  6 12
 661                 gitlogo put gray26  -to  8  9 13 11
 662                 gitlogo put gray26  -to  8 11 10 12
 663                 gitlogo put gray26  -to 11 11 13 14
 664                 gitlogo put gray26  -to  3 12  5 14
 665                 gitlogo put gray26  -to  5 13
 666                 gitlogo put gray26  -to 10 13
 667                 gitlogo put gray26  -to  4 14 12 15
 668                 gitlogo put gray26  -to  5 15 11 16
 669                 gitlogo redither
 670
 671                 wm iconphoto . -default gitlogo
 672         }
 673 }
 674
 675 ######################################################################
 676 ##
 677 ## config defaults
 678
 679 set cursor_ptr arrow
 680 font create font_diff -family Courier -size 10
 681 font create font_ui
 682 catch {
 683         label .dummy
 684         eval font configure font_ui [font actual [.dummy cget -font]]
 685         destroy .dummy
 686 }
 687
 688 font create font_uiitalic
 689 font create font_uibold
 690 font create font_diffbold
 691 font create font_diffitalic
 692
 693 foreach class {Button Checkbutton Entry Label
 694                 Labelframe Listbox Message
 695                 Radiobutton Spinbox Text} {
 696         option add *$class.font font_ui
 697 }
 698 if {![is_MacOSX]} {
 699         option add *Menu.font font_ui
 700 }
 701 unset class
 702
 703 if {[is_Windows] || [is_MacOSX]} {
 704         option add *Menu.tearOff 0
 705 }
 706
 707 if {[is_MacOSX]} {
 708         set M1B M1
 709         set M1T Cmd
 710 } else {
 711         set M1B Control
 712         set M1T Ctrl
 713 }
 714
 715 proc bind_button3 {w cmd} {
 716         bind $w <Any-Button-3> $cmd
 717         if {[is_MacOSX]} {
 718                 # Mac OS X sends Button-2 on right click through three-button mouse,
 719                 # or through trackpad right-clicking (two-finger touch + click).
 720                 bind $w <Any-Button-2> $cmd
 721                 bind $w <Control-Button-1> $cmd
 722         }
 723 }
 724
 725 proc apply_config {} {
 726         global repo_config font_descs
 727
 728         foreach option $font_descs {
 729                 set name [lindex $option 0]
 730                 set font [lindex $option 1]
 731                 if {[catch {
 732                         set need_weight 1
 733                         foreach {cn cv} $repo_config(gui.$name) {
 734                                 if {$cn eq {-weight}} {
 735                                         set need_weight 0
 736                                 }
 737                                 font configure $font $cn $cv
 738                         }
 739                         if {$need_weight} {
 740                                 font configure $font -weight normal
 741                         }
 742                         } err]} {
 743                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 744                 }
 745                 foreach {cn cv} [font configure $font] {
 746                         font configure ${font}bold $cn $cv
 747                         font configure ${font}italic $cn $cv
 748                 }
 749                 font configure ${font}bold -weight bold
 750                 font configure ${font}italic -slant italic
 751         }
 752 }
 753
 754 set default_config(branch.autosetupmerge) true
 755 set default_config(merge.tool) {}
 756 set default_config(mergetool.keepbackup) true
 757 set default_config(merge.diffstat) true
 758 set default_config(merge.summary) false
 759 set default_config(merge.verbosity) 2
 760 set default_config(user.name) {}
 761 set default_config(user.email) {}
 762
 763 set default_config(gui.encoding) [encoding system]
 764 set default_config(gui.matchtrackingbranch) false
 765 set default_config(gui.pruneduringfetch) false
 766 set default_config(gui.trustmtime) false
 767 set default_config(gui.fastcopyblame) false
 768 set default_config(gui.copyblamethreshold) 40
 769 set default_config(gui.blamehistoryctx) 7
 770 set default_config(gui.diffcontext) 5
 771 set default_config(gui.commitmsgwidth) 75
 772 set default_config(gui.newbranchtemplate) {}
 773 set default_config(gui.spellingdictionary) {}
 774 set default_config(gui.fontui) [font configure font_ui]
 775 set default_config(gui.fontdiff) [font configure font_diff]
 776 # TODO: this option should be added to the git-config documentation
 777 set default_config(gui.maxfilesdisplayed) 5000
 778 set font_descs {
 779         {fontui   font_ui   {mc "Main Font"}}
 780         {fontdiff font_diff {mc "Diff/Console Font"}}
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## find git
 786
 787 set _git  [_which git]
 788 if {$_git eq {}} {
 789         catch {wm withdraw .}
 790         tk_messageBox \
 791                 -icon error \
 792                 -type ok \
 793                 -title [mc "git-gui: fatal error"] \
 794                 -message [mc "Cannot find git in PATH."]
 795         exit 1
 796 }
 797
 798 ######################################################################
 799 ##
 800 ## version check
 801
 802 if {[catch {set _git_version [git --version]} err]} {
 803         catch {wm withdraw .}
 804         tk_messageBox \
 805                 -icon error \
 806                 -type ok \
 807                 -title [mc "git-gui: fatal error"] \
 808                 -message "Cannot determine Git version:
 809
 810 $err
 811
 812 [appname] requires Git 1.5.0 or later."
 813         exit 1
 814 }
 815 if {![regsub {^git version } $_git_version {} _git_version]} {
 816         catch {wm withdraw .}
 817         tk_messageBox \
 818                 -icon error \
 819                 -type ok \
 820                 -title [mc "git-gui: fatal error"] \
 821                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 822         exit 1
 823 }
 824
 825 set _real_git_version $_git_version
 826 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 827 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 828 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 829 regsub {\.GIT$} $_git_version {} _git_version
 830 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 831
 832 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 833         catch {wm withdraw .}
 834         if {[tk_messageBox \
 835                 -icon warning \
 836                 -type yesno \
 837                 -default no \
 838                 -title "[appname]: warning" \
 839                  -message [mc "Git version cannot be determined.
 840
 841 %s claims it is version '%s'.
 842
 843 %s requires at least Git 1.5.0 or later.
 844
 845 Assume '%s' is version 1.5.0?
 846 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 847                 set _git_version 1.5.0
 848         } else {
 849                 exit 1
 850         }
 851 }
 852 unset _real_git_version
 853
 854 proc git-version {args} {
 855         global _git_version
 856
 857         switch [llength $args] {
 858         0 {
 859                 return $_git_version
 860         }
 861
 862         2 {
 863                 set op [lindex $args 0]
 864                 set vr [lindex $args 1]
 865                 set cm [package vcompare $_git_version $vr]
 866                 return [expr $cm $op 0]
 867         }
 868
 869         4 {
 870                 set type [lindex $args 0]
 871                 set name [lindex $args 1]
 872                 set parm [lindex $args 2]
 873                 set body [lindex $args 3]
 874
 875                 if {($type ne {proc} && $type ne {method})} {
 876                         error "Invalid arguments to git-version"
 877                 }
 878                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 879                         error "Last arm of $type $name must be default"
 880                 }
 881
 882                 foreach {op vr cb} [lrange $body 0 end-2] {
 883                         if {[git-version $op $vr]} {
 884                                 return [uplevel [list $type $name $parm $cb]]
 885                         }
 886                 }
 887
 888                 return [uplevel [list $type $name $parm [lindex $body end]]]
 889         }
 890
 891         default {
 892                 error "git-version >= x"
 893         }
 894
 895         }
 896 }
 897
 898 if {[git-version < 1.5]} {
 899         catch {wm withdraw .}
 900         tk_messageBox \
 901                 -icon error \
 902                 -type ok \
 903                 -title [mc "git-gui: fatal error"] \
 904                 -message "[appname] requires Git 1.5.0 or later.
 905
 906 You are using [git-version]:
 907
 908 [git --version]"
 909         exit 1
 910 }
 911
 912 ######################################################################
 913 ##
 914 ## configure our library
 915
 916 set idx [file join $oguilib tclIndex]
 917 if {[catch {set fd [open $idx r]} err]} {
 918         catch {wm withdraw .}
 919         tk_messageBox \
 920                 -icon error \
 921                 -type ok \
 922                 -title [mc "git-gui: fatal error"] \
 923                 -message $err
 924         exit 1
 925 }
 926 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 927         set idx [list]
 928         while {[gets $fd n] >= 0} {
 929                 if {$n ne {} && ![string match #* $n]} {
 930                         lappend idx $n
 931                 }
 932         }
 933 } else {
 934         set idx {}
 935 }
 936 close $fd
 937
 938 if {$idx ne {}} {
 939         set loaded [list]
 940         foreach p $idx {
 941                 if {[lsearch -exact $loaded $p] >= 0} continue
 942                 source [file join $oguilib $p]
 943                 lappend loaded $p
 944         }
 945         unset loaded p
 946 } else {
 947         set auto_path [concat [list $oguilib] $auto_path]
 948 }
 949 unset -nocomplain idx fd
 950
 951 ######################################################################
 952 ##
 953 ## config file parsing
 954
 955 git-version proc _parse_config {arr_name args} {
 956         >= 1.5.3 {
 957                 upvar $arr_name arr
 958                 array unset arr
 959                 set buf {}
 960                 catch {
 961                         set fd_rc [eval \
 962                                 [list git_read config] \
 963                                 $args \
 964                                 [list --null --list]]
 965                         fconfigure $fd_rc -translation binary
 966                         set buf [read $fd_rc]
 967                         close $fd_rc
 968                 }
 969                 foreach line [split $buf "\0"] {
 970                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 971                                 if {[is_many_config $name]} {
 972                                         lappend arr($name) $value
 973                                 } else {
 974                                         set arr($name) $value
 975                                 }
 976                         }
 977                 }
 978         }
 979         default {
 980                 upvar $arr_name arr
 981                 array unset arr
 982                 catch {
 983                         set fd_rc [eval [list git_read config --list] $args]
 984                         while {[gets $fd_rc line] >= 0} {
 985                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 986                                         if {[is_many_config $name]} {
 987                                                 lappend arr($name) $value
 988                                         } else {
 989                                                 set arr($name) $value
 990                                         }
 991                                 }
 992                         }
 993                         close $fd_rc
 994                 }
 995         }
 996 }
 997
 998 proc load_config {include_global} {
 999         global repo_config global_config system_config default_config
1000
1001         if {$include_global} {
1002                 _parse_config system_config --system
1003                 _parse_config global_config --global
1004         }
1005         _parse_config repo_config
1006
1007         foreach name [array names default_config] {
1008                 if {[catch {set v $system_config($name)}]} {
1009                         set system_config($name) $default_config($name)
1010                 }
1011         }
1012         foreach name [array names system_config] {
1013                 if {[catch {set v $global_config($name)}]} {
1014                         set global_config($name) $system_config($name)
1015                 }
1016                 if {[catch {set v $repo_config($name)}]} {
1017                         set repo_config($name) $system_config($name)
1018                 }
1019         }
1020 }
1021
1022 ######################################################################
1023 ##
1024 ## feature option selection
1025
1026 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1027         unset _junk
1028 } else {
1029         set subcommand gui
1030 }
1031 if {$subcommand eq {gui.sh}} {
1032         set subcommand gui
1033 }
1034 if {$subcommand eq {gui} && [llength $argv] > 0} {
1035         set subcommand [lindex $argv 0]
1036         set argv [lrange $argv 1 end]
1037 }
1038
1039 enable_option multicommit
1040 enable_option branch
1041 enable_option transport
1042 disable_option bare
1043
1044 switch -- $subcommand {
1045 browser -
1046 blame {
1047         enable_option bare
1048
1049         disable_option multicommit
1050         disable_option branch
1051         disable_option transport
1052 }
1053 citool {
1054         enable_option singlecommit
1055         enable_option retcode
1056
1057         disable_option multicommit
1058         disable_option branch
1059         disable_option transport
1060
1061         while {[llength $argv] > 0} {
1062                 set a [lindex $argv 0]
1063                 switch -- $a {
1064                 --amend {
1065                         enable_option initialamend
1066                 }
1067                 --nocommit {
1068                         enable_option nocommit
1069                         enable_option nocommitmsg
1070                 }
1071                 --commitmsg {
1072                         disable_option nocommitmsg
1073                 }
1074                 default {
1075                         break
1076                 }
1077                 }
1078
1079                 set argv [lrange $argv 1 end]
1080         }
1081 }
1082 }
1083
1084 ######################################################################
1085 ##
1086 ## execution environment
1087
1088 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1089
1090 # Suggest our implementation of askpass, if none is set
1091 if {![info exists env(SSH_ASKPASS)]} {
1092         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1093 }
1094
1095 ######################################################################
1096 ##
1097 ## repository setup
1098
1099 set picked 0
1100 if {[catch {
1101                 set _gitdir $env(GIT_DIR)
1102                 set _prefix {}
1103                 }]
1104         && [catch {
1105                 # beware that from the .git dir this sets _gitdir to .
1106                 # and _prefix to the empty string
1107                 set _gitdir [git rev-parse --git-dir]
1108                 set _prefix [git rev-parse --show-prefix]
1109         } err]} {
1110         load_config 1
1111         apply_config
1112         choose_repository::pick
1113         set picked 1
1114 }
1115
1116 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1117 # run from the .git dir itself) lest the routines to find the worktree
1118 # get confused
1119 if {$_gitdir eq "."} {
1120         set _gitdir [pwd]
1121 }
1122
1123 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1124         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1125 }
1126 if {![file isdirectory $_gitdir]} {
1127         catch {wm withdraw .}
1128         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1129         exit 1
1130 }
1131 # _gitdir exists, so try loading the config
1132 load_config 0
1133 apply_config
1134 # try to set work tree from environment, falling back to core.worktree
1135 if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1136         set _gitworktree [get_config core.worktree]
1137 }
1138 if {$_prefix ne {}} {
1139         if {$_gitworktree eq {}} {
1140                 regsub -all {[^/]+/} $_prefix ../ cdup
1141         } else {
1142                 set cdup $_gitworktree
1143         }
1144         if {[catch {cd $cdup} err]} {
1145                 catch {wm withdraw .}
1146                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1147                 exit 1
1148         }
1149         set _gitworktree [pwd]
1150         unset cdup
1151 } elseif {![is_enabled bare]} {
1152         if {[is_bare]} {
1153                 catch {wm withdraw .}
1154                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1155                 exit 1
1156         }
1157         if {$_gitworktree eq {}} {
1158                 set _gitworktree [file dirname $_gitdir]
1159         }
1160         if {[catch {cd $_gitworktree} err]} {
1161                 catch {wm withdraw .}
1162                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1163                 exit 1
1164         }
1165         set _gitworktree [pwd]
1166 }
1167 set _reponame [file split [file normalize $_gitdir]]
1168 if {[lindex $_reponame end] eq {.git}} {
1169         set _reponame [lindex $_reponame end-1]
1170 } else {
1171         set _reponame [lindex $_reponame end]
1172 }
1173
1174 set env(GIT_DIR) $_gitdir
1175 set env(GIT_WORK_TREE) $_gitworktree
1176
1177 ######################################################################
1178 ##
1179 ## global init
1180
1181 set current_diff_path {}
1182 set current_diff_side {}
1183 set diff_actions [list]
1184
1185 set HEAD {}
1186 set PARENT {}
1187 set MERGE_HEAD [list]
1188 set commit_type {}
1189 set empty_tree {}
1190 set current_branch {}
1191 set is_detached 0
1192 set current_diff_path {}
1193 set is_3way_diff 0
1194 set is_submodule_diff 0
1195 set is_conflict_diff 0
1196 set selected_commit_type new
1197 set diff_empty_count 0
1198
1199 set nullid "0000000000000000000000000000000000000000"
1200 set nullid2 "0000000000000000000000000000000000000001"
1201
1202 ######################################################################
1203 ##
1204 ## task management
1205
1206 set rescan_active 0
1207 set diff_active 0
1208 set last_clicked {}
1209
1210 set disable_on_lock [list]
1211 set index_lock_type none
1212
1213 proc lock_index {type} {
1214         global index_lock_type disable_on_lock
1215
1216         if {$index_lock_type eq {none}} {
1217                 set index_lock_type $type
1218                 foreach w $disable_on_lock {
1219                         uplevel #0 $w disabled
1220                 }
1221                 return 1
1222         } elseif {$index_lock_type eq "begin-$type"} {
1223                 set index_lock_type $type
1224                 return 1
1225         }
1226         return 0
1227 }
1228
1229 proc unlock_index {} {
1230         global index_lock_type disable_on_lock
1231
1232         set index_lock_type none
1233         foreach w $disable_on_lock {
1234                 uplevel #0 $w normal
1235         }
1236 }
1237
1238 ######################################################################
1239 ##
1240 ## status
1241
1242 proc repository_state {ctvar hdvar mhvar} {
1243         global current_branch
1244         upvar $ctvar ct $hdvar hd $mhvar mh
1245
1246         set mh [list]
1247
1248         load_current_branch
1249         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1250                 set hd {}
1251                 set ct initial
1252                 return
1253         }
1254
1255         set merge_head [gitdir MERGE_HEAD]
1256         if {[file exists $merge_head]} {
1257                 set ct merge
1258                 set fd_mh [open $merge_head r]
1259                 while {[gets $fd_mh line] >= 0} {
1260                         lappend mh $line
1261                 }
1262                 close $fd_mh
1263                 return
1264         }
1265
1266         set ct normal
1267 }
1268
1269 proc PARENT {} {
1270         global PARENT empty_tree
1271
1272         set p [lindex $PARENT 0]
1273         if {$p ne {}} {
1274                 return $p
1275         }
1276         if {$empty_tree eq {}} {
1277                 set empty_tree [git mktree << {}]
1278         }
1279         return $empty_tree
1280 }
1281
1282 proc force_amend {} {
1283         global selected_commit_type
1284         global HEAD PARENT MERGE_HEAD commit_type
1285
1286         repository_state newType newHEAD newMERGE_HEAD
1287         set HEAD $newHEAD
1288         set PARENT $newHEAD
1289         set MERGE_HEAD $newMERGE_HEAD
1290         set commit_type $newType
1291
1292         set selected_commit_type amend
1293         do_select_commit_type
1294 }
1295
1296 proc rescan {after {honor_trustmtime 1}} {
1297         global HEAD PARENT MERGE_HEAD commit_type
1298         global ui_index ui_workdir ui_comm
1299         global rescan_active file_states
1300         global repo_config
1301
1302         if {$rescan_active > 0 || ![lock_index read]} return
1303
1304         repository_state newType newHEAD newMERGE_HEAD
1305         if {[string match amend* $commit_type]
1306                 && $newType eq {normal}
1307                 && $newHEAD eq $HEAD} {
1308         } else {
1309                 set HEAD $newHEAD
1310                 set PARENT $newHEAD
1311                 set MERGE_HEAD $newMERGE_HEAD
1312                 set commit_type $newType
1313         }
1314
1315         array unset file_states
1316
1317         if {!$::GITGUI_BCK_exists &&
1318                 (![$ui_comm edit modified]
1319                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1320                 if {[string match amend* $commit_type]} {
1321                 } elseif {[load_message GITGUI_MSG]} {
1322                 } elseif {[run_prepare_commit_msg_hook]} {
1323                 } elseif {[load_message MERGE_MSG]} {
1324                 } elseif {[load_message SQUASH_MSG]} {
1325                 }
1326                 $ui_comm edit reset
1327                 $ui_comm edit modified false
1328         }
1329
1330         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1331                 rescan_stage2 {} $after
1332         } else {
1333                 set rescan_active 1
1334                 ui_status [mc "Refreshing file status..."]
1335                 set fd_rf [git_read update-index \
1336                         -q \
1337                         --unmerged \
1338                         --ignore-missing \
1339                         --refresh \
1340                         ]
1341                 fconfigure $fd_rf -blocking 0 -translation binary
1342                 fileevent $fd_rf readable \
1343                         [list rescan_stage2 $fd_rf $after]
1344         }
1345 }
1346
1347 if {[is_Cygwin]} {
1348         set is_git_info_exclude {}
1349         proc have_info_exclude {} {
1350                 global is_git_info_exclude
1351
1352                 if {$is_git_info_exclude eq {}} {
1353                         if {[catch {exec test -f [gitdir info exclude]}]} {
1354                                 set is_git_info_exclude 0
1355                         } else {
1356                                 set is_git_info_exclude 1
1357                         }
1358                 }
1359                 return $is_git_info_exclude
1360         }
1361 } else {
1362         proc have_info_exclude {} {
1363                 return [file readable [gitdir info exclude]]
1364         }
1365 }
1366
1367 proc rescan_stage2 {fd after} {
1368         global rescan_active buf_rdi buf_rdf buf_rlo
1369
1370         if {$fd ne {}} {
1371                 read $fd
1372                 if {![eof $fd]} return
1373                 close $fd
1374         }
1375
1376         set ls_others [list --exclude-per-directory=.gitignore]
1377         if {[have_info_exclude]} {
1378                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1379         }
1380         set user_exclude [get_config core.excludesfile]
1381         if {$user_exclude ne {} && [file readable $user_exclude]} {
1382                 lappend ls_others "--exclude-from=$user_exclude"
1383         }
1384
1385         set buf_rdi {}
1386         set buf_rdf {}
1387         set buf_rlo {}
1388
1389         set rescan_active 3
1390         ui_status [mc "Scanning for modified files ..."]
1391         set fd_di [git_read diff-index --cached -z [PARENT]]
1392         set fd_df [git_read diff-files -z]
1393         set fd_lo [eval git_read ls-files --others -z $ls_others]
1394
1395         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1396         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1397         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1398         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1399         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1400         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1401 }
1402
1403 proc load_message {file} {
1404         global ui_comm
1405
1406         set f [gitdir $file]
1407         if {[file isfile $f]} {
1408                 if {[catch {set fd [open $f r]}]} {
1409                         return 0
1410                 }
1411                 fconfigure $fd -eofchar {}
1412                 set content [string trim [read $fd]]
1413                 close $fd
1414                 regsub -all -line {[ \r\t]+$} $content {} content
1415                 $ui_comm delete 0.0 end
1416                 $ui_comm insert end $content
1417                 return 1
1418         }
1419         return 0
1420 }
1421
1422 proc run_prepare_commit_msg_hook {} {
1423         global pch_error
1424
1425         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1426         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1427         # empty file but existant file.
1428
1429         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1430
1431         if {[file isfile [gitdir MERGE_MSG]]} {
1432                 set pcm_source "merge"
1433                 set fd_mm [open [gitdir MERGE_MSG] r]
1434                 puts -nonewline $fd_pcm [read $fd_mm]
1435                 close $fd_mm
1436         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1437                 set pcm_source "squash"
1438                 set fd_sm [open [gitdir SQUASH_MSG] r]
1439                 puts -nonewline $fd_pcm [read $fd_sm]
1440                 close $fd_sm
1441         } else {
1442                 set pcm_source ""
1443         }
1444
1445         close $fd_pcm
1446
1447         set fd_ph [githook_read prepare-commit-msg \
1448                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1449         if {$fd_ph eq {}} {
1450                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1451                 return 0;
1452         }
1453
1454         ui_status [mc "Calling prepare-commit-msg hook..."]
1455         set pch_error {}
1456
1457         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1458         fileevent $fd_ph readable \
1459                 [list prepare_commit_msg_hook_wait $fd_ph]
1460
1461         return 1;
1462 }
1463
1464 proc prepare_commit_msg_hook_wait {fd_ph} {
1465         global pch_error
1466
1467         append pch_error [read $fd_ph]
1468         fconfigure $fd_ph -blocking 1
1469         if {[eof $fd_ph]} {
1470                 if {[catch {close $fd_ph}]} {
1471                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1472                         hook_failed_popup prepare-commit-msg $pch_error
1473                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1474                         exit 1
1475                 } else {
1476                         load_message PREPARE_COMMIT_MSG
1477                 }
1478                 set pch_error {}
1479                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1480                 return
1481         }
1482         fconfigure $fd_ph -blocking 0
1483         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1484 }
1485
1486 proc read_diff_index {fd after} {
1487         global buf_rdi
1488
1489         append buf_rdi [read $fd]
1490         set c 0
1491         set n [string length $buf_rdi]
1492         while {$c < $n} {
1493                 set z1 [string first "\0" $buf_rdi $c]
1494                 if {$z1 == -1} break
1495                 incr z1
1496                 set z2 [string first "\0" $buf_rdi $z1]
1497                 if {$z2 == -1} break
1498
1499                 incr c
1500                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1501                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1502                 merge_state \
1503                         [encoding convertfrom $p] \
1504                         [lindex $i 4]? \
1505                         [list [lindex $i 0] [lindex $i 2]] \
1506                         [list]
1507                 set c $z2
1508                 incr c
1509         }
1510         if {$c < $n} {
1511                 set buf_rdi [string range $buf_rdi $c end]
1512         } else {
1513                 set buf_rdi {}
1514         }
1515
1516         rescan_done $fd buf_rdi $after
1517 }
1518
1519 proc read_diff_files {fd after} {
1520         global buf_rdf
1521
1522         append buf_rdf [read $fd]
1523         set c 0
1524         set n [string length $buf_rdf]
1525         while {$c < $n} {
1526                 set z1 [string first "\0" $buf_rdf $c]
1527                 if {$z1 == -1} break
1528                 incr z1
1529                 set z2 [string first "\0" $buf_rdf $z1]
1530                 if {$z2 == -1} break
1531
1532                 incr c
1533                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1534                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1535                 merge_state \
1536                         [encoding convertfrom $p] \
1537                         ?[lindex $i 4] \
1538                         [list] \
1539                         [list [lindex $i 0] [lindex $i 2]]
1540                 set c $z2
1541                 incr c
1542         }
1543         if {$c < $n} {
1544                 set buf_rdf [string range $buf_rdf $c end]
1545         } else {
1546                 set buf_rdf {}
1547         }
1548
1549         rescan_done $fd buf_rdf $after
1550 }
1551
1552 proc read_ls_others {fd after} {
1553         global buf_rlo
1554
1555         append buf_rlo [read $fd]
1556         set pck [split $buf_rlo "\0"]
1557         set buf_rlo [lindex $pck end]
1558         foreach p [lrange $pck 0 end-1] {
1559                 set p [encoding convertfrom $p]
1560                 if {[string index $p end] eq {/}} {
1561                         set p [string range $p 0 end-1]
1562                 }
1563                 merge_state $p ?O
1564         }
1565         rescan_done $fd buf_rlo $after
1566 }
1567
1568 proc rescan_done {fd buf after} {
1569         global rescan_active current_diff_path
1570         global file_states repo_config
1571         upvar $buf to_clear
1572
1573         if {![eof $fd]} return
1574         set to_clear {}
1575         close $fd
1576         if {[incr rescan_active -1] > 0} return
1577
1578         prune_selection
1579         unlock_index
1580         display_all_files
1581         if {$current_diff_path ne {}} { reshow_diff $after }
1582         if {$current_diff_path eq {}} { select_first_diff $after }
1583 }
1584
1585 proc prune_selection {} {
1586         global file_states selected_paths
1587
1588         foreach path [array names selected_paths] {
1589                 if {[catch {set still_here $file_states($path)}]} {
1590                         unset selected_paths($path)
1591                 }
1592         }
1593 }
1594
1595 ######################################################################
1596 ##
1597 ## ui helpers
1598
1599 proc mapicon {w state path} {
1600         global all_icons
1601
1602         if {[catch {set r $all_icons($state$w)}]} {
1603                 puts "error: no icon for $w state={$state} $path"
1604                 return file_plain
1605         }
1606         return $r
1607 }
1608
1609 proc mapdesc {state path} {
1610         global all_descs
1611
1612         if {[catch {set r $all_descs($state)}]} {
1613                 puts "error: no desc for state={$state} $path"
1614                 return $state
1615         }
1616         return $r
1617 }
1618
1619 proc ui_status {msg} {
1620         global main_status
1621         if {[info exists main_status]} {
1622                 $main_status show $msg
1623         }
1624 }
1625
1626 proc ui_ready {{test {}}} {
1627         global main_status
1628         if {[info exists main_status]} {
1629                 $main_status show [mc "Ready."] $test
1630         }
1631 }
1632
1633 proc escape_path {path} {
1634         regsub -all {\\} $path "\\\\" path
1635         regsub -all "\n" $path "\\n" path
1636         return $path
1637 }
1638
1639 proc short_path {path} {
1640         return [escape_path [lindex [file split $path] end]]
1641 }
1642
1643 set next_icon_id 0
1644 set null_sha1 [string repeat 0 40]
1645
1646 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1647         global file_states next_icon_id null_sha1
1648
1649         set s0 [string index $new_state 0]
1650         set s1 [string index $new_state 1]
1651
1652         if {[catch {set info $file_states($path)}]} {
1653                 set state __
1654                 set icon n[incr next_icon_id]
1655         } else {
1656                 set state [lindex $info 0]
1657                 set icon [lindex $info 1]
1658                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1659                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1660         }
1661
1662         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1663         elseif {$s0 eq {_}} {set s0 _}
1664
1665         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1666         elseif {$s1 eq {_}} {set s1 _}
1667
1668         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1669                 set head_info [list 0 $null_sha1]
1670         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1671                 && $head_info eq {}} {
1672                 set head_info $index_info
1673         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1674                 set index_info $head_info
1675                 set head_info {}
1676         }
1677
1678         set file_states($path) [list $s0$s1 $icon \
1679                 $head_info $index_info \
1680                 ]
1681         return $state
1682 }
1683
1684 proc display_file_helper {w path icon_name old_m new_m} {
1685         global file_lists
1686
1687         if {$new_m eq {_}} {
1688                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1689                 if {$lno >= 0} {
1690                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1691                         incr lno
1692                         $w conf -state normal
1693                         $w delete $lno.0 [expr {$lno + 1}].0
1694                         $w conf -state disabled
1695                 }
1696         } elseif {$old_m eq {_} && $new_m ne {_}} {
1697                 lappend file_lists($w) $path
1698                 set file_lists($w) [lsort -unique $file_lists($w)]
1699                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1700                 incr lno
1701                 $w conf -state normal
1702                 $w image create $lno.0 \
1703                         -align center -padx 5 -pady 1 \
1704                         -name $icon_name \
1705                         -image [mapicon $w $new_m $path]
1706                 $w insert $lno.1 "[escape_path $path]\n"
1707                 $w conf -state disabled
1708         } elseif {$old_m ne $new_m} {
1709                 $w conf -state normal
1710                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1711                 $w conf -state disabled
1712         }
1713 }
1714
1715 proc display_file {path state} {
1716         global file_states selected_paths
1717         global ui_index ui_workdir
1718
1719         set old_m [merge_state $path $state]
1720         set s $file_states($path)
1721         set new_m [lindex $s 0]
1722         set icon_name [lindex $s 1]
1723
1724         set o [string index $old_m 0]
1725         set n [string index $new_m 0]
1726         if {$o eq {U}} {
1727                 set o _
1728         }
1729         if {$n eq {U}} {
1730                 set n _
1731         }
1732         display_file_helper     $ui_index $path $icon_name $o $n
1733
1734         if {[string index $old_m 0] eq {U}} {
1735                 set o U
1736         } else {
1737                 set o [string index $old_m 1]
1738         }
1739         if {[string index $new_m 0] eq {U}} {
1740                 set n U
1741         } else {
1742                 set n [string index $new_m 1]
1743         }
1744         display_file_helper     $ui_workdir $path $icon_name $o $n
1745
1746         if {$new_m eq {__}} {
1747                 unset file_states($path)
1748                 catch {unset selected_paths($path)}
1749         }
1750 }
1751
1752 proc display_all_files_helper {w path icon_name m} {
1753         global file_lists
1754
1755         lappend file_lists($w) $path
1756         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1757         $w image create end \
1758                 -align center -padx 5 -pady 1 \
1759                 -name $icon_name \
1760                 -image [mapicon $w $m $path]
1761         $w insert end "[escape_path $path]\n"
1762 }
1763
1764 set files_warning 0
1765 proc display_all_files {} {
1766         global ui_index ui_workdir
1767         global file_states file_lists
1768         global last_clicked
1769         global files_warning
1770
1771         $ui_index conf -state normal
1772         $ui_workdir conf -state normal
1773
1774         $ui_index delete 0.0 end
1775         $ui_workdir delete 0.0 end
1776         set last_clicked {}
1777
1778         set file_lists($ui_index) [list]
1779         set file_lists($ui_workdir) [list]
1780
1781         set to_display [lsort [array names file_states]]
1782         set display_limit [get_config gui.maxfilesdisplayed]
1783         if {[llength $to_display] > $display_limit} {
1784                 if {!$files_warning} {
1785                         # do not repeatedly warn:
1786                         set files_warning 1
1787                         info_popup [mc "Displaying only %s of %s files." \
1788                                 $display_limit [llength $to_display]]
1789                 }
1790                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1791         }
1792         foreach path $to_display {
1793                 set s $file_states($path)
1794                 set m [lindex $s 0]
1795                 set icon_name [lindex $s 1]
1796
1797                 set s [string index $m 0]
1798                 if {$s ne {U} && $s ne {_}} {
1799                         display_all_files_helper $ui_index $path \
1800                                 $icon_name $s
1801                 }
1802
1803                 if {[string index $m 0] eq {U}} {
1804                         set s U
1805                 } else {
1806                         set s [string index $m 1]
1807                 }
1808                 if {$s ne {_}} {
1809                         display_all_files_helper $ui_workdir $path \
1810                                 $icon_name $s
1811                 }
1812         }
1813
1814         $ui_index conf -state disabled
1815         $ui_workdir conf -state disabled
1816 }
1817
1818 ######################################################################
1819 ##
1820 ## icons
1821
1822 set filemask {
1823 #define mask_width 14
1824 #define mask_height 15
1825 static unsigned char mask_bits[] = {
1826    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1827    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1828    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1829 }
1830
1831 image create bitmap file_plain -background white -foreground black -data {
1832 #define plain_width 14
1833 #define plain_height 15
1834 static unsigned char plain_bits[] = {
1835    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1836    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1837    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1838 } -maskdata $filemask
1839
1840 image create bitmap file_mod -background white -foreground blue -data {
1841 #define mod_width 14
1842 #define mod_height 15
1843 static unsigned char mod_bits[] = {
1844    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1845    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1846    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1847 } -maskdata $filemask
1848
1849 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1850 #define file_fulltick_width 14
1851 #define file_fulltick_height 15
1852 static unsigned char file_fulltick_bits[] = {
1853    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1854    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1855    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1856 } -maskdata $filemask
1857
1858 image create bitmap file_parttick -background white -foreground "#005050" -data {
1859 #define parttick_width 14
1860 #define parttick_height 15
1861 static unsigned char parttick_bits[] = {
1862    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1863    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1864    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1865 } -maskdata $filemask
1866
1867 image create bitmap file_question -background white -foreground black -data {
1868 #define file_question_width 14
1869 #define file_question_height 15
1870 static unsigned char file_question_bits[] = {
1871    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1872    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1873    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1874 } -maskdata $filemask
1875
1876 image create bitmap file_removed -background white -foreground red -data {
1877 #define file_removed_width 14
1878 #define file_removed_height 15
1879 static unsigned char file_removed_bits[] = {
1880    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1881    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1882    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1883 } -maskdata $filemask
1884
1885 image create bitmap file_merge -background white -foreground blue -data {
1886 #define file_merge_width 14
1887 #define file_merge_height 15
1888 static unsigned char file_merge_bits[] = {
1889    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1890    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1891    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1892 } -maskdata $filemask
1893
1894 image create bitmap file_statechange -background white -foreground green -data {
1895 #define file_merge_width 14
1896 #define file_merge_height 15
1897 static unsigned char file_statechange_bits[] = {
1898    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1899    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1900    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1901 } -maskdata $filemask
1902
1903 set ui_index .vpane.files.index.list
1904 set ui_workdir .vpane.files.workdir.list
1905
1906 set all_icons(_$ui_index)   file_plain
1907 set all_icons(A$ui_index)   file_fulltick
1908 set all_icons(M$ui_index)   file_fulltick
1909 set all_icons(D$ui_index)   file_removed
1910 set all_icons(U$ui_index)   file_merge
1911 set all_icons(T$ui_index)   file_statechange
1912
1913 set all_icons(_$ui_workdir) file_plain
1914 set all_icons(M$ui_workdir) file_mod
1915 set all_icons(D$ui_workdir) file_question
1916 set all_icons(U$ui_workdir) file_merge
1917 set all_icons(O$ui_workdir) file_plain
1918 set all_icons(T$ui_workdir) file_statechange
1919
1920 set max_status_desc 0
1921 foreach i {
1922                 {__ {mc "Unmodified"}}
1923
1924                 {_M {mc "Modified, not staged"}}
1925                 {M_ {mc "Staged for commit"}}
1926                 {MM {mc "Portions staged for commit"}}
1927                 {MD {mc "Staged for commit, missing"}}
1928
1929                 {_T {mc "File type changed, not staged"}}
1930                 {T_ {mc "File type changed, staged"}}
1931
1932                 {_O {mc "Untracked, not staged"}}
1933                 {A_ {mc "Staged for commit"}}
1934                 {AM {mc "Portions staged for commit"}}
1935                 {AD {mc "Staged for commit, missing"}}
1936
1937                 {_D {mc "Missing"}}
1938                 {D_ {mc "Staged for removal"}}
1939                 {DO {mc "Staged for removal, still present"}}
1940
1941                 {_U {mc "Requires merge resolution"}}
1942                 {U_ {mc "Requires merge resolution"}}
1943                 {UU {mc "Requires merge resolution"}}
1944                 {UM {mc "Requires merge resolution"}}
1945                 {UD {mc "Requires merge resolution"}}
1946                 {UT {mc "Requires merge resolution"}}
1947         } {
1948         set text [eval [lindex $i 1]]
1949         if {$max_status_desc < [string length $text]} {
1950                 set max_status_desc [string length $text]
1951         }
1952         set all_descs([lindex $i 0]) $text
1953 }
1954 unset i
1955
1956 ######################################################################
1957 ##
1958 ## util
1959
1960 proc scrollbar2many {list mode args} {
1961         foreach w $list {eval $w $mode $args}
1962 }
1963
1964 proc many2scrollbar {list mode sb top bottom} {
1965         $sb set $top $bottom
1966         foreach w $list {$w $mode moveto $top}
1967 }
1968
1969 proc incr_font_size {font {amt 1}} {
1970         set sz [font configure $font -size]
1971         incr sz $amt
1972         font configure $font -size $sz
1973         font configure ${font}bold -size $sz
1974         font configure ${font}italic -size $sz
1975 }
1976
1977 ######################################################################
1978 ##
1979 ## ui commands
1980
1981 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1982
1983 proc do_gitk {revs {is_submodule false}} {
1984         global current_diff_path file_states current_diff_side ui_index
1985         global _gitdir _gitworktree
1986
1987         # -- Always start gitk through whatever we were loaded with.  This
1988         #    lets us bypass using shell process on Windows systems.
1989         #
1990         set exe [_which gitk -script]
1991         set cmd [list [info nameofexecutable] $exe]
1992         if {$exe eq {}} {
1993                 error_popup [mc "Couldn't find gitk in PATH"]
1994         } else {
1995                 global env
1996
1997                 set pwd [pwd]
1998
1999                 if {!$is_submodule} {
2000                         if {![is_bare]} {
2001                                 cd $_gitworktree
2002                         }
2003                 } else {
2004                         cd $current_diff_path
2005                         if {$revs eq {--}} {
2006                                 set s $file_states($current_diff_path)
2007                                 set old_sha1 {}
2008                                 set new_sha1 {}
2009                                 switch -glob -- [lindex $s 0] {
2010                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2011                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2012                                 MM {
2013                                         if {$current_diff_side eq $ui_index} {
2014                                                 set old_sha1 [lindex [lindex $s 2] 1]
2015                                                 set new_sha1 [lindex [lindex $s 3] 1]
2016                                         } else {
2017                                                 set old_sha1 [lindex [lindex $s 3] 1]
2018                                         }
2019                                 }
2020                                 }
2021                                 set revs $old_sha1...$new_sha1
2022                         }
2023                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2024                         # we've been using for the main repository, so unset them.
2025                         # TODO we could make life easier (start up faster?) for gitk
2026                         # by setting these to the appropriate values to allow gitk
2027                         # to skip the heuristics to find their proper value
2028                         unset env(GIT_DIR)
2029                         unset env(GIT_WORK_TREE)
2030                 }
2031                 eval exec $cmd $revs "--" "--" &
2032
2033                 set env(GIT_DIR) $_gitdir
2034                 set env(GIT_WORK_TREE) $_gitworktree
2035                 cd $pwd
2036
2037                 ui_status $::starting_gitk_msg
2038                 after 10000 {
2039                         ui_ready $starting_gitk_msg
2040                 }
2041         }
2042 }
2043
2044 proc do_git_gui {} {
2045         global current_diff_path
2046
2047         # -- Always start git gui through whatever we were loaded with.  This
2048         #    lets us bypass using shell process on Windows systems.
2049         #
2050         set exe [_which git]
2051         if {$exe eq {}} {
2052                 error_popup [mc "Couldn't find git gui in PATH"]
2053         } else {
2054                 global env
2055                 global _gitdir _gitworktree
2056
2057                 # see note in do_gitk about unsetting these vars when
2058                 # running tools in a submodule
2059                 unset env(GIT_DIR)
2060                 unset env(GIT_WORK_TREE)
2061
2062                 set pwd [pwd]
2063                 cd $current_diff_path
2064
2065                 eval exec $exe gui &
2066
2067                 set env(GIT_DIR) $_gitdir
2068                 set env(GIT_WORK_TREE) $_gitworktree
2069                 cd $pwd
2070
2071                 ui_status $::starting_gitk_msg
2072                 after 10000 {
2073                         ui_ready $starting_gitk_msg
2074                 }
2075         }
2076 }
2077
2078 proc do_explore {} {
2079         global _gitworktree
2080         set explorer {}
2081         if {[is_Cygwin] || [is_Windows]} {
2082                 set explorer "explorer.exe"
2083         } elseif {[is_MacOSX]} {
2084                 set explorer "open"
2085         } else {
2086                 # freedesktop.org-conforming system is our best shot
2087                 set explorer "xdg-open"
2088         }
2089         eval exec $explorer $_gitworktree &
2090 }
2091
2092 set is_quitting 0
2093 set ret_code    1
2094
2095 proc terminate_me {win} {
2096         global ret_code
2097         if {$win ne {.}} return
2098         exit $ret_code
2099 }
2100
2101 proc do_quit {{rc {1}}} {
2102         global ui_comm is_quitting repo_config commit_type
2103         global GITGUI_BCK_exists GITGUI_BCK_i
2104         global ui_comm_spell
2105         global ret_code
2106
2107         if {$is_quitting} return
2108         set is_quitting 1
2109
2110         if {[winfo exists $ui_comm]} {
2111                 # -- Stash our current commit buffer.
2112                 #
2113                 set save [gitdir GITGUI_MSG]
2114                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2115                         file rename -force [gitdir GITGUI_BCK] $save
2116                         set GITGUI_BCK_exists 0
2117                 } else {
2118                         set msg [string trim [$ui_comm get 0.0 end]]
2119                         regsub -all -line {[ \r\t]+$} $msg {} msg
2120                         if {(![string match amend* $commit_type]
2121                                 || [$ui_comm edit modified])
2122                                 && $msg ne {}} {
2123                                 catch {
2124                                         set fd [open $save w]
2125                                         puts -nonewline $fd $msg
2126                                         close $fd
2127                                 }
2128                         } else {
2129                                 catch {file delete $save}
2130                         }
2131                 }
2132
2133                 # -- Cancel our spellchecker if its running.
2134                 #
2135                 if {[info exists ui_comm_spell]} {
2136                         $ui_comm_spell stop
2137                 }
2138
2139                 # -- Remove our editor backup, its not needed.
2140                 #
2141                 after cancel $GITGUI_BCK_i
2142                 if {$GITGUI_BCK_exists} {
2143                         catch {file delete [gitdir GITGUI_BCK]}
2144                 }
2145
2146                 # -- Stash our current window geometry into this repository.
2147                 #
2148                 set cfg_wmstate [wm state .]
2149                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2150                         set rc_wmstate {}
2151                 }
2152                 if {$cfg_wmstate ne $rc_wmstate} {
2153                         catch {git config gui.wmstate $cfg_wmstate}
2154                 }
2155                 if {$cfg_wmstate eq {zoomed}} {
2156                         # on Windows wm geometry will lie about window
2157                         # position (but not size) when window is zoomed
2158                         # restore the window before querying wm geometry
2159                         wm state . normal
2160                 }
2161                 set cfg_geometry [list]
2162                 lappend cfg_geometry [wm geometry .]
2163                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2164                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2165                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2166                         set rc_geometry {}
2167                 }
2168                 if {$cfg_geometry ne $rc_geometry} {
2169                         catch {git config gui.geometry $cfg_geometry}
2170                 }
2171         }
2172
2173         set ret_code $rc
2174
2175         # Briefly enable send again, working around Tk bug
2176         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2177         tk appname [appname]
2178
2179         destroy .
2180 }
2181
2182 proc do_rescan {} {
2183         rescan ui_ready
2184 }
2185
2186 proc ui_do_rescan {} {
2187         rescan {force_first_diff ui_ready}
2188 }
2189
2190 proc do_commit {} {
2191         commit_tree
2192 }
2193
2194 proc next_diff {{after {}}} {
2195         global next_diff_p next_diff_w next_diff_i
2196         show_diff $next_diff_p $next_diff_w {} {} $after
2197 }
2198
2199 proc find_anchor_pos {lst name} {
2200         set lid [lsearch -sorted -exact $lst $name]
2201
2202         if {$lid == -1} {
2203                 set lid 0
2204                 foreach lname $lst {
2205                         if {$lname >= $name} break
2206                         incr lid
2207                 }
2208         }
2209
2210         return $lid
2211 }
2212
2213 proc find_file_from {flist idx delta path mmask} {
2214         global file_states
2215
2216         set len [llength $flist]
2217         while {$idx >= 0 && $idx < $len} {
2218                 set name [lindex $flist $idx]
2219
2220                 if {$name ne $path && [info exists file_states($name)]} {
2221                         set state [lindex $file_states($name) 0]
2222
2223                         if {$mmask eq {} || [regexp $mmask $state]} {
2224                                 return $idx
2225                         }
2226                 }
2227
2228                 incr idx $delta
2229         }
2230
2231         return {}
2232 }
2233
2234 proc find_next_diff {w path {lno {}} {mmask {}}} {
2235         global next_diff_p next_diff_w next_diff_i
2236         global file_lists ui_index ui_workdir
2237
2238         set flist $file_lists($w)
2239         if {$lno eq {}} {
2240                 set lno [find_anchor_pos $flist $path]
2241         } else {
2242                 incr lno -1
2243         }
2244
2245         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2246                 if {$w eq $ui_index} {
2247                         set mmask "^$mmask"
2248                 } else {
2249                         set mmask "$mmask\$"
2250                 }
2251         }
2252
2253         set idx [find_file_from $flist $lno 1 $path $mmask]
2254         if {$idx eq {}} {
2255                 incr lno -1
2256                 set idx [find_file_from $flist $lno -1 $path $mmask]
2257         }
2258
2259         if {$idx ne {}} {
2260                 set next_diff_w $w
2261                 set next_diff_p [lindex $flist $idx]
2262                 set next_diff_i [expr {$idx+1}]
2263                 return 1
2264         } else {
2265                 return 0
2266         }
2267 }
2268
2269 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2270         global current_diff_path
2271
2272         if {$path ne $current_diff_path} {
2273                 return {}
2274         } elseif {[find_next_diff $w $path $lno $mmask]} {
2275                 return {next_diff;}
2276         } else {
2277                 return {reshow_diff;}
2278         }
2279 }
2280
2281 proc select_first_diff {after} {
2282         global ui_workdir
2283
2284         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2285             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2286                 next_diff $after
2287         } else {
2288                 uplevel #0 $after
2289         }
2290 }
2291
2292 proc force_first_diff {after} {
2293         global ui_workdir current_diff_path file_states
2294
2295         if {[info exists file_states($current_diff_path)]} {
2296                 set state [lindex $file_states($current_diff_path) 0]
2297         } else {
2298                 set state {OO}
2299         }
2300
2301         set reselect 0
2302         if {[string first {U} $state] >= 0} {
2303                 # Already a conflict, do nothing
2304         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2305                 set reselect 1
2306         } elseif {[string index $state 1] ne {O}} {
2307                 # Already a diff & no conflicts, do nothing
2308         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2309                 set reselect 1
2310         }
2311
2312         if {$reselect} {
2313                 next_diff $after
2314         } else {
2315                 uplevel #0 $after
2316         }
2317 }
2318
2319 proc toggle_or_diff {w x y} {
2320         global file_states file_lists current_diff_path ui_index ui_workdir
2321         global last_clicked selected_paths
2322
2323         set pos [split [$w index @$x,$y] .]
2324         set lno [lindex $pos 0]
2325         set col [lindex $pos 1]
2326         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2327         if {$path eq {}} {
2328                 set last_clicked {}
2329                 return
2330         }
2331
2332         set last_clicked [list $w $lno]
2333         array unset selected_paths
2334         $ui_index tag remove in_sel 0.0 end
2335         $ui_workdir tag remove in_sel 0.0 end
2336
2337         # Determine the state of the file
2338         if {[info exists file_states($path)]} {
2339                 set state [lindex $file_states($path) 0]
2340         } else {
2341                 set state {__}
2342         }
2343
2344         # Restage the file, or simply show the diff
2345         if {$col == 0 && $y > 1} {
2346                 # Conflicts need special handling
2347                 if {[string first {U} $state] >= 0} {
2348                         # $w must always be $ui_workdir, but...
2349                         if {$w ne $ui_workdir} { set lno {} }
2350                         merge_stage_workdir $path $lno
2351                         return
2352                 }
2353
2354                 if {[string index $state 1] eq {O}} {
2355                         set mmask {}
2356                 } else {
2357                         set mmask {[^O]}
2358                 }
2359
2360                 set after [next_diff_after_action $w $path $lno $mmask]
2361
2362                 if {$w eq $ui_index} {
2363                         update_indexinfo \
2364                                 "Unstaging [short_path $path] from commit" \
2365                                 [list $path] \
2366                                 [concat $after [list ui_ready]]
2367                 } elseif {$w eq $ui_workdir} {
2368                         update_index \
2369                                 "Adding [short_path $path]" \
2370                                 [list $path] \
2371                                 [concat $after [list ui_ready]]
2372                 }
2373         } else {
2374                 show_diff $path $w $lno
2375         }
2376 }
2377
2378 proc add_one_to_selection {w x y} {
2379         global file_lists last_clicked selected_paths
2380
2381         set lno [lindex [split [$w index @$x,$y] .] 0]
2382         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2383         if {$path eq {}} {
2384                 set last_clicked {}
2385                 return
2386         }
2387
2388         if {$last_clicked ne {}
2389                 && [lindex $last_clicked 0] ne $w} {
2390                 array unset selected_paths
2391                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2392         }
2393
2394         set last_clicked [list $w $lno]
2395         if {[catch {set in_sel $selected_paths($path)}]} {
2396                 set in_sel 0
2397         }
2398         if {$in_sel} {
2399                 unset selected_paths($path)
2400                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2401         } else {
2402                 set selected_paths($path) 1
2403                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2404         }
2405 }
2406
2407 proc add_range_to_selection {w x y} {
2408         global file_lists last_clicked selected_paths
2409
2410         if {[lindex $last_clicked 0] ne $w} {
2411                 toggle_or_diff $w $x $y
2412                 return
2413         }
2414
2415         set lno [lindex [split [$w index @$x,$y] .] 0]
2416         set lc [lindex $last_clicked 1]
2417         if {$lc < $lno} {
2418                 set begin $lc
2419                 set end $lno
2420         } else {
2421                 set begin $lno
2422                 set end $lc
2423         }
2424
2425         foreach path [lrange $file_lists($w) \
2426                 [expr {$begin - 1}] \
2427                 [expr {$end - 1}]] {
2428                 set selected_paths($path) 1
2429         }
2430         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2431 }
2432
2433 proc show_more_context {} {
2434         global repo_config
2435         if {$repo_config(gui.diffcontext) < 99} {
2436                 incr repo_config(gui.diffcontext)
2437                 reshow_diff
2438         }
2439 }
2440
2441 proc show_less_context {} {
2442         global repo_config
2443         if {$repo_config(gui.diffcontext) > 1} {
2444                 incr repo_config(gui.diffcontext) -1
2445                 reshow_diff
2446         }
2447 }
2448
2449 ######################################################################
2450 ##
2451 ## ui construction
2452
2453 set ui_comm {}
2454
2455 # -- Menu Bar
2456 #
2457 menu .mbar -tearoff 0
2458 if {[is_MacOSX]} {
2459         # -- Apple Menu (Mac OS X only)
2460         #
2461         .mbar add cascade -label Apple -menu .mbar.apple
2462         menu .mbar.apple
2463 }
2464 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2465 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2466 if {[is_enabled branch]} {
2467         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2468 }
2469 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2470         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2471 }
2472 if {[is_enabled transport]} {
2473         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2474         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2475 }
2476 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2477         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2478 }
2479
2480 # -- Repository Menu
2481 #
2482 menu .mbar.repository
2483
2484 if {![is_bare]} {
2485         .mbar.repository add command \
2486                 -label [mc "Explore Working Copy"] \
2487                 -command {do_explore}
2488         .mbar.repository add separator
2489 }
2490
2491 .mbar.repository add command \
2492         -label [mc "Browse Current Branch's Files"] \
2493         -command {browser::new $current_branch}
2494 set ui_browse_current [.mbar.repository index last]
2495 .mbar.repository add command \
2496         -label [mc "Browse Branch Files..."] \
2497         -command browser_open::dialog
2498 .mbar.repository add separator
2499
2500 .mbar.repository add command \
2501         -label [mc "Visualize Current Branch's History"] \
2502         -command {do_gitk $current_branch}
2503 set ui_visualize_current [.mbar.repository index last]
2504 .mbar.repository add command \
2505         -label [mc "Visualize All Branch History"] \
2506         -command {do_gitk --all}
2507 .mbar.repository add separator
2508
2509 proc current_branch_write {args} {
2510         global current_branch
2511         .mbar.repository entryconf $::ui_browse_current \
2512                 -label [mc "Browse %s's Files" $current_branch]
2513         .mbar.repository entryconf $::ui_visualize_current \
2514                 -label [mc "Visualize %s's History" $current_branch]
2515 }
2516 trace add variable current_branch write current_branch_write
2517
2518 if {[is_enabled multicommit]} {
2519         .mbar.repository add command -label [mc "Database Statistics"] \
2520                 -command do_stats
2521
2522         .mbar.repository add command -label [mc "Compress Database"] \
2523                 -command do_gc
2524
2525         .mbar.repository add command -label [mc "Verify Database"] \
2526                 -command do_fsck_objects
2527
2528         .mbar.repository add separator
2529
2530         if {[is_Cygwin]} {
2531                 .mbar.repository add command \
2532                         -label [mc "Create Desktop Icon"] \
2533                         -command do_cygwin_shortcut
2534         } elseif {[is_Windows]} {
2535                 .mbar.repository add command \
2536                         -label [mc "Create Desktop Icon"] \
2537                         -command do_windows_shortcut
2538         } elseif {[is_MacOSX]} {
2539                 .mbar.repository add command \
2540                         -label [mc "Create Desktop Icon"] \
2541                         -command do_macosx_app
2542         }
2543 }
2544
2545 if {[is_MacOSX]} {
2546         proc ::tk::mac::Quit {args} { do_quit }
2547 } else {
2548         .mbar.repository add command -label [mc Quit] \
2549                 -command do_quit \
2550                 -accelerator $M1T-Q
2551 }
2552
2553 # -- Edit Menu
2554 #
2555 menu .mbar.edit
2556 .mbar.edit add command -label [mc Undo] \
2557         -command {catch {[focus] edit undo}} \
2558         -accelerator $M1T-Z
2559 .mbar.edit add command -label [mc Redo] \
2560         -command {catch {[focus] edit redo}} \
2561         -accelerator $M1T-Y
2562 .mbar.edit add separator
2563 .mbar.edit add command -label [mc Cut] \
2564         -command {catch {tk_textCut [focus]}} \
2565         -accelerator $M1T-X
2566 .mbar.edit add command -label [mc Copy] \
2567         -command {catch {tk_textCopy [focus]}} \
2568         -accelerator $M1T-C
2569 .mbar.edit add command -label [mc Paste] \
2570         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2571         -accelerator $M1T-V
2572 .mbar.edit add command -label [mc Delete] \
2573         -command {catch {[focus] delete sel.first sel.last}} \
2574         -accelerator Del
2575 .mbar.edit add separator
2576 .mbar.edit add command -label [mc "Select All"] \
2577         -command {catch {[focus] tag add sel 0.0 end}} \
2578         -accelerator $M1T-A
2579
2580 # -- Branch Menu
2581 #
2582 if {[is_enabled branch]} {
2583         menu .mbar.branch
2584
2585         .mbar.branch add command -label [mc "Create..."] \
2586                 -command branch_create::dialog \
2587                 -accelerator $M1T-N
2588         lappend disable_on_lock [list .mbar.branch entryconf \
2589                 [.mbar.branch index last] -state]
2590
2591         .mbar.branch add command -label [mc "Checkout..."] \
2592                 -command branch_checkout::dialog \
2593                 -accelerator $M1T-O
2594         lappend disable_on_lock [list .mbar.branch entryconf \
2595                 [.mbar.branch index last] -state]
2596
2597         .mbar.branch add command -label [mc "Rename..."] \
2598                 -command branch_rename::dialog
2599         lappend disable_on_lock [list .mbar.branch entryconf \
2600                 [.mbar.branch index last] -state]
2601
2602         .mbar.branch add command -label [mc "Delete..."] \
2603                 -command branch_delete::dialog
2604         lappend disable_on_lock [list .mbar.branch entryconf \
2605                 [.mbar.branch index last] -state]
2606
2607         .mbar.branch add command -label [mc "Reset..."] \
2608                 -command merge::reset_hard
2609         lappend disable_on_lock [list .mbar.branch entryconf \
2610                 [.mbar.branch index last] -state]
2611 }
2612
2613 # -- Commit Menu
2614 #
2615 proc commit_btn_caption {} {
2616         if {[is_enabled nocommit]} {
2617                 return [mc "Done"]
2618         } else {
2619                 return [mc Commit@@verb]
2620         }
2621 }
2622
2623 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2624         menu .mbar.commit
2625
2626         if {![is_enabled nocommit]} {
2627                 .mbar.commit add radiobutton \
2628                         -label [mc "New Commit"] \
2629                         -command do_select_commit_type \
2630                         -variable selected_commit_type \
2631                         -value new
2632                 lappend disable_on_lock \
2633                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2634
2635                 .mbar.commit add radiobutton \
2636                         -label [mc "Amend Last Commit"] \
2637                         -command do_select_commit_type \
2638                         -variable selected_commit_type \
2639                         -value amend
2640                 lappend disable_on_lock \
2641                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2642
2643                 .mbar.commit add separator
2644         }
2645
2646         .mbar.commit add command -label [mc Rescan] \
2647                 -command ui_do_rescan \
2648                 -accelerator F5
2649         lappend disable_on_lock \
2650                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2651
2652         .mbar.commit add command -label [mc "Stage To Commit"] \
2653                 -command do_add_selection \
2654                 -accelerator $M1T-T
2655         lappend disable_on_lock \
2656                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2657
2658         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2659                 -command do_add_all \
2660                 -accelerator $M1T-I
2661         lappend disable_on_lock \
2662                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2663
2664         .mbar.commit add command -label [mc "Unstage From Commit"] \
2665                 -command do_unstage_selection \
2666                 -accelerator $M1T-U
2667         lappend disable_on_lock \
2668                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2669
2670         .mbar.commit add command -label [mc "Revert Changes"] \
2671                 -command do_revert_selection \
2672                 -accelerator $M1T-J
2673         lappend disable_on_lock \
2674                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2675
2676         .mbar.commit add separator
2677
2678         .mbar.commit add command -label [mc "Show Less Context"] \
2679                 -command show_less_context \
2680                 -accelerator $M1T-\-
2681
2682         .mbar.commit add command -label [mc "Show More Context"] \
2683                 -command show_more_context \
2684                 -accelerator $M1T-=
2685
2686         .mbar.commit add separator
2687
2688         if {![is_enabled nocommitmsg]} {
2689                 .mbar.commit add command -label [mc "Sign Off"] \
2690                         -command do_signoff \
2691                         -accelerator $M1T-S
2692         }
2693
2694         .mbar.commit add command -label [commit_btn_caption] \
2695                 -command do_commit \
2696                 -accelerator $M1T-Return
2697         lappend disable_on_lock \
2698                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2699 }
2700
2701 # -- Merge Menu
2702 #
2703 if {[is_enabled branch]} {
2704         menu .mbar.merge
2705         .mbar.merge add command -label [mc "Local Merge..."] \
2706                 -command merge::dialog \
2707                 -accelerator $M1T-M
2708         lappend disable_on_lock \
2709                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2710         .mbar.merge add command -label [mc "Abort Merge..."] \
2711                 -command merge::reset_hard
2712         lappend disable_on_lock \
2713                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2714 }
2715
2716 # -- Transport Menu
2717 #
2718 if {[is_enabled transport]} {
2719         menu .mbar.remote
2720
2721         .mbar.remote add command \
2722                 -label [mc "Add..."] \
2723                 -command remote_add::dialog \
2724                 -accelerator $M1T-A
2725         .mbar.remote add command \
2726                 -label [mc "Push..."] \
2727                 -command do_push_anywhere \
2728                 -accelerator $M1T-P
2729         .mbar.remote add command \
2730                 -label [mc "Delete Branch..."] \
2731                 -command remote_branch_delete::dialog
2732 }
2733
2734 if {[is_MacOSX]} {
2735         proc ::tk::mac::ShowPreferences {} {do_options}
2736 } else {
2737         # -- Edit Menu
2738         #
2739         .mbar.edit add separator
2740         .mbar.edit add command -label [mc "Options..."] \
2741                 -command do_options
2742 }
2743
2744 # -- Tools Menu
2745 #
2746 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2747         set tools_menubar .mbar.tools
2748         menu $tools_menubar
2749         $tools_menubar add separator
2750         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2751         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2752         set tools_tailcnt 3
2753         if {[array names repo_config guitool.*.cmd] ne {}} {
2754                 tools_populate_all
2755         }
2756 }
2757
2758 # -- Help Menu
2759 #
2760 .mbar add cascade -label [mc Help] -menu .mbar.help
2761 menu .mbar.help
2762
2763 if {[is_MacOSX]} {
2764         .mbar.apple add command -label [mc "About %s" [appname]] \
2765                 -command do_about
2766         .mbar.apple add separator
2767 } else {
2768         .mbar.help add command -label [mc "About %s" [appname]] \
2769                 -command do_about
2770 }
2771 . configure -menu .mbar
2772
2773 set doc_path [githtmldir]
2774 if {$doc_path ne {}} {
2775         set doc_path [file join $doc_path index.html]
2776
2777         if {[is_Cygwin]} {
2778                 set doc_path [exec cygpath --mixed $doc_path]
2779         }
2780 }
2781
2782 if {[file isfile $doc_path]} {
2783         set doc_url "file:$doc_path"
2784 } else {
2785         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2786 }
2787
2788 proc start_browser {url} {
2789         git "web--browse" $url
2790 }
2791
2792 .mbar.help add command -label [mc "Online Documentation"] \
2793         -command [list start_browser $doc_url]
2794
2795 .mbar.help add command -label [mc "Show SSH Key"] \
2796         -command do_ssh_key
2797
2798 unset doc_path doc_url
2799
2800 # -- Standard bindings
2801 #
2802 wm protocol . WM_DELETE_WINDOW do_quit
2803 bind all <$M1B-Key-q> do_quit
2804 bind all <$M1B-Key-Q> do_quit
2805 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2806 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2807
2808 set subcommand_args {}
2809 proc usage {} {
2810         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2811         exit 1
2812 }
2813
2814 proc normalize_relpath {path} {
2815         set elements {}
2816         foreach item [file split $path] {
2817                 if {$item eq {.}} continue
2818                 if {$item eq {..} && [llength $elements] > 0
2819                     && [lindex $elements end] ne {..}} {
2820                         set elements [lrange $elements 0 end-1]
2821                         continue
2822                 }
2823                 lappend elements $item
2824         }
2825         return [eval file join $elements]
2826 }
2827
2828 # -- Not a normal commit type invocation?  Do that instead!
2829 #
2830 switch -- $subcommand {
2831 browser -
2832 blame {
2833         if {$subcommand eq "blame"} {
2834                 set subcommand_args {[--line=<num>] rev? path}
2835         } else {
2836                 set subcommand_args {rev? path}
2837         }
2838         if {$argv eq {}} usage
2839         set head {}
2840         set path {}
2841         set jump_spec {}
2842         set is_path 0
2843         foreach a $argv {
2844                 if {$is_path || [file exists $_prefix$a]} {
2845                         if {$path ne {}} usage
2846                         set path [normalize_relpath $_prefix$a]
2847                         break
2848                 } elseif {$a eq {--}} {
2849                         if {$path ne {}} {
2850                                 if {$head ne {}} usage
2851                                 set head $path
2852                                 set path {}
2853                         }
2854                         set is_path 1
2855                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2856                         if {$jump_spec ne {} || $head ne {}} usage
2857                         set jump_spec [list $lnum]
2858                 } elseif {$head eq {}} {
2859                         if {$head ne {}} usage
2860                         set head $a
2861                         set is_path 1
2862                 } else {
2863                         usage
2864                 }
2865         }
2866         unset is_path
2867
2868         if {$head ne {} && $path eq {}} {
2869                 set path [normalize_relpath $_prefix$head]
2870                 set head {}
2871         }
2872
2873         if {$head eq {}} {
2874                 load_current_branch
2875         } else {
2876                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2877                         if {[catch {
2878                                         set head [git rev-parse --verify $head]
2879                                 } err]} {
2880                                 puts stderr $err
2881                                 exit 1
2882                         }
2883                 }
2884                 set current_branch $head
2885         }
2886
2887         switch -- $subcommand {
2888         browser {
2889                 if {$jump_spec ne {}} usage
2890                 if {$head eq {}} {
2891                         if {$path ne {} && [file isdirectory $path]} {
2892                                 set head $current_branch
2893                         } else {
2894                                 set head $path
2895                                 set path {}
2896                         }
2897                 }
2898                 browser::new $head $path
2899         }
2900         blame   {
2901                 if {$head eq {} && ![file exists $path]} {
2902                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2903                         exit 1
2904                 }
2905                 blame::new $head $path $jump_spec
2906         }
2907         }
2908         return
2909 }
2910 citool -
2911 gui {
2912         if {[llength $argv] != 0} {
2913                 puts -nonewline stderr "usage: $argv0"
2914                 if {$subcommand ne {gui}
2915                         && [file tail $argv0] ne "git-$subcommand"} {
2916                         puts -nonewline stderr " $subcommand"
2917                 }
2918                 puts stderr {}
2919                 exit 1
2920         }
2921         # fall through to setup UI for commits
2922 }
2923 default {
2924         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2925         exit 1
2926 }
2927 }
2928
2929 # -- Branch Control
2930 #
2931 frame .branch \
2932         -borderwidth 1 \
2933         -relief sunken
2934 label .branch.l1 \
2935         -text [mc "Current Branch:"] \
2936         -anchor w \
2937         -justify left
2938 label .branch.cb \
2939         -textvariable current_branch \
2940         -anchor w \
2941         -justify left
2942 pack .branch.l1 -side left
2943 pack .branch.cb -side left -fill x
2944 pack .branch -side top -fill x
2945
2946 # -- Main Window Layout
2947 #
2948 panedwindow .vpane -orient horizontal
2949 panedwindow .vpane.files -orient vertical
2950 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2951 pack .vpane -anchor n -side top -fill both -expand 1
2952
2953 # -- Index File List
2954 #
2955 frame .vpane.files.index -height 100 -width 200
2956 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2957         -background lightgreen -foreground black
2958 text $ui_index -background white -foreground black \
2959         -borderwidth 0 \
2960         -width 20 -height 10 \
2961         -wrap none \
2962         -cursor $cursor_ptr \
2963         -xscrollcommand {.vpane.files.index.sx set} \
2964         -yscrollcommand {.vpane.files.index.sy set} \
2965         -state disabled
2966 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2967 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2968 pack .vpane.files.index.title -side top -fill x
2969 pack .vpane.files.index.sx -side bottom -fill x
2970 pack .vpane.files.index.sy -side right -fill y
2971 pack $ui_index -side left -fill both -expand 1
2972
2973 # -- Working Directory File List
2974 #
2975 frame .vpane.files.workdir -height 100 -width 200
2976 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2977         -background lightsalmon -foreground black
2978 text $ui_workdir -background white -foreground black \
2979         -borderwidth 0 \
2980         -width 20 -height 10 \
2981         -wrap none \
2982         -cursor $cursor_ptr \
2983         -xscrollcommand {.vpane.files.workdir.sx set} \
2984         -yscrollcommand {.vpane.files.workdir.sy set} \
2985         -state disabled
2986 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2987 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2988 pack .vpane.files.workdir.title -side top -fill x
2989 pack .vpane.files.workdir.sx -side bottom -fill x
2990 pack .vpane.files.workdir.sy -side right -fill y
2991 pack $ui_workdir -side left -fill both -expand 1
2992
2993 .vpane.files add .vpane.files.workdir -sticky nsew
2994 .vpane.files add .vpane.files.index -sticky nsew
2995
2996 foreach i [list $ui_index $ui_workdir] {
2997         rmsel_tag $i
2998         $i tag conf in_diff -background [$i tag cget in_sel -background]
2999 }
3000 unset i
3001
3002 # -- Diff and Commit Area
3003 #
3004 frame .vpane.lower -height 300 -width 400
3005 frame .vpane.lower.commarea
3006 frame .vpane.lower.diff -relief sunken -borderwidth 1
3007 pack .vpane.lower.diff -fill both -expand 1
3008 pack .vpane.lower.commarea -side bottom -fill x
3009 .vpane add .vpane.lower -sticky nsew
3010
3011 # -- Commit Area Buttons
3012 #
3013 frame .vpane.lower.commarea.buttons
3014 label .vpane.lower.commarea.buttons.l -text {} \
3015         -anchor w \
3016         -justify left
3017 pack .vpane.lower.commarea.buttons.l -side top -fill x
3018 pack .vpane.lower.commarea.buttons -side left -fill y
3019
3020 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3021         -command ui_do_rescan
3022 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3023 lappend disable_on_lock \
3024         {.vpane.lower.commarea.buttons.rescan conf -state}
3025
3026 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3027         -command do_add_all
3028 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3029 lappend disable_on_lock \
3030         {.vpane.lower.commarea.buttons.incall conf -state}
3031
3032 if {![is_enabled nocommitmsg]} {
3033         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3034                 -command do_signoff
3035         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3036 }
3037
3038 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3039         -command do_commit
3040 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3041 lappend disable_on_lock \
3042         {.vpane.lower.commarea.buttons.commit conf -state}
3043
3044 if {![is_enabled nocommit]} {
3045         button .vpane.lower.commarea.buttons.push -text [mc Push] \
3046                 -command do_push_anywhere
3047         pack .vpane.lower.commarea.buttons.push -side top -fill x
3048 }
3049
3050 # -- Commit Message Buffer
3051 #
3052 frame .vpane.lower.commarea.buffer
3053 frame .vpane.lower.commarea.buffer.header
3054 set ui_comm .vpane.lower.commarea.buffer.t
3055 set ui_coml .vpane.lower.commarea.buffer.header.l
3056
3057 if {![is_enabled nocommit]} {
3058         radiobutton .vpane.lower.commarea.buffer.header.new \
3059                 -text [mc "New Commit"] \
3060                 -command do_select_commit_type \
3061                 -variable selected_commit_type \
3062                 -value new
3063         lappend disable_on_lock \
3064                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3065         radiobutton .vpane.lower.commarea.buffer.header.amend \
3066                 -text [mc "Amend Last Commit"] \
3067                 -command do_select_commit_type \
3068                 -variable selected_commit_type \
3069                 -value amend
3070         lappend disable_on_lock \
3071                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3072 }
3073
3074 label $ui_coml \
3075         -anchor w \
3076         -justify left
3077 proc trace_commit_type {varname args} {
3078         global ui_coml commit_type
3079         switch -glob -- $commit_type {
3080         initial       {set txt [mc "Initial Commit Message:"]}
3081         amend         {set txt [mc "Amended Commit Message:"]}
3082         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3083         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3084         merge         {set txt [mc "Merge Commit Message:"]}
3085         *             {set txt [mc "Commit Message:"]}
3086         }
3087         $ui_coml conf -text $txt
3088 }
3089 trace add variable commit_type write trace_commit_type
3090 pack $ui_coml -side left -fill x
3091
3092 if {![is_enabled nocommit]} {
3093         pack .vpane.lower.commarea.buffer.header.amend -side right
3094         pack .vpane.lower.commarea.buffer.header.new -side right
3095 }
3096
3097 text $ui_comm -background white -foreground black \
3098         -borderwidth 1 \
3099         -undo true \
3100         -maxundo 20 \
3101         -autoseparators true \
3102         -relief sunken \
3103         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3104         -font font_diff \
3105         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3106 scrollbar .vpane.lower.commarea.buffer.sby \
3107         -command [list $ui_comm yview]
3108 pack .vpane.lower.commarea.buffer.header -side top -fill x
3109 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3110 pack $ui_comm -side left -fill y
3111 pack .vpane.lower.commarea.buffer -side left -fill y
3112
3113 # -- Commit Message Buffer Context Menu
3114 #
3115 set ctxm .vpane.lower.commarea.buffer.ctxm
3116 menu $ctxm -tearoff 0
3117 $ctxm add command \
3118         -label [mc Cut] \
3119         -command {tk_textCut $ui_comm}
3120 $ctxm add command \
3121         -label [mc Copy] \
3122         -command {tk_textCopy $ui_comm}
3123 $ctxm add command \
3124         -label [mc Paste] \
3125         -command {tk_textPaste $ui_comm}
3126 $ctxm add command \
3127         -label [mc Delete] \
3128         -command {catch {$ui_comm delete sel.first sel.last}}
3129 $ctxm add separator
3130 $ctxm add command \
3131         -label [mc "Select All"] \
3132         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3133 $ctxm add command \
3134         -label [mc "Copy All"] \
3135         -command {
3136                 $ui_comm tag add sel 0.0 end
3137                 tk_textCopy $ui_comm
3138                 $ui_comm tag remove sel 0.0 end
3139         }
3140 $ctxm add separator
3141 $ctxm add command \
3142         -label [mc "Sign Off"] \
3143         -command do_signoff
3144 set ui_comm_ctxm $ctxm
3145
3146 # -- Diff Header
3147 #
3148 proc trace_current_diff_path {varname args} {
3149         global current_diff_path diff_actions file_states
3150         if {$current_diff_path eq {}} {
3151                 set s {}
3152                 set f {}
3153                 set p {}
3154                 set o disabled
3155         } else {
3156                 set p $current_diff_path
3157                 set s [mapdesc [lindex $file_states($p) 0] $p]
3158                 set f [mc "File:"]
3159                 set p [escape_path $p]
3160                 set o normal
3161         }
3162
3163         .vpane.lower.diff.header.status configure -text $s
3164         .vpane.lower.diff.header.file configure -text $f
3165         .vpane.lower.diff.header.path configure -text $p
3166         foreach w $diff_actions {
3167                 uplevel #0 $w $o
3168         }
3169 }
3170 trace add variable current_diff_path write trace_current_diff_path
3171
3172 frame .vpane.lower.diff.header -background gold
3173 label .vpane.lower.diff.header.status \
3174         -background gold \
3175         -foreground black \
3176         -width $max_status_desc \
3177         -anchor w \
3178         -justify left
3179 label .vpane.lower.diff.header.file \
3180         -background gold \
3181         -foreground black \
3182         -anchor w \
3183         -justify left
3184 label .vpane.lower.diff.header.path \
3185         -background gold \
3186         -foreground black \
3187         -anchor w \
3188         -justify left
3189 pack .vpane.lower.diff.header.status -side left
3190 pack .vpane.lower.diff.header.file -side left
3191 pack .vpane.lower.diff.header.path -fill x
3192 set ctxm .vpane.lower.diff.header.ctxm
3193 menu $ctxm -tearoff 0
3194 $ctxm add command \
3195         -label [mc Copy] \
3196         -command {
3197                 clipboard clear
3198                 clipboard append \
3199                         -format STRING \
3200                         -type STRING \
3201                         -- $current_diff_path
3202         }
3203 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3204 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3205
3206 # -- Diff Body
3207 #
3208 frame .vpane.lower.diff.body
3209 set ui_diff .vpane.lower.diff.body.t
3210 text $ui_diff -background white -foreground black \
3211         -borderwidth 0 \
3212         -width 80 -height 5 -wrap none \
3213         -font font_diff \
3214         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3215         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3216         -state disabled
3217 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3218         -command [list $ui_diff xview]
3219 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3220         -command [list $ui_diff yview]
3221 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3222 pack .vpane.lower.diff.body.sby -side right -fill y
3223 pack $ui_diff -side left -fill both -expand 1
3224 pack .vpane.lower.diff.header -side top -fill x
3225 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3226
3227 $ui_diff tag conf d_cr -elide true
3228 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
3229 $ui_diff tag conf d_+ -foreground {#00a000}
3230 $ui_diff tag conf d_- -foreground red
3231
3232 $ui_diff tag conf d_++ -foreground {#00a000}
3233 $ui_diff tag conf d_-- -foreground red
3234 $ui_diff tag conf d_+s \
3235         -foreground {#00a000} \
3236         -background {#e2effa}
3237 $ui_diff tag conf d_-s \
3238         -foreground red \
3239         -background {#e2effa}
3240 $ui_diff tag conf d_s+ \
3241         -foreground {#00a000} \
3242         -background ivory1
3243 $ui_diff tag conf d_s- \
3244         -foreground red \
3245         -background ivory1
3246
3247 $ui_diff tag conf d<<<<<<< \
3248         -foreground orange \
3249         -font font_diffbold
3250 $ui_diff tag conf d======= \
3251         -foreground orange \
3252         -font font_diffbold
3253 $ui_diff tag conf d>>>>>>> \
3254         -foreground orange \
3255         -font font_diffbold
3256
3257 $ui_diff tag raise sel
3258
3259 # -- Diff Body Context Menu
3260 #
3261
3262 proc create_common_diff_popup {ctxm} {
3263         $ctxm add command \
3264                 -label [mc Refresh] \
3265                 -command reshow_diff
3266         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3267         $ctxm add command \
3268                 -label [mc Copy] \
3269                 -command {tk_textCopy $ui_diff}
3270         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3271         $ctxm add command \
3272                 -label [mc "Select All"] \
3273                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3274         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3275         $ctxm add command \
3276                 -label [mc "Copy All"] \
3277                 -command {
3278                         $ui_diff tag add sel 0.0 end
3279                         tk_textCopy $ui_diff
3280                         $ui_diff tag remove sel 0.0 end
3281                 }
3282         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3283         $ctxm add separator
3284         $ctxm add command \
3285                 -label [mc "Decrease Font Size"] \
3286                 -command {incr_font_size font_diff -1}
3287         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3288         $ctxm add command \
3289                 -label [mc "Increase Font Size"] \
3290                 -command {incr_font_size font_diff 1}
3291         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3292         $ctxm add separator
3293         set emenu $ctxm.enc
3294         menu $emenu
3295         build_encoding_menu $emenu [list force_diff_encoding]
3296         $ctxm add cascade \
3297                 -label [mc "Encoding"] \
3298                 -menu $emenu
3299         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3300         $ctxm add separator
3301         $ctxm add command -label [mc "Options..."] \
3302                 -command do_options
3303 }
3304
3305 set ctxm .vpane.lower.diff.body.ctxm
3306 menu $ctxm -tearoff 0
3307 $ctxm add command \
3308         -label [mc "Apply/Reverse Hunk"] \
3309         -command {apply_hunk $cursorX $cursorY}
3310 set ui_diff_applyhunk [$ctxm index last]
3311 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3312 $ctxm add command \
3313         -label [mc "Apply/Reverse Line"] \
3314         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3315 set ui_diff_applyline [$ctxm index last]
3316 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3317 $ctxm add separator
3318 $ctxm add command \
3319         -label [mc "Show Less Context"] \
3320         -command show_less_context
3321 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3322 $ctxm add command \
3323         -label [mc "Show More Context"] \
3324         -command show_more_context
3325 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3326 $ctxm add separator
3327 create_common_diff_popup $ctxm
3328
3329 set ctxmmg .vpane.lower.diff.body.ctxmmg
3330 menu $ctxmmg -tearoff 0
3331 $ctxmmg add command \
3332         -label [mc "Run Merge Tool"] \
3333         -command {merge_resolve_tool}
3334 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3335 $ctxmmg add separator
3336 $ctxmmg add command \
3337         -label [mc "Use Remote Version"] \
3338         -command {merge_resolve_one 3}
3339 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3340 $ctxmmg add command \
3341         -label [mc "Use Local Version"] \
3342         -command {merge_resolve_one 2}
3343 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3344 $ctxmmg add command \
3345         -label [mc "Revert To Base"] \
3346         -command {merge_resolve_one 1}
3347 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3348 $ctxmmg add separator
3349 $ctxmmg add command \
3350         -label [mc "Show Less Context"] \
3351         -command show_less_context
3352 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3353 $ctxmmg add command \
3354         -label [mc "Show More Context"] \
3355         -command show_more_context
3356 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3357 $ctxmmg add separator
3358 create_common_diff_popup $ctxmmg
3359
3360 set ctxmsm .vpane.lower.diff.body.ctxmsm
3361 menu $ctxmsm -tearoff 0
3362 $ctxmsm add command \
3363         -label [mc "Visualize These Changes In The Submodule"] \
3364         -command {do_gitk -- true}
3365 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3366 $ctxmsm add command \
3367         -label [mc "Visualize Current Branch History In The Submodule"] \
3368         -command {do_gitk {} true}
3369 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3370 $ctxmsm add command \
3371         -label [mc "Visualize All Branch History In The Submodule"] \
3372         -command {do_gitk --all true}
3373 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3374 $ctxmsm add separator
3375 $ctxmsm add command \
3376         -label [mc "Start git gui In The Submodule"] \
3377         -command {do_git_gui}
3378 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3379 $ctxmsm add separator
3380 create_common_diff_popup $ctxmsm
3381
3382 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3383         global current_diff_path file_states
3384         set ::cursorX $x
3385         set ::cursorY $y
3386         if {[info exists file_states($current_diff_path)]} {
3387                 set state [lindex $file_states($current_diff_path) 0]
3388         } else {
3389                 set state {__}
3390         }
3391         if {[string first {U} $state] >= 0} {
3392                 tk_popup $ctxmmg $X $Y
3393         } elseif {$::is_submodule_diff} {
3394                 tk_popup $ctxmsm $X $Y
3395         } else {
3396                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3397                 if {$::ui_index eq $::current_diff_side} {
3398                         set l [mc "Unstage Hunk From Commit"]
3399                         if {$has_range} {
3400                                 set t [mc "Unstage Lines From Commit"]
3401                         } else {
3402                                 set t [mc "Unstage Line From Commit"]
3403                         }
3404                 } else {
3405                         set l [mc "Stage Hunk For Commit"]
3406                         if {$has_range} {
3407                                 set t [mc "Stage Lines For Commit"]
3408                         } else {
3409                                 set t [mc "Stage Line For Commit"]
3410                         }
3411                 }
3412                 if {$::is_3way_diff
3413                         || $current_diff_path eq {}
3414                         || {__} eq $state
3415                         || {_O} eq $state
3416                         || {_T} eq $state
3417                         || {T_} eq $state} {
3418                         set s disabled
3419                 } else {
3420                         set s normal
3421                 }
3422                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3423                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3424                 tk_popup $ctxm $X $Y
3425         }
3426 }
3427 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3428
3429 # -- Status Bar
3430 #
3431 set main_status [::status_bar::new .status]
3432 pack .status -anchor w -side bottom -fill x
3433 $main_status show [mc "Initializing..."]
3434
3435 # -- Load geometry
3436 #
3437 catch {
3438 set gm $repo_config(gui.geometry)
3439 wm geometry . [lindex $gm 0]
3440 .vpane sash place 0 \
3441         [lindex $gm 1] \
3442         [lindex [.vpane sash coord 0] 1]
3443 .vpane.files sash place 0 \
3444         [lindex [.vpane.files sash coord 0] 0] \
3445         [lindex $gm 2]
3446 unset gm
3447 }
3448
3449 # -- Load window state
3450 #
3451 catch {
3452 set gws $repo_config(gui.wmstate)
3453 wm state . $gws
3454 unset gws
3455 }
3456
3457 # -- Key Bindings
3458 #
3459 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3460 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3461 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3462 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3463 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3464 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3465 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3466 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3467 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3468 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3469 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3470 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3471 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3472 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3473 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3474 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3475 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3476 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3477 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3478 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3479 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3480 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3481
3482 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3483 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3484 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3485 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3486 bind $ui_diff <$M1B-Key-v> {break}
3487 bind $ui_diff <$M1B-Key-V> {break}
3488 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3489 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3490 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3491 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3492 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3493 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3494 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3495 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3496 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3497 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3498 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3499 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3500 bind $ui_diff <Button-1>   {focus %W}
3501
3502 if {[is_enabled branch]} {
3503         bind . <$M1B-Key-n> branch_create::dialog
3504         bind . <$M1B-Key-N> branch_create::dialog
3505         bind . <$M1B-Key-o> branch_checkout::dialog
3506         bind . <$M1B-Key-O> branch_checkout::dialog
3507         bind . <$M1B-Key-m> merge::dialog
3508         bind . <$M1B-Key-M> merge::dialog
3509 }
3510 if {[is_enabled transport]} {
3511         bind . <$M1B-Key-p> do_push_anywhere
3512         bind . <$M1B-Key-P> do_push_anywhere
3513 }
3514
3515 bind .   <Key-F5>     ui_do_rescan
3516 bind .   <$M1B-Key-r> ui_do_rescan
3517 bind .   <$M1B-Key-R> ui_do_rescan
3518 bind .   <$M1B-Key-s> do_signoff
3519 bind .   <$M1B-Key-S> do_signoff
3520 bind .   <$M1B-Key-t> do_add_selection
3521 bind .   <$M1B-Key-T> do_add_selection
3522 bind .   <$M1B-Key-i> do_add_all
3523 bind .   <$M1B-Key-I> do_add_all
3524 bind .   <$M1B-Key-minus> {show_less_context;break}
3525 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3526 bind .   <$M1B-Key-equal> {show_more_context;break}
3527 bind .   <$M1B-Key-plus> {show_more_context;break}
3528 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3529 bind .   <$M1B-Key-Return> do_commit
3530 foreach i [list $ui_index $ui_workdir] {
3531         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3532         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3533         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3534 }
3535 unset i
3536
3537 set file_lists($ui_index) [list]
3538 set file_lists($ui_workdir) [list]
3539
3540 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3541 focus -force $ui_comm
3542
3543 # -- Warn the user about environmental problems.  Cygwin's Tcl
3544 #    does *not* pass its env array onto any processes it spawns.
3545 #    This means that git processes get none of our environment.
3546 #
3547 if {[is_Cygwin]} {
3548         set ignored_env 0
3549         set suggest_user {}
3550         set msg [mc "Possible environment issues exist.
3551
3552 The following environment variables are probably
3553 going to be ignored by any Git subprocess run
3554 by %s:
3555
3556 " [appname]]
3557         foreach name [array names env] {
3558                 switch -regexp -- $name {
3559                 {^GIT_INDEX_FILE$} -
3560                 {^GIT_OBJECT_DIRECTORY$} -
3561                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3562                 {^GIT_DIFF_OPTS$} -
3563                 {^GIT_EXTERNAL_DIFF$} -
3564                 {^GIT_PAGER$} -
3565                 {^GIT_TRACE$} -
3566                 {^GIT_CONFIG$} -
3567                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3568                         append msg " - $name\n"
3569                         incr ignored_env
3570                 }
3571                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3572                         append msg " - $name\n"
3573                         incr ignored_env
3574                         set suggest_user $name
3575                 }
3576                 }
3577         }
3578         if {$ignored_env > 0} {
3579                 append msg [mc "
3580 This is due to a known issue with the
3581 Tcl binary distributed by Cygwin."]
3582
3583                 if {$suggest_user ne {}} {
3584                         append msg [mc "
3585
3586 A good replacement for %s
3587 is placing values for the user.name and
3588 user.email settings into your personal
3589 ~/.gitconfig file.
3590 " $suggest_user]
3591                 }
3592                 warn_popup $msg
3593         }
3594         unset ignored_env msg suggest_user name
3595 }
3596
3597 # -- Only initialize complex UI if we are going to stay running.
3598 #
3599 if {[is_enabled transport]} {
3600         load_all_remotes
3601
3602         set n [.mbar.remote index end]
3603         populate_remotes_menu
3604         set n [expr {[.mbar.remote index end] - $n}]
3605         if {$n > 0} {
3606                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3607                 .mbar.remote insert $n separator
3608         }
3609         unset n
3610 }
3611
3612 if {[winfo exists $ui_comm]} {
3613         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3614
3615         # -- If both our backup and message files exist use the
3616         #    newer of the two files to initialize the buffer.
3617         #
3618         if {$GITGUI_BCK_exists} {
3619                 set m [gitdir GITGUI_MSG]
3620                 if {[file isfile $m]} {
3621                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3622                                 catch {file delete [gitdir GITGUI_MSG]}
3623                         } else {
3624                                 $ui_comm delete 0.0 end
3625                                 $ui_comm edit reset
3626                                 $ui_comm edit modified false
3627                                 catch {file delete [gitdir GITGUI_BCK]}
3628                                 set GITGUI_BCK_exists 0
3629                         }
3630                 }
3631                 unset m
3632         }
3633
3634         proc backup_commit_buffer {} {
3635                 global ui_comm GITGUI_BCK_exists
3636
3637                 set m [$ui_comm edit modified]
3638                 if {$m || $GITGUI_BCK_exists} {
3639                         set msg [string trim [$ui_comm get 0.0 end]]
3640                         regsub -all -line {[ \r\t]+$} $msg {} msg
3641
3642                         if {$msg eq {}} {
3643                                 if {$GITGUI_BCK_exists} {
3644                                         catch {file delete [gitdir GITGUI_BCK]}
3645                                         set GITGUI_BCK_exists 0
3646                                 }
3647                         } elseif {$m} {
3648                                 catch {
3649                                         set fd [open [gitdir GITGUI_BCK] w]
3650                                         puts -nonewline $fd $msg
3651                                         close $fd
3652                                         set GITGUI_BCK_exists 1
3653                                 }
3654                         }
3655
3656                         $ui_comm edit modified false
3657                 }
3658
3659                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3660         }
3661
3662         backup_commit_buffer
3663
3664         # -- If the user has aspell available we can drive it
3665         #    in pipe mode to spellcheck the commit message.
3666         #
3667         set spell_cmd [list |]
3668         set spell_dict [get_config gui.spellingdictionary]
3669         lappend spell_cmd aspell
3670         if {$spell_dict ne {}} {
3671                 lappend spell_cmd --master=$spell_dict
3672         }
3673         lappend spell_cmd --mode=none
3674         lappend spell_cmd --encoding=utf-8
3675         lappend spell_cmd pipe
3676         if {$spell_dict eq {none}
3677          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3678                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3679         } else {
3680                 set ui_comm_spell [spellcheck::init \
3681                         $spell_fd \
3682                         $ui_comm \
3683                         $ui_comm_ctxm \
3684                 ]
3685         }
3686         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3687 }
3688
3689 lock_index begin-read
3690 if {![winfo ismapped .]} {
3691         wm deiconify .
3692 }
3693 after 1 {
3694         if {[is_enabled initialamend]} {
3695                 force_amend
3696         } else {
3697                 do_rescan
3698         }
3699
3700         if {[is_enabled nocommitmsg]} {
3701                 $ui_comm configure -state disabled -background gray
3702         }
3703 }
3704 if {[is_enabled multicommit]} {
3705         after 1000 hint_gc
3706 }
3707 if {[is_enabled retcode]} {
3708         bind . <Destroy> {+terminate_me %W}
3709 }
3710 if {$picked && [is_config_true gui.autoexplore]} {
3711         do_explore
3712 }