etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 1991-2008 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     cshrc
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from ~/.login or ~/.cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 setenv WM_PROJECT OpenFOAM
  35 setenv WM_PROJECT_VERSION 1.5.x
  36 if ( ! $?WM_PROJECT_VERSION ) setenv WM_PROJECT_VERSION dev
  37
  38 #!!User:
  39 #    either setenv FOAM_INST_DIR before sourcing this file or set
  40 #    foamInstall below to where OpenFOAM is installed
  41 #
  42 # Location of FOAM installation
  43 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  44 set foamInstall = $HOME/$WM_PROJECT
  45 # set foamInstall = ~$WM_PROJECT
  46 # set foamInstall = /usr/local/$WM_PROJECT
  47 # set foamInstall = /opt/$WM_PROJECT
  48
  49 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  50
  51
  52 # Location of site/user files
  53 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  54 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
  55 setenv WM_PROJECT_DIR $FOAM_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
  56 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
  57
  58
  59 # Location of third-party software
  60 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  61 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty
  62
  63
  64 # Operating System/Platform from Unix or MSWindows
  65 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  66 # WM_OS = Unix | MSWindows
  67 if ( ! $?WM_OS ) setenv WM_OS Unix
  68
  69
  70 # Compiler: set to Gcc, Gcc43 or Icc (for Intel's icc)
  71 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  72 if ( ! $?WM_COMPILER ) setenv WM_COMPILER Gcc
  73
  74 setenv WM_COMPILER_ARCH
  75 setenv WM_COMPILER_LIB_ARCH
  76
  77
  78 # Compilation options (architecture, precision, optimised, debug or profiling)
  79 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  80 # WM_ARCH_OPTION = 32 | 64
  81 if ( ! $?WM_ARCH_OPTION ) setenv WM_ARCH_OPTION 64
  82
  83 # WM_PRECISION_OPTION = DP | SP
  84 if ( ! $?WM_PRECISION_OPTION ) setenv WM_PRECISION_OPTION DP
  85
  86 # WM_COMPILE_OPTION = Opt | Debug | Prof
  87 if ( ! $?WM_COMPILE_OPTION ) setenv WM_COMPILE_OPTION Opt
  88
  89 # WM_JAVAC_OPTION = Opt | Debug
  90 if ( ! $?WM_JAVAC_OPTION ) setenv WM_JAVAC_OPTION Opt
  91
  92 # WM_MPLIB = | OPENMPI | LAM | MPICH | MPICH-GM | GAMMA | MPI
  93 if ( ! $?WM_MPLIB ) setenv WM_MPLIB OPENMPI
  94
  95
  96 # Run options (floating-point signal handling and memory initialisation)
  97 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  98 setenv FOAM_SIGFPE
  99 # setenv FOAM_SETNAN
 100
 101
 102 # Detect system type and set environment variables
 103 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 104 setenv WM_ARCH `uname -s`
 105
 106 switch ($WM_ARCH)
 107 case Linux:
 108     setenv WM_ARCH linux
 109
 110     switch (`uname -m`)
 111     case i686:
 112         breaksw
 113     case x86_64:
 114         switch ($WM_ARCH_OPTION)
 115         case 32:
 116             setenv WM_ARCH linux
 117             setenv WM_COMPILER_ARCH '-64'
 118             setenv WM_CC 'gcc'
 119             setenv WM_CXX 'g++'
 120             setenv WM_CFLAGS '-m32 -fPIC'
 121             setenv WM_CXXFLAGS '-m32 -fPIC'
 122             setenv WM_LDFLAGS '-m32'
 123             breaksw
 124         case 64:
 125             setenv WM_ARCH linux64
 126             setenv WM_COMPILER_LIB_ARCH 64
 127             setenv WM_CC 'gcc'
 128             setenv WM_CXX 'g++'
 129             setenv WM_CFLAGS '-m64 -fPIC'
 130             setenv WM_CXXFLAGS '-m64 -fPIC'
 131             setenv WM_LDFLAGS '-m64'
 132             breaksw
 133         default:
 134             echo Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64
 135             breaksw
 136         endsw
 137         breaksw
 138     case ia64:
 139         setenv WM_ARCH linuxIA64
 140         setenv WM_COMPILER I64
 141         breaksw
 142     default:
 143         echo Unknown processor type `uname -m` for Linux
 144         breaksw
 145     endsw
 146     breaksw
 147
 148 default:
 149     echo
 150     echo "Your '$WM_ARCH' operating system is not supported by this release"
 151     echo "of OpenFOAM. For further assistance, please contact www.openfoam.org"
 152     echo
 153     breaksw
 154
 155 endsw
 156
 157
 158 # Clean standard environment variables (path, PATH, MANPATH, LD_LIBRARY_PATH)
 159 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 160 set cleanProg=$WM_PROJECT_DIR/bin/foamCleanPath
 161
 162 if (! $?LD_LIBRARY_PATH ) then
 163     setenv LD_LIBRARY_PATH ''
 164 endif
 165 if (! $?MANPATH) then
 166     setenv MANPATH ''
 167 endif
 168
 169 # Remove anything under top-level foam directory
 170 set wildCards="$FOAM_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
 171
 172 #- Clean path/PATH
 173 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 174 set PATH=`$cleanProg "$colonPath" "$wildCards"`
 175 if ( $status == 0 ) then
 176     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 177 endif
 178
 179 #- Clean LD_LIBRARY_PATH
 180 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH" "$wildCards"`
 181
 182 #- Clean MANPATH
 183 setenv MANPATH `$cleanProg "$MANPATH" "$wildCards"`
 184
 185
 186 # Source project setup files
 187 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 188 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Executing: \!*"; source \!*'
 189
 190 _foamSource $WM_PROJECT_DIR/etc/settings.csh
 191 _foamSource $WM_PROJECT_DIR/etc/aliases.csh
 192
 193 # Source user setup files for optional packages
 194 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 195 # _foamSource $WM_PROJECT_DIR/etc/apps/paraview/cshrc
 196 _foamSource $WM_PROJECT_DIR/etc/apps/paraview3/cshrc
 197 # _foamSource $WM_PROJECT_DIR/etc/apps/ensightFoam/cshrc
 198
 199
 200 # Again clean environment (path, PATH, MANPATH, LD_LIBRARY_PATH)
 201 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 202 #- Clean path/PATH. Only remove duplicates
 203 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 204 set PATH=`$cleanProg "$colonPath"`
 205 if ( $status == 0 ) then
 206     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 207 endif
 208
 209 #- Clean LD_LIBRARY_PATH
 210 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH"`
 211
 212 #- Clean MANPATH
 213 setenv MANPATH `$cleanProg "$MANPATH"`
 214
 215 #- Clean LD_PRELOAD
 216 if ( $?LD_PRELOAD ) then
 217     setenv LD_PRELOAD `$cleanProg "$LD_PRELOAD"`
 218 endif
 219
 220 # cleanup environment:
 221 # ~~~~~~~~~~~~~~~~~~~~
 222 unalias _foamSource
 223 # -----------------------------------------------------------------------------