meson.build

   1 project('atk', 'c',
   2         version: '2.29.1',
   3         license: 'LGPLv2.1+',
   4         default_options: [
   5           'buildtype=debugoptimized',
   6           'warning_level=1',
   7           'c_std=c99',
   8         ],
   9         meson_version : '>= 0.46.0')
  10
  11 cc = meson.get_compiler('c')
  12 host_system = host_machine.system()
  13
  14 version = meson.project_version().split('.')
  15 atk_major_version = version[0].to_int()
  16 atk_minor_version = version[1].to_int()
  17 atk_micro_version = version[2].to_int()
  18
  19 atk_interface_age = 1
  20 atk_binary_age = 10000 * atk_major_version + 100 * atk_minor_version + 10 + atk_micro_version
  21
  22 atk_api_version = '1.0'
  23 atk_api_path = 'atk-@0@/atk'.format(atk_api_version)
  24
  25 atk_prefix = get_option('prefix')
  26 atk_libdir = join_paths(atk_prefix, get_option('libdir'))
  27 atk_sysconfdir = join_paths(atk_prefix, get_option('sysconfdir'))
  28 atk_includedir = join_paths(atk_prefix, get_option('includedir'))
  29 atk_datadir = join_paths(atk_prefix, get_option('datadir'))
  30 atk_libexecdir = join_paths(atk_prefix, get_option('libexecdir'))
  31
  32 atk_conf = configuration_data()
  33
  34 atk_conf.set_quoted('VERSION', meson.project_version())
  35 atk_conf.set_quoted('GETTEXT_PACKAGE', 'atk10')
  36
  37 # Maintain version scheme with libtool
  38 atk_soversion = 0
  39 atk_libversion = '@0@.@1@.@2@'.format(atk_soversion, (atk_binary_age - atk_interface_age), atk_interface_age)
  40
  41 add_project_arguments([ '-DG_DISABLE_SINGLE_INCLUDES', '-DATK_DISABLE_SINGLE_INCLUDES' ], language: 'c')
  42
  43 if cc.get_id() == 'msvc'
  44   add_project_arguments([ '-FImsvc_recommended_pragmas.h' ], language: 'c')
  45 endif
  46
  47 # Compiler and linker flags
  48 common_cflags = []
  49 common_ldflags = []
  50
  51 test_cflags = []
  52
  53 # Symbol visibility
  54 if get_option('default_library') != 'static'
  55   if host_system == 'windows'
  56     atk_conf.set('DLL_EXPORT', true)
  57     atk_conf.set('_ATK_EXTERN', '__declspec(dllexport) extern')
  58     if cc.get_id() != 'msvc'
  59       test_cflags += ['-fvisibility=hidden']
  60     endif
  61   else
  62     atk_conf.set('_ATK_EXTERN', '__attribute__((visibility("default"))) extern')
  63     test_cflags += ['-fvisibility=hidden']
  64   endif
  65 endif
  66
  67 # Check all compiler flags
  68 common_cflags += cc.get_supported_arguments(test_cflags)
  69
  70 # Linker flags
  71 if host_machine.system() == 'linux'
  72   test_ldflags = [ '-Wl,-Bsymbolic', '-Wl,-z,relro', '-Wl,-z,now', ]
  73   common_ldflags += cc.get_supported_link_arguments(test_ldflags)
  74 endif
  75
  76 # Maintain compatibility with autotools on macOS
  77 if host_machine.system() == 'darwin'
  78   common_ldflags += [ '-compatibility_version 1', '-current_version 1.0', ]
  79 endif
  80
  81 # Functions
  82 checked_funcs = [
  83   'bind_textdomain_codeset',
  84 ]
  85
  86 foreach f: checked_funcs
  87   if cc.has_function(f)
  88     atk_conf.set('HAVE_' + f.underscorify().to_upper(), 1)
  89   endif
  90 endforeach
  91
  92 # Dependencies
  93 gobject_req_version = '>= 2.31.2'
  94
  95 gobject_dep = dependency('gobject-2.0', version: gobject_req_version)
  96
  97 # Compat variables for pkgconfig
  98 pkgconf = configuration_data()
  99 pkgconf.set('prefix', atk_prefix)
 100 pkgconf.set('exec_prefix', atk_prefix)
 101 pkgconf.set('libdir', atk_libdir)
 102 pkgconf.set('includedir', atk_includedir)
 103 pkgconf.set('VERSION', meson.project_version())
 104 pkgconf.set('ATK_API_VERSION', atk_api_version)
 105 pkgconf.set('srcdir', '.')
 106
 107 foreach pkg: [ 'atk.pc', ]
 108   configure_file(input: pkg + '.in',
 109                  output: pkg,
 110                  configuration: pkgconf,
 111                  install: true,
 112                  install_dir: join_paths(atk_libdir, 'pkgconfig'))
 113 endforeach
 114
 115 gnome = import('gnome')
 116
 117 # Internal configuration header
 118 configure_file(output: 'config.h', configuration: atk_conf)
 119
 120 root_inc = include_directories('.')
 121
 122 subdir('atk')
 123 subdir('tests')
 124 subdir('po')
 125
 126 if get_option('docs')
 127   subdir('docs')
 128 endif