Girocco/CGI.pm

   1 package Girocco::CGI;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Girocco::Config;
   7
   8 BEGIN {
   9         our $VERSION = '0.1';
  10         our @ISA = qw(Exporter);
  11         our @EXPORT = qw(html_esc);
  12
  13         use CGI qw(:standard :escapeHTML -nosticky);
  14         use CGI::Util qw(unescape);
  15         use CGI::Carp qw(fatalsToBrowser);
  16 }
  17
  18
  19 sub new {
  20         my $class = shift;
  21         my ($heading, $section) = @_;
  22         my $gcgi = {};
  23
  24         $section ||= 'administration';
  25
  26         $gcgi->{cgi} = CGI->new;
  27
  28         my $cgiurl = $gcgi->{cgi}->url(-absolute => 1);
  29         ($gcgi->{srcname}) = ($cgiurl =~ m#^.*/\([a-zA-Z0-9_.\/-]+?\.cgi\)$#); #
  30         $gcgi->{srcname} = "cgi/".$gcgi->{srcname} if $gcgi->{srcname};
  31
  32         print $gcgi->{cgi}->header(-type=>'text/html', -charset => 'utf-8');
  33
  34         print <<EOT;
  35 <?xml version="1.0" encoding="utf-8"?>
  36 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
  37 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
  38
  39 <head>
  40 <title>$Girocco::Config::name :: $heading</title>
  41 <link rel="stylesheet" type="text/css" href="$Girocco::Config::gitwebfiles/gitweb.css"/>
  42 <link rel="stylesheet" type="text/css" href="$Girocco::Config::gitwebfiles/girocco.css"/>
  43 <link rel="shortcut icon" href="$Girocco::Config::gitwebfiles/git-favicon.png" type="image/png"/>
  44 <script src="$Girocco::Config::gitwebfiles/mootools.js" type="text/javascript"></script>
  45 <script src="$Girocco::Config::gitwebfiles/girocco.js" type="text/javascript"></script>
  46 </head>
  47
  48 <body>
  49
  50 <div class="page_header">
  51 <a href="http://git.or.cz/" title="Git homepage"><img src="$Girocco::Config::gitwebfiles/git-logo.png" width="72" height="27" alt="git" style="float:right; border-width:0px;"/></a>
  52 <a href="$Girocco::Config::gitweburl">$Girocco::Config::name</a> / $section / $heading
  53 </div>
  54
  55 EOT
  56
  57         bless $gcgi, $class;
  58 }
  59
  60 sub DESTROY {
  61         my $self = shift;
  62         if ($self->{srcname} and $Girocco::Config::giroccourl) {
  63                 my $hb = $Girocco::Config::giroccobranch ?
  64                         "hb=$Girocco::Config::giroccobranch;" : "";
  65                 print <<EOT;
  66 <div align="right">
  67 <a href="$Girocco::Config::giroccourl?a=blob;${hb}f=$self->{srcname}">(view source)</a>
  68 </div>
  69 EOT
  70         }
  71         print <<EOT;
  72 </body>
  73 </html>
  74 EOT
  75 }
  76
  77 sub cgi {
  78         my $self = shift;
  79         $self->{cgi};
  80 }
  81
  82 sub err {
  83         my $self = shift;
  84         print "<p style=\"color: red\">@_</p>\n";
  85         $self->{err}++;
  86 }
  87
  88 sub err_check {
  89         my $self = shift;
  90         my $err = $self->{err};
  91         $err and print "<p style=\"font-weight: bold\">Operation aborted due to $err errors.</p>\n";
  92         $err;
  93 }
  94
  95 sub wparam {
  96         my $self = shift;
  97         my ($param) = @_;
  98         my $val = $self->{cgi}->param($param);
  99         defined $val and $val =~ s/^\s*(.*?)\s*$/$1/;
 100         $val;
 101 }
 102
 103 sub srcname {
 104         my $self = shift;
 105         my ($srcname) = @_;
 106         $self->{srcname} = $srcname if $srcname;
 107         $self->{srcname};
 108 }
 109
 110 sub html_esc {
 111         my ($str) = @_;
 112         $str =~ s/&/&amp;/g;
 113         $str =~ s/</&lt;/g; $str =~ s/>/&gt;/g;
 114         $str =~ s/"/&quot;/g;
 115         $str;
 116 }
 117
 118 sub print_form_fields {
 119         my $self = shift;
 120         my ($fieldmap, $valuemap, @fields) = @_;
 121
 122         foreach my $field (map { $fieldmap->{$_} } @fields) {
 123                 print '<tr><td class="formlabel">'.$field->[0].':</td><td>';
 124                 if ($field->[2] eq 'text') {
 125                         print '<input type="text" name="'.$field->[1].'" size="80"';
 126                         print ' value="'.$valuemap->{$field->[1]}.'"' if $valuemap;
 127                         print ' />';
 128                 } else {
 129                         print '<textarea name="'.$field->[1].'" rows="5" cols="80">';
 130                         print $valuemap->{$field->[1]} if $valuemap;
 131                         print '</textarea>';
 132                 }
 133                 print "</td></tr>\n";
 134         }
 135 }
 136
 137
 138 1;