etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 1991-2008 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/cshrc
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from ~/.login or ~/.cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 setenv WM_PROJECT OpenFOAM
  35 setenv WM_PROJECT_VERSION 1.5.x
  36
  37 #!!User:
  38 #    either setenv FOAM_INST_DIR before sourcing this file or set
  39 #    foamInstall below to where OpenFOAM is installed
  40 #
  41 # Location of FOAM installation
  42 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  43 set foamInstall = $HOME/$WM_PROJECT
  44 # set foamInstall = ~$WM_PROJECT
  45 # set foamInstall = /usr/local/$WM_PROJECT
  46 # set foamInstall = /opt/$WM_PROJECT
  47
  48 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  49
  50
  51 # Location of site/user files
  52 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  53 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
  54 setenv WM_PROJECT_DIR $WM_PROJECT_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
  55 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
  56
  57
  58 # Location of third-party software
  59 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  60 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty
  61
  62
  63 # Operating System/Platform
  64 # ~~~~~~~~~~~~~~~~~~~~~~~~~
  65 # WM_OS = Unix | ????
  66 if ( ! $?WM_OS ) setenv WM_OS Unix
  67
  68
  69 # Compiler: set to Gcc, Gcc42 or Icc (for Intel's icc)
  70 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  71 if ( ! $?WM_COMPILER ) setenv WM_COMPILER Gcc
  72
  73 setenv WM_COMPILER_ARCH
  74 setenv WM_COMPILER_LIB_ARCH
  75
  76
  77 # Compilation options (architecture, precision, optimised, debug or profiling)
  78 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  79 # WM_ARCH_OPTION = 32 | 64
  80 if ( ! $?WM_ARCH_OPTION ) setenv WM_ARCH_OPTION 64
  81
  82 # WM_PRECISION_OPTION = DP | SP
  83 if ( ! $?WM_PRECISION_OPTION ) setenv WM_PRECISION_OPTION DP
  84
  85 # WM_COMPILE_OPTION = Opt | Debug | Prof
  86 if ( ! $?WM_COMPILE_OPTION ) setenv WM_COMPILE_OPTION Opt
  87
  88 # WM_JAVAC_OPTION = Opt | Debug
  89 if ( ! $?WM_JAVAC_OPTION ) setenv WM_JAVAC_OPTION Opt
  90
  91 # WM_MPLIB = | OPENMPI | LAM | MPICH | MPICH-GM | HPMPI | GAMMA | MPI | QSMPI
  92 if ( ! $?WM_MPLIB ) setenv WM_MPLIB OPENMPI
  93
  94
  95 # Run options (floating-point signal handling and memory initialisation)
  96 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  97 setenv FOAM_SIGFPE
  98 # setenv FOAM_SETNAN
  99
 100
 101 # Detect system type and set environment variables
 102 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 103 setenv WM_ARCH `uname -s`
 104
 105 switch ($WM_ARCH)
 106 case Linux:
 107     setenv WM_ARCH linux
 108
 109     switch (`uname -m`)
 110     case i686:
 111         breaksw
 112
 113     case x86_64:
 114         switch ($WM_ARCH_OPTION)
 115         case 32:
 116             setenv WM_ARCH linux
 117             setenv WM_COMPILER_ARCH '-64'
 118             setenv WM_CC 'gcc'
 119             setenv WM_CXX 'g++'
 120             setenv WM_CFLAGS '-m32 -fPIC'
 121             setenv WM_CXXFLAGS '-m32 -fPIC'
 122             setenv WM_LDFLAGS '-m32'
 123             breaksw
 124
 125         case 64:
 126             setenv WM_ARCH linux64
 127             setenv WM_COMPILER_LIB_ARCH 64
 128             setenv WM_CC 'gcc'
 129             setenv WM_CXX 'g++'
 130             setenv WM_CFLAGS '-m64 -fPIC'
 131             setenv WM_CXXFLAGS '-m64 -fPIC'
 132             setenv WM_LDFLAGS '-m64'
 133             breaksw
 134
 135         default:
 136             echo Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64
 137             breaksw
 138
 139         endsw
 140         breaksw
 141
 142     case ia64:
 143         setenv WM_ARCH linuxIA64
 144         setenv WM_COMPILER I64
 145         breaksw
 146
 147     case mips64:
 148         setenv WM_ARCH SiCortex64
 149         setenv WM_COMPILER_LIB_ARCH 64
 150         setenv WM_CC 'gcc'
 151         setenv WM_CXX 'g++'
 152         setenv WM_CFLAGS '-mabi=64 -fPIC'
 153         setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 154         setenv WM_LDFLAGS '-mabi=64 -G0'
 155         setenv WM_MPLIB MPI
 156         breaksw
 157
 158     case ppc64:
 159         setenv WM_ARCH linuxPPC64
 160         setenv WM_COMPILER_LIB_ARCH 64
 161         setenv WM_CC 'gcc'
 162         setenv WM_CXX 'g++'
 163         setenv WM_CFLAGS '-m64 -fPIC'
 164         setenv WM_CXXFLAGS '-m64 -fPIC'
 165         setenv WM_LDFLAGS '-m64'
 166         breaksw
 167
 168     default:
 169         echo Unknown processor type `uname -m` for Linux
 170         breaksw
 171
 172     endsw
 173     breaksw
 174
 175 case SunOS:
 176     setenv WM_ARCH SunOS64
 177     setenv WM_COMPILER_LIB_ARCH 64
 178     setenv WM_CC 'gcc'
 179     setenv WM_CXX 'g++'
 180     setenv WM_CFLAGS '-mabi=64 -fPIC'
 181     setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 182     setenv WM_LDFLAGS '-mabi=64 -G0'
 183     setenv WM_MPLIB FJMPI
 184     breaksw
 185
 186 default:
 187     echo
 188     echo "Your '$WM_ARCH' operating system is not supported by this release"
 189     echo "of OpenFOAM. For further assistance, please contact www.openfoam.org"
 190     echo
 191     breaksw
 192
 193 endsw
 194
 195
 196 # Clean standard environment variables (path, PATH, MANPATH, LD_LIBRARY_PATH)
 197 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 198 set cleanProg=$WM_PROJECT_DIR/bin/foamCleanPath
 199
 200 if (! $?LD_LIBRARY_PATH ) then
 201     setenv LD_LIBRARY_PATH ''
 202 endif
 203 if (! $?MANPATH) then
 204     setenv MANPATH ''
 205 endif
 206
 207 # Remove anything under top-level foam directory
 208 set wildCards="$WM_PROJECT_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
 209
 210 #- Clean path/PATH
 211 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 212 set PATH=`$cleanProg "$colonPath" "$wildCards"`
 213 if ( $status == 0 ) then
 214     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 215 endif
 216
 217 #- Clean LD_LIBRARY_PATH
 218 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH" "$wildCards"`
 219
 220 #- Clean MANPATH
 221 setenv MANPATH `$cleanProg "$MANPATH" "$wildCards"`
 222
 223
 224 # Source project setup files
 225 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 226 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Executing: \!*"; source \!*'
 227
 228 _foamSource $WM_PROJECT_DIR/etc/settings.csh
 229 _foamSource $WM_PROJECT_DIR/etc/aliases.csh
 230
 231 # Source user setup files for optional packages
 232 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 233 # _foamSource $WM_PROJECT_DIR/etc/apps/paraview/cshrc
 234 _foamSource $WM_PROJECT_DIR/etc/apps/paraview3/cshrc
 235 # _foamSource $WM_PROJECT_DIR/etc/apps/ensightFoam/cshrc
 236 _foamSource $WM_PROJECT_DIR/etc/apps/cint/cshrc
 237
 238
 239 # Again clean environment (path, PATH, MANPATH, LD_LIBRARY_PATH)
 240 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 241 #- Clean path/PATH. Only remove duplicates
 242 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 243 set PATH=`$cleanProg "$colonPath"`
 244 if ( $status == 0 ) then
 245     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 246 endif
 247
 248 #- Clean LD_LIBRARY_PATH
 249 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH"`
 250
 251 #- Clean MANPATH
 252 setenv MANPATH `$cleanProg "$MANPATH"`:
 253
 254 #- Clean LD_PRELOAD
 255 if ( $?LD_PRELOAD ) then
 256     setenv LD_PRELOAD `$cleanProg "$LD_PRELOAD"`
 257 endif
 258
 259 # cleanup environment:
 260 # ~~~~~~~~~~~~~~~~~~~~
 261 unset cleanProg
 262 unset wildCards
 263 unset colonPath
 264 unalias _foamSource
 265
 266 # -----------------------------------------------------------------------------