dev-games/glktermw/glktermw-0.8.0-r2.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit eutils autotools
   8
   9 MY_P=${P//./}
  10 DESCRIPTION="An ncurses implementation of the Glk API with Unicode support"
  11 HOMEPAGE="http://www.eblong.com/zarf/glk/"
  12 SRC_URI="mirror://ifarchive/programming/glk/implementations/${MY_P}.tar.gz"
  13
  14 LICENSE="Zarf"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE=""
  18
  19 RDEPEND="sys-libs/ncurses[unicode]"
  20 DEPEND="${RDEPEND}
  21         >=dev-games/glk-headers-0.7.0-r1"
  22
  23 S=${WORKDIR}/${PN}
  24
  25 src_prepare() {
  26         epatch "${FILESDIR}"/glktermw-0.8.0-r2-garglk-extensions.patch
  27
  28         cp "${FILESDIR}"/glktermw-0.8.0-configure.ac configure.ac || die "cp configure.ac failed"
  29         cp "${FILESDIR}"/glktermw-0.8.0-Makefile.am Makefile.am || die "cp Makefile.am failed"
  30         sed -i -e "s,@PV@,${PV}," configure.ac || die "sed failed"
  31         eautoreconf
  32
  33         rm glk.h gi_blorb.h gi_dispa.h glkstart.h || die "rm glk headers failed"
  34 }
  35
  36 src_install() {
  37         emake DESTDIR="${D}" install || die "emake install failed"
  38         dodoc readme.txt readme-orig.txt || die "dodoc failed"
  39
  40         insinto /etc/glkloader.d
  41         cat >"${T}"/glktermw.rc <<-EOF
  42                 [TermW]
  43                 path = /usr/$(get_libdir)/libglktermw.so
  44         EOF
  45         doins "${T}"/glktermw.rc || die "doins glktermw.rc failed"
  46 }