configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.63])
   4
   5 dnl ==========================================================================
   6 dnl                              Versioning
   7 dnl ==========================================================================
   8
   9 dnl Making releases:
  10 dnl   ATK_MICRO_VERSION += 1;
  11 dnl   ATK_INTERFACE_AGE += 1;
  12 dnl   ATK_BINARY_AGE += 1;
  13 dnl if any functions have been added, set ATK_INTERFACE_AGE to 0.
  14 dnl if backwards compatibility has been broken,
  15 dnl set ATK_BINARY_AGE _and_ ATK_INTERFACE_AGE to 0.
  16
  17 dnl The triplet
  18 m4_define([atk_major_version], [2])
  19 m4_define([atk_minor_version], [25])
  20 m4_define([atk_micro_version], [2])
  21 m4_define([atk_version],
  22           [atk_major_version.atk_minor_version.atk_micro_version])
  23
  24 dnl The X.Y in -latk-X.Y line. This is expected to stay 1.0 until Atk 3.
  25 m4_define([atk_api_version], [1.0])
  26
  27 dnl Number of releases since we've added interfaces
  28 m4_define([atk_interface_age], [1])
  29
  30 dnl binary_age includes major version as ATK 2 is still fully API and ABI compatible
  31 m4_define([atk_binary_age],
  32           [m4_eval(10000 * atk_major_version + 100 * atk_minor_version + 10 + atk_micro_version)])
  33
  34 m4_define([lt_current],
  35           [m4_eval(10000 * atk_major_version + 100 * atk_minor_version + 10 + atk_micro_version - atk_interface_age)])
  36 m4_define([lt_revision], [atk_interface_age])
  37 m4_define([lt_age], [m4_eval(atk_binary_age - atk_interface_age)])
  38 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  39 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  40
  41 AC_INIT([atk],
  42         [atk_version],
  43         [http://bugzilla.gnome.org/enter_bug.cgi?product=atk],
  44         [atk])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_SRCDIR([README])
  48 AC_CONFIG_MACRO_DIR([m4])
  49
  50 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-dist-gzip dist-xz tar-ustar])
  51
  52 # Support silent build rules, requires at least automake-1.11. Disable
  53 # by either passing --disable-silent-rules to configure or passing V=1
  54 # to make
  55 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  56
  57 dnl ==========================================================================
  58 dnl
  59 dnl If you add a version number here, you *must* add an AC_SUBST line for
  60 dnl it too, or it will never make it into the spec file!
  61 dnl
  62 dnl ==========================================================================
  63
  64 ATK_MAJOR_VERSION=atk_major_version
  65 ATK_MINOR_VERSION=atk_minor_version
  66 ATK_MICRO_VERSION=atk_micro_version
  67 ATK_VERSION=atk_version
  68 ATK_API_VERSION=atk_api_version
  69 ATK_INTERFACE_AGE=atk_interface_age
  70 ATK_BINARY_AGE=atk_binary_age
  71
  72 AC_SUBST(ATK_MAJOR_VERSION)
  73 AC_SUBST(ATK_MINOR_VERSION)
  74 AC_SUBST(ATK_VERSION)
  75 AC_SUBST(ATK_API_VERSION)
  76 AC_SUBST(ATK_MICRO_VERSION)
  77 AC_SUBST(ATK_INTERFACE_AGE)
  78 AC_SUBST(ATK_BINARY_AGE)
  79
  80 dnl libtool versioning
  81 LT_VERSION_INFO=lt_version_info
  82 LT_CURRENT_MINUS_AGE=lt_current_minus_age
  83 AC_SUBST(LT_VERSION_INFO)
  84 AC_SUBST(LT_CURRENT_MINUS_AGE)
  85
  86 dnl ==========================================================================
  87
  88 # Check for programs
  89 AC_PROG_CC
  90
  91 # Initialize libtool
  92 LT_PREREQ([2.2])
  93 LT_INIT([disable-static win32-dll])
  94
  95 AC_CHECK_FUNCS(bind_textdomain_codeset)
  96
  97 AC_MSG_CHECKING([for some Win32 platform])
  98 case "$host" in
  99   *-*-mingw*|*-*-cygwin*)
 100     platform_win32=yes
 101     ;;
 102   *)
 103     platform_win32=no
 104     ;;
 105 esac
 106 AC_MSG_RESULT([$platform_win32])
 107 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 108
 109 AC_MSG_CHECKING([for native Win32 platform])
 110 case "$host" in
 111   *-*-mingw*)
 112     atk_native_win32=yes
 113     case "$host" in
 114       x86_64-*-*)
 115         LIB_EXE_MACHINE_FLAG=X64
 116         ;;
 117       *)
 118         LIB_EXE_MACHINE_FLAG=X86
 119         ;;
 120     esac
 121     ;;
 122   *)
 123     atk_native_win32=no
 124     ;;
 125 esac
 126 AC_MSG_RESULT([$atk_native_win32])
 127 AM_CONDITIONAL(OS_WIN32, test "$atk_native_win32" = "yes")
 128
 129 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 130
 131 if test "$atk_native_win32" = "yes"; then
 132   AC_CHECK_TOOL(WINDRES, windres, no)
 133   if test "$WINDRES" = no; then
 134     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 135   fi
 136   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 137
 138 fi
 139 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 140
 141 dnl Cache $ACLOCAL_FLAGS
 142 AC_CACHE_CHECK([for aclocal flags], ac_cv_atk_aclocal_flags,[
 143    ac_cv_atk_aclocal_flags="$ACLOCAL_FLAGS"
 144 ])
 145 ACLOCAL="$ACLOCAL $ac_cv_atk_aclocal_flags"
 146
 147 AC_ARG_ENABLE(rebuilds,
 148               [AS_HELP_STRING([--disable-rebuilds],
 149                               [disable all source autogeneration rules])],,
 150               [enable_rebuilds=yes])
 151
 152 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 153
 154 changequote(,)dnl
 155 if test "x$GCC" = "xyes"; then
 156   case " $CFLAGS " in
 157   *[\ \ ]-Wall[\ \      ]*) ;;
 158   *) CFLAGS="$CFLAGS -Wall" ;;
 159   esac
 160 fi
 161 changequote([,])dnl
 162
 163 GLIB_REQUIRED_VERSION=2.31.2
 164 AC_SUBST(GLIB_REQUIRED_VERSION)
 165
 166 PKG_CHECK_MODULES(DEP, [gobject-2.0 >= $GLIB_REQUIRED_VERSION])
 167 AC_SUBST(DEP_CFLAGS)
 168 AC_SUBST(DEP_LIBS)
 169
 170 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 171 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 172 AC_SUBST(GLIB_MKENUMS)
 173 AC_SUBST(GLIB_GENMARSHAL)
 174
 175 # i18n stuff
 176 AM_GNU_GETTEXT_VERSION([0.19.2])
 177 AM_GNU_GETTEXT([external])
 178
 179 GETTEXT_PACKAGE=atk10
 180 AC_SUBST(GETTEXT_PACKAGE)
 181 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 182   [Define the gettext package to be used])
 183
 184 # Introspection support
 185 GOBJECT_INTROSPECTION_CHECK([1.32.0])
 186
 187 # Documentation support
 188 GTK_DOC_CHECK([1.25])
 189
 190 # define a MAINT-like variable REBUILD which is set if Perl
 191 # and awk are found, so autogenerated sources can be rebuilt
 192
 193 AC_PROG_AWK
 194 AC_CHECK_PROGS(PERL, perl5 perl)
 195
 196 # Check whether MSVC toolset is explicitly set
 197 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
 198 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
 199
 200 REBUILD=\#
 201 if test "x$enable_rebuilds" = "xyes" && \
 202         test -n "$PERL" && \
 203         $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 204      test -n "$AWK" ; then
 205   REBUILD=
 206 fi
 207 AC_SUBST(REBUILD)
 208
 209 # Check for the visibility flags
 210 ATK_HIDDEN_VISIBILITY_CFLAGS=""
 211 case "$host" in
 212   *-*-mingw*)
 213     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
 214     AC_DEFINE([_ATK_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
 215               [defines how to decorate public symbols while building])
 216     CFLAGS="${CFLAGS} -fvisibility=hidden"
 217     ;;
 218   *)
 219     dnl on other compilers, check if we can do -fvisibility=hidden
 220     SAVED_CFLAGS="${CFLAGS}"
 221     CFLAGS="-fvisibility=hidden"
 222     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
 223     AC_TRY_COMPILE([], [int main (void) { return 0; }],
 224                    AC_MSG_RESULT(yes)
 225                    enable_fvisibility_hidden=yes,
 226                    AC_MSG_RESULT(no)
 227                    enable_fvisibility_hidden=no)
 228     CFLAGS="${SAVED_CFLAGS}"
 229
 230     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
 231       AC_DEFINE([_ATK_EXTERN], [__attribute__((visibility("default"))) extern],
 232                 [defines how to decorate public symbols while building])
 233       ATK_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
 234     ])
 235     ;;
 236 esac
 237 AC_SUBST(ATK_HIDDEN_VISIBILITY_CFLAGS)
 238
 239 AC_CONFIG_FILES([
 240 Makefile
 241 po/Makefile.in
 242 atk.pc
 243 atk/Makefile
 244 atk/atk.rc
 245 atk/atkversion.h
 246 tests/Makefile
 247 win32/Makefile
 248 win32/vs9/Makefile
 249 win32/vs9/atk-version-paths.vsprops
 250 win32/vs10/Makefile
 251 win32/vs10/atk-version-paths.props
 252 win32/vs11/Makefile
 253 win32/vs12/Makefile
 254 win32/vs14/Makefile
 255 win32/vs15/Makefile
 256 docs/Makefile
 257 config.h.win32
 258 ])
 259
 260 AC_OUTPUT