wmweather+/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(wmweather+.c)
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(wmweather+, 2.12)
   5
   6 # We need GNU sources for certain features
   7 AH_VERBATIM([_GNU_SOURCE],
   8 [/* Enable GNU extensions on systems that have them */
   9 #ifndef _GNU_SOURCE
  10 # define _GNU_SOURCE
  11 #endif])
  12
  13 DATE=`date '+%B %e, %Y'`
  14 AC_SUBST(DATE)
  15 AC_SUBST(VERSION)
  16
  17 # for wmgeneral
  18 WMGENERAL_GUI="libwmgeneral-x11.a"
  19 AC_SUBST(WMGENERAL_GUI)
  20
  21 # Checks for programs.
  22 AC_PROG_AWK
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_RANLIB
  27
  28 # Checks for libraries.
  29 AC_CHECK_LIB([m],[cos])
  30 CHECK_LIBPCRE(, AC_MSG_ERROR(libpcre is required))
  31 LIBCURL_CHECK_CONFIG(yes,,,AC_MSG_ERROR(libcurl is required))
  32
  33 # Checks for header files.
  34 AC_PATH_XTRA
  35 AC_FIND_XPM
  36 if test "$LINK_XPM" = ""; then
  37     AC_MSG_ERROR(cannot find libxpm)
  38 fi
  39 CHECK_LIBWRASTER(, AC_MSG_ERROR(libwraster is required))
  40 AC_HEADER_STDC
  41 if test "$ac_cv_header_stdc" != "yes"; then AC_MSG_WARN(standard C headers not found); fi
  42 AC_HEADER_SYS_WAIT
  43 if test "$ac_cv_header_sys_wait_h" != "yes"; then AC_MSG_WARN(sys/wait.h not found); fi
  44 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/time.h],, AC_MSG_WARN($ac_header not found))
  45 AC_HEADER_TIME
  46
  47 # Checks for typedefs, structures, and compiler characteristics.
  48 AC_C_CONST
  49 AC_C_INLINE
  50 AC_TYPE_PID_T
  51 AC_TYPE_SIZE_T
  52 AC_CHECK_TYPES([ssize_t])
  53 AH_BOTTOM(
  54 [#if !HAVE_SSIZE_T
  55 typedef signed ssize_t;
  56 #endif])
  57 AC_STRUCT_TM
  58
  59 # Checks for library functions.
  60 AC_FUNC_FORK
  61 if test "$ac_cv_func_fork_works" != "yes"; then AC_MSG_WARN(fork() doesn't seem to work); fi
  62 AC_FUNC_MALLOC
  63 if test "$ac_cv_func_malloc_0_nonnull" != "yes"; then AC_MSG_WARN(malloc() doesn't seem to work); fi
  64 AC_FUNC_MEMCMP
  65 AC_FUNC_MKTIME
  66 AC_TYPE_SIGNAL
  67 AC_FUNC_STAT
  68 AC_FUNC_STRTOD
  69 AC_FUNC_VPRINTF
  70 if test "$ac_cv_func_vprintf" != "yes"; then AC_MSG_WARN(vprintf() doesn't seem to exist); fi
  71 AC_CHECK_FUNCS([atexit dup2 mkdir pow select strchr strcspn strdup strerror strrchr strspn strstr strtol],, AC_MSG_WARN($ac_func doesn't seem to be available))
  72 FUNC_SNPRINTF_LIBOBJ
  73 FUNC_VSNPRINTF_LIBOBJ
  74
  75 CFLAGS="$CFLAGS \$(X_CFLAGS) \$(LIBCURL_CPPFLAGS)"
  76 LIBS="$LIBS \$(LIBCURL)"
  77 XLIBS="\$(X_PRE_LIBS) \$(X_LIBS) \$(LINK_XPM) -lX11 -lXext \$(X_EXTRA_LIBS)"
  78 AC_SUBST(XLIBS)
  79
  80 AC_CONFIG_FILES([Makefile wmweather+.1])
  81 AC_CONFIG_FILES([b0rken/Makefile])
  82 AC_CONFIG_FILES([m4/Makefile])
  83 AC_CONFIG_FILES([wmgeneral/Makefile])
  84 AC_OUTPUT