dev-games/gnome-inform7/gnome-inform7-7.5t_p18.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=1
   6
   7 inherit eutils versionator autotools
   8
   9 MY_MAJOR=$(get_version_component_range 2)
  10 MY_LETTER=$(get_version_component_range 3)
  11 MY_MINOR=$(get_version_component_range 4)
  12
  13 MY_LOWERS=abcdefghijklmnopqrstuvwxyz
  14 MY_UPPERS=ABCDEFGHIJKLMNOPQRSTUVWXYZ
  15 MY_INDEX=${MY_LOWERS%${MY_LETTER}*}
  16 MY_UPPER=${MY_UPPERS:${#MY_INDEX}:1}
  17
  18 MY_PV=${MY_MAJOR}${MY_UPPER}${MY_MINOR#p}
  19 DESCRIPTION="GNOME user interface for Inform 7"
  20 HOMEPAGE="http://inform7.com/ http://sourceforge.net/projects/gnome-inform7/"
  21 SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"
  22
  23 LICENSE="GPL-2 LICENSE-BITSTREAM font-bh-ttf"
  24 SLOT="0"
  25 KEYWORDS="~amd64 ~x86"
  26 IUSE=""
  27
  28 DEPEND="=app-text/gtkspell-2*
  29         dev-libs/dbus-glib
  30         >=gnome-base/libgnomeui-2
  31         gnome-extra/gtkhtml:3.14
  32         media-libs/freetype:2
  33         media-libs/jpeg
  34         media-libs/libpng
  35         media-libs/libsdl
  36         media-libs/sdl-mixer
  37         || ( >=sys-apps/util-linux-2.16
  38                 <sys-libs/e2fsprogs-libs-1.41.8
  39                 <sys-fs/e2fsprogs-1.41.0 )
  40         virtual/libintl
  41         >=x11-libs/gtk+-2.8:2
  42         x11-libs/gtksourceview:2.0"
  43 RDEPEND="${DEPEND}
  44         ~dev-lang/inform-${PV}
  45         games-engines/glkfrotz
  46         games-engines/glulxe"
  47 DEPEND="${DEPEND}
  48         dev-games/glk-headers
  49         dev-util/pkgconfig
  50         sys-devel/gettext"
  51
  52 S=${WORKDIR}/${PN}-${MY_PV}
  53
  54 src_unpack() {
  55         unpack ${A}
  56         cd "${S}"
  57
  58         epatch "${FILESDIR}"/gnome-inform7-5J39-CFLAGS.patch
  59         epatch "${FILESDIR}"/gnome-inform7-5T18-unbundling.patch
  60         epatch "${FILESDIR}"/gnome-inform7-5T18-welcome.patch
  61         epatch "${FILESDIR}"/gnome-inform7-5J39-no-ossp-uuid.patch
  62         epatch "${FILESDIR}"/gnome-inform7-5T18-skein.patch
  63
  64         eautoreconf
  65
  66         rm src/gtkterp/garglk/{glk,gi_blorb,gi_dispa,glkstart}.h || die "rm glk headers failed"
  67 }
  68
  69 src_compile() {
  70         # Don't build libgtkerp-garglk.a: the library is useless except
  71         # when running under the IDE, and the IDE uses the glkfrotz and
  72         # glulxe binaries linked against glkloader.
  73         econf --disable-static || die "econf failed"
  74         emake || die "emake failed"
  75 }
  76
  77 src_install() {
  78         emake DESTDIR="${D}" install || die "emake install failed"
  79         dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "dodoc failed"
  80         dodoc src/gtkterp/{CharterBT.txt,TODO-garglk} || die "dodoc gtkterp failed"
  81
  82         cd "${D}"/usr/share
  83         mv gnome-inform7/Documentation doc/${PF}/html || die "mv Documentation failed"
  84         dosym /usr/share/doc/${PF}/html /usr/share/gnome-inform7/Documentation || die "dosym Documentation failed"
  85
  86         dosym /usr/{libexec,share/gnome-inform7/Compilers}/cBlorb || die "dosym cBlorb failed"
  87         dosym /usr/{libexec,share/gnome-inform7/Compilers}/inform-6.31-biplatform || die "dosym inform-6.31-biplatform failed"
  88         dosym /usr/{libexec,share/gnome-inform7/Compilers}/ni || die "dosym ni failed"
  89
  90         dosym /usr/share/{,gnome-}inform7/Inform7 || die "dosym Inform7 failed"
  91         dosym /usr/share/{,gnome-}inform7/Library || die "dosym Library failed"
  92 }