lisp/progmodes/m4-mode.el

   1 ;;; m4-mode.el --- m4 code editing commands for Emacs
   2
   3 ;; Copyright (C) 1996-1997, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Andrew Csillag <drew_csillag@geocities.com>
   6 ;; Maintainer: Andrew Csillag <drew_csillag@geocities.com>
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; A smart editing mode for m4 macro definitions.  It seems to have most of the
  27 ;; syntax right (sexp motion commands work, but function motion commands don't).
  28 ;; It also sets the font-lock syntax stuff for colorization
  29
  30 ;; To Do's:
  31
  32 ;; * want to make m4-m4-(buffer|region) look sorta like M-x compile look&feel ?
  33 ;; * sexp motion commands don't seem to work right
  34
  35 ;;; Thanks:
  36 ;;;         to Akim Demaille and Terry Jones for the bug reports
  37 ;;;         to Simon Marshall for the regexp tip
  38 ;;;         to Martin Buchholz for some general fixes
  39
  40 ;;; Code:
  41
  42 (defgroup m4 nil
  43   "m4 code editing commands for Emacs."
  44   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  45   :prefix "m4-"
  46   :group 'languages)
  47
  48 (defcustom m4-program "m4"
  49   "File name of the m4 executable.
  50 If m4 is not in your PATH, set this to an absolute file name."
  51   :version "24.4"
  52   :type 'file
  53   :group 'm4)
  54
  55 ;;options to m4
  56 (defcustom m4-program-options nil
  57   "Options to pass to `m4-program'."
  58   :type '(repeat string)
  59   :group 'm4)
  60
  61 ;;to use --prefix-builtins, you can use
  62 ;;(defconst m4-program-options '("-P"))
  63 ;;or
  64 ;;(defconst m4-program-options '("--prefix-builtins"))
  65
  66 (defvar m4-font-lock-keywords
  67   `(
  68     ("\\(\\b\\(m4_\\)?dnl\\b\\|^\\#\\).*$" . font-lock-comment-face)
  69 ;    ("\\(\\bdnl\\b\\|\\bm4_dnl\\b\\|^\\#\\).*$" . font-lock-comment-face)
  70     ("\\$[*#@0-9]" . font-lock-variable-name-face)
  71     ("\\\$\\\@" . font-lock-variable-name-face)
  72     ("\\\$\\\*" . font-lock-variable-name-face)
  73     ("\\b\\(builtin\\|change\\(com\\|quote\\|word\\)\\|d\\(e\\(bug\\(file\\|mode\\)\\|cr\\|f\\(ine\\|n\\)\\)\\|iv\\(ert\\|num\\)\\|nl\\|umpdef\\)\\|e\\(rrprint\\|syscmd\\|val\\)\\|f\\(ile\\|ormat\\)\\|gnu\\|i\\(f\\(def\\|else\\)\\|n\\(c\\(lude\\|r\\)\\|d\\(ex\\|ir\\)\\)\\)\\|l\\(en\\|ine\\)\\|m\\(4\\(exit\\|wrap\\)\\|aketemp\\)\\|p\\(atsubst\\|opdef\\|ushdef\\)\\|regexp\\|s\\(hift\\|include\\|ubstr\\|ys\\(cmd\\|val\\)\\)\\|tra\\(ceo\\(ff\\|n\\)\\|nslit\\)\\|un\\(d\\(efine\\|ivert\\)\\|ix\\)\\)\\b" . font-lock-keyword-face)
  74     ("\\b\\(m4_\\(builtin\\|change\\(com\\|quote\\|word\\)\\|d\\(e\\(bug\\(file\\|mode\\)\\|cr\\|f\\(ine\\|n\\)\\)\\|iv\\(ert\\|num\\)\\|nl\\|umpdef\\)\\|e\\(rrprint\\|syscmd\\|val\\)\\|f\\(ile\\|ormat\\)\\|i\\(f\\(def\\|else\\)\\|n\\(c\\(lude\\|r\\)\\|d\\(ex\\|ir\\)\\)\\)\\|l\\(en\\|ine\\)\\|m\\(4\\(_undefine\\|exit\\|wrap\\)\\|aketemp\\)\\|p\\(atsubst\\|opdef\\|ushdef\\)\\|regexp\\|s\\(hift\\|include\\|ubstr\\|ys\\(cmd\\|val\\)\\)\\|tra\\(ceo\\(ff\\|n\\)\\|nslit\\)\\|undivert\\)\\)\\b" . font-lock-keyword-face))
  75   "Default font-lock-keywords for `m4 mode'.")
  76
  77 (defcustom m4-mode-hook nil
  78   "Hook called by `m4-mode'."
  79   :type 'hook
  80   :group 'm4)
  81
  82 ;;this may still need some work
  83 (defvar m4-mode-syntax-table
  84   (let ((table (make-syntax-table)))
  85     (modify-syntax-entry ?` "('" table)
  86     (modify-syntax-entry ?' ")`" table)
  87     (modify-syntax-entry ?# "<\n" table)
  88     (modify-syntax-entry ?\n ">#" table)
  89     (modify-syntax-entry ?{  "_" table)
  90     (modify-syntax-entry ?}  "_" table)
  91     ;; FIXME: This symbol syntax for underscore looks OK on its own, but it's
  92     ;; odd that it should have the same syntax as { and } are these really
  93     ;; valid in m4 symbols?
  94     (modify-syntax-entry ?_  "_" table)
  95     ;; FIXME: These three chars with word syntax look wrong.
  96     (modify-syntax-entry ?*  "w" table)
  97     (modify-syntax-entry ?\"  "w" table)
  98     (modify-syntax-entry ?\"  "w" table)
  99     table)
 100   "Syntax table used while in `m4-mode'.")
 101
 102 (defvar m4-mode-map
 103   (let ((map (make-sparse-keymap))
 104         (menu-map (make-sparse-keymap)))
 105     (define-key map "\C-c\C-b" 'm4-m4-buffer)
 106     (define-key map "\C-c\C-r" 'm4-m4-region)
 107     (define-key map "\C-c\C-c" 'comment-region)
 108     (define-key map [menu-bar m4-mode] (cons "M4" menu-map))
 109     (define-key menu-map [m4c]
 110       '(menu-item "Comment Region" comment-region
 111                   :help "Comment Region"))
 112     (define-key menu-map [m4b]
 113       '(menu-item "M4 Buffer" m4-m4-buffer
 114                   :help "Send contents of the current buffer to m4"))
 115     (define-key menu-map [m4r]
 116       '(menu-item "M4 Region" m4-m4-region
 117                   :help "Send contents of the current region to m4"))
 118     map))
 119
 120 (defun m4-m4-buffer ()
 121   "Send contents of the current buffer to m4."
 122   (interactive)
 123   (shell-command-on-region
 124    (point-min) (point-max)
 125    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 126    "*m4-output*" nil)
 127   (switch-to-buffer-other-window "*m4-output*"))
 128
 129 (defun m4-m4-region ()
 130   "Send contents of the current region to m4."
 131   (interactive)
 132   (shell-command-on-region
 133    (point) (mark)
 134    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 135    "*m4-output*" nil)
 136   (switch-to-buffer-other-window "*m4-output*"))
 137
 138 (defun m4-current-defun-name ()
 139   "Return the name of the M4 function at point, or nil."
 140   (save-excursion
 141     (if (re-search-backward
 142          "^\\(\\(m4_\\)?define\\|A._DEFUN\\)(\\[?\\([A-Za-z0-9_]+\\)" nil t)
 143         (match-string-no-properties 3))))
 144
 145 ;;;###autoload
 146 (define-derived-mode m4-mode prog-mode "m4"
 147   "A major mode to edit m4 macro files."
 148   (setq-local comment-start "#")
 149   (setq-local parse-sexp-ignore-comments t)
 150   (setq-local add-log-current-defun-function #'m4-current-defun-name)
 151   (setq font-lock-defaults '(m4-font-lock-keywords nil)))
 152
 153 (provide 'm4-mode)
 154 ;;stuff to play with for debugging
 155 ;(char-to-string (char-syntax ?`))
 156
 157 ;;;how I generate the nasty looking regexps at the top
 158 ;;;(make-regexp '("builtin" "changecom" "changequote" "changeword" "debugfile"
 159 ;;;               "debugmode" "decr" "define" "defn" "divert" "divnum" "dnl"
 160 ;;;               "dumpdef" "errprint" "esyscmd" "eval" "file" "format" "gnu"
 161 ;;;               "ifdef" "ifelse" "include" "incr" "index" "indir" "len" "line"
 162 ;;;               "m4exit" "m4wrap" "maketemp" "patsubst" "popdef" "pushdef" "regexp"
 163 ;;;               "shift" "sinclude" "substr" "syscmd" "sysval" "traceoff" "traceon"
 164 ;;;               "translit" "undefine" "undivert" "unix"))
 165 ;;;(make-regexp '("m4_builtin" "m4_changecom" "m4_changequote" "m4_changeword"
 166 ;;;               "m4_debugfile" "m4_debugmode" "m4_decr" "m4_define" "m4_defn"
 167 ;;;               "m4_divert" "m4_divnum" "m4_dnl" "m4_dumpdef" "m4_errprint"
 168 ;;;               "m4_esyscmd" "m4_eval" "m4_file" "m4_format" "m4_ifdef" "m4_ifelse"
 169 ;;;               "m4_include" "m4_incr" "m4_index" "m4_indir" "m4_len" "m4_line"
 170 ;;;               "m4_m4exit" "m4_m4wrap" "m4_maketemp" "m4_patsubst" "m4_popdef"
 171 ;;;               "m4_pushdef" "m4_regexp" "m4_shift" "m4_sinclude" "m4_substr"
 172 ;;;               "m4_syscmd" "m4_sysval" "m4_traceoff" "m4_traceon" "m4_translit"
 173 ;;;               "m4_m4_undefine" "m4_undivert"))
 174
 175 ;;; m4-mode.el ends here