lisp/progmodes/m4-mode.el

   1 ;;; m4-mode.el --- m4 code editing commands for Emacs
   2
   3 ;; Copyright (C) 1996-1997, 2001-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Andrew Csillag <drew@thecsillags.com>
   6 ;; Keywords: languages, faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; A smart editing mode for m4 macro definitions.  It seems to have most of the
  26 ;; syntax right (sexp motion commands work, but function motion commands don't).
  27 ;; It also sets the font-lock syntax stuff for colorization
  28
  29 ;; To Do's:
  30
  31 ;; * want to make m4-m4-(buffer|region) look sorta like M-x compile look&feel ?
  32 ;; * sexp motion commands don't seem to work right
  33
  34 ;;; Thanks:
  35 ;;;         to Akim Demaille and Terry Jones for the bug reports
  36 ;;;         to Simon Marshall for the regexp tip
  37 ;;;         to Martin Buchholz for some general fixes
  38
  39 ;;; Code:
  40
  41 (defgroup m4 nil
  42   "m4 code editing commands for Emacs."
  43   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  44   :prefix "m4-"
  45   :group 'languages)
  46
  47 (defcustom m4-program "m4"
  48   "File name of the m4 executable.
  49 If m4 is not in your PATH, set this to an absolute file name."
  50   :version "24.4"
  51   :type 'file
  52   :group 'm4)
  53
  54 ;;options to m4
  55 (defcustom m4-program-options nil
  56   "Options to pass to `m4-program'."
  57   :type '(repeat string)
  58   :group 'm4)
  59
  60 ;;to use --prefix-builtins, you can use
  61 ;;(defconst m4-program-options '("-P"))
  62 ;;or
  63 ;;(defconst m4-program-options '("--prefix-builtins"))
  64
  65 (defvar m4-font-lock-keywords
  66   `(
  67     ("\\(\\_<\\(m4_\\)?dnl\\_>\\).*$" . font-lock-comment-face)
  68     ("\\$[*#@0-9]" . font-lock-variable-name-face)
  69     ("\\$\\@" . font-lock-variable-name-face)
  70     ("\\$\\*" . font-lock-variable-name-face)
  71     ("\\_<\\(m4_\\)?\\(builtin\\|change\\(com\\|quote\\|word\\)\\|d\\(e\\(bug\\(file\\|mode\\)\\|cr\\|f\\(ine\\|n\\)\\)\\|iv\\(ert\\|num\\)\\|nl\\|umpdef\\)\\|e\\(rrprint\\|syscmd\\|val\\)\\|f\\(ile\\|ormat\\)\\|gnu\\|i\\(f\\(def\\|else\\)\\|n\\(c\\(lude\\|r\\)\\|d\\(ex\\|ir\\)\\)\\)\\|l\\(en\\|ine\\)\\|m\\(4\\(exit\\|wrap\\)\\|aketemp\\)\\|p\\(atsubst\\|opdef\\|ushdef\\)\\|regexp\\|s\\(hift\\|include\\|ubstr\\|ys\\(cmd\\|val\\)\\)\\|tra\\(ceo\\(ff\\|n\\)\\|nslit\\)\\|un\\(d\\(efine\\|ivert\\)\\|ix\\)\\)\\_>" . font-lock-keyword-face))
  72   "Default `font-lock-keywords' for M4 mode.")
  73
  74 (defcustom m4-mode-hook nil
  75   "Hook called by `m4-mode'."
  76   :type 'hook
  77   :group 'm4)
  78
  79 ;;this may still need some work
  80 (defvar m4-mode-syntax-table
  81   (let ((table (make-syntax-table)))
  82     (modify-syntax-entry ?` "('" table)
  83     (modify-syntax-entry ?' ")`" table)
  84     (modify-syntax-entry ?# "<\n" table)
  85     (modify-syntax-entry ?\n ">#" table)
  86     (modify-syntax-entry ?{  "." table)
  87     (modify-syntax-entry ?}  "." table)
  88     (modify-syntax-entry ?_  "_" table)
  89     (modify-syntax-entry ?*  "." table)
  90     (modify-syntax-entry ?\"  "." table)
  91     table)
  92   "Syntax table used while in `m4-mode'.")
  93
  94 (defun m4--quoted-p (pos)
  95   "Return non-nil if POS is inside a quoted string."
  96   (let ((quoted nil))
  97     (dolist (o (nth 9 (save-excursion (syntax-ppss pos))))
  98       (if (eq (char-after o) ?\`) (setq quoted t)))
  99     quoted))
 100
 101 (defconst m4-syntax-propertize
 102   (syntax-propertize-rules
 103    ("#" (0 (when (m4--quoted-p (match-beginning 0))
 104              (string-to-syntax "."))))))
 105
 106 (defvar m4-mode-map
 107   (let ((map (make-sparse-keymap))
 108         (menu-map (make-sparse-keymap)))
 109     (define-key map "\C-c\C-b" 'm4-m4-buffer)
 110     (define-key map "\C-c\C-r" 'm4-m4-region)
 111     (define-key map "\C-c\C-c" 'comment-region)
 112     (define-key map [menu-bar m4-mode] (cons "M4" menu-map))
 113     (define-key menu-map [m4c]
 114       '(menu-item "Comment Region" comment-region
 115                   :help "Comment Region"))
 116     (define-key menu-map [m4b]
 117       '(menu-item "M4 Buffer" m4-m4-buffer
 118                   :help "Send contents of the current buffer to m4"))
 119     (define-key menu-map [m4r]
 120       '(menu-item "M4 Region" m4-m4-region
 121                   :help "Send contents of the current region to m4"))
 122     map))
 123
 124 (defun m4-m4-buffer ()
 125   "Send contents of the current buffer to m4."
 126   (interactive)
 127   (shell-command-on-region
 128    (point-min) (point-max)
 129    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 130    "*m4-output*" nil)
 131   (switch-to-buffer-other-window "*m4-output*"))
 132
 133 (defun m4-m4-region ()
 134   "Send contents of the current region to m4."
 135   (interactive)
 136   (shell-command-on-region
 137    (point) (mark)
 138    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 139    "*m4-output*" nil)
 140   (switch-to-buffer-other-window "*m4-output*"))
 141
 142 (defun m4-current-defun-name ()
 143   "Return the name of the M4 function at point, or nil."
 144   (save-excursion
 145     (if (re-search-backward
 146          "^\\(\\(m4_\\)?define\\|A._DEFUN\\)(\\[?\\([A-Za-z0-9_]+\\)" nil t)
 147         (match-string-no-properties 3))))
 148
 149 ;;;###autoload
 150 (define-derived-mode m4-mode prog-mode "m4"
 151   "A major mode to edit m4 macro files."
 152   (setq-local comment-start "#")
 153   (setq-local parse-sexp-ignore-comments t)
 154   (setq-local add-log-current-defun-function #'m4-current-defun-name)
 155   (setq-local syntax-propertize-function m4-syntax-propertize)
 156   (setq-local font-lock-defaults '(m4-font-lock-keywords nil)))
 157
 158 (provide 'm4-mode)
 159 ;;stuff to play with for debugging
 160 ;(char-to-string (char-syntax ?`))
 161
 162 ;;;how I generate the nasty looking regexps at the top
 163 ;;;(make-regexp '("builtin" "changecom" "changequote" "changeword" "debugfile"
 164 ;;;               "debugmode" "decr" "define" "defn" "divert" "divnum" "dnl"
 165 ;;;               "dumpdef" "errprint" "esyscmd" "eval" "file" "format" "gnu"
 166 ;;;               "ifdef" "ifelse" "include" "incr" "index" "indir" "len" "line"
 167 ;;;               "m4exit" "m4wrap" "maketemp" "patsubst" "popdef" "pushdef" "regexp"
 168 ;;;               "shift" "sinclude" "substr" "syscmd" "sysval" "traceoff" "traceon"
 169 ;;;               "translit" "undefine" "undivert" "unix"))
 170 ;;;(make-regexp '("m4_builtin" "m4_changecom" "m4_changequote" "m4_changeword"
 171 ;;;               "m4_debugfile" "m4_debugmode" "m4_decr" "m4_define" "m4_defn"
 172 ;;;               "m4_divert" "m4_divnum" "m4_dnl" "m4_dumpdef" "m4_errprint"
 173 ;;;               "m4_esyscmd" "m4_eval" "m4_file" "m4_format" "m4_ifdef" "m4_ifelse"
 174 ;;;               "m4_include" "m4_incr" "m4_index" "m4_indir" "m4_len" "m4_line"
 175 ;;;               "m4_m4exit" "m4_m4wrap" "m4_maketemp" "m4_patsubst" "m4_popdef"
 176 ;;;               "m4_pushdef" "m4_regexp" "m4_shift" "m4_sinclude" "m4_substr"
 177 ;;;               "m4_syscmd" "m4_sysval" "m4_traceoff" "m4_traceon" "m4_translit"
 178 ;;;               "m4_m4_undefine" "m4_undivert"))
 179
 180 ;;; m4-mode.el ends here